git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/table.pm

   1 package IkiWiki::Plugin::table;
   2 # by Victor Moral <victor@taquiones.net>
   3
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use IkiWiki 2.00;
   8
   9 sub import { #{{{
  10         hook(type => "getsetup", id => "table", call => \&getsetup);
  11         hook(type => "preprocess", id => "table", call => \&preprocess);
  12 } # }}}
  13
  14 sub getsetup () { #{{{
  15         return
  16                 plugin => {
  17                         safe => 1,
  18                         rebuild => undef,
  19                 },
  20 } #}}}
  21
  22 sub preprocess (@) { #{{{
  23         my %params =(
  24                 format  => 'auto',
  25                 header  => 'yes',
  26                 @_
  27         );
  28
  29         if (exists $params{file}) {
  30                 if (! $pagesources{$params{file}}) {
  31                         error gettext("cannot find file");
  32                 }
  33                 $params{data} = readfile(srcfile($params{file}));
  34                 add_depends($params{page}, $params{file});
  35         }
  36
  37         if (lc $params{format} eq 'auto') {
  38                 # first try the more simple format
  39                 if (is_dsv_data($params{data})) {
  40                         $params{format} = 'dsv';
  41                 }
  42                 else {
  43                         $params{format} = 'csv';
  44                 }
  45         }
  46
  47         my @data;
  48         if (lc $params{format} eq 'csv') {
  49                 @data=split_csv($params{data},
  50                         defined $params{delimiter} ? $params{delimiter} : ",",);
  51                 # linkify after parsing since html link quoting can
  52                 # confuse CSV parsing
  53                 if (! exists $params{file}) {
  54                         @data=map {
  55                                 [ map {
  56                                         IkiWiki::linkify($params{page},
  57                                                 $params{destpage}, $_);
  58                                 } @$_ ]
  59                         } @data;
  60                 }
  61         }
  62         elsif (lc $params{format} eq 'dsv') {
  63                 # linkify before parsing since wikilinks can contain the
  64                 # delimiter
  65                 if (! exists $params{file}) {
  66                         $params{data} = IkiWiki::linkify($params{page},
  67                                 $params{destpage}, $params{data});
  68                 }
  69                 @data=split_dsv($params{data},
  70                         defined $params{delimiter} ? $params{delimiter} : "|",);
  71         }
  72         else {
  73                 error gettext("unknown data format");
  74         }
  75
  76         my $header;
  77         if (lc($params{header}) eq "yes") {
  78                 $header=shift @data;
  79         }
  80         if (! @data) {
  81                 error gettext("empty data");
  82         }
  83
  84         my @lines;
  85         push @lines, defined $params{class}
  86                         ? "<table class=\"".$params{class}.'">'
  87                         : '<table>';
  88         push @lines, "\t<thead>",
  89                 genrow($params{page}, $params{destpage}, "th", @$header),
  90                 "\t</thead>" if defined $header;
  91         push @lines, "\t<tbody>" if defined $header;
  92         push @lines, genrow($params{page}, $params{destpage}, "td", @$_)
  93                 foreach @data;
  94         push @lines, "\t</tbody>" if defined $header;
  95         push @lines, '</table>';
  96         my $html = join("\n", @lines);
  97
  98         if (exists $params{file}) {
  99                 return $html."\n\n".
 100                         htmllink($params{page}, $params{destpage}, $params{file},
 101                                 linktext => gettext('Direct data download'));
 102         }
 103         else {
 104                 return $html;
 105         }
 106 } #}}}
 107
 108 sub is_dsv_data ($) { #{{{
 109         my $text = shift;
 110
 111         my ($line) = split(/\n/, $text);
 112         return $line =~ m{.+\|};
 113 }
 114
 115 sub split_csv ($$) { #{{{
 116         my @text_lines = split(/\n/, shift);
 117         my $delimiter = shift;
 118
 119         eval q{use Text::CSV};
 120         error($@) if $@;
 121         my $csv = Text::CSV->new({
 122                 sep_char        => $delimiter,
 123                 binary          => 1,
 124                 allow_loose_quotes => 1,
 125         }) || error("could not create a Text::CSV object");
 126
 127         my $l=0;
 128         my @data;
 129         foreach my $line (@text_lines) {
 130                 $l++;
 131                 if ($csv->parse($line)) {
 132                         push(@data, [ map { decode_utf8 $_ } $csv->fields() ]);
 133                 }
 134                 else {
 135                         debug(sprintf(gettext('parse fail at line %d: %s'),
 136                                 $l, $csv->error_input()));
 137                 }
 138         }
 139
 140         return @data;
 141 } #}}}
 142
 143 sub split_dsv ($$) { #{{{
 144         my @text_lines = split(/\n/, shift);
 145         my $delimiter = shift;
 146         $delimiter="|" unless defined $delimiter;
 147
 148         my @data;
 149         foreach my $line (@text_lines) {
 150                 push @data, [ split(/\Q$delimiter\E/, $line, -1) ];
 151         }
 152
 153         return @data;
 154 } #}}}
 155
 156 sub genrow ($$$@) { #{{{
 157         my $page = shift;
 158         my $destpage = shift;
 159         my $elt = shift;
 160         my @data = @_;
 161
 162         my @ret;
 163         push @ret, "\t\t<tr>";
 164         for (my $x=0; $x < @data; $x++) {
 165                 my $cell=htmlize($page, $destpage, $data[$x]);
 166                 my $colspan=1;
 167                 while ($x+1 < @data && $data[$x+1] eq '') {
 168                         $x++;
 169                         $colspan++;
 170                 }
 171                 if ($colspan > 1) {
 172                         push @ret, "\t\t\t<$elt colspan=\"$colspan\">$cell</$elt>"
 173                 }
 174                 else {
 175                         push @ret, "\t\t\t<$elt>$cell</$elt>"
 176                 }
 177         }
 178         push @ret, "\t\t</tr>";
 179
 180         return @ret;
 181 } #}}}
 182
 183 sub htmlize ($$$) { #{{{
 184         my $page = shift;
 185         my $destpage = shift;
 186
 187         return IkiWiki::htmlize($page, $destpage, pagetype($pagesources{$page}),
 188                 IkiWiki::preprocess($page, $destpage, shift));
 189 }
 190
 191 1