git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 2.00;
  12 use Encode;
  13 use Locale::Po4a::Chooser;
  14 use Locale::Po4a::Po;
  15 use File::Basename;
  16 use File::Copy;
  17 use File::Spec;
  18 use File::Temp;
  19 use Memoize;
  20 use UNIVERSAL;
  21
  22 my %translations;
  23 my @origneedsbuild;
  24 my %origsubs;
  25
  26 memoize("_istranslation");
  27 memoize("percenttranslated");
  28
  29 sub import { #{{{
  30         hook(type => "getsetup", id => "po", call => \&getsetup);
  31         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  32         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  33         hook(type => "scan", id => "po", call => \&scan, last =>1);
  34         hook(type => "filter", id => "po", call => \&filter);
  35         hook(type => "htmlize", id => "po", call => \&htmlize);
  36         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  37         hook(type => "change", id => "po", call => \&change);
  38         hook(type => "editcontent", id => "po", call => \&editcontent);
  39
  40         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  41         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  42         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  43         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  44         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  45         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  46         $origsubs{'urlto'}=\&IkiWiki::urlto;
  47         inject(name => "IkiWiki::urlto", call => \&myurlto);
  48 } #}}}
  49
  50
  51 # ,----
  52 # | Table of contents
  53 # `----
  54
  55 # 1. Hooks
  56 # 2. Injected functions
  57 # 3. Blackboxes for private data
  58 # 4. Helper functions
  59 # 5. PageSpec's
  60
  61
  62 # ,----
  63 # | Hooks
  64 # `----
  65
  66 sub getsetup () { #{{{
  67         return
  68                 plugin => {
  69                         safe => 0,
  70                         rebuild => 1,
  71                 },
  72                 po_master_language => {
  73                         type => "string",
  74                         example => {
  75                                 'code' => 'en',
  76                                 'name' => 'English'
  77                         },
  78                         description => "master language (non-PO files)",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 po_slave_languages => {
  83                         type => "string",
  84                         example => {
  85                                 'fr' => 'Français',
  86                                 'es' => 'Castellano',
  87                                 'de' => 'Deutsch'
  88                         },
  89                         description => "slave languages (PO files)",
  90                         safe => 1,
  91                         rebuild => 1,
  92                 },
  93                 po_translatable_pages => {
  94                         type => "pagespec",
  95                         example => "!*/Discussion",
  96                         description => "PageSpec controlling which pages are translatable",
  97                         link => "ikiwiki/PageSpec",
  98                         safe => 1,
  99                         rebuild => 1,
 100                 },
 101                 po_link_to => {
 102                         type => "string",
 103                         example => "current",
 104                         description => "internal linking behavior (default/current/negotiated)",
 105                         safe => 1,
 106                         rebuild => 1,
 107                 },
 108 } #}}}
 109
 110 sub checkconfig () { #{{{
 111         foreach my $field (qw{po_master_language po_slave_languages}) {
 112                 if (! exists $config{$field} || ! defined $config{$field}) {
 113                         error(sprintf(gettext("Must specify %s"), $field));
 114                 }
 115         }
 116         if (! (keys %{$config{po_slave_languages}})) {
 117                 error(gettext("At least one slave language must be defined in po_slave_languages"));
 118         }
 119         map {
 120                 islanguagecode($_)
 121                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 122         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 123         if (! exists $config{po_translatable_pages} ||
 124             ! defined $config{po_translatable_pages}) {
 125                 $config{po_translatable_pages}="";
 126         }
 127         if (! exists $config{po_link_to} ||
 128             ! defined $config{po_link_to}) {
 129                 $config{po_link_to}='default';
 130         }
 131         elsif (! grep {
 132                         $config{po_link_to} eq $_
 133                 } ('default', 'current', 'negotiated')) {
 134                 warn(sprintf(gettext('po_link_to=%s is not a valid setting, falling back to po_link_to=default'),
 135                                 $config{po_link_to}));
 136                 $config{po_link_to}='default';
 137         }
 138         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 139                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 140                 $config{po_link_to}='default';
 141         }
 142         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 143 } #}}}
 144
 145 sub needsbuild () { #{{{
 146         my $needsbuild=shift;
 147
 148         # backup @needsbuild content so that change() can know whether
 149         # a given master page was rendered because its source file was changed
 150         @origneedsbuild=(@$needsbuild);
 151
 152         buildtranslationscache();
 153
 154         # make existing translations depend on the corresponding master page
 155         foreach my $master (keys %translations) {
 156                 map add_depends($_, $master), values %{otherlanguages($master)};
 157         }
 158 } #}}}
 159
 160 # Massage the recorded state of internal links so that:
 161 # - it matches the actually generated links, rather than the links as written
 162 #   in the pages' source
 163 # - backlinks are consistent in all cases
 164 sub scan (@) { #{{{
 165         my %params=@_;
 166         my $page=$params{page};
 167         my $content=$params{content};
 168
 169         return unless UNIVERSAL::can("IkiWiki::Plugin::link", "import");
 170
 171         if (istranslation($page)) {
 172                 foreach my $destpage (@{$links{$page}}) {
 173                         if (istranslatable($destpage)) {
 174                                 # replace one occurence of $destpage in $links{$page}
 175                                 # (we only want to replace the one that was added by
 176                                 # IkiWiki::Plugin::link::scan, other occurences may be
 177                                 # there for other reasons)
 178                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 179                                         if (@{$links{$page}}[$i] eq $destpage) {
 180                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 181                                                 last;
 182                                         }
 183                                 }
 184                         }
 185                 }
 186         }
 187         elsif (! istranslatable($page) && ! istranslation($page)) {
 188                 foreach my $destpage (@{$links{$page}}) {
 189                         if (istranslatable($destpage)) {
 190                                 # make sure any destpage's translations has
 191                                 # $page in its backlinks
 192                                 push @{$links{$page}},
 193                                         values %{otherlanguages($destpage)};
 194                         }
 195                 }
 196         }
 197 } #}}}
 198
 199 # We use filter to convert PO to the master page's format,
 200 # since the rest of ikiwiki should not work on PO files.
 201 sub filter (@) { #{{{
 202         my %params = @_;
 203
 204         my $page = $params{page};
 205         my $destpage = $params{destpage};
 206         my $content = decode_utf8(encode_utf8($params{content}));
 207
 208         return $content if ( ! istranslation($page)
 209                              || alreadyfiltered($page, $destpage) );
 210
 211         # CRLF line terminators make poor Locale::Po4a feel bad
 212         $content=~s/\r\n/\n/g;
 213
 214         # Implementation notes
 215         #
 216         # 1. Locale::Po4a reads/writes from/to files, and I'm too lazy
 217         #    to learn how to disguise a variable as a file.
 218         # 2. There are incompatibilities between some File::Temp versions
 219         #    (including 0.18, bundled with Lenny's perl-modules package)
 220         #    and others (e.g. 0.20, previously present in the archive as
 221         #    a standalone package): under certain circumstances, some
 222         #    return a relative filename, whereas others return an absolute one;
 223         #    we here use this module in a way that is at least compatible
 224         #    with 0.18 and 0.20. Beware, hit'n'run refactorers!
 225         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
 226                                     DIR => File::Spec->tmpdir,
 227                                     UNLINK => 1)->filename;
 228         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
 229                                      DIR => File::Spec->tmpdir,
 230                                      UNLINK => 1)->filename;
 231
 232         writefile(basename($infile), File::Spec->tmpdir, $content);
 233
 234         my $masterfile = srcfile($pagesources{masterpage($page)});
 235         my (@pos,@masters);
 236         push @pos,$infile;
 237         push @masters,$masterfile;
 238         my %options = (
 239                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 240         );
 241         my $doc=Locale::Po4a::Chooser::new('text',%options);
 242         $doc->process(
 243                 'po_in_name'    => \@pos,
 244                 'file_in_name'  => \@masters,
 245                 'file_in_charset'  => 'utf-8',
 246                 'file_out_charset' => 'utf-8',
 247         ) or error("[po/filter:$page]: failed to translate");
 248         $doc->write($outfile) or error("[po/filter:$page] could not write $outfile");
 249         $content = readfile($outfile) or error("[po/filter:$page] could not read $outfile");
 250
 251         # Unlinking should happen automatically, thanks to File::Temp,
 252         # but it does not work here, probably because of the way writefile()
 253         # and Locale::Po4a::write() work.
 254         unlink $infile, $outfile;
 255
 256         setalreadyfiltered($page, $destpage);
 257         return $content;
 258 } #}}}
 259
 260 sub htmlize (@) { #{{{
 261         my %params=@_;
 262
 263         my $page = $params{page};
 264         my $content = $params{content};
 265         my $masterfile = srcfile($pagesources{masterpage($page)});
 266
 267         # force content to be htmlize'd as if it was the same type as the master page
 268         return IkiWiki::htmlize($page, $page, pagetype($masterfile), $content);
 269 } #}}}
 270
 271 sub pagetemplate (@) { #{{{
 272         my %params=@_;
 273         my $page=$params{page};
 274         my $destpage=$params{destpage};
 275         my $template=$params{template};
 276
 277         my ($masterpage, $lang) = istranslation($page);
 278
 279         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 280                 $template->param(percenttranslated => percenttranslated($page));
 281         }
 282         if ($template->query(name => "istranslation")) {
 283                 $template->param(istranslation => scalar istranslation($page));
 284         }
 285         if ($template->query(name => "istranslatable")) {
 286                 $template->param(istranslatable => istranslatable($page));
 287         }
 288         if ($template->query(name => "otherlanguages")) {
 289                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 290                 map add_depends($page, $_), (values %{otherlanguages($page)});
 291         }
 292         # Rely on IkiWiki::Render's genpage() to decide wether
 293         # a discussion link should appear on $page; this is not
 294         # totally accurate, though: some broken links may be generated
 295         # when cgiurl is disabled.
 296         # This compromise avoids some code duplication, and will probably
 297         # prevent future breakage when ikiwiki internals change.
 298         # Known limitations are preferred to future random bugs.
 299         if ($template->param('discussionlink') && istranslation($page)) {
 300                 $template->param('discussionlink' => htmllink(
 301                                                         $page,
 302                                                         $destpage,
 303                                                         $masterpage . '/' . gettext("Discussion"),
 304                                                         noimageinline => 1,
 305                                                         forcesubpage => 0,
 306                                                         linktext => gettext("Discussion"),
 307                                                         ));
 308         }
 309         # Remove broken parentlink to ./index.html on home page's translations.
 310         # It works because this hook has the "last" parameter set, to ensure it
 311         # runs after parentlinks' own pagetemplate hook.
 312         if ($template->param('parentlinks')
 313             && istranslation($page)
 314             && $masterpage eq "index") {
 315                 $template->param('parentlinks' => []);
 316         }
 317 } # }}}
 318
 319 sub change(@) { #{{{
 320         my @rendered=@_;
 321
 322         my $updated_po_files=0;
 323
 324         # Refresh/create POT and PO files as needed.
 325         foreach my $page (map pagename($_), @rendered) {
 326                 next unless istranslatable($page);
 327                 my $file=srcfile($pagesources{$page});
 328                 my $updated_pot_file=0;
 329                 # Only refresh Pot file if it does not exist, or if
 330                 # $pagesources{$page} was changed: don't if only the HTML was
 331                 # refreshed, e.g. because of a dependency.
 332                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 333                     || ! -e potfile($file)) {
 334                         refreshpot($file);
 335                         $updated_pot_file=1;
 336                 }
 337                 my @pofiles;
 338                 map {
 339                         push @pofiles, $_ if ($updated_pot_file || ! -e $_);
 340                 } (pofiles($file));
 341                 if (@pofiles) {
 342                         refreshpofiles($file, @pofiles);
 343                         map { IkiWiki::rcs_add($_); } @pofiles if ($config{rcs});
 344                         $updated_po_files=1;
 345                 }
 346         }
 347
 348         if ($updated_po_files) {
 349                 # Check staged changes in.
 350                 if ($config{rcs}) {
 351                         IkiWiki::disable_commit_hook();
 352                         IkiWiki::rcs_commit_staged(gettext("updated PO files"),
 353                                 "IkiWiki::Plugin::po::change", "127.0.0.1");
 354                         IkiWiki::enable_commit_hook();
 355                         IkiWiki::rcs_update();
 356                 }
 357                 # Reinitialize module's private variables.
 358                 resetalreadyfiltered();
 359                 resettranslationscache();
 360                 # Trigger a wiki refresh.
 361                 require IkiWiki::Render;
 362                 IkiWiki::refresh();
 363                 IkiWiki::saveindex();
 364         }
 365 } #}}}
 366
 367 # As we're previewing or saving a page, the content may have
 368 # changed, so tell the next filter() invocation it must not be lazy.
 369 sub editcontent () { #{{{
 370         my %params=@_;
 371
 372         unsetalreadyfiltered($params{page}, $params{page});
 373         return $params{content};
 374 } #}}}
 375
 376
 377 # ,----
 378 # | Injected functions
 379 # `----
 380
 381 # Implement po_link_to=current
 382 sub mybestlink ($$) { #{{{
 383         my $page=shift;
 384         my $link=shift;
 385
 386         my $res=$origsubs{'bestlink'}->($page, $link);
 387         if (length $res
 388             && $config{po_link_to} eq "current"
 389             && istranslatable($res)
 390             && istranslation($page)) {
 391                 return $res . "." . lang($page);
 392         }
 393         return $res;
 394 } #}}}
 395
 396 sub mybeautify_urlpath ($) { #{{{
 397         my $url=shift;
 398
 399         my $res=$origsubs{'beautify_urlpath'}->($url);
 400         if ($config{po_link_to} eq "negotiated") {
 401                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 402         }
 403         return $res;
 404 } #}}}
 405
 406 sub mytargetpage ($$) { #{{{
 407         my $page=shift;
 408         my $ext=shift;
 409
 410         if (istranslation($page) || istranslatable($page)) {
 411                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 412                 if (! $config{usedirs} || $masterpage eq 'index') {
 413                         return $masterpage . "." . $lang . "." . $ext;
 414                 }
 415                 else {
 416                         return $masterpage . "/index." . $lang . "." . $ext;
 417                 }
 418         }
 419         return $origsubs{'targetpage'}->($page, $ext);
 420 } #}}}
 421
 422 sub myurlto ($$;$) { #{{{
 423         my $to=shift;
 424         my $from=shift;
 425         my $absolute=shift;
 426
 427         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 428         if (! length $to
 429             && $config{po_link_to} eq "current"
 430             && istranslatable('index')) {
 431                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 432         }
 433         return $origsubs{'urlto'}->($to,$from,$absolute);
 434 } #}}}
 435
 436
 437 # ,----
 438 # | Blackboxes for private data
 439 # `----
 440
 441 {
 442         my %filtered;
 443
 444         sub alreadyfiltered($$) { #{{{
 445                 my $page=shift;
 446                 my $destpage=shift;
 447
 448                 return ( exists $filtered{$page}{$destpage}
 449                          && $filtered{$page}{$destpage} eq 1 );
 450         } #}}}
 451
 452         sub setalreadyfiltered($$) { #{{{
 453                 my $page=shift;
 454                 my $destpage=shift;
 455
 456                 $filtered{$page}{$destpage}=1;
 457         } #}}}
 458
 459         sub unsetalreadyfiltered($$) { #{{{
 460                 my $page=shift;
 461                 my $destpage=shift;
 462
 463                 if (exists $filtered{$page}{$destpage}) {
 464                         delete $filtered{$page}{$destpage};
 465                 }
 466         } #}}}
 467
 468         sub resetalreadyfiltered() { #{{{
 469                 undef %filtered;
 470         } #}}}
 471 }
 472
 473
 474 # ,----
 475 # | Helper functions
 476 # `----
 477
 478 sub istranslatable ($) { #{{{
 479         my $page=shift;
 480
 481         my $file=$pagesources{$page};
 482
 483         return 0 unless defined $file;
 484         return 0 if (defined pagetype($file) && pagetype($file) eq 'po');
 485         return 0 if $file =~ /\.pot$/;
 486         return pagespec_match($page, $config{po_translatable_pages});
 487 } #}}}
 488
 489 sub _istranslation ($) { #{{{
 490         my $page=shift;
 491
 492         my $file=$pagesources{$page};
 493
 494         return 0 unless (defined $file
 495                          && defined pagetype($file)
 496                          && pagetype($file) eq 'po');
 497         return 0 if $file =~ /\.pot$/;
 498
 499         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 500         return 0 unless (defined $masterpage && defined $lang
 501                          && length $masterpage && length $lang
 502                          && defined $pagesources{$masterpage}
 503                          && defined $config{po_slave_languages}{$lang});
 504
 505         return ($masterpage, $lang) if istranslatable($masterpage);
 506 } #}}}
 507
 508 sub istranslation ($) { #{{{
 509         my $page=shift;
 510
 511         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 512                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 513                 return ($masterpage, $lang);
 514         }
 515         return;
 516 } #}}}
 517
 518 sub masterpage ($) { #{{{
 519         my $page=shift;
 520
 521         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 522                 return $masterpage;
 523         }
 524         return $page;
 525 } #}}}
 526
 527 sub lang ($) { #{{{
 528         my $page=shift;
 529
 530         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 531                 return $lang;
 532         }
 533         return $config{po_master_language}{code};
 534 } #}}}
 535
 536 sub islanguagecode ($) { #{{{
 537         my $code=shift;
 538
 539         return ($code =~ /^[a-z]{2}$/);
 540 } #}}}
 541
 542 sub otherlanguages($) { #{{{
 543         my $page=shift;
 544
 545         my %ret;
 546         if (istranslatable($page)) {
 547                 %ret = %{$translations{$page}};
 548         }
 549         elsif (istranslation($page)) {
 550                 my $masterpage = masterpage($page);
 551                 $ret{$config{po_master_language}{code}} = $masterpage;
 552                 foreach my $lang (sort keys %{$translations{$masterpage}}) {
 553                         next if $lang eq lang($page);
 554                         $ret{$lang} = $translations{$masterpage}{$lang};
 555                 }
 556         }
 557         return \%ret;
 558 } #}}}
 559
 560 sub potfile ($) { #{{{
 561         my $masterfile=shift;
 562
 563         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 564         $dir='' if $dir eq './';
 565         return File::Spec->catpath('', $dir, $name . ".pot");
 566 } #}}}
 567
 568 sub pofile ($$) { #{{{
 569         my $masterfile=shift;
 570         my $lang=shift;
 571
 572         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 573         $dir='' if $dir eq './';
 574         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 575 } #}}}
 576
 577 sub pofiles ($) { #{{{
 578         my $masterfile=shift;
 579
 580         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 581 } #}}}
 582
 583 sub refreshpot ($) { #{{{
 584         my $masterfile=shift;
 585
 586         my $potfile=potfile($masterfile);
 587         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 588         my $doc=Locale::Po4a::Chooser::new('text',%options);
 589         $doc->{TT}{utf_mode} = 1;
 590         $doc->{TT}{file_in_charset} = 'utf-8';
 591         $doc->{TT}{file_out_charset} = 'utf-8';
 592         $doc->read($masterfile);
 593         # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
 594         # this is undocument use of internal Locale::Po4a::TransTractor's data,
 595         # compulsory since this module prevents us from using the porefs option.
 596         my %po_options = ('porefs' => 'none');
 597         $doc->{TT}{po_out}=Locale::Po4a::Po->new(\%po_options);
 598         $doc->{TT}{po_out}->set_charset('utf-8');
 599         # do the actual work
 600         $doc->parse;
 601         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 602         $doc->writepo($potfile);
 603 } #}}}
 604
 605 sub refreshpofiles ($@) { #{{{
 606         my $masterfile=shift;
 607         my @pofiles=@_;
 608
 609         my $potfile=potfile($masterfile);
 610         error("[po/refreshpofiles] POT file ($potfile) does not exist") unless (-e $potfile);
 611
 612         foreach my $pofile (@pofiles) {
 613                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 614                 if (-e $pofile) {
 615                         system("msgmerge", "-U", "--backup=none", $pofile, $potfile) == 0
 616                                 or error("[po/refreshpofiles:$pofile] failed to update");
 617                 }
 618                 else {
 619                         File::Copy::syscopy($potfile,$pofile)
 620                                 or error("[po/refreshpofiles:$pofile] failed to copy the POT file");
 621                 }
 622         }
 623 } #}}}
 624
 625 sub buildtranslationscache() { #{{{
 626         # use istranslation's side-effect
 627         map istranslation($_), (keys %pagesources);
 628 } #}}}
 629
 630 sub resettranslationscache() { #{{{
 631         undef %translations;
 632 } #}}}
 633
 634 sub urlto_with_orig_beautiful_urlpath($$) { #{{{
 635         my $to=shift;
 636         my $from=shift;
 637
 638         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 639         my $res=urlto($to, $from);
 640         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 641
 642         return $res;
 643 } #}}}
 644
 645 sub percenttranslated ($) { #{{{
 646         my $page=shift;
 647
 648         return gettext("N/A") unless istranslation($page);
 649         my $file=srcfile($pagesources{$page});
 650         my $masterfile = srcfile($pagesources{masterpage($page)});
 651         my (@pos,@masters);
 652         push @pos,$file;
 653         push @masters,$masterfile;
 654         my %options = (
 655                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 656         );
 657         my $doc=Locale::Po4a::Chooser::new('text',%options);
 658         $doc->process(
 659                 'po_in_name'    => \@pos,
 660                 'file_in_name'  => \@masters,
 661                 'file_in_charset'  => 'utf-8',
 662                 'file_out_charset' => 'utf-8',
 663         ) or error("[po/percenttranslated:$page]: failed to translate");
 664         my ($percent,$hit,$queries) = $doc->stats();
 665         return $percent;
 666 } #}}}
 667
 668 sub languagename ($) { #{{{
 669         my $code=shift;
 670
 671         return $config{po_master_language}{name}
 672                 if $code eq $config{po_master_language}{code};
 673         return $config{po_slave_languages}{$code}
 674                 if defined $config{po_slave_languages}{$code};
 675         return;
 676 } #}}}
 677
 678 sub otherlanguagesloop ($) { #{{{
 679         my $page=shift;
 680
 681         my @ret;
 682         my %otherpages=%{otherlanguages($page)};
 683         while (my ($lang, $otherpage) = each %otherpages) {
 684                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 685                         push @ret, {
 686                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 687                                 code => $lang,
 688                                 language => languagename($lang),
 689                                 master => 1,
 690                         };
 691                 }
 692                 else {
 693                         push @ret, {
 694                                 url => urlto($otherpage, $page),
 695                                 code => $lang,
 696                                 language => languagename($lang),
 697                                 percent => percenttranslated($otherpage),
 698                         }
 699                 }
 700         }
 701         return sort {
 702                         return -1 if $a->{code} eq $config{po_master_language}{code};
 703                         return 1 if $b->{code} eq $config{po_master_language}{code};
 704                         return $a->{language} cmp $b->{language};
 705                 } @ret;
 706 } #}}}
 707
 708
 709 # ,----
 710 # | PageSpec's
 711 # `----
 712
 713 package IkiWiki::PageSpec;
 714 use warnings;
 715 use strict;
 716 use IkiWiki 2.00;
 717
 718 sub match_istranslation ($;@) { #{{{
 719         my $page=shift;
 720
 721         if (IkiWiki::Plugin::po::istranslation($page)) {
 722                 return IkiWiki::SuccessReason->new("is a translation page");
 723         }
 724         else {
 725                 return IkiWiki::FailReason->new("is not a translation page");
 726         }
 727 } #}}}
 728
 729 sub match_istranslatable ($;@) { #{{{
 730         my $page=shift;
 731
 732         if (IkiWiki::Plugin::po::istranslatable($page)) {
 733                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
 734         }
 735         else {
 736                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
 737         }
 738 } #}}}
 739
 740 sub match_lang ($$;@) { #{{{
 741         my $page=shift;
 742         my $wanted=shift;
 743
 744         my $regexp=IkiWiki::glob2re($wanted);
 745         my $lang=IkiWiki::Plugin::po::lang($page);
 746         if ($lang!~/^$regexp$/i) {
 747                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
 748         }
 749         else {
 750                 return IkiWiki::SuccessReason->new("file language is $wanted");
 751         }
 752 } #}}}
 753
 754 sub match_currentlang ($$;@) { #{{{
 755         my $page=shift;
 756         shift;
 757         my %params=@_;
 758
 759         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
 760
 761         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
 762         my $lang=IkiWiki::Plugin::po::lang($page);
 763
 764         if ($lang eq $currentlang) {
 765                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
 766         }
 767         else {
 768                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
 769         }
 770 } #}}}
 771
 772 1