git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/table.pm

   1 package IkiWiki::Plugin::table;
   2 # by Victor Moral <victor@taquiones.net>
   3
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use IkiWiki 3.00;
   8
   9 sub import {
  10         hook(type => "getsetup", id => "table", call => \&getsetup);
  11         hook(type => "preprocess", id => "table", call => \&preprocess);
  12 }
  13
  14 sub getsetup () {
  15         return
  16                 plugin => {
  17                         safe => 1,
  18                         rebuild => undef,
  19                 },
  20 }
  21
  22 sub preprocess (@) {
  23         my %params =(
  24                 format  => 'auto',
  25                 header  => 'row',
  26                 @_
  27         );
  28
  29         if (exists $params{file}) {
  30                 if (! $pagesources{$params{file}}) {
  31                         error gettext("cannot find file");
  32                 }
  33                 $params{data} = readfile(srcfile($params{file}));
  34                 add_depends($params{page}, $params{file});
  35         }
  36
  37         if (lc $params{format} eq 'auto') {
  38                 # first try the more simple format
  39                 if (is_dsv_data($params{data})) {
  40                         $params{format} = 'dsv';
  41                 }
  42                 else {
  43                         $params{format} = 'csv';
  44                 }
  45         }
  46
  47         my @data;
  48         if (lc $params{format} eq 'csv') {
  49                 @data=split_csv($params{data},
  50                         defined $params{delimiter} ? $params{delimiter} : ",",);
  51                 # linkify after parsing since html link quoting can
  52                 # confuse CSV parsing
  53                 @data=map {
  54                         [ map {
  55                                 IkiWiki::linkify($params{page},
  56                                         $params{destpage}, $_);
  57                         } @$_ ]
  58                 } @data;
  59         }
  60         elsif (lc $params{format} eq 'dsv') {
  61                 # linkify before parsing since wikilinks can contain the
  62                 # delimiter
  63                 $params{data} = IkiWiki::linkify($params{page},
  64                         $params{destpage}, $params{data});
  65                 @data=split_dsv($params{data},
  66                         defined $params{delimiter} ? $params{delimiter} : "|",);
  67         }
  68         else {
  69                 error gettext("unknown data format");
  70         }
  71
  72         my $header;
  73         if (lc($params{header}) eq "row" || IkiWiki::yesno($params{header})) {
  74                 $header=shift @data;
  75         }
  76         if (! @data) {
  77                 error gettext("empty data");
  78         }
  79
  80         my @lines;
  81         push @lines, defined $params{class}
  82                         ? "<table class=\"".$params{class}.'">'
  83                         : '<table>';
  84         push @lines, "\t<thead>",
  85                 genrow(\%params, "th", @$header),
  86                 "\t</thead>" if defined $header;
  87         push @lines, "\t<tbody>" if defined $header;
  88         push @lines, genrow(\%params, "td", @$_) foreach @data;
  89         push @lines, "\t</tbody>" if defined $header;
  90         push @lines, '</table>';
  91         my $html = join("\n", @lines);
  92
  93         if (exists $params{file}) {
  94                 return $html."\n\n".
  95                         htmllink($params{page}, $params{destpage}, $params{file},
  96                                 linktext => gettext('Direct data download'));
  97         }
  98         else {
  99                 return $html;
 100         }
 101 }
 102
 103 sub is_dsv_data ($) {
 104         my $text = shift;
 105
 106         my ($line) = split(/\n/, $text);
 107         return $line =~ m{.+\|};
 108 }
 109
 110 sub split_csv ($$) {
 111         my @text_lines = split(/\n/, shift);
 112         my $delimiter = shift;
 113
 114         eval q{use Text::CSV};
 115         error($@) if $@;
 116         my $csv = Text::CSV->new({
 117                 sep_char        => $delimiter,
 118                 binary          => 1,
 119                 allow_loose_quotes => 1,
 120         }) || error("could not create a Text::CSV object");
 121
 122         my $l=0;
 123         my @data;
 124         foreach my $line (@text_lines) {
 125                 $l++;
 126                 if ($csv->parse($line)) {
 127                         push(@data, [ map { decode_utf8 $_ } $csv->fields() ]);
 128                 }
 129                 else {
 130                         debug(sprintf(gettext('parse fail at line %d: %s'),
 131                                 $l, $csv->error_input()));
 132                 }
 133         }
 134
 135         return @data;
 136 }
 137
 138 sub split_dsv ($$) {
 139         my @text_lines = split(/\n/, shift);
 140         my $delimiter = shift;
 141         $delimiter="|" unless defined $delimiter;
 142
 143         my @data;
 144         foreach my $line (@text_lines) {
 145                 push @data, [ split(/\Q$delimiter\E/, $line, -1) ];
 146         }
 147
 148         return @data;
 149 }
 150
 151 sub genrow ($@) {
 152         my %params=%{shift()};
 153         my $elt = shift;
 154         my @data = @_;
 155
 156         my $page=$params{page};
 157         my $destpage=$params{destpage};
 158         my $type=pagetype($pagesources{$page});
 159
 160         my @ret;
 161         push @ret, "\t\t<tr>";
 162         for (my $x=0; $x < @data; $x++) {
 163                 my $cell=IkiWiki::htmlize($page, $destpage, $type,
 164                          IkiWiki::preprocess($page, $destpage, $data[$x]));
 165
 166                 # automatic colspan for empty cells
 167                 my $colspan=1;
 168                 while ($x+1 < @data && $data[$x+1] eq '') {
 169                         $x++;
 170                         $colspan++;
 171                 }
 172
 173                 # check if the first column should be a header
 174                 my $e=$elt;
 175                 if ($x == 0 && lc($params{header}) eq "column") {
 176                         $e="th";
 177                 }
 178
 179                 if ($colspan > 1) {
 180                         push @ret, "\t\t\t<$e colspan=\"$colspan\">$cell</$e>"
 181                 }
 182                 else {
 183                         push @ret, "\t\t\t<$e>$cell</$e>"
 184                 }
 185         }
 186         push @ret, "\t\t</tr>";
 187
 188         return @ret;
 189 }
 190
 191 1