git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 2.00;
  12 use Encode;
  13 use Locale::Po4a::Chooser;
  14 use Locale::Po4a::Po;
  15 use File::Basename;
  16 use File::Copy;
  17 use File::Spec;
  18 use File::Temp;
  19 use Memoize;
  20 use UNIVERSAL;
  21
  22 my %translations;
  23 my @origneedsbuild;
  24 my %origsubs;
  25
  26 memoize("_istranslation");
  27 memoize("percenttranslated");
  28
  29 sub import { #{{{
  30         hook(type => "getsetup", id => "po", call => \&getsetup);
  31         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  32         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  33         hook(type => "scan", id => "po", call => \&scan, last =>1);
  34         hook(type => "filter", id => "po", call => \&filter);
  35         hook(type => "htmlize", id => "po", call => \&htmlize);
  36         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  37         hook(type => "change", id => "po", call => \&change);
  38         hook(type => "editcontent", id => "po", call => \&editcontent);
  39
  40         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  41         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  42         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  43         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  44         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  45         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  46         $origsubs{'urlto'}=\&IkiWiki::urlto;
  47         inject(name => "IkiWiki::urlto", call => \&myurlto);
  48 } #}}}
  49
  50
  51 # ,----
  52 # | Table of contents
  53 # `----
  54
  55 # 1. Hooks
  56 # 2. Injected functions
  57 # 3. Blackboxes for private data
  58 # 4. Helper functions
  59 # 5. PageSpec's
  60
  61
  62 # ,----
  63 # | Hooks
  64 # `----
  65
  66 sub getsetup () { #{{{
  67         return
  68                 plugin => {
  69                         safe => 0,
  70                         rebuild => 1,
  71                 },
  72                 po_master_language => {
  73                         type => "string",
  74                         example => {
  75                                 'code' => 'en',
  76                                 'name' => 'English'
  77                         },
  78                         description => "master language (non-PO files)",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 po_slave_languages => {
  83                         type => "string",
  84                         example => {
  85                                 'fr' => 'Français',
  86                                 'es' => 'Castellano',
  87                                 'de' => 'Deutsch'
  88                         },
  89                         description => "slave languages (PO files)",
  90                         safe => 1,
  91                         rebuild => 1,
  92                 },
  93                 po_translatable_pages => {
  94                         type => "pagespec",
  95                         example => "!*/Discussion",
  96                         description => "PageSpec controlling which pages are translatable",
  97                         link => "ikiwiki/PageSpec",
  98                         safe => 1,
  99                         rebuild => 1,
 100                 },
 101                 po_link_to => {
 102                         type => "string",
 103                         example => "current",
 104                         description => "internal linking behavior (default/current/negotiated)",
 105                         safe => 1,
 106                         rebuild => 1,
 107                 },
 108 } #}}}
 109
 110 sub checkconfig () { #{{{
 111         foreach my $field (qw{po_master_language po_slave_languages}) {
 112                 if (! exists $config{$field} || ! defined $config{$field}) {
 113                         error(sprintf(gettext("Must specify %s"), $field));
 114                 }
 115         }
 116         if (! (keys %{$config{po_slave_languages}})) {
 117                 error(gettext("At least one slave language must be defined in po_slave_languages"));
 118         }
 119         map {
 120                 islanguagecode($_)
 121                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 122         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 123         if (! exists $config{po_translatable_pages} ||
 124             ! defined $config{po_translatable_pages}) {
 125                 $config{po_translatable_pages}="";
 126         }
 127         if (! exists $config{po_link_to} ||
 128             ! defined $config{po_link_to}) {
 129                 $config{po_link_to}='default';
 130         }
 131         elsif (! grep {
 132                         $config{po_link_to} eq $_
 133                 } ('default', 'current', 'negotiated')) {
 134                 warn(sprintf(gettext('po_link_to=%s is not a valid setting, falling back to po_link_to=default'),
 135                                 $config{po_link_to}));
 136                 $config{po_link_to}='default';
 137         }
 138         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 139                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 140                 $config{po_link_to}='default';
 141         }
 142         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 143 } #}}}
 144
 145 sub needsbuild () { #{{{
 146         my $needsbuild=shift;
 147
 148         # backup @needsbuild content so that change() can know whether
 149         # a given master page was rendered because its source file was changed
 150         @origneedsbuild=(@$needsbuild);
 151
 152         buildtranslationscache();
 153
 154         # make existing translations depend on the corresponding master page
 155         foreach my $master (keys %translations) {
 156                 map add_depends($_, $master), values %{otherlanguages($master)};
 157         }
 158 } #}}}
 159
 160 # Massage the recorded state of internal links so that:
 161 # - it matches the actually generated links, rather than the links as written
 162 #   in the pages' source
 163 # - backlinks are consistent in all cases
 164 sub scan (@) { #{{{
 165         my %params=@_;
 166         my $page=$params{page};
 167         my $content=$params{content};
 168
 169         return unless UNIVERSAL::can("IkiWiki::Plugin::link", "import");
 170
 171         if (istranslation($page)) {
 172                 foreach my $destpage (@{$links{$page}}) {
 173                         if (istranslatable($destpage)) {
 174                                 # replace one occurence of $destpage in $links{$page}
 175                                 # (we only want to replace the one that was added by
 176                                 # IkiWiki::Plugin::link::scan, other occurences may be
 177                                 # there for other reasons)
 178                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 179                                         if (@{$links{$page}}[$i] eq $destpage) {
 180                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 181                                                 last;
 182                                         }
 183                                 }
 184                         }
 185                 }
 186         }
 187         elsif (! istranslatable($page) && ! istranslation($page)) {
 188                 foreach my $destpage (@{$links{$page}}) {
 189                         if (istranslatable($destpage)) {
 190                                 # make sure any destpage's translations has
 191                                 # $page in its backlinks
 192                                 push @{$links{$page}},
 193                                         values %{otherlanguages($destpage)};
 194                         }
 195                 }
 196         }
 197 } #}}}
 198
 199 # We use filter to convert PO to the master page's format,
 200 # since the rest of ikiwiki should not work on PO files.
 201 sub filter (@) { #{{{
 202         my %params = @_;
 203
 204         my $page = $params{page};
 205         my $destpage = $params{destpage};
 206         my $content = decode_utf8(encode_utf8($params{content}));
 207
 208         return $content if ( ! istranslation($page)
 209                              || alreadyfiltered($page, $destpage) );
 210
 211         # CRLF line terminators make poor Locale::Po4a feel bad
 212         $content=~s/\r\n/\n/g;
 213
 214         # Implementation notes
 215         #
 216         # 1. Locale::Po4a reads/writes from/to files, and I'm too lazy
 217         #    to learn how to disguise a variable as a file.
 218         # 2. There are incompatibilities between some File::Temp versions
 219         #    (including 0.18, bundled with Lenny's perl-modules package)
 220         #    and others (e.g. 0.20, previously present in the archive as
 221         #    a standalone package): under certain circumstances, some
 222         #    return a relative filename, whereas others return an absolute one;
 223         #    we here use this module in a way that is at least compatible
 224         #    with 0.18 and 0.20. Beware, hit'n'run refactorers!
 225         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
 226                                     DIR => File::Spec->tmpdir,
 227                                     UNLINK => 1)->filename;
 228         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
 229                                      DIR => File::Spec->tmpdir,
 230                                      UNLINK => 1)->filename;
 231
 232         writefile(basename($infile), File::Spec->tmpdir, $content);
 233
 234         my $masterfile = srcfile($pagesources{masterpage($page)});
 235         my (@pos,@masters);
 236         push @pos,$infile;
 237         push @masters,$masterfile;
 238         my %options = (
 239                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 240         );
 241         my $doc=Locale::Po4a::Chooser::new('text',%options);
 242         $doc->process(
 243                 'po_in_name'    => \@pos,
 244                 'file_in_name'  => \@masters,
 245                 'file_in_charset'  => 'utf-8',
 246                 'file_out_charset' => 'utf-8',
 247         ) or error("[po/filter:$page]: failed to translate");
 248         $doc->write($outfile) or error("[po/filter:$page] could not write $outfile");
 249         $content = readfile($outfile) or error("[po/filter:$page] could not read $outfile");
 250
 251         # Unlinking should happen automatically, thanks to File::Temp,
 252         # but it does not work here, probably because of the way writefile()
 253         # and Locale::Po4a::write() work.
 254         unlink $infile, $outfile;
 255
 256         setalreadyfiltered($page, $destpage);
 257         return $content;
 258 } #}}}
 259
 260 sub htmlize (@) { #{{{
 261         my %params=@_;
 262
 263         my $page = $params{page};
 264         my $content = $params{content};
 265
 266         # ignore PO files this plugin did not create
 267         return $content unless istranslation($page);
 268
 269         # force content to be htmlize'd as if it was the same type as the master page
 270         return IkiWiki::htmlize($page, $page,
 271                                 pagetype(srcfile($pagesources{masterpage($page)})),
 272                                 $content);
 273 } #}}}
 274
 275 sub pagetemplate (@) { #{{{
 276         my %params=@_;
 277         my $page=$params{page};
 278         my $destpage=$params{destpage};
 279         my $template=$params{template};
 280
 281         my ($masterpage, $lang) = istranslation($page);
 282
 283         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 284                 $template->param(percenttranslated => percenttranslated($page));
 285         }
 286         if ($template->query(name => "istranslation")) {
 287                 $template->param(istranslation => scalar istranslation($page));
 288         }
 289         if ($template->query(name => "istranslatable")) {
 290                 $template->param(istranslatable => istranslatable($page));
 291         }
 292         if ($template->query(name => "HOMEPAGEURL")) {
 293                 $template->param(homepageurl => homepageurl($page));
 294         }
 295         if ($template->query(name => "otherlanguages")) {
 296                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 297                 map add_depends($page, $_), (values %{otherlanguages($page)});
 298         }
 299         # Rely on IkiWiki::Render's genpage() to decide wether
 300         # a discussion link should appear on $page; this is not
 301         # totally accurate, though: some broken links may be generated
 302         # when cgiurl is disabled.
 303         # This compromise avoids some code duplication, and will probably
 304         # prevent future breakage when ikiwiki internals change.
 305         # Known limitations are preferred to future random bugs.
 306         if ($template->param('discussionlink') && istranslation($page)) {
 307                 $template->param('discussionlink' => htmllink(
 308                                                         $page,
 309                                                         $destpage,
 310                                                         $masterpage . '/' . gettext("Discussion"),
 311                                                         noimageinline => 1,
 312                                                         forcesubpage => 0,
 313                                                         linktext => gettext("Discussion"),
 314                                                         ));
 315         }
 316         # Remove broken parentlink to ./index.html on home page's translations.
 317         # It works because this hook has the "last" parameter set, to ensure it
 318         # runs after parentlinks' own pagetemplate hook.
 319         if ($template->param('parentlinks')
 320             && istranslation($page)
 321             && $masterpage eq "index") {
 322                 $template->param('parentlinks' => []);
 323         }
 324 } # }}}
 325
 326 sub change(@) { #{{{
 327         my @rendered=@_;
 328
 329         my $updated_po_files=0;
 330
 331         # Refresh/create POT and PO files as needed.
 332         foreach my $page (map pagename($_), @rendered) {
 333                 next unless istranslatable($page);
 334                 my $file=srcfile($pagesources{$page});
 335                 my $updated_pot_file=0;
 336                 # Only refresh Pot file if it does not exist, or if
 337                 # $pagesources{$page} was changed: don't if only the HTML was
 338                 # refreshed, e.g. because of a dependency.
 339                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 340                     || ! -e potfile($file)) {
 341                         refreshpot($file);
 342                         $updated_pot_file=1;
 343                 }
 344                 my @pofiles;
 345                 map {
 346                         push @pofiles, $_ if ($updated_pot_file || ! -e $_);
 347                 } (pofiles($file));
 348                 if (@pofiles) {
 349                         refreshpofiles($file, @pofiles);
 350                         map { IkiWiki::rcs_add($_); } @pofiles if ($config{rcs});
 351                         $updated_po_files=1;
 352                 }
 353         }
 354
 355         if ($updated_po_files) {
 356                 # Check staged changes in.
 357                 if ($config{rcs}) {
 358                         IkiWiki::disable_commit_hook();
 359                         IkiWiki::rcs_commit_staged(gettext("updated PO files"),
 360                                 "IkiWiki::Plugin::po::change", "127.0.0.1");
 361                         IkiWiki::enable_commit_hook();
 362                         IkiWiki::rcs_update();
 363                 }
 364                 # Reinitialize module's private variables.
 365                 resetalreadyfiltered();
 366                 resettranslationscache();
 367                 # Trigger a wiki refresh.
 368                 require IkiWiki::Render;
 369                 # without preliminary saveindex/loadindex, refresh()
 370                 # complains about a lot of uninitialized variables
 371                 IkiWiki::saveindex();
 372                 IkiWiki::loadindex();
 373                 IkiWiki::refresh();
 374                 IkiWiki::saveindex();
 375         }
 376 } #}}}
 377
 378 # As we're previewing or saving a page, the content may have
 379 # changed, so tell the next filter() invocation it must not be lazy.
 380 sub editcontent () { #{{{
 381         my %params=@_;
 382
 383         unsetalreadyfiltered($params{page}, $params{page});
 384         return $params{content};
 385 } #}}}
 386
 387
 388 # ,----
 389 # | Injected functions
 390 # `----
 391
 392 # Implement po_link_to 'current' and 'negotiated' settings.
 393 sub mybestlink ($$) { #{{{
 394         my $page=shift;
 395         my $link=shift;
 396
 397         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 398         if (length $res
 399             && ($config{po_link_to} eq "current" || $config{po_link_to} eq "negotiated")
 400             && istranslatable($res)
 401             && istranslation($page)) {
 402                 return $res . "." . lang($page);
 403         }
 404         return $res;
 405 } #}}}
 406
 407 sub mybeautify_urlpath ($) { #{{{
 408         my $url=shift;
 409
 410         my $res=$origsubs{'beautify_urlpath'}->($url);
 411         if ($config{po_link_to} eq "negotiated") {
 412                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 413                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 414                 map {
 415                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 416                 } (keys %{$config{po_slave_languages}});
 417         }
 418         return $res;
 419 } #}}}
 420
 421 sub mytargetpage ($$) { #{{{
 422         my $page=shift;
 423         my $ext=shift;
 424
 425         if (istranslation($page) || istranslatable($page)) {
 426                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 427                 if (! $config{usedirs} || $masterpage eq 'index') {
 428                         return $masterpage . "." . $lang . "." . $ext;
 429                 }
 430                 else {
 431                         return $masterpage . "/index." . $lang . "." . $ext;
 432                 }
 433         }
 434         return $origsubs{'targetpage'}->($page, $ext);
 435 } #}}}
 436
 437 sub myurlto ($$;$) { #{{{
 438         my $to=shift;
 439         my $from=shift;
 440         my $absolute=shift;
 441
 442         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 443         if (! length $to
 444             && $config{po_link_to} eq "current"
 445             && istranslatable('index')) {
 446                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 447         }
 448         return $origsubs{'urlto'}->($to,$from,$absolute);
 449 } #}}}
 450
 451
 452 # ,----
 453 # | Blackboxes for private data
 454 # `----
 455
 456 {
 457         my %filtered;
 458
 459         sub alreadyfiltered($$) { #{{{
 460                 my $page=shift;
 461                 my $destpage=shift;
 462
 463                 return ( exists $filtered{$page}{$destpage}
 464                          && $filtered{$page}{$destpage} eq 1 );
 465         } #}}}
 466
 467         sub setalreadyfiltered($$) { #{{{
 468                 my $page=shift;
 469                 my $destpage=shift;
 470
 471                 $filtered{$page}{$destpage}=1;
 472         } #}}}
 473
 474         sub unsetalreadyfiltered($$) { #{{{
 475                 my $page=shift;
 476                 my $destpage=shift;
 477
 478                 if (exists $filtered{$page}{$destpage}) {
 479                         delete $filtered{$page}{$destpage};
 480                 }
 481         } #}}}
 482
 483         sub resetalreadyfiltered() { #{{{
 484                 undef %filtered;
 485         } #}}}
 486 }
 487
 488
 489 # ,----
 490 # | Helper functions
 491 # `----
 492
 493 sub maybe_add_leading_slash ($;$) { #{{{
 494         my $str=shift;
 495         my $add=shift;
 496         $add=1 unless defined $add;
 497         return '/' . $str if $add;
 498         return $str;
 499 } #}}}
 500
 501 sub istranslatable ($) { #{{{
 502         my $page=shift;
 503
 504         $page=~s#^/##;
 505         my $file=$pagesources{$page};
 506
 507         return 0 unless defined $file;
 508         return 0 if (defined pagetype($file) && pagetype($file) eq 'po');
 509         return 0 if $file =~ /\.pot$/;
 510         return pagespec_match($page, $config{po_translatable_pages});
 511 } #}}}
 512
 513 sub _istranslation ($) { #{{{
 514         my $page=shift;
 515
 516         my $hasleadingslash = ($page=~s#^/##);
 517         my $file=$pagesources{$page};
 518         return 0 unless (defined $file
 519                          && defined pagetype($file)
 520                          && pagetype($file) eq 'po');
 521         return 0 if $file =~ /\.pot$/;
 522
 523         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 524         return 0 unless (defined $masterpage && defined $lang
 525                          && length $masterpage && length $lang
 526                          && defined $pagesources{$masterpage}
 527                          && defined $config{po_slave_languages}{$lang});
 528
 529         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 530                 if istranslatable($masterpage);
 531 } #}}}
 532
 533 sub istranslation ($) { #{{{
 534         my $page=shift;
 535
 536         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 537                 my $hasleadingslash = ($masterpage=~s#^/##);
 538                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 539                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 540                         if istranslatable($masterpage);
 541         }
 542         return;
 543 } #}}}
 544
 545 sub masterpage ($) { #{{{
 546         my $page=shift;
 547
 548         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 549                 return $masterpage;
 550         }
 551         return $page;
 552 } #}}}
 553
 554 sub lang ($) { #{{{
 555         my $page=shift;
 556
 557         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 558                 return $lang;
 559         }
 560         return $config{po_master_language}{code};
 561 } #}}}
 562
 563 sub islanguagecode ($) { #{{{
 564         my $code=shift;
 565
 566         return ($code =~ /^[a-z]{2}$/);
 567 } #}}}
 568
 569 sub otherlanguages($) { #{{{
 570         my $page=shift;
 571
 572         my %ret;
 573         if (istranslatable($page)) {
 574                 %ret = %{$translations{$page}} if defined $translations{$page};
 575         }
 576         elsif (istranslation($page)) {
 577                 my $masterpage = masterpage($page);
 578                 $ret{$config{po_master_language}{code}} = $masterpage;
 579                 foreach my $lang (sort keys %{$translations{$masterpage}}) {
 580                         next if $lang eq lang($page);
 581                         $ret{$lang} = $translations{$masterpage}{$lang};
 582                 }
 583         }
 584         return \%ret;
 585 } #}}}
 586
 587 sub potfile ($) { #{{{
 588         my $masterfile=shift;
 589
 590         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 591         $dir='' if $dir eq './';
 592         return File::Spec->catpath('', $dir, $name . ".pot");
 593 } #}}}
 594
 595 sub pofile ($$) { #{{{
 596         my $masterfile=shift;
 597         my $lang=shift;
 598
 599         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 600         $dir='' if $dir eq './';
 601         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 602 } #}}}
 603
 604 sub pofiles ($) { #{{{
 605         my $masterfile=shift;
 606
 607         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 608 } #}}}
 609
 610 sub refreshpot ($) { #{{{
 611         my $masterfile=shift;
 612
 613         my $potfile=potfile($masterfile);
 614         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 615         my $doc=Locale::Po4a::Chooser::new('text',%options);
 616         $doc->{TT}{utf_mode} = 1;
 617         $doc->{TT}{file_in_charset} = 'utf-8';
 618         $doc->{TT}{file_out_charset} = 'utf-8';
 619         $doc->read($masterfile);
 620         # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
 621         # this is undocument use of internal Locale::Po4a::TransTractor's data,
 622         # compulsory since this module prevents us from using the porefs option.
 623         my %po_options = ('porefs' => 'none');
 624         $doc->{TT}{po_out}=Locale::Po4a::Po->new(\%po_options);
 625         $doc->{TT}{po_out}->set_charset('utf-8');
 626         # do the actual work
 627         $doc->parse;
 628         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 629         $doc->writepo($potfile);
 630 } #}}}
 631
 632 sub refreshpofiles ($@) { #{{{
 633         my $masterfile=shift;
 634         my @pofiles=@_;
 635
 636         my $potfile=potfile($masterfile);
 637         error("[po/refreshpofiles] POT file ($potfile) does not exist") unless (-e $potfile);
 638
 639         foreach my $pofile (@pofiles) {
 640                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 641                 if (-e $pofile) {
 642                         system("msgmerge", "-U", "--backup=none", $pofile, $potfile) == 0
 643                                 or error("[po/refreshpofiles:$pofile] failed to update");
 644                 }
 645                 else {
 646                         File::Copy::syscopy($potfile,$pofile)
 647                                 or error("[po/refreshpofiles:$pofile] failed to copy the POT file");
 648                 }
 649         }
 650 } #}}}
 651
 652 sub buildtranslationscache() { #{{{
 653         # use istranslation's side-effect
 654         map istranslation($_), (keys %pagesources);
 655 } #}}}
 656
 657 sub resettranslationscache() { #{{{
 658         undef %translations;
 659 } #}}}
 660
 661 sub urlto_with_orig_beautiful_urlpath($$) { #{{{
 662         my $to=shift;
 663         my $from=shift;
 664
 665         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 666         my $res=urlto($to, $from);
 667         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 668
 669         return $res;
 670 } #}}}
 671
 672 sub percenttranslated ($) { #{{{
 673         my $page=shift;
 674
 675         return gettext("N/A") unless istranslation($page);
 676         my $file=srcfile($pagesources{$page});
 677         my $masterfile = srcfile($pagesources{masterpage($page)});
 678         my (@pos,@masters);
 679         push @pos,$file;
 680         push @masters,$masterfile;
 681         my %options = (
 682                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 683         );
 684         my $doc=Locale::Po4a::Chooser::new('text',%options);
 685         $doc->process(
 686                 'po_in_name'    => \@pos,
 687                 'file_in_name'  => \@masters,
 688                 'file_in_charset'  => 'utf-8',
 689                 'file_out_charset' => 'utf-8',
 690         ) or error("[po/percenttranslated:$page]: failed to translate");
 691         my ($percent,$hit,$queries) = $doc->stats();
 692         return $percent;
 693 } #}}}
 694
 695 sub languagename ($) { #{{{
 696         my $code=shift;
 697
 698         return $config{po_master_language}{name}
 699                 if $code eq $config{po_master_language}{code};
 700         return $config{po_slave_languages}{$code}
 701                 if defined $config{po_slave_languages}{$code};
 702         return;
 703 } #}}}
 704
 705 sub otherlanguagesloop ($) { #{{{
 706         my $page=shift;
 707
 708         my @ret;
 709         my %otherpages=%{otherlanguages($page)};
 710         while (my ($lang, $otherpage) = each %otherpages) {
 711                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 712                         push @ret, {
 713                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 714                                 code => $lang,
 715                                 language => languagename($lang),
 716                                 master => 1,
 717                         };
 718                 }
 719                 else {
 720                         push @ret, {
 721                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 722                                 code => $lang,
 723                                 language => languagename($lang),
 724                                 percent => percenttranslated($otherpage),
 725                         }
 726                 }
 727         }
 728         return sort {
 729                         return -1 if $a->{code} eq $config{po_master_language}{code};
 730                         return 1 if $b->{code} eq $config{po_master_language}{code};
 731                         return $a->{language} cmp $b->{language};
 732                 } @ret;
 733 } #}}}
 734
 735 sub homepageurl (;$) { #{{{
 736         my $page=shift;
 737
 738         return urlto('', $page);
 739 } #}}}
 740
 741 # ,----
 742 # | PageSpec's
 743 # `----
 744
 745 package IkiWiki::PageSpec;
 746 use warnings;
 747 use strict;
 748 use IkiWiki 2.00;
 749
 750 sub match_istranslation ($;@) { #{{{
 751         my $page=shift;
 752
 753         if (IkiWiki::Plugin::po::istranslation($page)) {
 754                 return IkiWiki::SuccessReason->new("is a translation page");
 755         }
 756         else {
 757                 return IkiWiki::FailReason->new("is not a translation page");
 758         }
 759 } #}}}
 760
 761 sub match_istranslatable ($;@) { #{{{
 762         my $page=shift;
 763
 764         if (IkiWiki::Plugin::po::istranslatable($page)) {
 765                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
 766         }
 767         else {
 768                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
 769         }
 770 } #}}}
 771
 772 sub match_lang ($$;@) { #{{{
 773         my $page=shift;
 774         my $wanted=shift;
 775
 776         my $regexp=IkiWiki::glob2re($wanted);
 777         my $lang=IkiWiki::Plugin::po::lang($page);
 778         if ($lang!~/^$regexp$/i) {
 779                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
 780         }
 781         else {
 782                 return IkiWiki::SuccessReason->new("file language is $wanted");
 783         }
 784 } #}}}
 785
 786 sub match_currentlang ($$;@) { #{{{
 787         my $page=shift;
 788         shift;
 789         my %params=@_;
 790
 791         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
 792
 793         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
 794         my $lang=IkiWiki::Plugin::po::lang($page);
 795
 796         if ($lang eq $currentlang) {
 797                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
 798         }
 799         else {
 800                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
 801         }
 802 } #}}}
 803
 804 1