git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/cvs.pm

   1 #!/usr/pkg/bin/perl
   2 package IkiWiki::Plugin::cvs;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7
   8 sub import {
   9         hook(type => "checkconfig", id => "cvs", call => \&checkconfig);
  10         hook(type => "getsetup", id => "cvs", call => \&getsetup);
  11         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  12         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  13         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  14         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  15         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  16         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  17         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  18         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  19         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  20         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  21 }
  22
  23 sub checkconfig () {
  24         if (! defined $config{cvspath}) {
  25                 $config{cvspath}="ikiwiki";
  26         }
  27         if (exists $config{cvspath}) {
  28                 # code depends on the path not having extraneous slashes
  29                 $config{cvspath}=~tr#/#/#s;
  30                 $config{cvspath}=~s/\/$//;
  31                 $config{cvspath}=~s/^\///;
  32         }
  33         if (defined $config{cvs_wrapper} && length $config{cvs_wrapper}) {
  34                 push @{$config{wrappers}}, {
  35                         wrapper => $config{cvs_wrapper},
  36                         wrappermode => (defined $config{cvs_wrappermode} ? $config{cvs_wrappermode} : "04755"),
  37                 };
  38         }
  39 }
  40
  41 sub getsetup () {
  42         return
  43                 plugin => {
  44                         safe => 0, # rcs plugin
  45                         rebuild => undef,
  46                 },
  47                 cvsrepo => {
  48                         type => "string",
  49                         example => "/cvs/wikirepo",
  50                         description => "cvs repository location",
  51                         safe => 0, # path
  52                         rebuild => 0,
  53                 },
  54                 cvspath => {
  55                         type => "string",
  56                         example => "ikiwiki",
  57                         description => "path inside repository where the wiki is located",
  58                         safe => 0, # paranoia
  59                         rebuild => 0,
  60                 },
  61                 cvs_wrapper => {
  62                         type => "string",
  63                         example => "/cvs/wikirepo/CVSROOT/post-commit",
  64                         description => "cvs post-commit hook to generate (triggered by CVSROOT/loginfo entry",
  65                         safe => 0, # file
  66                         rebuild => 0,
  67                 },
  68                 cvs_wrappermode => {
  69                         type => "string",
  70                         example => '04755',
  71                         description => "mode for cvs_wrapper (can safely be made suid)",
  72                         safe => 0,
  73                         rebuild => 0,
  74                 },
  75                 historyurl => {
  76                         type => "string",
  77                         example => "http://cvs.example.org/cvsweb.cgi/ikiwiki/[[file]]",
  78                         description => "cvsweb url to show file history ([[file]] substituted)",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 diffurl => {
  83                         type => "string",
  84                         example => "http://cvs.example.org/cvsweb.cgi/ikiwiki/[[file]].diff?r1=text&amp;tr1=[[r1]]&amp;r2=text&amp;tr2=[[r2]]",
  85                         description => "cvsweb url to show a diff ([[file]], [[r1]], and [[r2]] substituted)",
  86                         safe => 1,
  87                         rebuild => 1,
  88                 },
  89 }
  90
  91 sub cvs_info ($$) {
  92         my $field=shift;
  93         my $file=shift;
  94
  95         chdir $config{srcdir} || error("Cannot chdir to $config{srcdir}: $!");
  96
  97         my $info=`cvs status $file`;
  98         my ($ret)=$info=~/^\s*$field:\s*(\S+)/m;
  99         return $ret;
 100 }
 101
 102 sub cvs_runcvs(@) {
 103         my ($cmd) = @_;
 104         unshift @$cmd, 'cvs', '-Q';
 105
 106         eval q{use IPC::Cmd};
 107         error($@) if $@;
 108
 109         chdir $config{srcdir} || error("Cannot chdir to $config{srcdir}: $!");
 110
 111         my ($success, $error_code, $full_buf, $stdout_buf, $stderr_buf) =
 112                 IPC::Cmd::run(command => $cmd, verbose => 0);
 113         if (! $success) {
 114                 warn(join(" ", @$cmd) . " exited with code $error_code\n");
 115                 warn(join "", @$stderr_buf);
 116         }
 117         return $success;
 118 }
 119
 120 sub cvs_shquote_commit ($) {
 121         my $message = shift;
 122
 123         eval q{use String::ShellQuote};
 124         error($@) if $@;
 125
 126         return shell_quote(IkiWiki::possibly_foolish_untaint($message));
 127 }
 128
 129 sub cvs_is_controlling {
 130         my $dir=shift;
 131         $dir=$config{srcdir} unless defined($dir);
 132         return (-d "$dir/CVS") ? 1 : 0;
 133 }
 134
 135 sub rcs_update () {
 136         return unless cvs_is_controlling;
 137         cvs_runcvs(['update', '-dP']);
 138 }
 139
 140 sub rcs_prepedit ($) {
 141         # Prepares to edit a file under revision control. Returns a token
 142         # that must be passed into rcs_commit when the file is ready
 143         # for committing.
 144         # The file is relative to the srcdir.
 145         my $file=shift;
 146
 147         return unless cvs_is_controlling;
 148
 149         # For cvs, return the revision of the file when
 150         # editing begins.
 151         my $rev=cvs_info("Repository revision", "$file");
 152         return defined $rev ? $rev : "";
 153 }
 154
 155 sub rcs_commit ($$$;$$) {
 156         # Tries to commit the page; returns undef on _success_ and
 157         # a version of the page with the rcs's conflict markers on failure.
 158         # The file is relative to the srcdir.
 159         my $file=shift;
 160         my $message=shift;
 161         my $rcstoken=shift;
 162         my $user=shift;
 163         my $ipaddr=shift;
 164
 165         return unless cvs_is_controlling;
 166
 167         if (defined $user) {
 168                 $message="web commit by $user".(length $message ? ": $message" : "");
 169         }
 170         elsif (defined $ipaddr) {
 171                 $message="web commit from $ipaddr".(length $message ? ": $message" : "");
 172         }
 173
 174         # Check to see if the page has been changed by someone
 175         # else since rcs_prepedit was called.
 176         my ($oldrev)=$rcstoken=~/^([0-9]+)$/; # untaint
 177         my $rev=cvs_info("Repository revision", "$config{srcdir}/$file");
 178         if (defined $rev && defined $oldrev && $rev != $oldrev) {
 179                 # Merge their changes into the file that we've
 180                 # changed.
 181                 cvs_runcvs(['update', $file]) ||
 182                         warn("cvs merge from $oldrev to $rev failed\n");
 183         }
 184
 185         if (! cvs_runcvs(['commit', '-m', cvs_shquote_commit $message])) {
 186                 my $conflict=readfile("$config{srcdir}/$file");
 187                 cvs_runcvs(['update', '-C', $file]) ||
 188                         warn("cvs revert failed\n");
 189                 return $conflict;
 190         }
 191
 192         return undef # success
 193 }
 194
 195 sub rcs_commit_staged ($$$) {
 196         # Commits all staged changes. Changes can be staged using rcs_add,
 197         # rcs_remove, and rcs_rename.
 198         my ($message, $user, $ipaddr)=@_;
 199
 200         if (defined $user) {
 201                 $message="web commit by $user".(length $message ? ": $message" : "");
 202         }
 203         elsif (defined $ipaddr) {
 204                 $message="web commit from $ipaddr".(length $message ? ": $message" : "");
 205         }
 206
 207         if (! cvs_runcvs(['commit', '-m', cvs_shquote_commit $message])) {
 208                 warn "cvs staged commit failed\n";
 209                 return 1; # failure
 210         }
 211         return undef # success
 212 }
 213
 214 sub rcs_add ($) {
 215         # filename is relative to the root of the srcdir
 216         my $file=shift;
 217         my $parent=IkiWiki::dirname($file);
 218         my @files_to_add = ($file);
 219
 220         eval q{use File::MimeInfo};
 221         error($@) if $@;
 222
 223         until ((length($parent) == 0) || cvs_is_controlling("$config{srcdir}/$parent")){
 224                 push @files_to_add, $parent;
 225                 $parent = IkiWiki::dirname($parent);
 226         }
 227
 228         while ($file = pop @files_to_add) {
 229                 if (@files_to_add == 0) {
 230                         # file
 231                         my $filemime = File::MimeInfo::default($file);
 232                         if (defined($filemime) && $filemime eq 'text/plain') {
 233                                 cvs_runcvs(['add', $file]) ||
 234                                         warn("cvs add $file failed\n");
 235                         } else {
 236                                 cvs_runcvs(['add', '-kb', $file]) ||
 237                                         warn("cvs add binary $file failed\n");
 238                         }
 239                 } else {
 240                         # directory
 241                         cvs_runcvs(['add', $file]) ||
 242                                 warn("cvs add $file failed\n");
 243                 }
 244         }
 245 }
 246
 247 sub rcs_remove ($) {
 248         # filename is relative to the root of the srcdir
 249         my $file=shift;
 250
 251         return unless cvs_is_controlling;
 252
 253         cvs_runcvs(['rm', '-f', $file]) ||
 254                 warn("cvs rm $file failed\n");
 255 }
 256
 257 sub rcs_rename ($$) {
 258         # filenames relative to the root of the srcdir
 259         my ($src, $dest)=@_;
 260
 261         return unless cvs_is_controlling;
 262
 263         chdir $config{srcdir} || error("Cannot chdir to $config{srcdir}: $!");
 264
 265         if (system("mv", "$src", "$dest") != 0) {
 266                 warn("filesystem rename failed\n");
 267         }
 268
 269         rcs_add($dest);
 270         rcs_remove($src);
 271 }
 272
 273 sub rcs_recentchanges($) {
 274         my $num = shift;
 275         my @ret;
 276
 277         return unless cvs_is_controlling;
 278
 279         eval q{use Date::Parse};
 280         error($@) if $@;
 281
 282         chdir $config{srcdir} || error("Cannot chdir to $config{srcdir}: $!");
 283
 284         # There's no cvsps option to get the last N changesets.
 285         # Write full output to a temp file and read backwards.
 286
 287         eval q{use File::Temp qw/tempfile/};
 288         error($@) if $@;
 289         eval q{use File::ReadBackwards};
 290         error($@) if $@;
 291
 292         my (undef, $tmpfile) = tempfile(OPEN=>0);
 293         system("env TZ=UTC cvsps -q --cvs-direct -z 30 -x >$tmpfile");
 294         if ($? == -1) {
 295                 error "couldn't run cvsps: $!\n";
 296         } elsif (($? >>8) != 0) {
 297                 error "cvsps exited " . ($? >> 8) . ": $!\n";
 298         }
 299
 300         tie(*SPSVC, 'File::ReadBackwards', $tmpfile)
 301                 || error "couldn't open $tmpfile for read: $!\n";
 302
 303         while (my $line = <SPSVC>) {
 304                 $line =~ /^$/ || error "expected blank line, got $line";
 305
 306                 my ($rev, $user, $committype, $when);
 307                 my (@message, @pages);
 308
 309                 # We're reading backwards.
 310                 # Forwards, an entry looks like so:
 311                 # ---------------------
 312                 # PatchSet $rev
 313                 # Date: $when
 314                 # Author: $user (or user CGI runs as, for web commits)
 315                 # Branch: branch
 316                 # Tag: tag
 317                 # Log:
 318                 # @message_lines
 319                 # Members:
 320                 #       @pages (and revisions)
 321                 #
 322
 323                 while ($line = <SPSVC>) {
 324                         last if ($line =~ /^Members:/);
 325                         for ($line) {
 326                                 s/^\s+//;
 327                                 s/\s+$//;
 328                         }
 329                         my ($page, $revs) = split(/:/, $line);
 330                         my ($oldrev, $newrev) = split(/->/, $revs);
 331                         $oldrev =~ s/INITIAL/0/;
 332                         $newrev =~ s/\(DEAD\)//;
 333                         my $diffurl = defined $config{diffurl} ? $config{diffurl} : "";
 334                         $diffurl=~s/\[\[file\]\]/$page/g;
 335                         $diffurl=~s/\[\[r1\]\]/$oldrev/g;
 336                         $diffurl=~s/\[\[r2\]\]/$newrev/g;
 337                         unshift @pages, {
 338                                 page => pagename($page),
 339                                 diffurl => $diffurl,
 340                         } if length $page;
 341                 }
 342
 343                 while ($line = <SPSVC>) {
 344                         last if ($line =~ /^Log:$/);
 345                         chomp $line;
 346                         unshift @message, { line => $line };
 347                 }
 348                 $committype = "web";
 349                 if (defined $message[0] &&
 350                     $message[0]->{line}=~/$config{web_commit_regexp}/) {
 351                         $user=defined $2 ? "$2" : "$3";
 352                         $message[0]->{line}=$4;
 353                 } else {
 354                         $committype="cvs";
 355                 }
 356
 357                 $line = <SPSVC>;        # Tag
 358                 $line = <SPSVC>;        # Branch
 359
 360                 $line = <SPSVC>;
 361                 if ($line =~ /^Author: (.*)$/) {
 362                         $user = $1 unless defined $user && length $user;
 363                 } else {
 364                         error "expected Author, got $line";
 365                 }
 366
 367                 $line = <SPSVC>;
 368                 if ($line =~ /^Date: (.*)$/) {
 369                         $when = str2time($1, 'UTC');
 370                 } else {
 371                         error "expected Date, got $line";
 372                 }
 373
 374                 $line = <SPSVC>;
 375                 if ($line =~ /^PatchSet (.*)$/) {
 376                         $rev = $1;
 377                 } else {
 378                         error "expected PatchSet, got $line";
 379                 }
 380
 381                 $line = <SPSVC>;        # ---------------------
 382
 383                 push @ret, {
 384                         rev => $rev,
 385                         user => $user,
 386                         committype => $committype,
 387                         when => $when,
 388                         message => [@message],
 389                         pages => [@pages],
 390                 } if @pages;
 391                 last if @ret >= $num;
 392         }
 393
 394         unlink($tmpfile) || error "couldn't unlink $tmpfile: $!\n";
 395
 396         return @ret;
 397 }
 398
 399 sub rcs_diff ($) {
 400         my $rev=IkiWiki::possibly_foolish_untaint(int(shift));
 401
 402         chdir $config{srcdir} || error("Cannot chdir to $config{srcdir}: $!");
 403
 404         # diff output is unavoidably preceded by the cvsps PatchSet entry
 405         my @cvsps = `env TZ=UTC cvsps -q --cvs-direct -z 30 -g -s $rev`;
 406         my $blank_lines_seen = 0;
 407
 408         while (my $line = shift @cvsps) {
 409                 $blank_lines_seen++ if ($line =~ /^$/);
 410                 last if $blank_lines_seen == 2;
 411         }
 412
 413         if (wantarray) {
 414                 return @cvsps;
 415         } else {
 416                 return join("", @cvsps);
 417         }
 418 }
 419
 420 sub rcs_getctime ($) {
 421         my $file=shift;
 422
 423         my $cvs_log_infoline=qr/^date: (.+);\s+author/;
 424
 425         open CVSLOG, "cvs -Q log -r1.1 '$file' |"
 426                 || error "couldn't get cvs log output: $!\n";
 427
 428         my $date;
 429         while (<CVSLOG>) {
 430                 if (/$cvs_log_infoline/) {
 431                         $date=$1;
 432                 }
 433         }
 434         close CVSLOG || warn "cvs log $file exited $?";
 435
 436         if (! defined $date) {
 437                 warn "failed to parse cvs log for $file\n";
 438                 return 0;
 439         }
 440
 441         eval q{use Date::Parse};
 442         error($@) if $@;
 443         $date=str2time($date, 'UTC');
 444         debug("found ctime ".localtime($date)." for $file");
 445         return $date;
 446 }
 447
 448 1