git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/git.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::git;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use Encode;
   8 use open qw{:utf8 :std};
   9
  10 my $sha1_pattern     = qr/[0-9a-fA-F]{40}/; # pattern to validate Git sha1sums
  11 my $dummy_commit_msg = 'dummy commit';      # message to skip in recent changes
  12 my $no_chdir=0;
  13
  14 sub import {
  15         hook(type => "checkconfig", id => "git", call => \&checkconfig);
  16         hook(type => "getsetup", id => "git", call => \&getsetup);
  17         hook(type => "genwrapper", id => "git", call => \&genwrapper);
  18         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  19         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  20         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  21         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  22         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  23         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  24         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  25         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  26         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  27         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  28         hook(type => "rcs", id => "rcs_receive", call => \&rcs_receive);
  29 }
  30
  31 sub checkconfig () {
  32         if (! defined $config{gitorigin_branch}) {
  33                 $config{gitorigin_branch}="origin";
  34         }
  35         if (! defined $config{gitmaster_branch}) {
  36                 $config{gitmaster_branch}="master";
  37         }
  38         if (defined $config{git_wrapper} &&
  39             length $config{git_wrapper}) {
  40                 push @{$config{wrappers}}, {
  41                         wrapper => $config{git_wrapper},
  42                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  43                 };
  44         }
  45
  46         if (defined $config{git_test_receive_wrapper} &&
  47             length $config{git_test_receive_wrapper}) {
  48                 push @{$config{wrappers}}, {
  49                         test_receive => 1,
  50                         wrapper => $config{git_test_receive_wrapper},
  51                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  52                 };
  53         }
  54
  55         # Run receive test only if being called by the wrapper, and not
  56         # when generating same.
  57         if ($config{test_receive} && ! exists $config{wrapper}) {
  58                 require IkiWiki::Receive;
  59                 IkiWiki::Receive::test();
  60         }
  61 }
  62
  63 sub getsetup () {
  64         return
  65                 plugin => {
  66                         safe => 0, # rcs plugin
  67                         rebuild => undef,
  68                 },
  69                 git_wrapper => {
  70                         type => "string",
  71                         example => "/git/wiki.git/hooks/post-update",
  72                         description => "git hook to generate",
  73                         safe => 0, # file
  74                         rebuild => 0,
  75                 },
  76                 git_wrappermode => {
  77                         type => "string",
  78                         example => '06755',
  79                         description => "mode for git_wrapper (can safely be made suid)",
  80                         safe => 0,
  81                         rebuild => 0,
  82                 },
  83                 git_test_receive_wrapper => {
  84                         type => "string",
  85                         example => "/git/wiki.git/hooks/pre-receive",
  86                         description => "git pre-receive hook to generate",
  87                         safe => 0, # file
  88                         rebuild => 0,
  89                 },
  90                 untrusted_committers => {
  91                         type => "string",
  92                         example => [],
  93                         description => "unix users whose commits should be checked by the pre-receive hook",
  94                         safe => 0,
  95                         rebuild => 0,
  96                 },
  97                 historyurl => {
  98                         type => "string",
  99                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=history;f=[[file]]",
 100                         description => "gitweb url to show file history ([[file]] substituted)",
 101                         safe => 1,
 102                         rebuild => 1,
 103                 },
 104                 diffurl => {
 105                         type => "string",
 106                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=blobdiff;f=[[file]];h=[[sha1_to]];hp=[[sha1_from]];hb=[[sha1_commit]];hpb=[[sha1_parent]]",
 107                         description => "gitweb url to show a diff ([[file]], [[sha1_to]], [[sha1_from]], [[sha1_commit]], and [[sha1_parent]] substituted)",
 108                         safe => 1,
 109                         rebuild => 1,
 110                 },
 111                 gitorigin_branch => {
 112                         type => "string",
 113                         example => "origin",
 114                         description => "where to pull and push changes (set to empty string to disable)",
 115                         safe => 0, # paranoia
 116                         rebuild => 0,
 117                 },
 118                 gitmaster_branch => {
 119                         type => "string",
 120                         example => "master",
 121                         description => "branch that the wiki is stored in",
 122                         safe => 0, # paranoia
 123                         rebuild => 0,
 124                 },
 125 }
 126
 127 sub genwrapper {
 128         if ($config{test_receive}) {
 129                 require IkiWiki::Receive;
 130                 return IkiWiki::Receive::genwrapper();
 131         }
 132         else {
 133                 return "";
 134         }
 135 }
 136
 137 sub safe_git (&@) {
 138         # Start a child process safely without resorting /bin/sh.
 139         # Return command output or success state (in scalar context).
 140
 141         my ($error_handler, @cmdline) = @_;
 142
 143         my $pid = open my $OUT, "-|";
 144
 145         error("Cannot fork: $!") if !defined $pid;
 146
 147         if (!$pid) {
 148                 # In child.
 149                 # Git commands want to be in wc.
 150                 if (! $no_chdir) {
 151                         chdir $config{srcdir}
 152                             or error("Cannot chdir to $config{srcdir}: $!");
 153                 }
 154                 exec @cmdline or error("Cannot exec '@cmdline': $!");
 155         }
 156         # In parent.
 157
 158         # git output is probably utf-8 encoded, but may contain
 159         # other encodings or invalidly encoded stuff. So do not rely
 160         # on the normal utf-8 IO layer, decode it by hand.
 161         binmode($OUT);
 162
 163         my @lines;
 164         while (<$OUT>) {
 165                 $_=decode_utf8($_, 0);
 166
 167                 chomp;
 168
 169                 push @lines, $_;
 170         }
 171
 172         close $OUT;
 173
 174         $error_handler->("'@cmdline' failed: $!") if $? && $error_handler;
 175
 176         return wantarray ? @lines : ($? == 0);
 177 }
 178 # Convenient wrappers.
 179 sub run_or_die ($@) { safe_git(\&error, @_) }
 180 sub run_or_cry ($@) { safe_git(sub { warn @_ },  @_) }
 181 sub run_or_non ($@) { safe_git(undef,            @_) }
 182
 183
 184 sub merge_past ($$$) {
 185         # Unlike with Subversion, Git cannot make a 'svn merge -rN:M file'.
 186         # Git merge commands work with the committed changes, except in the
 187         # implicit case of '-m' of git checkout(1).  So we should invent a
 188         # kludge here.  In principle, we need to create a throw-away branch
 189         # in preparing for the merge itself.  Since branches are cheap (and
 190         # branching is fast), this shouldn't cost high.
 191         #
 192         # The main problem is the presence of _uncommitted_ local changes.  One
 193         # possible approach to get rid of this situation could be that we first
 194         # make a temporary commit in the master branch and later restore the
 195         # initial state (this is possible since Git has the ability to undo a
 196         # commit, i.e. 'git reset --soft HEAD^').  The method can be summarized
 197         # as follows:
 198         #
 199         #       - create a diff of HEAD:current-sha1
 200         #       - dummy commit
 201         #       - create a dummy branch and switch to it
 202         #       - rewind to past (reset --hard to the current-sha1)
 203         #       - apply the diff and commit
 204         #       - switch to master and do the merge with the dummy branch
 205         #       - make a soft reset (undo the last commit of master)
 206         #
 207         # The above method has some drawbacks: (1) it needs a redundant commit
 208         # just to get rid of local changes, (2) somewhat slow because of the
 209         # required system forks.  Until someone points a more straight method
 210         # (which I would be grateful) I have implemented an alternative method.
 211         # In this approach, we hide all the modified files from Git by renaming
 212         # them (using the 'rename' builtin) and later restore those files in
 213         # the throw-away branch (that is, we put the files themselves instead
 214         # of applying a patch).
 215
 216         my ($sha1, $file, $message) = @_;
 217
 218         my @undo;      # undo stack for cleanup in case of an error
 219         my $conflict;  # file content with conflict markers
 220
 221         eval {
 222                 # Hide local changes from Git by renaming the modified file.
 223                 # Relative paths must be converted to absolute for renaming.
 224                 my ($target, $hidden) = (
 225                     "$config{srcdir}/${file}", "$config{srcdir}/${file}.${sha1}"
 226                 );
 227                 rename($target, $hidden)
 228                     or error("rename '$target' to '$hidden' failed: $!");
 229                 # Ensure to restore the renamed file on error.
 230                 push @undo, sub {
 231                         return if ! -e "$hidden"; # already renamed
 232                         rename($hidden, $target)
 233                             or warn "rename '$hidden' to '$target' failed: $!";
 234                 };
 235
 236                 my $branch = "throw_away_${sha1}"; # supposed to be unique
 237
 238                 # Create a throw-away branch and rewind backward.
 239                 push @undo, sub { run_or_cry('git', 'branch', '-D', $branch) };
 240                 run_or_die('git', 'branch', $branch, $sha1);
 241
 242                 # Switch to throw-away branch for the merge operation.
 243                 push @undo, sub {
 244                         if (!run_or_cry('git', 'checkout', $config{gitmaster_branch})) {
 245                                 run_or_cry('git', 'checkout','-f',$config{gitmaster_branch});
 246                         }
 247                 };
 248                 run_or_die('git', 'checkout', $branch);
 249
 250                 # Put the modified file in _this_ branch.
 251                 rename($hidden, $target)
 252                     or error("rename '$hidden' to '$target' failed: $!");
 253
 254                 # _Silently_ commit all modifications in the current branch.
 255                 run_or_non('git', 'commit', '-m', $message, '-a');
 256                 # ... and re-switch to master.
 257                 run_or_die('git', 'checkout', $config{gitmaster_branch});
 258
 259                 # Attempt to merge without complaining.
 260                 if (!run_or_non('git', 'pull', '--no-commit', '.', $branch)) {
 261                         $conflict = readfile($target);
 262                         run_or_die('git', 'reset', '--hard');
 263                 }
 264         };
 265         my $failure = $@;
 266
 267         # Process undo stack (in reverse order).  By policy cleanup
 268         # actions should normally print a warning on failure.
 269         while (my $handle = pop @undo) {
 270                 $handle->();
 271         }
 272
 273         error("Git merge failed!\n$failure\n") if $failure;
 274
 275         return $conflict;
 276 }
 277
 278 sub parse_diff_tree ($@) {
 279         # Parse the raw diff tree chunk and return the info hash.
 280         # See git-diff-tree(1) for the syntax.
 281
 282         my ($prefix, $dt_ref) = @_;
 283
 284         # End of stream?
 285         return if !defined @{ $dt_ref } ||
 286                   !defined @{ $dt_ref }[0] || !length @{ $dt_ref }[0];
 287
 288         my %ci;
 289         # Header line.
 290         while (my $line = shift @{ $dt_ref }) {
 291                 return if $line !~ m/^(.+) ($sha1_pattern)/;
 292
 293                 my $sha1 = $2;
 294                 $ci{'sha1'} = $sha1;
 295                 last;
 296         }
 297
 298         # Identification lines for the commit.
 299         while (my $line = shift @{ $dt_ref }) {
 300                 # Regexps are semi-stolen from gitweb.cgi.
 301                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
 302                         $ci{'tree'} = $1;
 303                 }
 304                 elsif ($line =~ m/^parent ([0-9a-fA-F]{40})$/) {
 305                         # XXX: collecting in reverse order
 306                         push @{ $ci{'parents'} }, $1;
 307                 }
 308                 elsif ($line =~ m/^(author|committer) (.*) ([0-9]+) (.*)$/) {
 309                         my ($who, $name, $epoch, $tz) =
 310                            ($1,   $2,    $3,     $4 );
 311
 312                         $ci{  $who          } = $name;
 313                         $ci{ "${who}_epoch" } = $epoch;
 314                         $ci{ "${who}_tz"    } = $tz;
 315
 316                         if ($name =~ m/^[^<]+\s+<([^@>]+)/) {
 317                                 $ci{"${who}_username"} = $1;
 318                         }
 319                         elsif ($name =~ m/^([^<]+)\s+<>$/) {
 320                                 $ci{"${who}_username"} = $1;
 321                         }
 322                         else {
 323                                 $ci{"${who}_username"} = $name;
 324                         }
 325                 }
 326                 elsif ($line =~ m/^$/) {
 327                         # Trailing empty line signals next section.
 328                         last;
 329                 }
 330         }
 331
 332         debug("No 'tree' seen in diff-tree output") if !defined $ci{'tree'};
 333
 334         if (defined $ci{'parents'}) {
 335                 $ci{'parent'} = @{ $ci{'parents'} }[0];
 336         }
 337         else {
 338                 $ci{'parent'} = 0 x 40;
 339         }
 340
 341         # Commit message (optional).
 342         while ($dt_ref->[0] =~ /^    /) {
 343                 my $line = shift @{ $dt_ref };
 344                 $line =~ s/^    //;
 345                 push @{ $ci{'comment'} }, $line;
 346         }
 347         shift @{ $dt_ref } if $dt_ref->[0] =~ /^$/;
 348
 349         # Modified files.
 350         while (my $line = shift @{ $dt_ref }) {
 351                 if ($line =~ m{^
 352                         (:+)       # number of parents
 353                         ([^\t]+)\t # modes, sha1, status
 354                         (.*)       # file names
 355                 $}xo) {
 356                         my $num_parents = length $1;
 357                         my @tmp = split(" ", $2);
 358                         my ($file, $file_to) = split("\t", $3);
 359                         my @mode_from = splice(@tmp, 0, $num_parents);
 360                         my $mode_to = shift(@tmp);
 361                         my @sha1_from = splice(@tmp, 0, $num_parents);
 362                         my $sha1_to = shift(@tmp);
 363                         my $status = shift(@tmp);
 364
 365                         # git does not output utf-8 filenames, but instead
 366                         # double-quotes them with the utf-8 characters
 367                         # escaped as \nnn\nnn.
 368                         if ($file =~ m/^"(.*)"$/) {
 369                                 ($file=$1) =~ s/\\([0-7]{1,3})/chr(oct($1))/eg;
 370                         }
 371                         $file =~ s/^\Q$prefix\E//;
 372                         if (length $file) {
 373                                 push @{ $ci{'details'} }, {
 374                                         'file'      => decode("utf8", $file),
 375                                         'sha1_from' => $sha1_from[0],
 376                                         'sha1_to'   => $sha1_to,
 377                                         'mode_from' => $mode_from[0],
 378                                         'mode_to'   => $mode_to,
 379                                         'status'    => $status,
 380                                 };
 381                         }
 382                         next;
 383                 };
 384                 last;
 385         }
 386
 387         return \%ci;
 388 }
 389
 390 sub git_commit_info ($;$) {
 391         # Return an array of commit info hashes of num commits
 392         # starting from the given sha1sum.
 393         my ($sha1, $num) = @_;
 394
 395         my @opts;
 396         push @opts, "--max-count=$num" if defined $num;
 397
 398         my @raw_lines = run_or_die('git', 'log', @opts,
 399                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 400                 '-r', $sha1, '--', '.');
 401         my ($prefix) = run_or_die('git', 'rev-parse', '--show-prefix');
 402
 403         my @ci;
 404         while (my $parsed = parse_diff_tree(($prefix or ""), \@raw_lines)) {
 405                 push @ci, $parsed;
 406         }
 407
 408         warn "Cannot parse commit info for '$sha1' commit" if !@ci;
 409
 410         return wantarray ? @ci : $ci[0];
 411 }
 412
 413 sub git_sha1 (;$) {
 414         # Return head sha1sum (of given file).
 415         my $file = shift || q{--};
 416
 417         # Ignore error since a non-existing file might be given.
 418         my ($sha1) = run_or_non('git', 'rev-list', '--max-count=1', 'HEAD',
 419                 '--', $file);
 420         if ($sha1) {
 421                 ($sha1) = $sha1 =~ m/($sha1_pattern)/; # sha1 is untainted now
 422         }
 423         else {
 424                 debug("Empty sha1sum for '$file'.");
 425         }
 426         return defined $sha1 ? $sha1 : q{};
 427 }
 428
 429 sub rcs_update () {
 430         # Update working directory.
 431
 432         if (length $config{gitorigin_branch}) {
 433                 run_or_cry('git', 'pull', $config{gitorigin_branch});
 434         }
 435 }
 436
 437 sub rcs_prepedit ($) {
 438         # Return the commit sha1sum of the file when editing begins.
 439         # This will be later used in rcs_commit if a merge is required.
 440         my ($file) = @_;
 441
 442         return git_sha1($file);
 443 }
 444
 445 sub rcs_commit ($$$;$$) {
 446         # Try to commit the page; returns undef on _success_ and
 447         # a version of the page with the rcs's conflict markers on
 448         # failure.
 449
 450         my ($file, $message, $rcstoken, $user, $ipaddr) = @_;
 451
 452         # Check to see if the page has been changed by someone else since
 453         # rcs_prepedit was called.
 454         my $cur    = git_sha1($file);
 455         my ($prev) = $rcstoken =~ /^($sha1_pattern)$/; # untaint
 456
 457         if (defined $cur && defined $prev && $cur ne $prev) {
 458                 my $conflict = merge_past($prev, $file, $dummy_commit_msg);
 459                 return $conflict if defined $conflict;
 460         }
 461
 462         rcs_add($file);
 463         return rcs_commit_staged($message, $user, $ipaddr);
 464 }
 465
 466 sub rcs_commit_staged ($$$) {
 467         # Commits all staged changes. Changes can be staged using rcs_add,
 468         # rcs_remove, and rcs_rename.
 469         my ($message, $user, $ipaddr)=@_;
 470
 471         # Set the commit author and email to the web committer.
 472         my %env=%ENV;
 473         if (defined $user || defined $ipaddr) {
 474                 my $u=encode_utf8(defined $user ? $user : $ipaddr);
 475                 $ENV{GIT_AUTHOR_NAME}=$u;
 476                 $ENV{GIT_AUTHOR_EMAIL}="$u\@web";
 477         }
 478
 479         $message = IkiWiki::possibly_foolish_untaint($message);
 480         my @opts;
 481         if ($message !~ /\S/) {
 482                 # Force git to allow empty commit messages.
 483                 # (If this version of git supports it.)
 484                 my ($version)=`git --version` =~ /git version (.*)/;
 485                 if ($version ge "1.5.4") {
 486                         push @opts, '--cleanup=verbatim';
 487                 }
 488                 else {
 489                         $message.=".";
 490                 }
 491         }
 492         push @opts, '-q';
 493         # git commit returns non-zero if file has not been really changed.
 494         # so we should ignore its exit status (hence run_or_non).
 495         if (run_or_non('git', 'commit', @opts, '-m', $message)) {
 496                 if (length $config{gitorigin_branch}) {
 497                         run_or_cry('git', 'push', $config{gitorigin_branch});
 498                 }
 499         }
 500
 501         %ENV=%env;
 502         return undef; # success
 503 }
 504
 505 sub rcs_add ($) {
 506         # Add file to archive.
 507
 508         my ($file) = @_;
 509
 510         run_or_cry('git', 'add', $file);
 511 }
 512
 513 sub rcs_remove ($) {
 514         # Remove file from archive.
 515
 516         my ($file) = @_;
 517
 518         run_or_cry('git', 'rm', '-f', $file);
 519 }
 520
 521 sub rcs_rename ($$) {
 522         my ($src, $dest) = @_;
 523
 524         run_or_cry('git', 'mv', '-f', $src, $dest);
 525 }
 526
 527 sub rcs_recentchanges ($) {
 528         # List of recent changes.
 529
 530         my ($num) = @_;
 531
 532         eval q{use Date::Parse};
 533         error($@) if $@;
 534
 535         my @rets;
 536         foreach my $ci (git_commit_info('HEAD', $num || 1)) {
 537                 # Skip redundant commits.
 538                 next if ($ci->{'comment'} && @{$ci->{'comment'}}[0] eq $dummy_commit_msg);
 539
 540                 my ($sha1, $when) = (
 541                         $ci->{'sha1'},
 542                         $ci->{'author_epoch'}
 543                 );
 544
 545                 my @pages;
 546                 foreach my $detail (@{ $ci->{'details'} }) {
 547                         my $file = $detail->{'file'};
 548
 549                         my $diffurl = defined $config{'diffurl'} ? $config{'diffurl'} : "";
 550                         $diffurl =~ s/\[\[file\]\]/$file/go;
 551                         $diffurl =~ s/\[\[sha1_parent\]\]/$ci->{'parent'}/go;
 552                         $diffurl =~ s/\[\[sha1_from\]\]/$detail->{'sha1_from'}/go;
 553                         $diffurl =~ s/\[\[sha1_to\]\]/$detail->{'sha1_to'}/go;
 554                         $diffurl =~ s/\[\[sha1_commit\]\]/$sha1/go;
 555
 556                         push @pages, {
 557                                 page => pagename($file),
 558                                 diffurl => $diffurl,
 559                         };
 560                 }
 561
 562                 my @messages;
 563                 my $pastblank=0;
 564                 foreach my $line (@{$ci->{'comment'}}) {
 565                         $pastblank=1 if $line eq '';
 566                         next if $pastblank && $line=~m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i;
 567                         push @messages, { line => $line };
 568                 }
 569
 570                 my $user=$ci->{'author_username'};
 571                 my $web_commit = ($ci->{'author'} =~ /\@web>/);
 572
 573                 # compatability code for old web commit messages
 574                 if (! $web_commit &&
 575                       defined $messages[0] &&
 576                       $messages[0]->{line} =~ m/$config{web_commit_regexp}/) {
 577                         $user = defined $2 ? "$2" : "$3";
 578                         $messages[0]->{line} = $4;
 579                         $web_commit=1;
 580                 }
 581
 582                 push @rets, {
 583                         rev        => $sha1,
 584                         user       => $user,
 585                         committype => $web_commit ? "web" : "git",
 586                         when       => $when,
 587                         message    => [@messages],
 588                         pages      => [@pages],
 589                 } if @pages;
 590
 591                 last if @rets >= $num;
 592         }
 593
 594         return @rets;
 595 }
 596
 597 sub rcs_diff ($) {
 598         my $rev=shift;
 599         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 600         my @lines;
 601         foreach my $line (run_or_non("git", "show", $sha1)) {
 602                 if (@lines || $line=~/^diff --git/) {
 603                         push @lines, $line."\n";
 604                 }
 605         }
 606         if (wantarray) {
 607                 return @lines;
 608         }
 609         else {
 610                 return join("", @lines);
 611         }
 612 }
 613
 614 sub rcs_getctime ($) {
 615         my $file=shift;
 616         # Remove srcdir prefix
 617         $file =~ s/^\Q$config{srcdir}\E\/?//;
 618
 619         my @raw_lines = run_or_die('git', 'log',
 620                 '--follow', '--no-merges',
 621                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 622                 '-r', '--', $file);
 623         my @ci;
 624         while (my $parsed = parse_diff_tree("", \@raw_lines)) {
 625                 push @ci, $parsed;
 626         }
 627         my $ctime = $ci[$#ci]->{'author_epoch'};
 628         debug("ctime for '$file': ". localtime($ctime));
 629
 630         return $ctime;
 631 }
 632
 633 sub rcs_receive () {
 634         # The wiki may not be the only thing in the git repo.
 635         # Determine if it is in a subdirectory by examining the srcdir,
 636         # and its parents, looking for the .git directory.
 637         my $subdir="";
 638         my $dir=$config{srcdir};
 639         while (! -d "$dir/.git") {
 640                 $subdir=IkiWiki::basename($dir)."/".$subdir;
 641                 $dir=IkiWiki::dirname($dir);
 642                 if (! length $dir) {
 643                         error("cannot determine root of git repo");
 644                 }
 645         }
 646
 647         my @rets;
 648         while (<>) {
 649                 chomp;
 650                 my ($oldrev, $newrev, $refname) = split(' ', $_, 3);
 651
 652                 # only allow changes to gitmaster_branch
 653                 if ($refname !~ /^refs\/heads\/\Q$config{gitmaster_branch}\E$/) {
 654                         error sprintf(gettext("you are not allowed to change %s"), $refname);
 655                 }
 656
 657                 # Avoid chdir when running git here, because the changes
 658                 # are in the master git repo, not the srcdir repo.
 659                 # The pre-recieve hook already puts us in the right place.
 660                 $no_chdir=1;
 661                 my @changes=git_commit_info($oldrev."..".$newrev);
 662                 $no_chdir=0;
 663
 664                 foreach my $ci (@changes) {
 665                         foreach my $detail (@{ $ci->{'details'} }) {
 666                                 my $file = $detail->{'file'};
 667
 668                                 # check that all changed files are in the
 669                                 # subdir
 670                                 if (length $subdir &&
 671                                     ! ($file =~ s/^\Q$subdir\E//)) {
 672                                         error sprintf(gettext("you are not allowed to change %s"), $file);
 673                                 }
 674
 675                                 my ($action, $mode, $path);
 676                                 if ($detail->{'status'} =~ /^[M]+\d*$/) {
 677                                         $action="change";
 678                                         $mode=$detail->{'mode_to'};
 679                                 }
 680                                 elsif ($detail->{'status'} =~ /^[AM]+\d*$/) {
 681                                         $action="add";
 682                                         $mode=$detail->{'mode_to'};
 683                                 }
 684                                 elsif ($detail->{'status'} =~ /^[DAM]+\d*/) {
 685                                         $action="remove";
 686                                         $mode=$detail->{'mode_from'};
 687                                 }
 688                                 else {
 689                                         error "unknown status ".$detail->{'status'};
 690                                 }
 691
 692                                 # test that the file mode is ok
 693                                 if ($mode !~ /^100[64][64][64]$/) {
 694                                         error sprintf(gettext("you cannot act on a file with mode %s"), $mode);
 695                                 }
 696                                 if ($action eq "change") {
 697                                         if ($detail->{'mode_from'} ne $detail->{'mode_to'}) {
 698                                                 error gettext("you are not allowed to change file modes");
 699                                         }
 700                                 }
 701
 702                                 # extract attachment to temp file
 703                                 if (($action eq 'add' || $action eq 'change') &&
 704                                      ! pagetype($file)) {
 705                                         eval q{use File::Temp};
 706                                         die $@ if $@;
 707                                         my $fh;
 708                                         ($fh, $path)=File::Temp::tempfile("XXXXXXXXXX", UNLINK => 1);
 709                                         if (system("git show ".$detail->{sha1_to}." > '$path'") != 0) {
 710                                                 error("failed writing temp file");
 711                                         }
 712                                 }
 713
 714                                 push @rets, {
 715                                         file => $file,
 716                                         action => $action,
 717                                         path => $path,
 718                                 };
 719                         }
 720                 }
 721         }
 722
 723         return reverse @rets;
 724 }
 725
 726 1