git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/autoindex.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::autoindex;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use Encode;
   8
   9 sub import {
  10         hook(type => "checkconfig", id => "autoindex", call => \&checkconfig);
  11         hook(type => "getsetup", id => "autoindex", call => \&getsetup);
  12         hook(type => "refresh", id => "autoindex", call => \&refresh);
  13         IkiWiki::loadplugin("transient");
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                 },
  22                 autoindex_commit => {
  23                         type => "boolean",
  24                         example => 1,
  25                         default => 1,
  26                         description => "commit autocreated index pages",
  27                         safe => 1,
  28                         rebuild => 0,
  29                 },
  30 }
  31
  32 sub checkconfig () {
  33         if (! defined $config{autoindex_commit}) {
  34                 $config{autoindex_commit} = 1;
  35         }
  36 }
  37
  38 sub genindex ($) {
  39         my $page=shift;
  40         my $file=newpagefile($page, $config{default_pageext});
  41
  42         add_autofile($file, "autoindex", sub {
  43                         my $message = sprintf(gettext("creating index page %s"),
  44                                 $page);
  45                         debug($message);
  46
  47                         my $dir = $config{srcdir};
  48                         if (! $config{autoindex_commit}) {
  49                                 no warnings 'once';
  50                                 $dir = $IkiWiki::Plugin::transient::transientdir;
  51                         }
  52
  53                         my $template = template("autoindex.tmpl");
  54                         $template->param(page => $page);
  55                         writefile($file, $dir, $template->output);
  56
  57                         if ($config{rcs} && $config{autoindex_commit}) {
  58                                 IkiWiki::disable_commit_hook();
  59                                 IkiWiki::rcs_add($file);
  60                                 IkiWiki::rcs_commit_staged(message => $message);
  61                                 IkiWiki::enable_commit_hook();
  62                         }
  63                 });
  64 }
  65
  66 sub refresh () {
  67         eval q{use File::Find};
  68         error($@) if $@;
  69         eval q{use Cwd};
  70         error($@) if $@;
  71         my $origdir=getcwd();
  72
  73         my (%pages, %dirs);
  74         foreach my $dir ($config{srcdir}, @{$config{underlaydirs}}, $config{underlaydir}) {
  75                 chdir($dir) || next;
  76
  77                 find({
  78                         no_chdir => 1,
  79                         wanted => sub {
  80                                 my $file=decode_utf8($_);
  81                                 $file=~s/^\.\/?//;
  82                                 return unless length $file;
  83                                 if (IkiWiki::file_pruned($file)) {
  84                                         no warnings 'once';
  85                                         $File::Find::prune=1;
  86                                 }
  87                                 elsif (! -l $_) {
  88                                         my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
  89                                         return unless defined $f;
  90                                         return if $f =~ /\._([^.]+)$/; # skip internal page
  91                                         if (! -d _) {
  92                                                 $pages{pagename($f)}=1;
  93                                         }
  94                                         elsif ($dir eq $config{srcdir} || ! $config{autoindex_commit}) {
  95                                                 $dirs{$f}=1;
  96                                         }
  97                                 }
  98                         }
  99                 }, '.');
 100
 101                 chdir($origdir) || die "chdir $origdir: $!";
 102         }
 103
 104         # Compatibility code.
 105         #
 106         # {deleted} contains pages that have been deleted at some point.
 107         # This plugin used to delete from the hash sometimes, but no longer
 108         # does; in [[todo/autoindex_should_use_add__95__autofile]] Joey
 109         # thought the old behaviour was probably a bug.
 110         #
 111         # The effect of listing a page in {deleted} was to avoid re-creating
 112         # it; we migrate these pages to {autofile} which has the same effect.
 113         # However, {autofile} contains source filenames whereas {deleted}
 114         # contains page names.
 115         my %deleted;
 116         if (ref $wikistate{autoindex}{deleted}) {
 117                 %deleted=%{$wikistate{autoindex}{deleted}};
 118                 delete $wikistate{autoindex}{deleted};
 119         }
 120         elsif (ref $pagestate{index}{autoindex}{deleted}) {
 121                 # an even older version
 122                 %deleted=%{$pagestate{index}{autoindex}{deleted}};
 123                 delete $pagestate{index}{autoindex};
 124         }
 125
 126         if (keys %deleted) {
 127                 foreach my $dir (keys %deleted) {
 128                         my $file=newpagefile($dir, $config{default_pageext});
 129                         $wikistate{autoindex}{autofile}{$file} = 1;
 130                 }
 131         }
 132
 133         foreach my $dir (keys %dirs) {
 134                 if (! exists $pages{$dir} && grep /^$dir\/.*/, keys %pages) {
 135                         genindex($dir);
 136                 }
 137         }
 138 }
 139
 140 1