git.oblomov.eu Git - linux-2.6/blob - arch/sh/kernel/vmlinux.lds.S

   1 /* $Id: vmlinux.lds.S,v 1.8 2003/05/16 17:18:14 lethal Exp $
   2  * ld script to make SuperH Linux kernel
   3  * Written by Niibe Yutaka
   4  */
   5 #include <asm/thread_info.h>
   6 #include <asm-generic/vmlinux.lds.h>
   7
   8 #ifdef CONFIG_CPU_LITTLE_ENDIAN
   9 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  10 #else
  11 OUTPUT_FORMAT("elf32-shbig-linux", "elf32-shbig-linux", "elf32-shbig-linux")
  12 #endif
  13 OUTPUT_ARCH(sh)
  14 ENTRY(_start)
  15 SECTIONS
  16 {
  17   . = CONFIG_PAGE_OFFSET + CONFIG_MEMORY_START + CONFIG_ZERO_PAGE_OFFSET;
  18   _text = .;                    /* Text and read-only data */
  19   text = .;                     /* Text and read-only data */
  20   .empty_zero_page : {
  21         *(.empty_zero_page)
  22         } = 0
  23   .text : {
  24         *(.text)
  25         SCHED_TEXT
  26         LOCK_TEXT
  27         *(.fixup)
  28         *(.gnu.warning)
  29         } = 0x0009
  30
  31   . = ALIGN(16);                /* Exception table */
  32   __start___ex_table = .;
  33   __ex_table : { *(__ex_table) }
  34   __stop___ex_table = .;
  35
  36   RODATA
  37
  38   _etext = .;                   /* End of text section */
  39
  40   .data : {                     /* Data */
  41         *(.data)
  42
  43          /* Align the initial ramdisk image (INITRD) on page boundaries. */
  44          . = ALIGN(PAGE_SIZE);
  45          __rd_start = .;
  46          *(.initrd)
  47          . = ALIGN(PAGE_SIZE);
  48          __rd_end = .;
  49
  50         CONSTRUCTORS
  51         }
  52
  53   . = ALIGN(PAGE_SIZE);
  54   .data.page_aligned : { *(.data.idt) }
  55
  56   . = ALIGN(32);
  57   __per_cpu_start = .;
  58   .data.percpu : { *(.data.percpu) }
  59   __per_cpu_end = .;
  60   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  61
  62   _edata = .;                   /* End of data section */
  63
  64   . = ALIGN(THREAD_SIZE);               /* init_task */
  65   .data.init_task : { *(.data.init_task) }
  66
  67   . = ALIGN(PAGE_SIZE);         /* Init code and data */
  68   __init_begin = .;
  69   _sinittext = .;
  70   .init.text : { *(.init.text) }
  71   _einittext = .;
  72   .init.data : { *(.init.data) }
  73   . = ALIGN(16);
  74   __setup_start = .;
  75   .init.setup : { *(.init.setup) }
  76   __setup_end = .;
  77   __initcall_start = .;
  78   .initcall.init : {
  79         INITCALLS
  80   }
  81   __initcall_end = .;
  82   __con_initcall_start = .;
  83   .con_initcall.init : { *(.con_initcall.init) }
  84   __con_initcall_end = .;
  85   SECURITY_INIT
  86   __initramfs_start = .;
  87   .init.ramfs : { *(.init.ramfs) }
  88   __initramfs_end = .;
  89   __machvec_start = .;
  90   .init.machvec : { *(.init.machvec) }
  91   __machvec_end = .;
  92   . = ALIGN(PAGE_SIZE);
  93   __init_end = .;
  94
  95   . = ALIGN(4);
  96   __bss_start = .;              /* BSS */
  97   .bss : { *(.bss) }
  98
  99   . = ALIGN(4);
 100   _end = . ;
 101
 102   /* When something in the kernel is NOT compiled as a module, the
 103    * module cleanup code and data are put into these segments.  Both
 104    * can then be thrown away, as cleanup code is never called unless
 105    * it's a module.
 106    */
 107   /DISCARD/ : {
 108         *(.exit.text)
 109         *(.exit.data)
 110         *(.exitcall.exit)
 111         }
 112
 113   /* Stabs debugging sections.  */
 114   .stab 0 : { *(.stab) }
 115   .stabstr 0 : { *(.stabstr) }
 116   .stab.excl 0 : { *(.stab.excl) }
 117   .stab.exclstr 0 : { *(.stab.exclstr) }
 118   .stab.index 0 : { *(.stab.index) }
 119   .stab.indexstr 0 : { *(.stab.indexstr) }
 120   .comment 0 : { *(.comment) }
 121   /* DWARF debug sections.
 122      Symbols in the DWARF debugging section are relative to the beginning
 123      of the section so we begin .debug at 0.  */
 124   /* DWARF 1 */
 125   .debug          0 : { *(.debug) }
 126   .line           0 : { *(.line) }
 127   /* GNU DWARF 1 extensions */
 128   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 129   .debug_sfnames  0 : { *(.debug_sfnames) }
 130   /* DWARF 1.1 and DWARF 2 */
 131   .debug_aranges  0 : { *(.debug_aranges) }
 132   .debug_pubnames 0 : { *(.debug_pubnames) }
 133   /* DWARF 2 */
 134   .debug_info     0 : { *(.debug_info) }
 135   .debug_abbrev   0 : { *(.debug_abbrev) }
 136   .debug_line     0 : { *(.debug_line) }
 137   .debug_frame    0 : { *(.debug_frame) }
 138   .debug_str      0 : { *(.debug_str) }
 139   .debug_loc      0 : { *(.debug_loc) }
 140   .debug_macinfo  0 : { *(.debug_macinfo) }
 141   /* SGI/MIPS DWARF 2 extensions */
 142   .debug_weaknames 0 : { *(.debug_weaknames) }
 143   .debug_funcnames 0 : { *(.debug_funcnames) }
 144   .debug_typenames 0 : { *(.debug_typenames) }
 145   .debug_varnames  0 : { *(.debug_varnames) }
 146   /* These must appear regardless of  .  */
 147 }