git.oblomov.eu Git - linux-2.6/blob - arch/s390/kernel/head.S

   1 /*
   2  *  arch/s390/kernel/head.S
   3  *
   4  * Copyright (C) IBM Corp. 1999,2006
   5  *
   6  *    Author(s): Hartmut Penner <hp@de.ibm.com>
   7  *               Martin Schwidefsky <schwidefsky@de.ibm.com>
   8  *               Rob van der Heij <rvdhei@iae.nl>
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  *
  11  * There are 5 different IPL methods
  12  *  1) load the image directly into ram at address 0 and do an PSW restart
  13  *  2) linload will load the image from address 0x10000 to memory 0x10000
  14  *     and start the code thru LPSW 0x0008000080010000 (VM only, deprecated)
  15  *  3) generate the tape ipl header, store the generated image on a tape
  16  *     and ipl from it
  17  *     In case of SL tape you need to IPL 5 times to get past VOL1 etc
  18  *  4) generate the vm reader ipl header, move the generated image to the
  19  *     VM reader (use option NOH!) and do a ipl from reader (VM only)
  20  *  5) direct call of start by the SALIPL loader
  21  *  We use the cpuid to distinguish between VM and native ipl
  22  *  params for kernel are pushed to 0x10400 (see setup.h)
  23  *
  24  */
  25
  26 #include <asm/setup.h>
  27 #include <asm/lowcore.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/thread_info.h>
  30 #include <asm/page.h>
  31
  32 #ifdef CONFIG_64BIT
  33 #define ARCH_OFFSET     4
  34 #else
  35 #define ARCH_OFFSET     0
  36 #endif
  37
  38 #ifndef CONFIG_IPL
  39         .org   0
  40         .long  0x00080000,0x80000000+startup   # Just a restart PSW
  41 #else
  42 #ifdef CONFIG_IPL_TAPE
  43 #define IPL_BS 1024
  44         .org   0
  45         .long  0x00080000,0x80000000+iplstart  # The first 24 bytes are loaded
  46         .long  0x27000000,0x60000001           # by ipl to addresses 0-23.
  47         .long  0x02000000,0x20000000+IPL_BS    # (a PSW and two CCWs).
  48         .long  0x00000000,0x00000000           # external old psw
  49         .long  0x00000000,0x00000000           # svc old psw
  50         .long  0x00000000,0x00000000           # program check old psw
  51         .long  0x00000000,0x00000000           # machine check old psw
  52         .long  0x00000000,0x00000000           # io old psw
  53         .long  0x00000000,0x00000000
  54         .long  0x00000000,0x00000000
  55         .long  0x00000000,0x00000000
  56         .long  0x000a0000,0x00000058           # external new psw
  57         .long  0x000a0000,0x00000060           # svc new psw
  58         .long  0x000a0000,0x00000068           # program check new psw
  59         .long  0x000a0000,0x00000070           # machine check new psw
  60         .long  0x00080000,0x80000000+.Lioint   # io new psw
  61
  62         .org   0x100
  63 #
  64 # subroutine for loading from tape
  65 # Paramters:
  66 #  R1 = device number
  67 #  R2 = load address
  68 .Lloader:
  69         st    %r14,.Lldret
  70         la    %r3,.Lorbread                    # r3 = address of orb
  71         la    %r5,.Lirb                        # r5 = address of irb
  72         st    %r2,.Lccwread+4                  # initialize CCW data addresses
  73         lctl  %c6,%c6,.Lcr6
  74         slr   %r2,%r2
  75 .Lldlp:
  76         la    %r6,3                            # 3 retries
  77 .Lssch:
  78         ssch  0(%r3)                           # load chunk of IPL_BS bytes
  79         bnz   .Llderr
  80 .Lw4end:
  81         bas   %r14,.Lwait4io
  82         tm    8(%r5),0x82                      # do we have a problem ?
  83         bnz   .Lrecov
  84         slr   %r7,%r7
  85         icm   %r7,3,10(%r5)                    # get residual count
  86         lcr   %r7,%r7
  87         la    %r7,IPL_BS(%r7)                  # IPL_BS-residual=#bytes read
  88         ar    %r2,%r7                          # add to total size
  89         tm    8(%r5),0x01                      # found a tape mark ?
  90         bnz   .Ldone
  91         l     %r0,.Lccwread+4                  # update CCW data addresses
  92         ar    %r0,%r7
  93         st    %r0,.Lccwread+4
  94         b     .Lldlp
  95 .Ldone:
  96         l     %r14,.Lldret
  97         br    %r14                             # r2 contains the total size
  98 .Lrecov:
  99         bas   %r14,.Lsense                     # do the sensing
 100         bct   %r6,.Lssch                       # dec. retry count & branch
 101         b     .Llderr
 102 #
 103 # Sense subroutine
 104 #
 105 .Lsense:
 106         st    %r14,.Lsnsret
 107         la    %r7,.Lorbsense
 108         ssch  0(%r7)                           # start sense command
 109         bnz   .Llderr
 110         bas   %r14,.Lwait4io
 111         l     %r14,.Lsnsret
 112         tm    8(%r5),0x82                      # do we have a problem ?
 113         bnz   .Llderr
 114         br    %r14
 115 #
 116 # Wait for interrupt subroutine
 117 #
 118 .Lwait4io:
 119         lpsw  .Lwaitpsw
 120 .Lioint:
 121         c     %r1,0xb8                         # compare subchannel number
 122         bne   .Lwait4io
 123         tsch  0(%r5)
 124         slr   %r0,%r0
 125         tm    8(%r5),0x82                      # do we have a problem ?
 126         bnz   .Lwtexit
 127         tm    8(%r5),0x04                      # got device end ?
 128         bz    .Lwait4io
 129 .Lwtexit:
 130         br    %r14
 131 .Llderr:
 132         lpsw  .Lcrash
 133
 134         .align 8
 135 .Lorbread:
 136         .long  0x00000000,0x0080ff00,.Lccwread
 137         .align 8
 138 .Lorbsense:
 139         .long  0x00000000,0x0080ff00,.Lccwsense
 140         .align 8
 141 .Lccwread:
 142         .long  0x02200000+IPL_BS,0x00000000
 143 .Lccwsense:
 144         .long  0x04200001,0x00000000
 145 .Lwaitpsw:
 146         .long  0x020a0000,0x80000000+.Lioint
 147
 148 .Lirb:  .long  0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
 149 .Lcr6:  .long  0xff000000
 150         .align 8
 151 .Lcrash:.long  0x000a0000,0x00000000
 152 .Lldret:.long  0
 153 .Lsnsret: .long 0
 154 #endif  /* CONFIG_IPL_TAPE */
 155
 156 #ifdef CONFIG_IPL_VM
 157 #define IPL_BS 0x730
 158         .org   0
 159         .long  0x00080000,0x80000000+iplstart  # The first 24 bytes are loaded
 160         .long  0x02000018,0x60000050           # by ipl to addresses 0-23.
 161         .long  0x02000068,0x60000050           # (a PSW and two CCWs).
 162         .fill  80-24,1,0x40                    # bytes 24-79 are discarded !!
 163         .long  0x020000f0,0x60000050           # The next 160 byte are loaded
 164         .long  0x02000140,0x60000050           # to addresses 0x18-0xb7
 165         .long  0x02000190,0x60000050           # They form the continuation
 166         .long  0x020001e0,0x60000050           # of the CCW program started
 167         .long  0x02000230,0x60000050           # by ipl and load the range
 168         .long  0x02000280,0x60000050           # 0x0f0-0x730 from the image
 169         .long  0x020002d0,0x60000050           # to the range 0x0f0-0x730
 170         .long  0x02000320,0x60000050           # in memory. At the end of
 171         .long  0x02000370,0x60000050           # the channel program the PSW
 172         .long  0x020003c0,0x60000050           # at location 0 is loaded.
 173         .long  0x02000410,0x60000050           # Initial processing starts
 174         .long  0x02000460,0x60000050           # at 0xf0 = iplstart.
 175         .long  0x020004b0,0x60000050
 176         .long  0x02000500,0x60000050
 177         .long  0x02000550,0x60000050
 178         .long  0x020005a0,0x60000050
 179         .long  0x020005f0,0x60000050
 180         .long  0x02000640,0x60000050
 181         .long  0x02000690,0x60000050
 182         .long  0x020006e0,0x20000050
 183
 184         .org   0xf0
 185 #
 186 # subroutine for loading cards from the reader
 187 #
 188 .Lloader:
 189         la    %r3,.Lorb                        # r2 = address of orb into r2
 190         la    %r5,.Lirb                        # r4 = address of irb
 191         la    %r6,.Lccws
 192         la    %r7,20
 193 .Linit:
 194         st    %r2,4(%r6)                       # initialize CCW data addresses
 195         la    %r2,0x50(%r2)
 196         la    %r6,8(%r6)
 197         bct   7,.Linit
 198
 199         lctl  %c6,%c6,.Lcr6                    # set IO subclass mask
 200         slr   %r2,%r2
 201 .Lldlp:
 202         ssch  0(%r3)                           # load chunk of 1600 bytes
 203         bnz   .Llderr
 204 .Lwait4irq:
 205         mvc   0x78(8),.Lnewpsw                 # set up IO interrupt psw
 206         lpsw  .Lwaitpsw
 207 .Lioint:
 208         c     %r1,0xb8                         # compare subchannel number
 209         bne   .Lwait4irq
 210         tsch  0(%r5)
 211
 212         slr   %r0,%r0
 213         ic    %r0,8(%r5)                       # get device status
 214         chi   %r0,8                            # channel end ?
 215         be    .Lcont
 216         chi   %r0,12                           # channel end + device end ?
 217         be    .Lcont
 218
 219         l     %r0,4(%r5)
 220         s     %r0,8(%r3)                       # r0/8 = number of ccws executed
 221         mhi   %r0,10                           # *10 = number of bytes in ccws
 222         lh    %r3,10(%r5)                      # get residual count
 223         sr    %r0,%r3                          # #ccws*80-residual=#bytes read
 224         ar    %r2,%r0
 225
 226         br    %r14                             # r2 contains the total size
 227
 228 .Lcont:
 229         ahi   %r2,0x640                        # add 0x640 to total size
 230         la    %r6,.Lccws
 231         la    %r7,20
 232 .Lincr:
 233         l     %r0,4(%r6)                       # update CCW data addresses
 234         ahi   %r0,0x640
 235         st    %r0,4(%r6)
 236         ahi   %r6,8
 237         bct   7,.Lincr
 238
 239         b     .Lldlp
 240 .Llderr:
 241         lpsw  .Lcrash
 242
 243         .align 8
 244 .Lorb:  .long  0x00000000,0x0080ff00,.Lccws
 245 .Lirb:  .long  0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
 246 .Lcr6:  .long  0xff000000
 247 .Lloadp:.long  0,0
 248         .align 8
 249 .Lcrash:.long  0x000a0000,0x00000000
 250 .Lnewpsw:
 251         .long  0x00080000,0x80000000+.Lioint
 252 .Lwaitpsw:
 253         .long  0x020a0000,0x80000000+.Lioint
 254
 255         .align 8
 256 .Lccws: .rept  19
 257         .long  0x02600050,0x00000000
 258         .endr
 259         .long  0x02200050,0x00000000
 260 #endif  /* CONFIG_IPL_VM */
 261
 262 iplstart:
 263         lh    %r1,0xb8                         # test if subchannel number
 264         bct   %r1,.Lnoload                     #  is valid
 265         l     %r1,0xb8                         # load ipl subchannel number
 266         la    %r2,IPL_BS                       # load start address
 267         bas   %r14,.Lloader                    # load rest of ipl image
 268         l     %r12,.Lparm                      # pointer to parameter area
 269         st    %r1,IPL_DEVICE+ARCH_OFFSET-PARMAREA(%r12) # save ipl device number
 270
 271 #
 272 # load parameter file from ipl device
 273 #
 274 .Lagain1:
 275         l     %r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12) # ramdisk loc. is temp
 276         bas   %r14,.Lloader                    # load parameter file
 277         ltr   %r2,%r2                          # got anything ?
 278         bz    .Lnopf
 279         chi   %r2,895
 280         bnh   .Lnotrunc
 281         la    %r2,895
 282 .Lnotrunc:
 283         l     %r4,INITRD_START+ARCH_OFFSET-PARMAREA(%r12)
 284         clc   0(3,%r4),.L_hdr                  # if it is HDRx
 285         bz    .Lagain1                         # skip dataset header
 286         clc   0(3,%r4),.L_eof                  # if it is EOFx
 287         bz    .Lagain1                         # skip dateset trailer
 288         la    %r5,0(%r4,%r2)
 289         lr    %r3,%r2
 290 .Lidebc:
 291         tm    0(%r5),0x80                      # high order bit set ?
 292         bo    .Ldocv                           #  yes -> convert from EBCDIC
 293         ahi   %r5,-1
 294         bct   %r3,.Lidebc
 295         b     .Lnocv
 296 .Ldocv:
 297         l     %r3,.Lcvtab
 298         tr    0(256,%r4),0(%r3)                # convert parameters to ascii
 299         tr    256(256,%r4),0(%r3)
 300         tr    512(256,%r4),0(%r3)
 301         tr    768(122,%r4),0(%r3)
 302 .Lnocv: la    %r3,COMMAND_LINE-PARMAREA(%r12)  # load adr. of command line
 303         mvc   0(256,%r3),0(%r4)
 304         mvc   256(256,%r3),256(%r4)
 305         mvc   512(256,%r3),512(%r4)
 306         mvc   768(122,%r3),768(%r4)
 307         slr   %r0,%r0
 308         b     .Lcntlp
 309 .Ldelspc:
 310         ic    %r0,0(%r2,%r3)
 311         chi   %r0,0x20                         # is it a space ?
 312         be    .Lcntlp
 313         ahi   %r2,1
 314         b     .Leolp
 315 .Lcntlp:
 316         brct  %r2,.Ldelspc
 317 .Leolp:
 318         slr   %r0,%r0
 319         stc   %r0,0(%r2,%r3)                   # terminate buffer
 320 .Lnopf:
 321
 322 #
 323 # load ramdisk from ipl device
 324 #
 325 .Lagain2:
 326         l     %r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12) # addr of ramdisk
 327         bas   %r14,.Lloader                    # load ramdisk
 328         st    %r2,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r12) # store size of ramdisk
 329         ltr   %r2,%r2
 330         bnz   .Lrdcont
 331         st    %r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12) # no ramdisk found
 332 .Lrdcont:
 333         l     %r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12)
 334
 335         clc   0(3,%r2),.L_hdr                  # skip HDRx and EOFx
 336         bz    .Lagain2
 337         clc   0(3,%r2),.L_eof
 338         bz    .Lagain2
 339
 340 #ifdef CONFIG_IPL_VM
 341 #
 342 # reset files in VM reader
 343 #
 344         stidp __LC_CPUID                       # store cpuid
 345         tm    __LC_CPUID,0xff                  # running VM ?
 346         bno   .Lnoreset
 347         la    %r2,.Lreset
 348         lhi   %r3,26
 349         diag  %r2,%r3,8
 350         la    %r5,.Lirb
 351         stsch 0(%r5)                           # check if irq is pending
 352         tm    30(%r5),0x0f                     # by verifying if any of the
 353         bnz   .Lwaitforirq                     # activity or status control
 354         tm    31(%r5),0xff                     # bits is set in the schib
 355         bz    .Lnoreset
 356 .Lwaitforirq:
 357         mvc   0x78(8),.Lrdrnewpsw              # set up IO interrupt psw
 358 .Lwaitrdrirq:
 359         lpsw  .Lrdrwaitpsw
 360 .Lrdrint:
 361         c     %r1,0xb8                         # compare subchannel number
 362         bne   .Lwaitrdrirq
 363         la    %r5,.Lirb
 364         tsch  0(%r5)
 365 .Lnoreset:
 366         b     .Lnoload
 367
 368         .align 8
 369 .Lrdrnewpsw:
 370         .long  0x00080000,0x80000000+.Lrdrint
 371 .Lrdrwaitpsw:
 372         .long  0x020a0000,0x80000000+.Lrdrint
 373 #endif
 374
 375 #
 376 # everything loaded, go for it
 377 #
 378 .Lnoload:
 379         l     %r1,.Lstartup
 380         br    %r1
 381
 382 .Lparm: .long  PARMAREA
 383 .Lstartup: .long startup
 384 .Lcvtab:.long  _ebcasc                         # ebcdic to ascii table
 385 .Lreset:.byte  0xc3,0xc8,0xc1,0xd5,0xc7,0xc5,0x40,0xd9,0xc4,0xd9,0x40
 386         .byte  0xc1,0xd3,0xd3,0x40,0xd2,0xc5,0xc5,0xd7,0x40,0xd5,0xd6
 387         .byte  0xc8,0xd6,0xd3,0xc4             # "change rdr all keep nohold"
 388 .L_eof: .long  0xc5d6c600       /* C'EOF' */
 389 .L_hdr: .long  0xc8c4d900       /* C'HDR' */
 390
 391 #endif  /* CONFIG_IPL */
 392
 393 #
 394 # SALIPL loader support. Based on a patch by Rob van der Heij.
 395 # This entry point is called directly from the SALIPL loader and
 396 # doesn't need a builtin ipl record.
 397 #
 398         .org  0x800
 399         .globl start
 400 start:
 401         stm   %r0,%r15,0x07b0           # store registers
 402         basr  %r12,%r0
 403 .base:
 404         l     %r11,.parm
 405         l     %r8,.cmd                  # pointer to command buffer
 406
 407         ltr   %r9,%r9                   # do we have SALIPL parameters?
 408         bp    .sk8x8
 409
 410         mvc   0(64,%r8),0x00b0          # copy saved registers
 411         xc    64(240-64,%r8),0(%r8)     # remainder of buffer
 412         tr    0(64,%r8),.lowcase
 413         b     .gotr
 414 .sk8x8:
 415         mvc   0(240,%r8),0(%r9)         # copy iplparms into buffer
 416 .gotr:
 417         l     %r10,.tbl                 # EBCDIC to ASCII table
 418         tr    0(240,%r8),0(%r10)
 419         stidp __LC_CPUID                # Are we running on VM maybe
 420         cli   __LC_CPUID,0xff
 421         bnz   .test
 422         .long 0x83300060                # diag 3,0,x'0060' - storage size
 423         b     .done
 424 .test:
 425         mvc   0x68(8),.pgmnw            # set up pgm check handler
 426         l     %r2,.fourmeg
 427         lr    %r3,%r2
 428         bctr  %r3,%r0                   # 4M-1
 429 .loop:  iske  %r0,%r3
 430         ar    %r3,%r2
 431 .pgmx:
 432         sr    %r3,%r2
 433         la    %r3,1(%r3)
 434 .done:
 435         l     %r1,.memsize
 436         st    %r3,ARCH_OFFSET(%r1)
 437         slr   %r0,%r0
 438         st    %r0,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r11)
 439         st    %r0,INITRD_START+ARCH_OFFSET-PARMAREA(%r11)
 440         j     startup                   # continue with startup
 441 .tbl:   .long _ebcasc                   # translate table
 442 .cmd:   .long COMMAND_LINE              # address of command line buffer
 443 .parm:  .long PARMAREA
 444 .memsize: .long memory_size
 445 .fourmeg: .long 0x00400000              # 4M
 446 .pgmnw: .long 0x00080000,.pgmx
 447 .lowcase:
 448         .byte 0x00,0x01,0x02,0x03,0x04,0x05,0x06,0x07
 449         .byte 0x08,0x09,0x0a,0x0b,0x0c,0x0d,0x0e,0x0f
 450         .byte 0x10,0x11,0x12,0x13,0x14,0x15,0x16,0x17
 451         .byte 0x18,0x19,0x1a,0x1b,0x1c,0x1d,0x1e,0x1f
 452         .byte 0x20,0x21,0x22,0x23,0x24,0x25,0x26,0x27
 453         .byte 0x28,0x29,0x2a,0x2b,0x2c,0x2d,0x2e,0x2f
 454         .byte 0x30,0x31,0x32,0x33,0x34,0x35,0x36,0x37
 455         .byte 0x38,0x39,0x3a,0x3b,0x3c,0x3d,0x3e,0x3f
 456         .byte 0x40,0x41,0x42,0x43,0x44,0x45,0x46,0x47
 457         .byte 0x48,0x49,0x4a,0x4b,0x4c,0x4d,0x4e,0x4f
 458         .byte 0x50,0x51,0x52,0x53,0x54,0x55,0x56,0x57
 459         .byte 0x58,0x59,0x5a,0x5b,0x5c,0x5d,0x5e,0x5f
 460         .byte 0x60,0x61,0x62,0x63,0x64,0x65,0x66,0x67
 461         .byte 0x68,0x69,0x6a,0x6b,0x6c,0x6d,0x6e,0x6f
 462         .byte 0x70,0x71,0x72,0x73,0x74,0x75,0x76,0x77
 463         .byte 0x78,0x79,0x7a,0x7b,0x7c,0x7d,0x7e,0x7f
 464
 465         .byte 0x80,0x81,0x82,0x83,0x84,0x85,0x86,0x87
 466         .byte 0x88,0x89,0x8a,0x8b,0x8c,0x8d,0x8e,0x8f
 467         .byte 0x90,0x91,0x92,0x93,0x94,0x95,0x96,0x97
 468         .byte 0x98,0x99,0x9a,0x9b,0x9c,0x9d,0x9e,0x9f
 469         .byte 0xa0,0xa1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7
 470         .byte 0xa8,0xa9,0xaa,0xab,0xac,0xad,0xae,0xaf
 471         .byte 0xb0,0xb1,0xb2,0xb3,0xb4,0xb5,0xb6,0xb7
 472         .byte 0xb8,0xb9,0xba,0xbb,0xbc,0xbd,0xbe,0xbf
 473         .byte 0xc0,0x81,0x82,0x83,0x84,0x85,0x86,0x87   # .abcdefg
 474         .byte 0x88,0x89,0xca,0xcb,0xcc,0xcd,0xce,0xcf   # hi
 475         .byte 0xd0,0x91,0x92,0x93,0x94,0x95,0x96,0x97   # .jklmnop
 476         .byte 0x98,0x99,0xda,0xdb,0xdc,0xdd,0xde,0xdf   # qr
 477         .byte 0xe0,0xe1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7   # ..stuvwx
 478         .byte 0xa8,0xa9,0xea,0xeb,0xec,0xed,0xee,0xef   # yz
 479         .byte 0xf0,0xf1,0xf2,0xf3,0xf4,0xf5,0xf6,0xf7
 480         .byte 0xf8,0xf9,0xfa,0xfb,0xfc,0xfd,0xfe,0xff
 481
 482 .macro GET_IPL_DEVICE
 483 .Lget_ipl_device:
 484         l     %r1,0xb8                  # get sid
 485         sll   %r1,15                    # test if subchannel is enabled
 486         srl   %r1,31
 487         ltr   %r1,%r1
 488         bz    2f-.LPG1(%r13)            # subchannel disabled
 489         l     %r1,0xb8
 490         la    %r5,.Lipl_schib-.LPG1(%r13)
 491         stsch 0(%r5)                    # get schib of subchannel
 492         bnz   2f-.LPG1(%r13)            # schib not available
 493         tm    5(%r5),0x01               # devno valid?
 494         bno   2f-.LPG1(%r13)
 495         la    %r6,ipl_parameter_flags-.LPG1(%r13)
 496         oi    3(%r6),0x01               # set flag
 497         la    %r2,ipl_devno-.LPG1(%r13)
 498         mvc   0(2,%r2),6(%r5)           # store devno
 499         tm    4(%r5),0x80               # qdio capable device?
 500         bno   2f-.LPG1(%r13)
 501         oi    3(%r6),0x02               # set flag
 502
 503         # copy ipl parameters
 504
 505         lhi   %r0,4096
 506         l     %r2,20(%r0)               # get address of parameter list
 507         lhi   %r3,IPL_PARMBLOCK_ORIGIN
 508         st    %r3,20(%r0)
 509         lhi   %r4,1
 510         cr    %r2,%r3                   # start parameters < destination ?
 511         jl    0f
 512         lhi   %r1,1                     # copy direction is upwards
 513         j     1f
 514 0:      lhi   %r1,-1                    # copy direction is downwards
 515         ar    %r2,%r0
 516         ar    %r3,%r0
 517         ar    %r2,%r1
 518         ar    %r3,%r1
 519 1:      mvc   0(1,%r3),0(%r2)           # finally copy ipl parameters
 520         ar    %r3,%r1
 521         ar    %r2,%r1
 522         sr    %r0,%r4
 523         jne   1b
 524         b     2f-.LPG1(%r13)
 525
 526         .align 4
 527 .Lipl_schib:
 528         .rept 13
 529         .long 0
 530         .endr
 531
 532         .globl ipl_parameter_flags
 533 ipl_parameter_flags:
 534         .long 0
 535         .globl ipl_devno
 536 ipl_devno:
 537         .word 0
 538 2:
 539 .endm
 540
 541 #ifdef CONFIG_64BIT
 542 #include "head64.S"
 543 #else
 544 #include "head31.S"
 545 #endif