git.oblomov.eu Git - ikiwiki/blob - IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use open qw{:utf8 :std};
   9
  10 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime %pagecase
  11             %renderedfiles %oldrenderedfiles %pagesources %depends %hooks
  12             %forcerebuild};
  13
  14 use Exporter q{import};
  15 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  16                  bestlink htmllink readfile writefile pagetype srcfile pagename
  17                  displaytime will_render
  18                  %config %links %renderedfiles %pagesources);
  19 our $VERSION = 1.01; # plugin interface version
  20
  21 # Optimisation.
  22 use Memoize;
  23 memoize("abs2rel");
  24 memoize("pagespec_translate");
  25 memoize("file_pruned");
  26
  27 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  28 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  29
  30 sub defaultconfig () { #{{{
  31         wiki_file_prune_regexps => [qr/\.\./, qr/^\./, qr/\/\./, qr/\.x?html?$/,
  32                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//],
  33         wiki_link_regexp => qr/\[\[(?:([^\]\|]+)\|)?([^\s\]]+)\]\]/,
  34         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  35         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  36         verbose => 0,
  37         syslog => 0,
  38         wikiname => "wiki",
  39         default_pageext => "mdwn",
  40         cgi => 0,
  41         rcs => 'svn',
  42         notify => 0,
  43         url => '',
  44         cgiurl => '',
  45         historyurl => '',
  46         diffurl => '',
  47         anonok => 0,
  48         rss => 0,
  49         atom => 0,
  50         discussion => 1,
  51         rebuild => 0,
  52         refresh => 0,
  53         getctime => 0,
  54         w3mmode => 0,
  55         wrapper => undef,
  56         wrappermode => undef,
  57         svnrepo => undef,
  58         svnpath => "trunk",
  59         srcdir => undef,
  60         destdir => undef,
  61         pingurl => [],
  62         templatedir => "$installdir/share/ikiwiki/templates",
  63         underlaydir => "$installdir/share/ikiwiki/basewiki",
  64         setup => undef,
  65         adminuser => undef,
  66         adminemail => undef,
  67         plugin => [qw{mdwn inline htmlscrubber passwordauth}],
  68         timeformat => '%c',
  69         locale => undef,
  70         sslcookie => 0,
  71         httpauth => 0,
  72         userdir => "",
  73 } #}}}
  74
  75 sub checkconfig () { #{{{
  76         # locale stuff; avoid LC_ALL since it overrides everything
  77         if (defined $ENV{LC_ALL}) {
  78                 $ENV{LANG} = $ENV{LC_ALL};
  79                 delete $ENV{LC_ALL};
  80         }
  81         if (defined $config{locale}) {
  82                 eval q{use POSIX};
  83                 error($@) if $@;
  84                 $ENV{LANG} = $config{locale}
  85                         if POSIX::setlocale(&POSIX::LC_TIME, $config{locale});
  86         }
  87
  88         if ($config{w3mmode}) {
  89                 eval q{use Cwd q{abs_path}};
  90                 error($@) if $@;
  91                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
  92                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
  93                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
  94                         unless $config{cgiurl} =~ m!file:///!;
  95                 $config{url}="file://".$config{destdir};
  96         }
  97
  98         if ($config{cgi} && ! length $config{url}) {
  99                 error("Must specify url to wiki with --url when using --cgi\n");
 100         }
 101
 102         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 103                 unless exists $config{wikistatedir};
 104
 105         if ($config{rcs}) {
 106                 eval qq{require IkiWiki::Rcs::$config{rcs}};
 107                 if ($@) {
 108                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 109                 }
 110         }
 111         else {
 112                 require IkiWiki::Rcs::Stub;
 113         }
 114
 115         run_hooks(checkconfig => sub { shift->() });
 116 } #}}}
 117
 118 sub loadplugins () { #{{{
 119         loadplugin($_) foreach @{$config{plugin}};
 120
 121         run_hooks(getopt => sub { shift->() });
 122         if (grep /^-/, @ARGV) {
 123                 print STDERR "Unknown option: $_\n"
 124                         foreach grep /^-/, @ARGV;
 125                 usage();
 126         }
 127 } #}}}
 128
 129 sub loadplugin ($) { #{{{
 130         my $plugin=shift;
 131
 132         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 133         eval qq{use $mod};
 134         if ($@) {
 135                 error("Failed to load plugin $mod: $@");
 136         }
 137 } #}}}
 138
 139 sub error ($) { #{{{
 140         if ($config{cgi}) {
 141                 print "Content-type: text/html\n\n";
 142                 print misctemplate("Error", "<p>Error: @_</p>");
 143         }
 144         log_message(error => @_);
 145         exit(1);
 146 } #}}}
 147
 148 sub debug ($) { #{{{
 149         return unless $config{verbose};
 150         log_message(debug => @_);
 151 } #}}}
 152
 153 my $log_open=0;
 154 sub log_message ($$) { #{{{
 155         my $type=shift;
 156
 157         if ($config{syslog}) {
 158                 require Sys::Syslog;
 159                 unless ($log_open) {
 160                         Sys::Syslog::setlogsock('unix');
 161                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 162                         $log_open=1;
 163                 }
 164                 eval {
 165                         Sys::Syslog::syslog($type, join(" ", @_));
 166                 }
 167         }
 168         elsif (! $config{cgi}) {
 169                 print "@_\n";
 170         }
 171         else {
 172                 print STDERR "@_\n";
 173         }
 174 } #}}}
 175
 176 sub possibly_foolish_untaint ($) { #{{{
 177         my $tainted=shift;
 178         my ($untainted)=$tainted=~/(.*)/;
 179         return $untainted;
 180 } #}}}
 181
 182 sub basename ($) { #{{{
 183         my $file=shift;
 184
 185         $file=~s!.*/+!!;
 186         return $file;
 187 } #}}}
 188
 189 sub dirname ($) { #{{{
 190         my $file=shift;
 191
 192         $file=~s!/*[^/]+$!!;
 193         return $file;
 194 } #}}}
 195
 196 sub pagetype ($) { #{{{
 197         my $page=shift;
 198
 199         if ($page =~ /\.([^.]+)$/) {
 200                 return $1 if exists $hooks{htmlize}{$1};
 201         }
 202         return undef;
 203 } #}}}
 204
 205 sub pagename ($) { #{{{
 206         my $file=shift;
 207
 208         my $type=pagetype($file);
 209         my $page=$file;
 210         $page=~s/\Q.$type\E*$// if defined $type;
 211         return $page;
 212 } #}}}
 213
 214 sub htmlpage ($) { #{{{
 215         my $page=shift;
 216
 217         return $page.".html";
 218 } #}}}
 219
 220 sub srcfile ($) { #{{{
 221         my $file=shift;
 222
 223         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 224         return "$config{underlaydir}/$file" if -e "$config{underlaydir}/$file";
 225         error("internal error: $file cannot be found");
 226 } #}}}
 227
 228 sub readfile ($;$) { #{{{
 229         my $file=shift;
 230         my $binary=shift;
 231
 232         if (-l $file) {
 233                 error("cannot read a symlink ($file)");
 234         }
 235
 236         local $/=undef;
 237         open (IN, $file) || error("failed to read $file: $!");
 238         binmode(IN) if ($binary);
 239         my $ret=<IN>;
 240         close IN;
 241         return $ret;
 242 } #}}}
 243
 244 sub writefile ($$$;$) { #{{{
 245         my $file=shift; # can include subdirs
 246         my $destdir=shift; # directory to put file in
 247         my $content=shift;
 248         my $binary=shift;
 249
 250         my $test=$file;
 251         while (length $test) {
 252                 if (-l "$destdir/$test") {
 253                         error("cannot write to a symlink ($test)");
 254                 }
 255                 $test=dirname($test);
 256         }
 257
 258         my $dir=dirname("$destdir/$file");
 259         if (! -d $dir) {
 260                 my $d="";
 261                 foreach my $s (split(m!/+!, $dir)) {
 262                         $d.="$s/";
 263                         if (! -d $d) {
 264                                 mkdir($d) || error("failed to create directory $d: $!");
 265                         }
 266                 }
 267         }
 268
 269         open (OUT, ">$destdir/$file") || error("failed to write $destdir/$file: $!");
 270         binmode(OUT) if ($binary);
 271         print OUT $content;
 272         close OUT;
 273 } #}}}
 274
 275 my %cleared;
 276 sub will_render ($$;$) { #{{{
 277         my $page=shift;
 278         my $dest=shift;
 279         my $clear=shift;
 280
 281         # Important security check.
 282         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 283             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 284                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 285         }
 286
 287         if (! $clear || $cleared{$page}) {
 288                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 289         }
 290         else {
 291                 $renderedfiles{$page}=[$dest];
 292                 $cleared{$page}=1;
 293         }
 294 } #}}}
 295
 296 sub bestlink ($$) { #{{{
 297         my $page=shift;
 298         my $link=shift;
 299
 300         my $cwd=$page;
 301
 302         # relative links
 303         while ($link=~s!(^|/)\.\./!!g) {
 304                 $cwd=~s!/?[^/]+$!!;
 305         }
 306
 307         do {
 308                 my $l=$cwd;
 309                 $l.="/" if length $l;
 310                 $l.=$link;
 311
 312                 if (exists $links{$l}) {
 313                         return $l;
 314                 }
 315                 elsif (exists $pagecase{lc $l}) {
 316                         return $pagecase{lc $l};
 317                 }
 318         } while $cwd=~s!/?[^/]+$!!;
 319
 320         #print STDERR "warning: page $page, broken link: $link\n";
 321         return "";
 322 } #}}}
 323
 324 sub isinlinableimage ($) { #{{{
 325         my $file=shift;
 326
 327         $file=~/\.(png|gif|jpg|jpeg)$/i;
 328 } #}}}
 329
 330 sub pagetitle ($) { #{{{
 331         my $page=shift;
 332         $page=~s/__(\d+)__/&#$1;/g;
 333         $page=~y/_/ /;
 334         return $page;
 335 } #}}}
 336
 337 sub titlepage ($) { #{{{
 338         my $title=shift;
 339         $title=~y/ /_/;
 340         $title=~s/([^-[:alnum:]_:+\/.])/"__".ord($1)."__"/eg;
 341         return $title;
 342 } #}}}
 343
 344 sub cgiurl (@) { #{{{
 345         my %params=@_;
 346
 347         return $config{cgiurl}."?".join("&amp;", map "$_=$params{$_}", keys %params);
 348 } #}}}
 349
 350 sub baseurl (;$) { #{{{
 351         my $page=shift;
 352
 353         return "$config{url}/" if ! defined $page;
 354
 355         $page=~s/[^\/]+$//;
 356         $page=~s/[^\/]+\//..\//g;
 357         return $page;
 358 } #}}}
 359
 360 sub abs2rel ($$) { #{{{
 361         # Work around very innefficient behavior in File::Spec if abs2rel
 362         # is passed two relative paths. It's much faster if paths are
 363         # absolute! (Debian bug #376658; fixed in debian unstable now)
 364         my $path="/".shift;
 365         my $base="/".shift;
 366
 367         require File::Spec;
 368         my $ret=File::Spec->abs2rel($path, $base);
 369         $ret=~s/^// if defined $ret;
 370         return $ret;
 371 } #}}}
 372
 373 sub displaytime ($) { #{{{
 374         my $time=shift;
 375
 376         eval q{use POSIX};
 377         error($@) if $@;
 378         # strftime doesn't know about encodings, so make sure
 379         # its output is properly treated as utf8
 380         return decode_utf8(POSIX::strftime(
 381                         $config{timeformat}, localtime($time)));
 382 } #}}}
 383
 384 sub htmllink ($$$;$$$) { #{{{
 385         my $lpage=shift; # the page doing the linking
 386         my $page=shift; # the page that will contain the link (different for inline)
 387         my $link=shift;
 388         my $noimageinline=shift; # don't turn links into inline html images
 389         my $forcesubpage=shift; # force a link to a subpage
 390         my $linktext=shift; # set to force the link text to something
 391
 392         my $bestlink;
 393         if (! $forcesubpage) {
 394                 $bestlink=bestlink($lpage, $link);
 395         }
 396         else {
 397                 $bestlink="$lpage/".lc($link);
 398         }
 399
 400         $linktext=pagetitle(basename($link)) unless defined $linktext;
 401
 402         return "<span class=\"selflink\">$linktext</span>"
 403                 if length $bestlink && $page eq $bestlink;
 404
 405         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 406                 $bestlink=htmlpage($bestlink);
 407         }
 408         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 409                 return "<span><a href=\"".
 410                         cgiurl(do => "create", page => lc($link), from => $page).
 411                         "\">?</a>$linktext</span>"
 412         }
 413
 414         $bestlink=abs2rel($bestlink, dirname($page));
 415
 416         if (! $noimageinline && isinlinableimage($bestlink)) {
 417                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 418         }
 419         return "<a href=\"$bestlink\">$linktext</a>";
 420 } #}}}
 421
 422 sub htmlize ($$$) { #{{{
 423         my $page=shift;
 424         my $type=shift;
 425         my $content=shift;
 426
 427         if (exists $hooks{htmlize}{$type}) {
 428                 $content=$hooks{htmlize}{$type}{call}->(
 429                         page => $page,
 430                         content => $content,
 431                 );
 432         }
 433         else {
 434                 error("htmlization of $type not supported");
 435         }
 436
 437         run_hooks(sanitize => sub {
 438                 $content=shift->(
 439                         page => $page,
 440                         content => $content,
 441                 );
 442         });
 443
 444         return $content;
 445 } #}}}
 446
 447 sub linkify ($$$) { #{{{
 448         my $lpage=shift; # the page containing the links
 449         my $page=shift; # the page the link will end up on (different for inline)
 450         my $content=shift;
 451
 452         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 453                 $2 ? ( $1 ? "[[$2|$3]]" : htmllink($lpage, $page, titlepage($3), 0, 0, pagetitle($2)))
 454                    : ( $1 ? "[[$3]]" :    htmllink($lpage, $page, titlepage($3)))
 455         }eg;
 456
 457         return $content;
 458 } #}}}
 459
 460 my %preprocessing;
 461 sub preprocess ($$$;$) { #{{{
 462         my $page=shift; # the page the data comes from
 463         my $destpage=shift; # the page the data will appear in (different for inline)
 464         my $content=shift;
 465         my $scan=shift;
 466
 467         my $handle=sub {
 468                 my $escape=shift;
 469                 my $command=shift;
 470                 my $params=shift;
 471                 if (length $escape) {
 472                         return "[[$command $params]]";
 473                 }
 474                 elsif (exists $hooks{preprocess}{$command}) {
 475                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 476                         # Note: preserve order of params, some plugins may
 477                         # consider it significant.
 478                         my @params;
 479                         while ($params =~ /(?:(\w+)=)?(?:"""(.*?)"""|"([^"]+)"|(\S+))(?:\s+|$)/sg) {
 480                                 my $key=$1;
 481                                 my $val;
 482                                 if (defined $2) {
 483                                         $val=$2;
 484                                         $val=~s/\r\n/\n/mg;
 485                                         $val=~s/^\n+//g;
 486                                         $val=~s/\n+$//g;
 487                                 }
 488                                 elsif (defined $3) {
 489                                         $val=$3;
 490                                 }
 491                                 elsif (defined $4) {
 492                                         $val=$4;
 493                                 }
 494
 495                                 if (defined $key) {
 496                                         push @params, $key, $val;
 497                                 }
 498                                 else {
 499                                         push @params, $val, '';
 500                                 }
 501                         }
 502                         if ($preprocessing{$page}++ > 3) {
 503                                 # Avoid loops of preprocessed pages preprocessing
 504                                 # other pages that preprocess them, etc.
 505                                 return "[[$command preprocessing loop detected on $page at depth $preprocessing{$page}]]";
 506                         }
 507                         my $ret=$hooks{preprocess}{$command}{call}->(
 508                                 @params,
 509                                 page => $page,
 510                                 destpage => $destpage,
 511                         );
 512                         $preprocessing{$page}--;
 513                         return $ret;
 514                 }
 515                 else {
 516                         return "[[$command $params]]";
 517                 }
 518         };
 519
 520         $content =~ s{(\\?)\[\[(\w+)\s+((?:(?:\w+=)?(?:""".*?"""|"[^"]+"|[^\s\]]+)\s*)*)\]\]}{$handle->($1, $2, $3)}seg;
 521         return $content;
 522 } #}}}
 523
 524 sub filter ($$) { #{{{
 525         my $page=shift;
 526         my $content=shift;
 527
 528         run_hooks(filter => sub {
 529                 $content=shift->(page => $page, content => $content);
 530         });
 531
 532         return $content;
 533 } #}}}
 534
 535 sub indexlink () { #{{{
 536         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 537 } #}}}
 538
 539 sub lockwiki () { #{{{
 540         # Take an exclusive lock on the wiki to prevent multiple concurrent
 541         # run issues. The lock will be dropped on program exit.
 542         if (! -d $config{wikistatedir}) {
 543                 mkdir($config{wikistatedir});
 544         }
 545         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 546                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 547         if (! flock(WIKILOCK, 2 | 4)) {
 548                 debug("wiki seems to be locked, waiting for lock");
 549                 my $wait=600; # arbitrary, but don't hang forever to
 550                               # prevent process pileup
 551                 for (1..600) {
 552                         return if flock(WIKILOCK, 2 | 4);
 553                         sleep 1;
 554                 }
 555                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 556         }
 557 } #}}}
 558
 559 sub unlockwiki () { #{{{
 560         close WIKILOCK;
 561 } #}}}
 562
 563 sub loadindex () { #{{{
 564         open (IN, "$config{wikistatedir}/index") || return;
 565         while (<IN>) {
 566                 $_=possibly_foolish_untaint($_);
 567                 chomp;
 568                 my %items;
 569                 $items{link}=[];
 570                 $items{dest}=[];
 571                 foreach my $i (split(/ /, $_)) {
 572                         my ($item, $val)=split(/=/, $i, 2);
 573                         push @{$items{$item}}, decode_entities($val);
 574                 }
 575
 576                 next unless exists $items{src}; # skip bad lines for now
 577
 578                 my $page=pagename($items{src}[0]);
 579                 if (! $config{rebuild}) {
 580                         $pagesources{$page}=$items{src}[0];
 581                         $oldpagemtime{$page}=$items{mtime}[0];
 582                         $oldlinks{$page}=[@{$items{link}}];
 583                         $links{$page}=[@{$items{link}}];
 584                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 585                         $renderedfiles{$page}=[@{$items{dest}}];
 586                         $oldrenderedfiles{$page}=[@{$items{dest}}];
 587                         $pagecase{lc $page}=$page;
 588                 }
 589                 $pagectime{$page}=$items{ctime}[0];
 590         }
 591         close IN;
 592 } #}}}
 593
 594 sub saveindex () { #{{{
 595         run_hooks(savestate => sub { shift->() });
 596
 597         if (! -d $config{wikistatedir}) {
 598                 mkdir($config{wikistatedir});
 599         }
 600         open (OUT, ">$config{wikistatedir}/index") ||
 601                 error("cannot write to $config{wikistatedir}/index: $!");
 602         foreach my $page (keys %oldpagemtime) {
 603                 next unless $oldpagemtime{$page};
 604                 my $line="mtime=$oldpagemtime{$page} ".
 605                         "ctime=$pagectime{$page} ".
 606                         "src=$pagesources{$page}";
 607                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 608                 my %count;
 609                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 610                 if (exists $depends{$page}) {
 611                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 612                 }
 613                 print OUT $line."\n";
 614         }
 615         close OUT;
 616 } #}}}
 617
 618 sub template_params (@) { #{{{
 619         my $filename=shift;
 620
 621         require HTML::Template;
 622         return filter => sub {
 623                         my $text_ref = shift;
 624                         $$text_ref=&Encode::decode_utf8($$text_ref);
 625                 },
 626                 filename => "$config{templatedir}/$filename",
 627                 loop_context_vars => 1,
 628                 die_on_bad_params => 0,
 629                 @_;
 630 } #}}}
 631
 632 sub template ($;@) { #{{{
 633         HTML::Template->new(template_params(@_));
 634 } #}}}
 635
 636 sub misctemplate ($$;@) { #{{{
 637         my $title=shift;
 638         my $pagebody=shift;
 639
 640         my $template=template("misc.tmpl");
 641         $template->param(
 642                 title => $title,
 643                 indexlink => indexlink(),
 644                 wikiname => $config{wikiname},
 645                 pagebody => $pagebody,
 646                 baseurl => baseurl(),
 647                 @_,
 648         );
 649         run_hooks(pagetemplate => sub {
 650                 shift->(page => "", destpage => "", template => $template);
 651         });
 652         return $template->output;
 653 }#}}}
 654
 655 sub hook (@) { # {{{
 656         my %param=@_;
 657
 658         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 659                 error "hook requires type, call, and id parameters";
 660         }
 661
 662         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 663
 664         $hooks{$param{type}}{$param{id}}=\%param;
 665 } # }}}
 666
 667 sub run_hooks ($$) { # {{{
 668         # Calls the given sub for each hook of the given type,
 669         # passing it the hook function to call.
 670         my $type=shift;
 671         my $sub=shift;
 672
 673         if (exists $hooks{$type}) {
 674                 my @deferred;
 675                 foreach my $id (keys %{$hooks{$type}}) {
 676                         if ($hooks{$type}{$id}{last}) {
 677                                 push @deferred, $id;
 678                                 next;
 679                         }
 680                         $sub->($hooks{$type}{$id}{call});
 681                 }
 682                 foreach my $id (@deferred) {
 683                         $sub->($hooks{$type}{$id}{call});
 684                 }
 685         }
 686 } #}}}
 687
 688 sub globlist_to_pagespec ($) { #{{{
 689         my @globlist=split(' ', shift);
 690
 691         my (@spec, @skip);
 692         foreach my $glob (@globlist) {
 693                 if ($glob=~/^!(.*)/) {
 694                         push @skip, $glob;
 695                 }
 696                 else {
 697                         push @spec, $glob;
 698                 }
 699         }
 700
 701         my $spec=join(" or ", @spec);
 702         if (@skip) {
 703                 my $skip=join(" and ", @skip);
 704                 if (length $spec) {
 705                         $spec="$skip and ($spec)";
 706                 }
 707                 else {
 708                         $spec=$skip;
 709                 }
 710         }
 711         return $spec;
 712 } #}}}
 713
 714 sub is_globlist ($) { #{{{
 715         my $s=shift;
 716         $s=~/[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or";
 717 } #}}}
 718
 719 sub safequote ($) { #{{{
 720         my $s=shift;
 721         $s=~s/[{}]//g;
 722         return "q{$s}";
 723 } #}}}
 724
 725 sub pagespec_merge ($$) { #{{{
 726         my $a=shift;
 727         my $b=shift;
 728
 729         return $a if $a eq $b;
 730
 731         # Support for old-style GlobLists.
 732         if (is_globlist($a)) {
 733                 $a=globlist_to_pagespec($a);
 734         }
 735         if (is_globlist($b)) {
 736                 $b=globlist_to_pagespec($b);
 737         }
 738
 739         return "($a) or ($b)";
 740 } #}}}
 741
 742 sub pagespec_translate ($) { #{{{
 743         # This assumes that $page is in scope in the function
 744         # that evalulates the translated pagespec code.
 745         my $spec=shift;
 746
 747         # Support for old-style GlobLists.
 748         if (is_globlist($spec)) {
 749                 $spec=globlist_to_pagespec($spec);
 750         }
 751
 752         # Convert spec to perl code.
 753         my $code="";
 754         while ($spec=~m/\s*(\!|\(|\)|\w+\([^\)]+\)|[^\s()]+)\s*/ig) {
 755                 my $word=$1;
 756                 if (lc $word eq "and") {
 757                         $code.=" &&";
 758                 }
 759                 elsif (lc $word eq "or") {
 760                         $code.=" ||";
 761                 }
 762                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
 763                         $code.=" ".$word;
 764                 }
 765                 elsif ($word =~ /^(link|backlink|created_before|created_after|creation_month|creation_year|creation_day)\((.+)\)$/) {
 766                         $code.=" match_$1(\$page, ".safequote($2).")";
 767                 }
 768                 else {
 769                         $code.=" match_glob(\$page, ".safequote($word).")";
 770                 }
 771         }
 772
 773         return $code;
 774 } #}}}
 775
 776 sub add_depends ($$) { #{{{
 777         my $page=shift;
 778         my $pagespec=shift;
 779
 780         if (! exists $depends{$page}) {
 781                 $depends{$page}=$pagespec;
 782         }
 783         else {
 784                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
 785         }
 786 } # }}}
 787
 788 sub file_pruned ($$) { #{{{
 789         require File::Spec;
 790         my $file=File::Spec->canonpath(shift);
 791         my $base=File::Spec->canonpath(shift);
 792         $file=~s#^\Q$base\E/*##;
 793
 794         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
 795         $file =~ m/$regexp/;
 796 } #}}}
 797
 798 sub pagespec_match ($$) { #{{{
 799         my $page=shift;
 800         my $spec=shift;
 801
 802         return eval pagespec_translate($spec);
 803 } #}}}
 804
 805 sub match_glob ($$) { #{{{
 806         my $page=shift;
 807         my $glob=shift;
 808
 809         # turn glob into safe regexp
 810         $glob=quotemeta($glob);
 811         $glob=~s/\\\*/.*/g;
 812         $glob=~s/\\\?/./g;
 813
 814         return $page=~/^$glob$/i;
 815 } #}}}
 816
 817 sub match_link ($$) { #{{{
 818         my $page=shift;
 819         my $link=lc(shift);
 820
 821         my $links = $links{$page} or return undef;
 822         foreach my $p (@$links) {
 823                 return 1 if lc $p eq $link;
 824         }
 825         return 0;
 826 } #}}}
 827
 828 sub match_backlink ($$) { #{{{
 829         match_link(pop, pop);
 830 } #}}}
 831
 832 sub match_created_before ($$) { #{{{
 833         my $page=shift;
 834         my $testpage=shift;
 835
 836         if (exists $pagectime{$testpage}) {
 837                 return $pagectime{$page} < $pagectime{$testpage};
 838         }
 839         else {
 840                 return 0;
 841         }
 842 } #}}}
 843
 844 sub match_created_after ($$) { #{{{
 845         my $page=shift;
 846         my $testpage=shift;
 847
 848         if (exists $pagectime{$testpage}) {
 849                 return $pagectime{$page} > $pagectime{$testpage};
 850         }
 851         else {
 852                 return 0;
 853         }
 854 } #}}}
 855
 856 sub match_creation_day ($$) { #{{{
 857         return ((gmtime($pagectime{shift()}))[3] == shift);
 858 } #}}}
 859
 860 sub match_creation_month ($$) { #{{{
 861         return ((gmtime($pagectime{shift()}))[4] + 1 == shift);
 862 } #}}}
 863
 864 sub match_creation_year ($$) { #{{{
 865         return ((gmtime($pagectime{shift()}))[5] + 1900 == shift);
 866 } #}}}
 867
 868 1