git.oblomov.eu Git - ikiwiki/blob - ikiwiki-calendar.in

   1 #!/usr/bin/perl
   2 use warnings;
   3 use strict;
   4 use lib '.'; # For use in nonstandard directory, munged by Makefile.
   5 use IkiWiki;
   6 use IkiWiki::Setup;
   7 use Getopt::Long;
   8
   9 sub usage () {
  10         die gettext("usage: ikiwiki-calendar [-f] your.setup [pagespec] [year]"), "\n";
  11 }
  12
  13 my $force=0;
  14 GetOptions(
  15         "force" => \$force,
  16 ) || usage();
  17 my $setup=shift         || usage();
  18 my $pagespec=shift;
  19 my $startyear=shift     || 1900+(localtime(time))[5];
  20 my $endyear=shift       || $startyear;
  21
  22 %config=IkiWiki::defaultconfig();
  23 IkiWiki::Setup::load($setup);
  24 IkiWiki::loadplugins();
  25 IkiWiki::checkconfig();
  26
  27 my $archivebase = 'archives';
  28 $archivebase = $config{archivebase} if defined $config{archivebase};
  29
  30 if (! defined $pagespec) {
  31         $pagespec=$config{archive_pagespec} || "*";
  32 }
  33
  34 sub writearchive ($$;$) {
  35         my $template=template(shift);
  36         my $year=shift;
  37         my $month=shift;
  38
  39         my $page=defined $month ? "$year/$month" : $year;
  40
  41         my $pagefile=newpagefile("$archivebase/$page", $config{default_pageext});
  42         $template->param(pagespec => $pagespec);
  43         $template->param(year => $year);
  44         $template->param(month => $month) if defined $month;
  45
  46         if ($force || ! -e "$config{srcdir}/$pagefile") {
  47                 writefile($pagefile, $config{srcdir}, $template->output);
  48                 IkiWiki::rcs_add($pagefile) if $config{rcs};
  49         }
  50 }
  51
  52 foreach my $y ($startyear..$endyear) {
  53         writearchive("calendaryear.tmpl", $y);
  54         foreach my $m (qw{01 02 03 04 05 06 07 08 09 10 11 12}) {
  55                 writearchive("calendarmonth.tmpl", $y, $m);
  56         }
  57 }
  58
  59 IkiWiki::rcs_commit_staged(gettext("calendar update"), undef, undef)
  60         if $config{rcs};
  61
  62 exec("ikiwiki", "-setup", $setup, "-refresh");
  63 die "failed to run ikiwiki -setup $setup -refresh\n";