git.oblomov.eu Git - linux-2.6/blob - arch/x86/lguest/i386_head.S

   1 #include <linux/linkage.h>
   2 #include <linux/lguest.h>
   3 #include <asm/lguest_hcall.h>
   4 #include <asm/asm-offsets.h>
   5 #include <asm/thread_info.h>
   6 #include <asm/processor-flags.h>
   7
   8 /*G:020 This is where we begin: head.S notes that the boot header's platform
   9  * type field is "1" (lguest), so calls us here.  The boot header is in %esi.
  10  *
  11  * WARNING: be very careful here!  We're running at addresses equal to physical
  12  * addesses (around 0), not above PAGE_OFFSET as most code expectes
  13  * (eg. 0xC0000000).  Jumps are relative, so they're OK, but we can't touch any
  14  * data.
  15  *
  16  * The .section line puts this code in .init.text so it will be discarded after
  17  * boot. */
  18 .section .init.text, "ax", @progbits
  19 ENTRY(lguest_entry)
  20         /* Make initial hypercall now, so we can set up the pagetables. */
  21         movl $LHCALL_LGUEST_INIT, %eax
  22         movl $lguest_data - __PAGE_OFFSET, %edx
  23         int $LGUEST_TRAP_ENTRY
  24
  25         /* The Host put the toplevel pagetable in lguest_data.pgdir.  The movsl
  26          * instruction uses %esi implicitly. */
  27         movl lguest_data - __PAGE_OFFSET + LGUEST_DATA_pgdir, %esi
  28
  29         /* Copy first 32 entries of page directory to __PAGE_OFFSET entries.
  30          * This means the first 128M of kernel memory will be mapped at
  31          * PAGE_OFFSET where the kernel expects to run.  This will get it far
  32          * enough through boot to switch to its own pagetables. */
  33         movl $32, %ecx
  34         movl %esi, %edi
  35         addl $((__PAGE_OFFSET >> 22) * 4), %edi
  36         rep
  37         movsl
  38
  39         /* Set up the initial stack so we can run C code. */
  40         movl $(init_thread_union+THREAD_SIZE),%esp
  41
  42         /* Jumps are relative, and we're running __PAGE_OFFSET too low at the
  43          * moment. */
  44         jmp lguest_init+__PAGE_OFFSET
  45
  46 /*G:055 We create a macro which puts the assembler code between lgstart_ and
  47  * lgend_ markers.  These templates are put in the .text section: they can't be
  48  * discarded after boot as we may need to patch modules, too. */
  49 .text
  50 #define LGUEST_PATCH(name, insns...)                    \
  51         lgstart_##name: insns; lgend_##name:;           \
  52         .globl lgstart_##name; .globl lgend_##name
  53
  54 LGUEST_PATCH(cli, movl $0, lguest_data+LGUEST_DATA_irq_enabled)
  55 LGUEST_PATCH(sti, movl $X86_EFLAGS_IF, lguest_data+LGUEST_DATA_irq_enabled)
  56 LGUEST_PATCH(popf, movl %eax, lguest_data+LGUEST_DATA_irq_enabled)
  57 LGUEST_PATCH(pushf, movl lguest_data+LGUEST_DATA_irq_enabled, %eax)
  58 /*:*/
  59
  60 /* These demark the EIP range where host should never deliver interrupts. */
  61 .global lguest_noirq_start
  62 .global lguest_noirq_end
  63
  64 /*M:004 When the Host reflects a trap or injects an interrupt into the Guest,
  65  * it sets the eflags interrupt bit on the stack based on
  66  * lguest_data.irq_enabled, so the Guest iret logic does the right thing when
  67  * restoring it.  However, when the Host sets the Guest up for direct traps,
  68  * such as system calls, the processor is the one to push eflags onto the
  69  * stack, and the interrupt bit will be 1 (in reality, interrupts are always
  70  * enabled in the Guest).
  71  *
  72  * This turns out to be harmless: the only trap which should happen under Linux
  73  * with interrupts disabled is Page Fault (due to our lazy mapping of vmalloc
  74  * regions), which has to be reflected through the Host anyway.  If another
  75  * trap *does* go off when interrupts are disabled, the Guest will panic, and
  76  * we'll never get to this iret! :*/
  77
  78 /*G:045 There is one final paravirt_op that the Guest implements, and glancing
  79  * at it you can see why I left it to last.  It's *cool*!  It's in *assembler*!
  80  *
  81  * The "iret" instruction is used to return from an interrupt or trap.  The
  82  * stack looks like this:
  83  *   old address
  84  *   old code segment & privilege level
  85  *   old processor flags ("eflags")
  86  *
  87  * The "iret" instruction pops those values off the stack and restores them all
  88  * at once.  The only problem is that eflags includes the Interrupt Flag which
  89  * the Guest can't change: the CPU will simply ignore it when we do an "iret".
  90  * So we have to copy eflags from the stack to lguest_data.irq_enabled before
  91  * we do the "iret".
  92  *
  93  * There are two problems with this: firstly, we need to use a register to do
  94  * the copy and secondly, the whole thing needs to be atomic.  The first
  95  * problem is easy to solve: push %eax on the stack so we can use it, and then
  96  * restore it at the end just before the real "iret".
  97  *
  98  * The second is harder: copying eflags to lguest_data.irq_enabled will turn
  99  * interrupts on before we're finished, so we could be interrupted before we
 100  * return to userspace or wherever.  Our solution to this is to surround the
 101  * code with lguest_noirq_start: and lguest_noirq_end: labels.  We tell the
 102  * Host that it is *never* to interrupt us there, even if interrupts seem to be
 103  * enabled. */
 104 ENTRY(lguest_iret)
 105         pushl   %eax
 106         movl    12(%esp), %eax
 107 lguest_noirq_start:
 108         /* Note the %ss: segment prefix here.  Normal data accesses use the
 109          * "ds" segment, but that will have already been restored for whatever
 110          * we're returning to (such as userspace): we can't trust it.  The %ss:
 111          * prefix makes sure we use the stack segment, which is still valid. */
 112         movl    %eax,%ss:lguest_data+LGUEST_DATA_irq_enabled
 113         popl    %eax
 114         iret
 115 lguest_noirq_end: