git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/remove.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::remove;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         hook(type => "getsetup", id => "remove", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "remove", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "remove", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "remove", call => \&sessioncgi);
  13
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                         section => "web",
  22                 },
  23 }
  24
  25 sub check_canremove ($$$) {
  26         my $page=shift;
  27         my $q=shift;
  28         my $session=shift;
  29
  30         # Must be a known source file.
  31         if (! exists $pagesources{$page}) {
  32                 error(sprintf(gettext("%s does not exist"),
  33                         htmllink("", "", $page, noimageinline => 1)));
  34         }
  35
  36         # Must exist on disk, and be a regular file.
  37         my $file=$pagesources{$page};
  38         if (! -e "$config{srcdir}/$file") {
  39                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be deleted"), $file));
  40         }
  41         elsif (-l "$config{srcdir}/$file" && ! -f _) {
  42                 error(sprintf(gettext("%s is not a file"), $file));
  43         }
  44
  45         # If a user can't upload an attachment, don't let them delete it.
  46         # This is sorta overkill, but better safe than sorry.
  47         if (! defined pagetype($pagesources{$page})) {
  48                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
  49                         IkiWiki::Plugin::attachment::check_canattach($session, $page, "$config{srcdir}/$file");
  50                 }
  51                 else {
  52                         error("removal of attachments is not allowed");
  53                 }
  54         }
  55
  56         my $canremove;
  57         IkiWiki::run_hooks(canremove => sub {
  58                 return if defined $canremove;
  59                 my $ret=shift->(page => $page, cgi => $q, session => $session);
  60                 if (defined $ret) {
  61                         if ($ret eq "") {
  62                                 $canremove=1;
  63                         }
  64                         elsif (ref $ret eq 'CODE') {
  65                                 $ret->();
  66                                 $canremove=0;
  67                         }
  68                         elsif (defined $ret) {
  69                                 error($ret);
  70                                 $canremove=0;
  71                         }
  72                 }
  73         });
  74         return defined $canremove ? $canremove : 1;
  75 }
  76
  77 sub formbuilder_setup (@) {
  78         my %params=@_;
  79         my $form=$params{form};
  80         my $q=$params{cgi};
  81
  82         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
  83             $form->field("do") eq "create")) {
  84                 # Removal button for the page, and also for attachments.
  85                 push @{$params{buttons}}, "Remove" if $form->field("do") eq "edit";
  86                 $form->tmpl_param("field-remove" => '<input name="_submit" type="submit" value="Remove Attachments" />');
  87         }
  88 }
  89
  90 sub confirmation_form ($$) {
  91         my $q=shift;
  92         my $session=shift;
  93
  94         eval q{use CGI::FormBuilder};
  95         error($@) if $@;
  96         my $f = CGI::FormBuilder->new(
  97                 name => "remove",
  98                 header => 0,
  99                 charset => "utf-8",
 100                 method => 'POST',
 101                 javascript => 0,
 102                 params => $q,
 103                 action => $config{cgiurl},
 104                 stylesheet => 1,
 105                 fields => [qw{do page}],
 106         );
 107
 108         $f->field(name => "sid", type => "hidden", value => $session->id,
 109                 force => 1);
 110         $f->field(name => "do", type => "hidden", value => "remove", force => 1);
 111
 112         return $f, ["Remove", "Cancel"];
 113 }
 114
 115 sub removal_confirm ($$@) {
 116         my $q=shift;
 117         my $session=shift;
 118         my $attachment=shift;
 119         my @pages=@_;
 120
 121         foreach my $page (@pages) {
 122                 IkiWiki::check_canedit($page, $q, $session);
 123                 check_canremove($page, $q, $session);
 124         }
 125
 126         # Save current form state to allow returning to it later
 127         # without losing any edits.
 128         # (But don't save what button was submitted, to avoid
 129         # looping back to here.)
 130         # Note: "_submit" is CGI::FormBuilder internals.
 131         $q->param(-name => "_submit", -value => "");
 132         $session->param(postremove => scalar $q->Vars);
 133         IkiWiki::cgi_savesession($session);
 134
 135         my ($f, $buttons)=confirmation_form($q, $session);
 136         $f->title(sprintf(gettext("confirm removal of %s"),
 137                 join(", ", map { pagetitle($_) } @pages)));
 138         $f->field(name => "page", type => "hidden", value => \@pages, force => 1);
 139         if (defined $attachment) {
 140                 $f->field(name => "attachment", type => "hidden",
 141                         value => $attachment, force => 1);
 142         }
 143
 144         IkiWiki::showform($f, $buttons, $session, $q);
 145         exit 0;
 146 }
 147
 148 sub postremove ($) {
 149         my $session=shift;
 150
 151         # Load saved form state and return to edit form.
 152         my $postremove=CGI->new($session->param("postremove"));
 153         $session->clear("postremove");
 154         IkiWiki::cgi_savesession($session);
 155         IkiWiki::cgi($postremove, $session);
 156 }
 157
 158 sub formbuilder (@) {
 159         my %params=@_;
 160         my $form=$params{form};
 161
 162         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
 163             $form->field("do") eq "create")) {
 164                 my $q=$params{cgi};
 165                 my $session=$params{session};
 166
 167                 if ($form->submitted eq "Remove" && $form->field("do") eq "edit") {
 168                         removal_confirm($q, $session, 0, $form->field("page"));
 169                 }
 170                 elsif ($form->submitted eq "Remove Attachments") {
 171                         my @selected=map { Encode::decode_utf8($_) } $q->param("attachment_select");
 172                         if (! @selected) {
 173                                 error(gettext("Please select the attachments to remove."));
 174                         }
 175                         removal_confirm($q, $session, 1, @selected);
 176                 }
 177         }
 178 }
 179
 180 sub sessioncgi ($$) {
 181         my $q=shift;
 182
 183         if ($q->param("do") eq 'remove') {
 184                 my $session=shift;
 185                 my ($form, $buttons)=confirmation_form($q, $session);
 186                 IkiWiki::decode_form_utf8($form);
 187
 188                 if ($form->submitted eq 'Cancel') {
 189                         postremove($session);
 190                 }
 191                 elsif ($form->submitted eq 'Remove' && $form->validate) {
 192                         IkiWiki::checksessionexpiry($q, $session, $q->param('sid'));
 193
 194                         my @pages=$form->field("page");
 195
 196                         # Validate removal by checking that the page exists,
 197                         # and that the user is allowed to edit(/remove) it.
 198                         my @files;
 199                         foreach my $page (@pages) {
 200                                 IkiWiki::check_canedit($page, $q, $session);
 201                                 check_canremove($page, $q, $session);
 202
 203                                 # This untaint is safe because of the
 204                                 # checks performed above, which verify the
 205                                 # page is a normal file, etc.
 206                                 push @files, IkiWiki::possibly_foolish_untaint($pagesources{$page});
 207                         }
 208
 209                         # Do removal, and update the wiki.
 210                         require IkiWiki::Render;
 211                         if ($config{rcs}) {
 212                                 IkiWiki::disable_commit_hook();
 213                                 foreach my $file (@files) {
 214                                         IkiWiki::rcs_remove($file);
 215                                 }
 216                                 IkiWiki::rcs_commit_staged(
 217                                         message => gettext("removed"),
 218                                         session => $session,
 219                                 );
 220                                 IkiWiki::enable_commit_hook();
 221                                 IkiWiki::rcs_update();
 222                         }
 223                         else {
 224                                 foreach my $file (@files) {
 225                                         IkiWiki::prune("$config{srcdir}/$file");
 226                                 }
 227                         }
 228                         IkiWiki::refresh();
 229                         IkiWiki::saveindex();
 230
 231                         if ($q->param("attachment")) {
 232                                 # Attachments were deleted, so redirect
 233                                 # back to the edit form.
 234                                 postremove($session);
 235                         }
 236                         else {
 237                                 # The page is gone, so redirect to parent
 238                                 # of the page.
 239                                 my $parent=IkiWiki::dirname($pages[0]);
 240                                 if (! exists $pagesources{$parent}) {
 241                                         $parent="index";
 242                                 }
 243                                 IkiWiki::redirect($q, urlto($parent, '/', 1));
 244                         }
 245                 }
 246                 else {
 247                         removal_confirm($q, $session, 0, $form->field("page"));
 248                 }
 249
 250                 exit 0;
 251         }
 252 }
 253
 254 1