git.oblomov.eu Git - linux-2.6/blob - arch/x86_64/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/vsyscall32.h>
  16 #include <linux/linkage.h>
  17
  18 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  19
  20         .macro IA32_ARG_FIXUP noebp=0
  21         movl    %edi,%r8d
  22         .if \noebp
  23         .else
  24         movl    %ebp,%r9d
  25         .endif
  26         xchg    %ecx,%esi
  27         movl    %ebx,%edi
  28         movl    %edx,%edx       /* zero extension */
  29         .endm
  30
  31         /* clobbers %eax */
  32         .macro  CLEAR_RREGS
  33         xorl    %eax,%eax
  34         movq    %rax,R11(%rsp)
  35         movq    %rax,R10(%rsp)
  36         movq    %rax,R9(%rsp)
  37         movq    %rax,R8(%rsp)
  38         .endm
  39
  40         .macro CFI_STARTPROC32 simple
  41         CFI_STARTPROC   \simple
  42         CFI_UNDEFINED   r8
  43         CFI_UNDEFINED   r9
  44         CFI_UNDEFINED   r10
  45         CFI_UNDEFINED   r11
  46         CFI_UNDEFINED   r12
  47         CFI_UNDEFINED   r13
  48         CFI_UNDEFINED   r14
  49         CFI_UNDEFINED   r15
  50         .endm
  51
  52 /*
  53  * 32bit SYSENTER instruction entry.
  54  *
  55  * Arguments:
  56  * %eax System call number.
  57  * %ebx Arg1
  58  * %ecx Arg2
  59  * %edx Arg3
  60  * %esi Arg4
  61  * %edi Arg5
  62  * %ebp user stack
  63  * 0(%ebp) Arg6
  64  *
  65  * Interrupts off.
  66  *
  67  * This is purely a fast path. For anything complicated we use the int 0x80
  68  * path below.  Set up a complete hardware stack frame to share code
  69  * with the int 0x80 path.
  70  */
  71 ENTRY(ia32_sysenter_target)
  72         CFI_STARTPROC32 simple
  73         CFI_DEF_CFA     rsp,0
  74         CFI_REGISTER    rsp,rbp
  75         swapgs
  76         movq    %gs:pda_kernelstack, %rsp
  77         addq    $(PDA_STACKOFFSET),%rsp
  78         sti
  79         movl    %ebp,%ebp               /* zero extension */
  80         pushq   $__USER32_DS
  81         CFI_ADJUST_CFA_OFFSET 8
  82         /*CFI_REL_OFFSET ss,0*/
  83         pushq   %rbp
  84         CFI_ADJUST_CFA_OFFSET 8
  85         CFI_REL_OFFSET rsp,0
  86         pushfq
  87         CFI_ADJUST_CFA_OFFSET 8
  88         /*CFI_REL_OFFSET rflags,0*/
  89         movl    $VSYSCALL32_SYSEXIT, %r10d
  90         CFI_REGISTER rip,r10
  91         pushq   $__USER32_CS
  92         CFI_ADJUST_CFA_OFFSET 8
  93         /*CFI_REL_OFFSET cs,0*/
  94         movl    %eax, %eax
  95         pushq   %r10
  96         CFI_ADJUST_CFA_OFFSET 8
  97         CFI_REL_OFFSET rip,0
  98         pushq   %rax
  99         CFI_ADJUST_CFA_OFFSET 8
 100         cld
 101         SAVE_ARGS 0,0,1
 102         /* no need to do an access_ok check here because rbp has been
 103            32bit zero extended */
 104 1:      movl    (%rbp),%r9d
 105         .section __ex_table,"a"
 106         .quad 1b,ia32_badarg
 107         .previous
 108         GET_THREAD_INFO(%r10)
 109         orl    $TS_COMPAT,threadinfo_status(%r10)
 110         testl  $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 111         CFI_REMEMBER_STATE
 112         jnz  sysenter_tracesys
 113 sysenter_do_call:
 114         cmpl    $(IA32_NR_syscalls-1),%eax
 115         ja      ia32_badsys
 116         IA32_ARG_FIXUP 1
 117         call    *ia32_sys_call_table(,%rax,8)
 118         movq    %rax,RAX-ARGOFFSET(%rsp)
 119         GET_THREAD_INFO(%r10)
 120         cli
 121         testl   $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 122         jnz     int_ret_from_sys_call
 123         andl    $~TS_COMPAT,threadinfo_status(%r10)
 124         /* clear IF, that popfq doesn't enable interrupts early */
 125         andl  $~0x200,EFLAGS-R11(%rsp)
 126         RESTORE_ARGS 1,24,1,1,1,1
 127         popfq
 128         CFI_ADJUST_CFA_OFFSET -8
 129         /*CFI_RESTORE rflags*/
 130         popq    %rcx                            /* User %esp */
 131         CFI_ADJUST_CFA_OFFSET -8
 132         CFI_REGISTER rsp,rcx
 133         movl    $VSYSCALL32_SYSEXIT,%edx        /* User %eip */
 134         CFI_REGISTER rip,rdx
 135         swapgs
 136         sti             /* sti only takes effect after the next instruction */
 137         /* sysexit */
 138         .byte   0xf, 0x35
 139
 140 sysenter_tracesys:
 141         CFI_RESTORE_STATE
 142         SAVE_REST
 143         CLEAR_RREGS
 144         movq    $-ENOSYS,RAX(%rsp)      /* really needed? */
 145         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 146         call    syscall_trace_enter
 147         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 148         RESTORE_REST
 149         movl    %ebp, %ebp
 150         /* no need to do an access_ok check here because rbp has been
 151            32bit zero extended */
 152 1:      movl    (%rbp),%r9d
 153         .section __ex_table,"a"
 154         .quad 1b,ia32_badarg
 155         .previous
 156         jmp     sysenter_do_call
 157         CFI_ENDPROC
 158 ENDPROC(ia32_sysenter_target)
 159
 160 /*
 161  * 32bit SYSCALL instruction entry.
 162  *
 163  * Arguments:
 164  * %eax System call number.
 165  * %ebx Arg1
 166  * %ecx return EIP
 167  * %edx Arg3
 168  * %esi Arg4
 169  * %edi Arg5
 170  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 171  * %esp user stack
 172  * 0(%esp) Arg6
 173  *
 174  * Interrupts off.
 175  *
 176  * This is purely a fast path. For anything complicated we use the int 0x80
 177  * path below.  Set up a complete hardware stack frame to share code
 178  * with the int 0x80 path.
 179  */
 180 ENTRY(ia32_cstar_target)
 181         CFI_STARTPROC32 simple
 182         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 183         CFI_REGISTER    rip,rcx
 184         /*CFI_REGISTER  rflags,r11*/
 185         swapgs
 186         movl    %esp,%r8d
 187         CFI_REGISTER    rsp,r8
 188         movq    %gs:pda_kernelstack,%rsp
 189         sti
 190         SAVE_ARGS 8,1,1
 191         movl    %eax,%eax       /* zero extension */
 192         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 193         movq    %rcx,RIP-ARGOFFSET(%rsp)
 194         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 195         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 196         movl    %ebp,%ecx
 197         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 198         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 199         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 200         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 201         movq    %r8,RSP-ARGOFFSET(%rsp)
 202         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 203         /* no need to do an access_ok check here because r8 has been
 204            32bit zero extended */
 205         /* hardware stack frame is complete now */
 206 1:      movl    (%r8),%r9d
 207         .section __ex_table,"a"
 208         .quad 1b,ia32_badarg
 209         .previous
 210         GET_THREAD_INFO(%r10)
 211         orl   $TS_COMPAT,threadinfo_status(%r10)
 212         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 213         CFI_REMEMBER_STATE
 214         jnz   cstar_tracesys
 215 cstar_do_call:
 216         cmpl $IA32_NR_syscalls-1,%eax
 217         ja  ia32_badsys
 218         IA32_ARG_FIXUP 1
 219         call *ia32_sys_call_table(,%rax,8)
 220         movq %rax,RAX-ARGOFFSET(%rsp)
 221         GET_THREAD_INFO(%r10)
 222         cli
 223         testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 224         jnz  int_ret_from_sys_call
 225         andl $~TS_COMPAT,threadinfo_status(%r10)
 226         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
 227         movl RIP-ARGOFFSET(%rsp),%ecx
 228         CFI_REGISTER rip,rcx
 229         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 230         /*CFI_REGISTER rflags,r11*/
 231         movl RSP-ARGOFFSET(%rsp),%esp
 232         CFI_RESTORE rsp
 233         swapgs
 234         sysretl
 235
 236 cstar_tracesys:
 237         CFI_RESTORE_STATE
 238         SAVE_REST
 239         CLEAR_RREGS
 240         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 241         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 242         call syscall_trace_enter
 243         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 244         RESTORE_REST
 245         movl RSP-ARGOFFSET(%rsp), %r8d
 246         /* no need to do an access_ok check here because r8 has been
 247            32bit zero extended */
 248 1:      movl    (%r8),%r9d
 249         .section __ex_table,"a"
 250         .quad 1b,ia32_badarg
 251         .previous
 252         jmp cstar_do_call
 253 END(ia32_cstar_target)
 254
 255 ia32_badarg:
 256         movq $-EFAULT,%rax
 257         jmp ia32_sysret
 258         CFI_ENDPROC
 259
 260 /*
 261  * Emulated IA32 system calls via int 0x80.
 262  *
 263  * Arguments:
 264  * %eax System call number.
 265  * %ebx Arg1
 266  * %ecx Arg2
 267  * %edx Arg3
 268  * %esi Arg4
 269  * %edi Arg5
 270  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 271  *
 272  * Notes:
 273  * Uses the same stack frame as the x86-64 version.
 274  * All registers except %eax must be saved (but ptrace may violate that)
 275  * Arguments are zero extended. For system calls that want sign extension and
 276  * take long arguments a wrapper is needed. Most calls can just be called
 277  * directly.
 278  * Assumes it is only called from user space and entered with interrupts off.
 279  */
 280
 281 ENTRY(ia32_syscall)
 282         CFI_STARTPROC   simple
 283         CFI_DEF_CFA     rsp,SS+8-RIP
 284         /*CFI_REL_OFFSET        ss,SS-RIP*/
 285         CFI_REL_OFFSET  rsp,RSP-RIP
 286         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 287         /*CFI_REL_OFFSET        cs,CS-RIP*/
 288         CFI_REL_OFFSET  rip,RIP-RIP
 289         swapgs
 290         sti
 291         movl %eax,%eax
 292         pushq %rax
 293         CFI_ADJUST_CFA_OFFSET 8
 294         cld
 295         /* note the registers are not zero extended to the sf.
 296            this could be a problem. */
 297         SAVE_ARGS 0,0,1
 298         GET_THREAD_INFO(%r10)
 299         orl   $TS_COMPAT,threadinfo_status(%r10)
 300         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 301         jnz ia32_tracesys
 302 ia32_do_syscall:
 303         cmpl $(IA32_NR_syscalls-1),%eax
 304         ja  ia32_badsys
 305         IA32_ARG_FIXUP
 306         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 307 ia32_sysret:
 308         movq %rax,RAX-ARGOFFSET(%rsp)
 309         jmp int_ret_from_sys_call
 310
 311 ia32_tracesys:
 312         SAVE_REST
 313         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 314         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 315         call syscall_trace_enter
 316         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 317         RESTORE_REST
 318         jmp ia32_do_syscall
 319 END(ia32_syscall)
 320
 321 ia32_badsys:
 322         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 323         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 324         jmp int_ret_from_sys_call
 325
 326 quiet_ni_syscall:
 327         movq $-ENOSYS,%rax
 328         ret
 329         CFI_ENDPROC
 330
 331         .macro PTREGSCALL label, func, arg
 332         .globl \label
 333 \label:
 334         leaq \func(%rip),%rax
 335         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 336         jmp  ia32_ptregs_common
 337         .endm
 338
 339         CFI_STARTPROC32
 340
 341         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 342         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 343         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 344         PTREGSCALL stub32_sigsuspend, sys32_sigsuspend, %rcx
 345         PTREGSCALL stub32_execve, sys32_execve, %rcx
 346         PTREGSCALL stub32_fork, sys_fork, %rdi
 347         PTREGSCALL stub32_clone, sys32_clone, %rdx
 348         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 349         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 350         PTREGSCALL stub32_rt_sigsuspend, sys_rt_sigsuspend, %rdx
 351
 352 ENTRY(ia32_ptregs_common)
 353         popq %r11
 354         CFI_ENDPROC
 355         CFI_STARTPROC32 simple
 356         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 357         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 358         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 359         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 360         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 361         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 362         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 363 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 364 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 365         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 366 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 367         SAVE_REST
 368         call *%rax
 369         RESTORE_REST
 370         jmp  ia32_sysret        /* misbalances the return cache */
 371         CFI_ENDPROC
 372 END(ia32_ptregs_common)
 373
 374         .section .rodata,"a"
 375         .align 8
 376 ia32_sys_call_table:
 377         .quad sys_restart_syscall
 378         .quad sys_exit
 379         .quad stub32_fork
 380         .quad sys_read
 381         .quad sys_write
 382         .quad compat_sys_open           /* 5 */
 383         .quad sys_close
 384         .quad sys32_waitpid
 385         .quad sys_creat
 386         .quad sys_link
 387         .quad sys_unlink                /* 10 */
 388         .quad stub32_execve
 389         .quad sys_chdir
 390         .quad compat_sys_time
 391         .quad sys_mknod
 392         .quad sys_chmod         /* 15 */
 393         .quad sys_lchown16
 394         .quad quiet_ni_syscall                  /* old break syscall holder */
 395         .quad sys_stat
 396         .quad sys32_lseek
 397         .quad sys_getpid                /* 20 */
 398         .quad compat_sys_mount  /* mount  */
 399         .quad sys_oldumount     /* old_umount  */
 400         .quad sys_setuid16
 401         .quad sys_getuid16
 402         .quad compat_sys_stime  /* stime */             /* 25 */
 403         .quad sys32_ptrace      /* ptrace */
 404         .quad sys_alarm
 405         .quad sys_fstat /* (old)fstat */
 406         .quad sys_pause
 407         .quad compat_sys_utime  /* 30 */
 408         .quad quiet_ni_syscall  /* old stty syscall holder */
 409         .quad quiet_ni_syscall  /* old gtty syscall holder */
 410         .quad sys_access
 411         .quad sys_nice
 412         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 413         .quad sys_sync
 414         .quad sys32_kill
 415         .quad sys_rename
 416         .quad sys_mkdir
 417         .quad sys_rmdir         /* 40 */
 418         .quad sys_dup
 419         .quad sys32_pipe
 420         .quad compat_sys_times
 421         .quad quiet_ni_syscall                  /* old prof syscall holder */
 422         .quad sys_brk           /* 45 */
 423         .quad sys_setgid16
 424         .quad sys_getgid16
 425         .quad sys_signal
 426         .quad sys_geteuid16
 427         .quad sys_getegid16     /* 50 */
 428         .quad sys_acct
 429         .quad sys_umount                        /* new_umount */
 430         .quad quiet_ni_syscall                  /* old lock syscall holder */
 431         .quad compat_sys_ioctl
 432         .quad compat_sys_fcntl64                /* 55 */
 433         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 434         .quad sys_setpgid
 435         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 436         .quad sys32_olduname
 437         .quad sys_umask         /* 60 */
 438         .quad sys_chroot
 439         .quad sys32_ustat
 440         .quad sys_dup2
 441         .quad sys_getppid
 442         .quad sys_getpgrp               /* 65 */
 443         .quad sys_setsid
 444         .quad sys32_sigaction
 445         .quad sys_sgetmask
 446         .quad sys_ssetmask
 447         .quad sys_setreuid16    /* 70 */
 448         .quad sys_setregid16
 449         .quad stub32_sigsuspend
 450         .quad compat_sys_sigpending
 451         .quad sys_sethostname
 452         .quad compat_sys_setrlimit      /* 75 */
 453         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 454         .quad compat_sys_getrusage
 455         .quad sys32_gettimeofday
 456         .quad sys32_settimeofday
 457         .quad sys_getgroups16   /* 80 */
 458         .quad sys_setgroups16
 459         .quad sys32_old_select
 460         .quad sys_symlink
 461         .quad sys_lstat
 462         .quad sys_readlink              /* 85 */
 463 #ifdef CONFIG_IA32_AOUT
 464         .quad sys_uselib
 465 #else
 466         .quad quiet_ni_syscall
 467 #endif
 468         .quad sys_swapon
 469         .quad sys_reboot
 470         .quad compat_sys_old_readdir
 471         .quad sys32_mmap                /* 90 */
 472         .quad sys_munmap
 473         .quad sys_truncate
 474         .quad sys_ftruncate
 475         .quad sys_fchmod
 476         .quad sys_fchown16              /* 95 */
 477         .quad sys_getpriority
 478         .quad sys_setpriority
 479         .quad quiet_ni_syscall                  /* old profil syscall holder */
 480         .quad compat_sys_statfs
 481         .quad compat_sys_fstatfs                /* 100 */
 482         .quad sys_ioperm
 483         .quad compat_sys_socketcall
 484         .quad sys_syslog
 485         .quad compat_sys_setitimer
 486         .quad compat_sys_getitimer      /* 105 */
 487         .quad compat_sys_newstat
 488         .quad compat_sys_newlstat
 489         .quad compat_sys_newfstat
 490         .quad sys32_uname
 491         .quad stub32_iopl               /* 110 */
 492         .quad sys_vhangup
 493         .quad quiet_ni_syscall  /* old "idle" system call */
 494         .quad sys32_vm86_warning        /* vm86old */
 495         .quad compat_sys_wait4
 496         .quad sys_swapoff               /* 115 */
 497         .quad sys32_sysinfo
 498         .quad sys32_ipc
 499         .quad sys_fsync
 500         .quad stub32_sigreturn
 501         .quad stub32_clone              /* 120 */
 502         .quad sys_setdomainname
 503         .quad sys_uname
 504         .quad sys_modify_ldt
 505         .quad compat_sys_adjtimex
 506         .quad sys32_mprotect            /* 125 */
 507         .quad compat_sys_sigprocmask
 508         .quad quiet_ni_syscall          /* create_module */
 509         .quad sys_init_module
 510         .quad sys_delete_module
 511         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 512         .quad sys_quotactl
 513         .quad sys_getpgid
 514         .quad sys_fchdir
 515         .quad quiet_ni_syscall  /* bdflush */
 516         .quad sys_sysfs         /* 135 */
 517         .quad sys_personality
 518         .quad quiet_ni_syscall  /* for afs_syscall */
 519         .quad sys_setfsuid16
 520         .quad sys_setfsgid16
 521         .quad sys_llseek                /* 140 */
 522         .quad compat_sys_getdents
 523         .quad compat_sys_select
 524         .quad sys_flock
 525         .quad sys_msync
 526         .quad compat_sys_readv          /* 145 */
 527         .quad compat_sys_writev
 528         .quad sys_getsid
 529         .quad sys_fdatasync
 530         .quad sys32_sysctl      /* sysctl */
 531         .quad sys_mlock         /* 150 */
 532         .quad sys_munlock
 533         .quad sys_mlockall
 534         .quad sys_munlockall
 535         .quad sys_sched_setparam
 536         .quad sys_sched_getparam   /* 155 */
 537         .quad sys_sched_setscheduler
 538         .quad sys_sched_getscheduler
 539         .quad sys_sched_yield
 540         .quad sys_sched_get_priority_max
 541         .quad sys_sched_get_priority_min  /* 160 */
 542         .quad sys_sched_rr_get_interval
 543         .quad compat_sys_nanosleep
 544         .quad sys_mremap
 545         .quad sys_setresuid16
 546         .quad sys_getresuid16   /* 165 */
 547         .quad sys32_vm86_warning        /* vm86 */
 548         .quad quiet_ni_syscall  /* query_module */
 549         .quad sys_poll
 550         .quad compat_sys_nfsservctl
 551         .quad sys_setresgid16   /* 170 */
 552         .quad sys_getresgid16
 553         .quad sys_prctl
 554         .quad stub32_rt_sigreturn
 555         .quad sys32_rt_sigaction
 556         .quad sys32_rt_sigprocmask      /* 175 */
 557         .quad sys32_rt_sigpending
 558         .quad compat_sys_rt_sigtimedwait
 559         .quad sys32_rt_sigqueueinfo
 560         .quad stub32_rt_sigsuspend
 561         .quad sys32_pread               /* 180 */
 562         .quad sys32_pwrite
 563         .quad sys_chown16
 564         .quad sys_getcwd
 565         .quad sys_capget
 566         .quad sys_capset
 567         .quad stub32_sigaltstack
 568         .quad sys32_sendfile
 569         .quad quiet_ni_syscall          /* streams1 */
 570         .quad quiet_ni_syscall          /* streams2 */
 571         .quad stub32_vfork            /* 190 */
 572         .quad compat_sys_getrlimit
 573         .quad sys32_mmap2
 574         .quad sys32_truncate64
 575         .quad sys32_ftruncate64
 576         .quad sys32_stat64              /* 195 */
 577         .quad sys32_lstat64
 578         .quad sys32_fstat64
 579         .quad sys_lchown
 580         .quad sys_getuid
 581         .quad sys_getgid                /* 200 */
 582         .quad sys_geteuid
 583         .quad sys_getegid
 584         .quad sys_setreuid
 585         .quad sys_setregid
 586         .quad sys_getgroups     /* 205 */
 587         .quad sys_setgroups
 588         .quad sys_fchown
 589         .quad sys_setresuid
 590         .quad sys_getresuid
 591         .quad sys_setresgid     /* 210 */
 592         .quad sys_getresgid
 593         .quad sys_chown
 594         .quad sys_setuid
 595         .quad sys_setgid
 596         .quad sys_setfsuid              /* 215 */
 597         .quad sys_setfsgid
 598         .quad sys_pivot_root
 599         .quad sys_mincore
 600         .quad sys_madvise
 601         .quad compat_sys_getdents64     /* 220 getdents64 */
 602         .quad compat_sys_fcntl64
 603         .quad quiet_ni_syscall          /* tux */
 604         .quad quiet_ni_syscall          /* security */
 605         .quad sys_gettid
 606         .quad sys_readahead     /* 225 */
 607         .quad sys_setxattr
 608         .quad sys_lsetxattr
 609         .quad sys_fsetxattr
 610         .quad sys_getxattr
 611         .quad sys_lgetxattr     /* 230 */
 612         .quad sys_fgetxattr
 613         .quad sys_listxattr
 614         .quad sys_llistxattr
 615         .quad sys_flistxattr
 616         .quad sys_removexattr   /* 235 */
 617         .quad sys_lremovexattr
 618         .quad sys_fremovexattr
 619         .quad sys_tkill
 620         .quad sys_sendfile64
 621         .quad compat_sys_futex          /* 240 */
 622         .quad compat_sys_sched_setaffinity
 623         .quad compat_sys_sched_getaffinity
 624         .quad sys32_set_thread_area
 625         .quad sys32_get_thread_area
 626         .quad compat_sys_io_setup       /* 245 */
 627         .quad sys_io_destroy
 628         .quad compat_sys_io_getevents
 629         .quad compat_sys_io_submit
 630         .quad sys_io_cancel
 631         .quad sys_fadvise64             /* 250 */
 632         .quad quiet_ni_syscall  /* free_huge_pages */
 633         .quad sys_exit_group
 634         .quad sys32_lookup_dcookie
 635         .quad sys_epoll_create
 636         .quad sys_epoll_ctl             /* 255 */
 637         .quad sys_epoll_wait
 638         .quad sys_remap_file_pages
 639         .quad sys_set_tid_address
 640         .quad compat_sys_timer_create
 641         .quad compat_sys_timer_settime  /* 260 */
 642         .quad compat_sys_timer_gettime
 643         .quad sys_timer_getoverrun
 644         .quad sys_timer_delete
 645         .quad compat_sys_clock_settime
 646         .quad compat_sys_clock_gettime  /* 265 */
 647         .quad compat_sys_clock_getres
 648         .quad compat_sys_clock_nanosleep
 649         .quad compat_sys_statfs64
 650         .quad compat_sys_fstatfs64
 651         .quad sys_tgkill                /* 270 */
 652         .quad compat_sys_utimes
 653         .quad sys32_fadvise64_64
 654         .quad quiet_ni_syscall  /* sys_vserver */
 655         .quad sys_mbind
 656         .quad compat_sys_get_mempolicy  /* 275 */
 657         .quad sys_set_mempolicy
 658         .quad compat_sys_mq_open
 659         .quad sys_mq_unlink
 660         .quad compat_sys_mq_timedsend
 661         .quad compat_sys_mq_timedreceive        /* 280 */
 662         .quad compat_sys_mq_notify
 663         .quad compat_sys_mq_getsetattr
 664         .quad compat_sys_kexec_load     /* reserved for kexec */
 665         .quad compat_sys_waitid
 666         .quad quiet_ni_syscall          /* 285: sys_altroot */
 667         .quad sys_add_key
 668         .quad sys_request_key
 669         .quad sys_keyctl
 670         .quad sys_ioprio_set
 671         .quad sys_ioprio_get            /* 290 */
 672         .quad sys_inotify_init
 673         .quad sys_inotify_add_watch
 674         .quad sys_inotify_rm_watch
 675         .quad sys_migrate_pages
 676         .quad compat_sys_openat         /* 295 */
 677         .quad sys_mkdirat
 678         .quad sys_mknodat
 679         .quad sys_fchownat
 680         .quad compat_sys_futimesat
 681         .quad sys32_fstatat             /* 300 */
 682         .quad sys_unlinkat
 683         .quad sys_renameat
 684         .quad sys_linkat
 685         .quad sys_symlinkat
 686         .quad sys_readlinkat            /* 305 */
 687         .quad sys_fchmodat
 688         .quad sys_faccessat
 689         .quad quiet_ni_syscall          /* pselect6 for now */
 690         .quad quiet_ni_syscall          /* ppoll for now */
 691         .quad sys_unshare               /* 310 */
 692         .quad compat_sys_set_robust_list
 693         .quad compat_sys_get_robust_list
 694         .quad sys_splice
 695         .quad sys_sync_file_range
 696         .quad sys_tee
 697         .quad compat_sys_vmsplice
 698         .quad compat_sys_move_pages
 699 ia32_syscall_end: