git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/meta.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki metadata plugin.
   3 package IkiWiki::Plugin::meta;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8
   9 my %metaheaders;
  10
  11 sub import {
  12         hook(type => "getsetup", id => "meta", call => \&getsetup);
  13         hook(type => "needsbuild", id => "meta", call => \&needsbuild);
  14         hook(type => "preprocess", id => "meta", call => \&preprocess, scan => 1);
  15         hook(type => "pagetemplate", id => "meta", call => \&pagetemplate);
  16 }
  17
  18 sub getsetup () {
  19         return
  20                 plugin => {
  21                         safe => 1,
  22                         rebuild => undef,
  23                         section => "core",
  24                 },
  25 }
  26
  27 sub needsbuild (@) {
  28         my $needsbuild=shift;
  29         foreach my $page (keys %pagestate) {
  30                 if (exists $pagestate{$page}{meta}) {
  31                         if (exists $pagesources{$page} &&
  32                             grep { $_ eq $pagesources{$page} } @$needsbuild) {
  33                                 # remove state, it will be re-added
  34                                 # if the preprocessor directive is still
  35                                 # there during the rebuild
  36                                 delete $pagestate{$page}{meta};
  37                         }
  38                 }
  39         }
  40         return $needsbuild;
  41 }
  42
  43 sub scrub ($$$) {
  44         if (IkiWiki::Plugin::htmlscrubber->can("sanitize")) {
  45                 return IkiWiki::Plugin::htmlscrubber::sanitize(
  46                         content => shift, page => shift, destpage => shift);
  47         }
  48         else {
  49                 return shift;
  50         }
  51 }
  52
  53 sub safeurl ($) {
  54         my $url=shift;
  55         if (exists $IkiWiki::Plugin::htmlscrubber::{safe_url_regexp} &&
  56             defined $IkiWiki::Plugin::htmlscrubber::safe_url_regexp) {
  57                 return $url=~/$IkiWiki::Plugin::htmlscrubber::safe_url_regexp/;
  58         }
  59         else {
  60                 return 1;
  61         }
  62 }
  63
  64 sub htmlize ($$$) {
  65         my $page = shift;
  66         my $destpage = shift;
  67
  68         return IkiWiki::htmlize($page, $destpage, pagetype($pagesources{$page}),
  69                 IkiWiki::linkify($page, $destpage,
  70                 IkiWiki::preprocess($page, $destpage, shift)));
  71 }
  72
  73 sub preprocess (@) {
  74         return "" unless @_;
  75         my %params=@_;
  76         my $key=shift;
  77         my $value=$params{$key};
  78         delete $params{$key};
  79         my $page=$params{page};
  80         delete $params{page};
  81         my $destpage=$params{destpage};
  82         delete $params{destpage};
  83         delete $params{preview};
  84
  85         eval q{use HTML::Entities};
  86         # Always decode, even if encoding later, since it might not be
  87         # fully encoded.
  88         $value=decode_entities($value);
  89
  90         # Metadata collection that needs to happen during the scan pass.
  91         if ($key eq 'title') {
  92                 $pagestate{$page}{meta}{title}=$value;
  93                 if (exists $params{sortas}) {
  94                         $pagestate{$page}{meta}{titlesort}=$params{sortas};
  95                 }
  96                 else {
  97                         delete $pagestate{$page}{meta}{titlesort};
  98                 }
  99                 return "";
 100         }
 101         elsif ($key eq 'description') {
 102                 $pagestate{$page}{meta}{description}=$value;
 103                 # fallthrough
 104         }
 105         elsif ($key eq 'guid') {
 106                 $pagestate{$page}{meta}{guid}=$value;
 107                 # fallthrough
 108         }
 109         elsif ($key eq 'license') {
 110                 push @{$metaheaders{$page}}, '<link rel="license" href="#page_license" />';
 111                 $pagestate{$page}{meta}{license}=$value;
 112                 return "";
 113         }
 114         elsif ($key eq 'copyright') {
 115                 push @{$metaheaders{$page}}, '<link rel="copyright" href="#page_copyright" />';
 116                 $pagestate{$page}{meta}{copyright}=$value;
 117                 return "";
 118         }
 119         elsif ($key eq 'link' && ! %params) {
 120                 # hidden WikiLink
 121                 add_link($page, $value);
 122                 return "";
 123         }
 124         elsif ($key eq 'author') {
 125                 $pagestate{$page}{meta}{author}=$value;
 126                 if (exists $params{sortas}) {
 127                         $pagestate{$page}{meta}{authorsort}=$params{sortas};
 128                 }
 129                 else {
 130                         delete $pagestate{$page}{meta}{authorsort};
 131                 }
 132                 # fallthorough
 133         }
 134         elsif ($key eq 'authorurl') {
 135                 $pagestate{$page}{meta}{authorurl}=$value if safeurl($value);
 136                 # fallthrough
 137         }
 138         elsif ($key eq 'permalink') {
 139                 $pagestate{$page}{meta}{permalink}=$value if safeurl($value);
 140                 # fallthrough
 141         }
 142         elsif ($key eq 'date') {
 143                 eval q{use Date::Parse};
 144                 if (! $@) {
 145                         my $time = str2time($value);
 146                         $IkiWiki::pagectime{$page}=$time if defined $time;
 147                 }
 148         }
 149         elsif ($key eq 'updated') {
 150                 eval q{use Date::Parse};
 151                 if (! $@) {
 152                         my $time = str2time($value);
 153                         $pagestate{$page}{meta}{updated}=$time if defined $time;
 154                 }
 155         }
 156
 157         if (! defined wantarray) {
 158                 # avoid collecting duplicate data during scan pass
 159                 return;
 160         }
 161
 162         # Metadata handling that happens only during preprocessing pass.
 163         if ($key eq 'permalink') {
 164                 if (safeurl($value)) {
 165                         push @{$metaheaders{$page}}, scrub('<link rel="bookmark" href="'.encode_entities($value).'" />', $page, $destpage);
 166                 }
 167         }
 168         elsif ($key eq 'stylesheet') {
 169                 my $rel=exists $params{rel} ? $params{rel} : "alternate stylesheet";
 170                 my $title=exists $params{title} ? $params{title} : $value;
 171                 # adding .css to the value prevents using any old web
 172                 # editable page as a stylesheet
 173                 my $stylesheet=bestlink($page, $value.".css");
 174                 if (! length $stylesheet) {
 175                         error gettext("stylesheet not found")
 176                 }
 177                 push @{$metaheaders{$page}}, scrub('<link href="'.urlto($stylesheet, $page).
 178                         '" rel="'.encode_entities($rel).
 179                         '" title="'.encode_entities($title).
 180                         "\" type=\"text/css\" />", $page, $destpage);
 181         }
 182         elsif ($key eq 'script') {
 183                 my $defer=exists $params{defer} ? ' defer="defer"' : '';
 184                 my $async=exists $params{async} ? ' async="async"' : '';
 185                 my $js=bestlink($page, $value.".js");
 186                 if (! length $js) {
 187                         error gettext("script not found");
 188                 }
 189                 push @{$metaheaders{$page}}, scrub('<script src="'.urlto($js, $page).
 190                         '"' . $defer . $async . ' type="text/javascript" />',
 191                         $page, $destpage);
 192         }
 193         elsif ($key eq 'openid') {
 194                 my $delegate=0; # both by default
 195                 if (exists $params{delegate}) {
 196                         $delegate = 1 if lc $params{delegate} eq 'openid';
 197                         $delegate = 2 if lc $params{delegate} eq 'openid2';
 198                 }
 199                 if (exists $params{server} && safeurl($params{server})) {
 200                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($params{server}).
 201                                 '" rel="openid.server" />' if $delegate ne 2;
 202                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($params{server}).
 203                                 '" rel="openid2.provider" />' if $delegate ne 1;
 204                 }
 205                 if (safeurl($value)) {
 206                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($value).
 207                                 '" rel="openid.delegate" />' if $delegate ne 2;
 208                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($value).
 209                                 '" rel="openid2.local_id" />' if $delegate ne 1;
 210                 }
 211                 if (exists $params{"xrds-location"} && safeurl($params{"xrds-location"})) {
 212                         # force url absolute
 213                         eval q{use URI};
 214                         error($@) if $@;
 215                         my $url=URI->new_abs($params{"xrds-location"}, $config{url});
 216                         push @{$metaheaders{$page}}, '<meta http-equiv="X-XRDS-Location" '.
 217                                 'content="'.encode_entities($url).'" />';
 218                 }
 219         }
 220         elsif ($key eq 'redir') {
 221                 return "" if $page ne $destpage;
 222                 my $safe=0;
 223                 if ($value !~ /^\w+:\/\//) {
 224                         my ($redir_page, $redir_anchor) = split /\#/, $value;
 225
 226                         my $link=bestlink($page, $redir_page);
 227                         if (! length $link) {
 228                                 error gettext("redir page not found")
 229                         }
 230                         add_depends($page, $link, deptype("presence"));
 231
 232                         $value=urlto($link, $page);
 233                         $value.='#'.$redir_anchor if defined $redir_anchor;
 234                         $safe=1;
 235
 236                         # redir cycle detection
 237                         $pagestate{$page}{meta}{redir}=$link;
 238                         my $at=$page;
 239                         my %seen;
 240                         while (exists $pagestate{$at}{meta}{redir}) {
 241                                 if ($seen{$at}) {
 242                                         error gettext("redir cycle is not allowed")
 243                                 }
 244                                 $seen{$at}=1;
 245                                 $at=$pagestate{$at}{meta}{redir};
 246                         }
 247                 }
 248                 else {
 249                         $value=encode_entities($value);
 250                 }
 251                 my $delay=int(exists $params{delay} ? $params{delay} : 0);
 252                 my $redir="<meta http-equiv=\"refresh\" content=\"$delay; URL=$value\" />";
 253                 if (! $safe) {
 254                         $redir=scrub($redir, $page, $destpage);
 255                 }
 256                 push @{$metaheaders{$page}}, $redir;
 257         }
 258         elsif ($key eq 'link') {
 259                 if (%params) {
 260                         push @{$metaheaders{$page}}, scrub("<link href=\"".encode_entities($value)."\" ".
 261                                 join(" ", map {
 262                                         encode_entities($_)."=\"".encode_entities(decode_entities($params{$_}))."\""
 263                                 } keys %params).
 264                                 " />\n", $page, $destpage);
 265                 }
 266         }
 267         elsif ($key eq 'robots') {
 268                 push @{$metaheaders{$page}}, '<meta name="robots"'.
 269                         ' content="'.encode_entities($value).'" />';
 270         }
 271         elsif ($key eq 'description') {
 272                 push @{$metaheaders{$page}}, '<meta name="'.
 273                         encode_entities($key).
 274                         '" content="'.encode_entities($value).'" />';
 275         }
 276         elsif ($key eq 'name') {
 277                 push @{$metaheaders{$page}}, scrub('<meta '.$key.'="'.
 278                         encode_entities($value).
 279                         join(' ', map { "$_=\"$params{$_}\"" } keys %params).
 280                         ' />', $page, $destpage);
 281         }
 282         else {
 283                 push @{$metaheaders{$page}}, scrub('<meta name="'.
 284                         encode_entities($key).'" content="'.
 285                         encode_entities($value).'" />', $page, $destpage);
 286         }
 287
 288         return "";
 289 }
 290
 291 sub pagetemplate (@) {
 292         my %params=@_;
 293         my $page=$params{page};
 294         my $destpage=$params{destpage};
 295         my $template=$params{template};
 296
 297         if (exists $metaheaders{$page} && $template->query(name => "meta")) {
 298                 # avoid duplicate meta lines
 299                 my %seen;
 300                 $template->param(meta => join("\n", grep { (! $seen{$_}) && ($seen{$_}=1) } @{$metaheaders{$page}}));
 301         }
 302         if (exists $pagestate{$page}{meta}{title} && $template->query(name => "title")) {
 303                 $template->param(title => HTML::Entities::encode_numeric($pagestate{$page}{meta}{title}));
 304                 $template->param(title_overridden => 1);
 305         }
 306
 307         foreach my $field (qw{author authorurl permalink}) {
 308                 $template->param($field => $pagestate{$page}{meta}{$field})
 309                         if exists $pagestate{$page}{meta}{$field} && $template->query(name => $field);
 310         }
 311
 312         foreach my $field (qw{permalink}) {
 313                 $template->param($field => IkiWiki::urlabs($pagestate{$page}{meta}{$field}, $config{url}))
 314                         if exists $pagestate{$page}{meta}{$field} && $template->query(name => $field);
 315         }
 316
 317         foreach my $field (qw{description}) {
 318                 $template->param($field => HTML::Entities::encode_numeric($pagestate{$page}{meta}{$field}))
 319                         if exists $pagestate{$page}{meta}{$field} && $template->query(name => $field);
 320         }
 321
 322         foreach my $field (qw{license copyright}) {
 323                 if (exists $pagestate{$page}{meta}{$field} && $template->query(name => $field) &&
 324                     ($page eq $destpage || ! exists $pagestate{$destpage}{meta}{$field} ||
 325                      $pagestate{$page}{meta}{$field} ne $pagestate{$destpage}{meta}{$field})) {
 326                         $template->param($field => htmlize($page, $destpage, $pagestate{$page}{meta}{$field}));
 327                 }
 328         }
 329 }
 330
 331 sub get_sort_key {
 332         my $page = shift;
 333         my $meta = shift;
 334
 335         # e.g. titlesort (also makes sense for author)
 336         my $key = $pagestate{$page}{meta}{$meta . "sort"};
 337         return $key if defined $key;
 338
 339         # e.g. title
 340         $key = $pagestate{$page}{meta}{$meta};
 341         return $key if defined $key;
 342
 343         # fall back to closer-to-core things
 344         if ($meta eq 'title') {
 345                 return pagetitle(IkiWiki::basename($page));
 346         }
 347         elsif ($meta eq 'date') {
 348                 return $IkiWiki::pagectime{$page};
 349         }
 350         elsif ($meta eq 'updated') {
 351                 return $IkiWiki::pagemtime{$page};
 352         }
 353         else {
 354                 return '';
 355         }
 356 }
 357
 358 sub match {
 359         my $field=shift;
 360         my $page=shift;
 361
 362         # turn glob into a safe regexp
 363         my $re=IkiWiki::glob2re(shift);
 364
 365         my $val;
 366         if (exists $pagestate{$page}{meta}{$field}) {
 367                 $val=$pagestate{$page}{meta}{$field};
 368         }
 369         elsif ($field eq 'title') {
 370                 $val = pagetitle($page);
 371         }
 372
 373         if (defined $val) {
 374                 if ($val=~$re) {
 375                         return IkiWiki::SuccessReason->new("$re matches $field of $page", $page => $IkiWiki::DEPEND_CONTENT, "" => 1);
 376                 }
 377                 else {
 378                         return IkiWiki::FailReason->new("$re does not match $field of $page", $page => $IkiWiki::DEPEND_CONTENT, "" => 1);
 379                 }
 380         }
 381         else {
 382                 return IkiWiki::FailReason->new("$page does not have a $field", $page => $IkiWiki::DEPEND_CONTENT);
 383         }
 384 }
 385
 386 package IkiWiki::PageSpec;
 387
 388 sub match_title ($$;@) {
 389         IkiWiki::Plugin::meta::match("title", @_);
 390 }
 391
 392 sub match_author ($$;@) {
 393         IkiWiki::Plugin::meta::match("author", @_);
 394 }
 395
 396 sub match_authorurl ($$;@) {
 397         IkiWiki::Plugin::meta::match("authorurl", @_);
 398 }
 399
 400 sub match_license ($$;@) {
 401         IkiWiki::Plugin::meta::match("license", @_);
 402 }
 403
 404 sub match_copyright ($$;@) {
 405         IkiWiki::Plugin::meta::match("copyright", @_);
 406 }
 407
 408 sub match_guid ($$;@) {
 409         IkiWiki::Plugin::meta::match("guid", @_);
 410 }
 411
 412 package IkiWiki::SortSpec;
 413
 414 sub cmp_meta {
 415         my $meta = shift;
 416         error(gettext("sort=meta requires a parameter")) unless defined $meta;
 417
 418         if ($meta eq 'updated' || $meta eq 'date') {
 419                 return IkiWiki::Plugin::meta::get_sort_key($a, $meta)
 420                         <=>
 421                         IkiWiki::Plugin::meta::get_sort_key($b, $meta);
 422         }
 423
 424         return IkiWiki::Plugin::meta::get_sort_key($a, $meta)
 425                 cmp
 426                 IkiWiki::Plugin::meta::get_sort_key($b, $meta);
 427 }
 428
 429 # A prototype of how sort=title could behave in 4.0 or something
 430 sub cmp_meta_title {
 431         $_[0] = 'title';
 432         return cmp_meta(@_);
 433 }
 434
 435 1