git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/img.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki enhanced image handling plugin
   3 # Christian Mock cm@tahina.priv.at 20061002
   4 package IkiWiki::Plugin::img;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki 2.00;
   9
  10 my %imgdefaults;
  11
  12 sub import { #{{{
  13         hook(type => "preprocess", id => "img", call => \&preprocess, scan => 1);
  14 } #}}}
  15
  16 sub preprocess (@) { #{{{
  17         my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
  18         my %params=@_;
  19
  20         if (! exists $imgdefaults{$params{page}}) {
  21                 $imgdefaults{$params{page}} = {};
  22         }
  23         my $size = $params{size} || $imgdefaults{$params{page}}->{size} || 'full';
  24         my $alt = $params{alt} || $imgdefaults{$params{page}}->{alt} || '';
  25         my $title = $params{title} || $imgdefaults{$params{page}}->{title} || '';
  26         my $caption = $params{caption} || $imgdefaults{$params{page}}->{caption} || '';
  27
  28         if ($image eq 'defaults') {
  29                 $imgdefaults{$params{page}} = {
  30                         size => $size,
  31                         alt => $alt,
  32                         title => $title,
  33                         caption => $caption,
  34                 };
  35                 return '';
  36         }
  37
  38         push @{$links{$params{page}}}, $image;
  39         # optimisation: detect scan mode, and avoid generating the image
  40         if (! defined wantarray) {
  41                 return;
  42         }
  43
  44         my $file = bestlink($params{page}, $image);
  45
  46         my $dir = $params{page};
  47         my $base = IkiWiki::basename($file);
  48
  49         eval q{use Image::Magick};
  50         error($@) if $@;
  51         my $im = Image::Magick->new;
  52         my $imglink;
  53         my $r;
  54
  55         if ($size ne 'full') {
  56                 my ($w, $h) = ($size =~ /^(\d+)x(\d+)$/);
  57                 return "[[img ".sprintf(gettext('bad size "%s"'), $size)."]]"
  58                         unless (defined $w && defined $h);
  59
  60                 my $outfile = "$config{destdir}/$dir/${w}x${h}-$base";
  61                 $imglink = "$dir/${w}x${h}-$base";
  62
  63                 will_render($params{page}, $imglink);
  64
  65                 if (-e $outfile && (-M srcfile($file) >= -M $outfile)) {
  66                         $r = $im->Read($outfile);
  67                         return "[[img ".sprintf(gettext("failed to read %s: %s"), $outfile, $r)."]]" if $r;
  68                 }
  69                 else {
  70                         $r = $im->Read(srcfile($file));
  71                         return "[[img ".sprintf(gettext("failed to read %s: %s"), $file, $r)."]]" if $r;
  72
  73                         $r = $im->Resize(geometry => "${w}x${h}");
  74                         return "[[img ".sprintf(gettext("failed to resize: %s"), $r)."]]" if $r;
  75
  76                         # don't actually write file in preview mode
  77                         if (! $params{preview}) {
  78                                 my @blob = $im->ImageToBlob();
  79                                 writefile($imglink, $config{destdir}, $blob[0], 1);
  80                         }
  81                         else {
  82                                 $imglink = $file;
  83                         }
  84                 }
  85         }
  86         else {
  87                 $r = $im->Read(srcfile($file));
  88                 return "[[img ".sprintf(gettext("failed to read %s: %s"), $file, $r)."]]" if $r;
  89                 $imglink = $file;
  90         }
  91
  92         add_depends($imglink, $params{page});
  93
  94         my ($fileurl, $imgurl);
  95         if (! $params{preview}) {
  96                 $fileurl=urlto($file, $params{destpage});
  97                 $imgurl=urlto($imglink, $params{destpage});
  98         }
  99         else {
 100                 $fileurl="$config{url}/$file";
 101                 $imgurl="$config{url}/$imglink";
 102         }
 103
 104         if (! defined($im->Get("width")) || ! defined($im->Get("height"))) {
 105                 return "[[img ".sprintf(gettext("failed to determine size of image %s"), $file)."]]";
 106         }
 107
 108         my $imgtag='<img src="'.$imgurl.
 109                 '" alt="'.$alt.'" width="'.$im->Get("width").
 110                 '" height="'.$im->Get("height").'"'.
 111                 (defined $title ? ' title="'.$title.'"' : '').
 112                 (exists $params{class} ? ' class="'.$params{class}.'"' : '').
 113                 (exists $params{id} ? ' id="'.$params{id}.'"' : '').
 114                 ' />';
 115
 116         if (! defined $params{link} || lc($params{link}) eq 'yes') {
 117                 $imgtag='<a href="'.$fileurl.'">'.$imgtag.'</a>';
 118         }
 119         elsif ($params{link} =~ /^\w+:\/\//) {
 120                 $imgtag='<a href="'.$params{link}.'">'.$imgtag.'</a>';
 121         }
 122         elsif (length bestlink($params{page}, $params{link})) {
 123                 add_depends($params{page}, $params{link});
 124                 $imgtag=htmllink($params{page}, $params{destpage},
 125                         $params{link}, linktext => $imgtag,
 126                         noimageinline => 1);
 127         }
 128
 129         if (defined $caption) {
 130                 return '<table class="img">'.
 131                         '<caption>'.$caption.'</caption>'.
 132                         '<tr><td>'.$imgtag.'</td></tr>'.
 133                         '</table>';
 134         }
 135         else {
 136                 return $imgtag;
 137         }
 138 } #}}}
 139
 140 1