git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                         section => "core",
  53                 },
  54                 rss => {
  55                         type => "boolean",
  56                         example => 0,
  57                         description => "enable rss feeds by default?",
  58                         safe => 1,
  59                         rebuild => 1,
  60                 },
  61                 atom => {
  62                         type => "boolean",
  63                         example => 0,
  64                         description => "enable atom feeds by default?",
  65                         safe => 1,
  66                         rebuild => 1,
  67                 },
  68                 allowrss => {
  69                         type => "boolean",
  70                         example => 0,
  71                         description => "allow rss feeds to be used?",
  72                         safe => 1,
  73                         rebuild => 1,
  74                 },
  75                 allowatom => {
  76                         type => "boolean",
  77                         example => 0,
  78                         description => "allow atom feeds to be used?",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 pingurl => {
  83                         type => "string",
  84                         example => "http://rpc.technorati.com/rpc/ping",
  85                         description => "urls to ping (using XML-RPC) on feed update",
  86                         safe => 1,
  87                         rebuild => 0,
  88                 },
  89 }
  90
  91 sub checkconfig () {
  92         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  93                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  94         }
  95         if ($config{rss}) {
  96                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  97         }
  98         if ($config{atom}) {
  99                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
 100         }
 101         if (! exists $config{pingurl}) {
 102                 $config{pingurl}=[];
 103         }
 104 }
 105
 106 sub format (@) {
 107         my %params=@_;
 108
 109         # Fill in the inline content generated earlier. This is actually an
 110         # optimisation.
 111         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 112                 delete @inline[$1,]
 113         }eg;
 114         return $params{content};
 115 }
 116
 117 sub sessioncgi ($$) {
 118         my $q=shift;
 119         my $session=shift;
 120
 121         if ($q->param('do') eq 'blog') {
 122                 my $page=titlepage(decode_utf8($q->param('title')));
 123                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 124                 # if the page already exists, munge it to be unique
 125                 my $from=$q->param('from');
 126                 my $add="";
 127                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 128                         $add=1 unless length $add;
 129                         $add++;
 130                 }
 131                 $q->param('page', $page.$add);
 132                 # now go create the page
 133                 $q->param('do', 'create');
 134                 # make sure the editpage plugin in loaded
 135                 if (IkiWiki->can("cgi_editpage")) {
 136                         IkiWiki::cgi_editpage($q, $session);
 137                 }
 138                 else {
 139                         error(gettext("page editing not allowed"));
 140                 }
 141                 exit;
 142         }
 143 }
 144
 145 # Back to ikiwiki namespace for the rest, this code is very much
 146 # internal to ikiwiki even though it's separated into a plugin.
 147 package IkiWiki;
 148
 149 my %toping;
 150 my %feedlinks;
 151
 152 sub preprocess_inline (@) {
 153         my %params=@_;
 154
 155         if (! exists $params{pages} && ! exists $params{pagenames}) {
 156                 error gettext("missing pages parameter");
 157         }
 158         my $raw=yesno($params{raw});
 159         my $archive=yesno($params{archive});
 160         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 161         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 162         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 163         my $feeds=! $nested && (exists $params{feeds} ? yesno($params{feeds}) : !$quick && ! $raw);
 164         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 165         my $feedonly=yesno($params{feedonly});
 166         if (! exists $params{show} && ! $archive) {
 167                 $params{show}=10;
 168         }
 169         if (! exists $params{feedshow} && exists $params{show}) {
 170                 $params{feedshow}=$params{show};
 171         }
 172         my $desc;
 173         if (exists $params{description}) {
 174                 $desc = $params{description}
 175         }
 176         else {
 177                 $desc = $config{wikiname};
 178         }
 179         my $actions=yesno($params{actions});
 180         if (exists $params{template}) {
 181                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 182         }
 183         else {
 184                 $params{template} = $archive ? "archivepage" : "inlinepage";
 185         }
 186
 187         my @list;
 188
 189         if (exists $params{pagenames}) {
 190                 foreach my $p (qw(sort pages)) {
 191                         if (exists $params{$p}) {
 192                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 193                                         "pagenames", $p);
 194                         }
 195                 }
 196
 197                 @list = map { bestlink($params{page}, $_) }
 198                         split ' ', $params{pagenames};
 199
 200                 if (yesno($params{reverse})) {
 201                         @list=reverse(@list);
 202                 }
 203
 204                 foreach my $p (@list) {
 205                         add_depends($params{page}, $p, deptype($quick ? "presence" : "content"));
 206                 }
 207         }
 208         else {
 209                 my $num=0;
 210                 if ($params{show}) {
 211                         $num=$params{show};
 212                 }
 213                 if ($params{feedshow} && $num < $params{feedshow} && $num > 0) {
 214                         $num=$params{feedshow};
 215                 }
 216                 if ($params{skip} && $num) {
 217                         $num+=$params{skip};
 218                 }
 219
 220                 @list = pagespec_match_list($params{page}, $params{pages},
 221                         deptype => deptype($quick ? "presence" : "content"),
 222                         filter => sub { $_[0] eq $params{page} },
 223                         sort => exists $params{sort} ? $params{sort} : "age",
 224                         reverse => yesno($params{reverse}),
 225                         ($num ? (num => $num) : ()),
 226                 );
 227         }
 228
 229         if (exists $params{skip}) {
 230                 @list=@list[$params{skip} .. $#list];
 231         }
 232
 233         my @feedlist;
 234         if ($feeds) {
 235                 if (exists $params{feedshow} &&
 236                     $params{feedshow} && @list > $params{feedshow}) {
 237                         @feedlist=@list[0..$params{feedshow} - 1];
 238                 }
 239                 else {
 240                         @feedlist=@list;
 241                 }
 242         }
 243
 244         if ($params{show} && @list > $params{show}) {
 245                 @list=@list[0..$params{show} - 1];
 246         }
 247
 248         if ($feeds && exists $params{feedpages}) {
 249                 @feedlist = pagespec_match_list(
 250                         $params{page}, "($params{pages}) and ($params{feedpages})",
 251                         deptype => deptype($quick ? "presence" : "content"),
 252                         list => \@feedlist,
 253                 );
 254         }
 255
 256         my ($feedbase, $feednum);
 257         if ($feeds) {
 258                 # Ensure that multiple feeds on a page go to unique files.
 259
 260                 # Feedfile can lead to conflicts if usedirs is not enabled,
 261                 # so avoid supporting it in that case.
 262                 delete $params{feedfile} if ! $config{usedirs};
 263                 # Tight limits on legal feedfiles, to avoid security issues
 264                 # and conflicts.
 265                 if (defined $params{feedfile}) {
 266                         if ($params{feedfile} =~ /\// ||
 267                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 268                                 error("illegal feedfile");
 269                         }
 270                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 271                 }
 272                 $feedbase=targetpage($params{destpage}, "", $params{feedfile});
 273
 274                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 275                 if (exists $knownfeeds{$feedid}) {
 276                         $feednum=$knownfeeds{$feedid};
 277                 }
 278                 else {
 279                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 280                                 if ($feeds) {
 281                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 282                                 }
 283                         }
 284                         else {
 285                                 $feednum=$knownfeeds{$feedid}="";
 286                                 if ($feeds) {
 287                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 288                                 }
 289                         }
 290                 }
 291         }
 292
 293         my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
 294         my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
 295
 296         my $ret="";
 297         my $feedlinksincluded=0;
 298
 299         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 300             (exists $params{postform} && yesno($params{postform}))) &&
 301             IkiWiki->can("cgi_editpage")) {
 302                 # Add a blog post form, with feed buttons.
 303                 my $formtemplate=template_depends("blogpost.tmpl", $params{page}, blind_cache => 1);
 304                 $formtemplate->param(cgiurl => IkiWiki::cgiurl());
 305                 $formtemplate->param(rootpage => rootpage(%params));
 306                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 307                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 308                 if (exists $params{postformtext}) {
 309                         $formtemplate->param(postformtext =>
 310                                 $params{postformtext});
 311                 }
 312                 else {
 313                         $formtemplate->param(postformtext =>
 314                                 gettext("Add a new post titled:"));
 315                 }
 316                 $ret.=$formtemplate->output;
 317
 318                 # The post form includes the feed buttons, so
 319                 # emptyfeeds cannot be hidden.
 320                 $emptyfeeds=1;
 321                 $feedlinksincluded=1;
 322         }
 323         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist) && $feedonly) {
 324                 # Add feed buttons.
 325                 my $linktemplate=template_depends("feedlink.tmpl", $params{page}, blind_cache => 1);
 326                 $linktemplate->param(rssurl => $rssurl) if $rss;
 327                 $linktemplate->param(atomurl => $atomurl) if $atom;
 328                 $ret.=$linktemplate->output;
 329                 $feedlinksincluded=1;
 330         }
 331
 332         if (! $feedonly) {
 333                 my $template;
 334                 if (! $raw) {
 335                         # cannot use wiki pages as templates; template not sanitized due to
 336                         # format hook hack
 337                         eval {
 338                                 $template=template_depends($params{template}.".tmpl", $params{page},
 339                                         blind_cache => 1);
 340                         };
 341                         if ($@) {
 342                                 error sprintf(gettext("failed to process template %s"), $params{template}.".tmpl").": $@";
 343                         }
 344                 }
 345                 my $needcontent=$raw || (!($archive && $quick) && $template->query(name => 'content'));
 346
 347                 foreach my $page (@list) {
 348                         my $file = $pagesources{$page};
 349                         my $type = pagetype($file);
 350                         if (! $raw) {
 351                                 if ($needcontent) {
 352                                         # Get the content before populating the
 353                                         # template, since getting the content uses
 354                                         # the same template if inlines are nested.
 355                                         my $content=get_inline_content($page, $params{destpage});
 356                                         $template->param(content => $content);
 357                                 }
 358                                 $template->param(pageurl => urlto($page, $params{destpage}));
 359                                 $template->param(inlinepage => $page);
 360                                 $template->param(title => pagetitle(basename($page)));
 361                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}, 1));
 362                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 363                                 $template->param(first => 1) if $page eq $list[0];
 364                                 $template->param(last => 1) if $page eq $list[$#list];
 365                                 $template->param(html5 => $config{html5});
 366                                 if (! $feedlinksincluded) {
 367                                         $template->param(hasfeeds => 1);
 368                                         $template->param(rssurl => $rssurl) if $rss;
 369                                         $template->param(atomurl => $atomurl) if $atom;
 370                                 }
 371
 372                                 if ($actions) {
 373                                         my $file = $pagesources{$page};
 374                                         my $type = pagetype($file);
 375                                         if ($config{discussion}) {
 376                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 377                                                     (length $config{cgiurl} ||
 378                                                      exists $pagesources{$page."/".lc($config{discussionpage})})) {
 379                                                         $template->param(have_actions => 1);
 380                                                         $template->param(discussionlink =>
 381                                                                 htmllink($page,
 382                                                                         $params{destpage},
 383                                                                         $config{discussionpage},
 384                                                                         noimageinline => 1,
 385                                                                         forcesubpage => 1));
 386                                                 }
 387                                         }
 388                                         if (length $config{cgiurl} &&
 389                                             defined $type &&
 390                                             IkiWiki->can("cgi_editpage")) {
 391                                                 $template->param(have_actions => 1);
 392                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 393
 394                                         }
 395                                 }
 396
 397                                 run_hooks(pagetemplate => sub {
 398                                         shift->(page => $page, destpage => $params{destpage},
 399                                                 template => $template,);
 400                                 });
 401
 402                                 $ret.=$template->output;
 403                                 $template->clear_params;
 404                         }
 405                         else {
 406                                 if (defined $type) {
 407                                         $ret.="\n".
 408                                               linkify($page, $params{destpage},
 409                                               preprocess($page, $params{destpage},
 410                                               filter($page, $params{destpage},
 411                                               readfile(srcfile($file)))));
 412                                 }
 413                                 else {
 414                                         $ret.="\n".
 415                                               readfile(srcfile($file));
 416                                 }
 417                         }
 418                 }
 419         }
 420
 421         if ($feeds && ($emptyfeeds || @feedlist)) {
 422                 if ($rss) {
 423                         my $rssp=$feedbase."rss".$feednum;
 424                         will_render($params{destpage}, $rssp);
 425                         if (! $params{preview}) {
 426                                 writefile($rssp, $config{destdir},
 427                                         genfeed("rss",
 428                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
 429                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 430                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
 431                         }
 432                 }
 433                 if ($atom) {
 434                         my $atomp=$feedbase."atom".$feednum;
 435                         will_render($params{destpage}, $atomp);
 436                         if (! $params{preview}) {
 437                                 writefile($atomp, $config{destdir},
 438                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
 439                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 440                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
 441                         }
 442                 }
 443         }
 444
 445         clear_inline_content_cache();
 446
 447         return $ret if $raw || $nested;
 448         push @inline, $ret;
 449         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 450 }
 451
 452 sub pagetemplate_inline (@) {
 453         my %params=@_;
 454         my $page=$params{page};
 455         my $template=$params{template};
 456
 457         $template->param(feedlinks => $feedlinks{$page})
 458                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 459 }
 460
 461 {
 462 my %inline_content;
 463 my $cached_destpage="";
 464
 465 sub get_inline_content ($$) {
 466         my $page=shift;
 467         my $destpage=shift;
 468
 469         if (exists $inline_content{$page} && $cached_destpage eq $destpage) {
 470                 return $inline_content{$page};
 471         }
 472
 473         my $file=$pagesources{$page};
 474         my $type=pagetype($file);
 475         my $ret="";
 476         if (defined $type) {
 477                 $nested++;
 478                 $ret=htmlize($page, $destpage, $type,
 479                        linkify($page, $destpage,
 480                        preprocess($page, $destpage,
 481                        filter($page, $destpage,
 482                        readfile(srcfile($file))))));
 483                 $nested--;
 484                 if (isinternal($page)) {
 485                         # make inlined text of internal pages searchable
 486                         run_hooks(indexhtml => sub {
 487                                 shift->(page => $page, destpage => $page,
 488                                         content => $ret);
 489                         });
 490                 }
 491         }
 492
 493         if ($cached_destpage ne $destpage) {
 494                 clear_inline_content_cache();
 495                 $cached_destpage=$destpage;
 496         }
 497         return $inline_content{$page}=$ret;
 498 }
 499
 500 sub clear_inline_content_cache () {
 501         %inline_content=();
 502 }
 503
 504 }
 505
 506 sub date_822 ($) {
 507         my $time=shift;
 508
 509         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 510         POSIX::setlocale(&POSIX::LC_TIME, "C");
 511         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 512         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 513         return $ret;
 514 }
 515
 516 sub absolute_urls ($$) {
 517         # needed because rss sucks
 518         my $html=shift;
 519         my $baseurl=shift;
 520
 521         my $url=$baseurl;
 522         $url=~s/[^\/]+$//;
 523         my $urltop; # calculated if needed
 524
 525         my $ret="";
 526
 527         eval q{use HTML::Parser; use HTML::Tagset};
 528         die $@ if $@;
 529         my $p = HTML::Parser->new(api_version => 3);
 530         $p->handler(default => sub { $ret.=join("", @_) }, "text");
 531         $p->handler(start => sub {
 532                 my ($tagname, $pos, $text) = @_;
 533                 if (ref $HTML::Tagset::linkElements{$tagname}) {
 534                         while (4 <= @$pos) {
 535                                 # use attribute sets from right to left
 536                                 # to avoid invalidating the offsets
 537                                 # when replacing the values
 538                                 my ($k_offset, $k_len, $v_offset, $v_len) =
 539                                         splice(@$pos, -4);
 540                                 my $attrname = lc(substr($text, $k_offset, $k_len));
 541                                 next unless grep { $_ eq $attrname } @{$HTML::Tagset::linkElements{$tagname}};
 542                                 next unless $v_offset; # 0 v_offset means no value
 543                                 my $v = substr($text, $v_offset, $v_len);
 544                                 $v =~ s/^([\'\"])(.*)\1$/$2/;
 545                                 if ($v=~/^#/) {
 546                                         $v=$baseurl.$v; # anchor
 547                                 }
 548                                 elsif ($v=~/^(?!\w+:)[^\/]/) {
 549                                         $v=$url.$v; # relative url
 550                                 }
 551                                 elsif ($v=~/^\//) {
 552                                         if (! defined $urltop) {
 553                                                 # what is the non path part of the url?
 554                                                 my $top_uri = URI->new($url);
 555                                                 $top_uri->path_query(""); # reset the path
 556                                                 $urltop = $top_uri->as_string;
 557                                         }
 558                                         $v=$urltop.$v; # url relative to top of site
 559                                 }
 560                                 $v =~ s/\"/&quot;/g; # since we quote with ""
 561                                 substr($text, $v_offset, $v_len) = qq("$v");
 562                         }
 563                 }
 564                 $ret.=$text;
 565         }, "tagname, tokenpos, text");
 566         $p->parse($html);
 567         $p->eof;
 568
 569         return $ret;
 570 }
 571
 572 sub genfeed ($$$$$@) {
 573         my $feedtype=shift;
 574         my $feedurl=shift;
 575         my $feeddesc=shift;
 576         my $guid=shift;
 577         my $page=shift;
 578         my @pages=@_;
 579
 580         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 581
 582         my $itemtemplate=template_depends($feedtype."item.tmpl", $page, blind_cache => 1);
 583         my $content="";
 584         my $lasttime = 0;
 585         foreach my $p (@pages) {
 586                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 587                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 588
 589                 $itemtemplate->param(
 590                         title => pagetitle(basename($p)),
 591                         url => $u,
 592                         permalink => $u,
 593                         cdate_822 => date_822($pagectime{$p}),
 594                         mdate_822 => date_822($pagemtime{$p}),
 595                         cdate_3339 => date_3339($pagectime{$p}),
 596                         mdate_3339 => date_3339($pagemtime{$p}),
 597                 );
 598
 599                 if (exists $pagestate{$p}) {
 600                         if (exists $pagestate{$p}{meta}{guid}) {
 601                                 eval q{use HTML::Entities};
 602                                 $itemtemplate->param(guid => HTML::Entities::encode_numeric($pagestate{$p}{meta}{guid}));
 603                         }
 604
 605                         if (exists $pagestate{$p}{meta}{updated}) {
 606                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 607                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 608                         }
 609                 }
 610
 611                 if ($itemtemplate->query(name => "enclosure")) {
 612                         my $file=$pagesources{$p};
 613                         my $type=pagetype($file);
 614                         if (defined $type) {
 615                                 $itemtemplate->param(content => $pcontent);
 616                         }
 617                         else {
 618                                 my $size=(srcfile_stat($file))[8];
 619                                 my $mime="unknown";
 620                                 eval q{use File::MimeInfo};
 621                                 if (! $@) {
 622                                         $mime = mimetype($file);
 623                                 }
 624                                 $itemtemplate->param(
 625                                         enclosure => $u,
 626                                         type => $mime,
 627                                         length => $size,
 628                                 );
 629                         }
 630                 }
 631                 else {
 632                         $itemtemplate->param(content => $pcontent);
 633                 }
 634
 635                 run_hooks(pagetemplate => sub {
 636                         shift->(page => $p, destpage => $page,
 637                                 template => $itemtemplate);
 638                 });
 639
 640                 $content.=$itemtemplate->output;
 641                 $itemtemplate->clear_params;
 642
 643                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 644         }
 645
 646         my $template=template_depends($feedtype."page.tmpl", $page, blind_cache => 1);
 647         $template->param(
 648                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 649                 wikiname => $config{wikiname},
 650                 pageurl => $url,
 651                 content => $content,
 652                 feeddesc => $feeddesc,
 653                 guid => $guid,
 654                 feeddate => date_3339($lasttime),
 655                 feedurl => $feedurl,
 656                 version => $IkiWiki::version,
 657         );
 658         run_hooks(pagetemplate => sub {
 659                 shift->(page => $page, destpage => $page,
 660                         template => $template);
 661         });
 662
 663         return $template->output;
 664 }
 665
 666 sub pingurl (@) {
 667         return unless @{$config{pingurl}} && %toping;
 668
 669         eval q{require RPC::XML::Client};
 670         if ($@) {
 671                 debug(gettext("RPC::XML::Client not found, not pinging"));
 672                 return;
 673         }
 674
 675         # daemonize here so slow pings don't slow down wiki updates
 676         defined(my $pid = fork) or error("Can't fork: $!");
 677         return if $pid;
 678         chdir '/';
 679         POSIX::setsid() or error("Can't start a new session: $!");
 680         open STDIN, '/dev/null';
 681         open STDOUT, '>/dev/null';
 682         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 683
 684         # Don't need to keep a lock on the wiki as a daemon.
 685         IkiWiki::unlockwiki();
 686
 687         foreach my $page (keys %toping) {
 688                 my $title=pagetitle(basename($page), 0);
 689                 my $url=urlto($page, "", 1);
 690                 foreach my $pingurl (@{$config{pingurl}}) {
 691                         debug("Pinging $pingurl for $page");
 692                         eval {
 693                                 my $client = RPC::XML::Client->new($pingurl);
 694                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 695                                         $title, $url);
 696                                 my $res = $client->send_request($req);
 697                                 if (! ref $res) {
 698                                         error("Did not receive response to ping");
 699                                 }
 700                                 my $r=$res->value;
 701                                 if (! exists $r->{flerror} || $r->{flerror}) {
 702                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 703                                 }
 704                         };
 705                         if ($@) {
 706                                 error "Ping failed: $@";
 707                         }
 708                 }
 709         }
 710
 711         exit 0; # daemon done
 712 }
 713
 714
 715 sub rootpage (@) {
 716         my %params=@_;
 717
 718         my $rootpage;
 719         if (exists $params{rootpage}) {
 720                 $rootpage=bestlink($params{page}, $params{rootpage});
 721                 if (!length $rootpage) {
 722                         $rootpage=$params{rootpage};
 723                 }
 724         }
 725         else {
 726                 $rootpage=$params{page};
 727         }
 728         return $rootpage;
 729 }
 730
 731 1