git.oblomov.eu Git - linux-2.6/blob - arch/v850/kernel/vmlinux.lds.S

   1 /*
   2  * arch/v850/vmlinux.lds.S -- kernel linker script for v850 platforms
   3  *
   4  *  Copyright (C) 2002,03,04,05  NEC Electronics Corporation
   5  *  Copyright (C) 2002,03,04,05  Miles Bader <miles@gnu.org>
   6  *
   7  * This file is subject to the terms and conditions of the GNU General
   8  * Public License.  See the file COPYING in the main directory of this
   9  * archive for more details.
  10  *
  11  * Written by Miles Bader <miles@gnu.org>
  12  */
  13
  14
  15 #define VMLINUX_SYMBOL(_sym_) _##_sym_
  16 #include <asm-generic/vmlinux.lds.h>
  17
  18 /* For most platforms, this will define useful things like RAM addr/size.  */
  19 #include <asm/machdep.h>
  20
  21
  22 /* The following macros contain the usual definitions for various data areas.
  23    The prefix `RAMK_' is used to indicate macros suitable for kernels loaded
  24    into RAM, and similarly `ROMK_' for ROM-resident kernels.  Note that all
  25    symbols are prefixed with an extra `_' for compatibility with the v850
  26    toolchain.  */
  27
  28
  29 /* Interrupt vectors.  */
  30 #define INTV_CONTENTS                                                         \
  31                 . = ALIGN (0x10) ;                                            \
  32                 __intv_start = . ;                                            \
  33                         *(.intv.reset)  /* Reset vector */                    \
  34                 . = __intv_start + 0x10 ;                                     \
  35                         *(.intv.common) /* Vectors common to all v850e proc */\
  36                 . = __intv_start + 0x80 ;                                     \
  37                         *(.intv.mach)   /* Machine-specific int. vectors.  */ \
  38                 __intv_end = . ;
  39
  40 #define RODATA_CONTENTS                                                       \
  41                 . = ALIGN (16) ;                                              \
  42                         *(.rodata) *(.rodata.*)                               \
  43                         *(__vermagic)           /* Kernel version magic */    \
  44                         *(.rodata1)                                           \
  45                 /* PCI quirks */                                              \
  46                 ___start_pci_fixups_early = . ;                               \
  47                         *(.pci_fixup_early)                                   \
  48                 ___end_pci_fixups_early = . ;                                 \
  49                 ___start_pci_fixups_header = . ;                              \
  50                         *(.pci_fixup_header)                                  \
  51                 ___end_pci_fixups_header = . ;                                \
  52                 ___start_pci_fixups_final = . ;                               \
  53                         *(.pci_fixup_final)                                   \
  54                 ___end_pci_fixups_final = . ;                                 \
  55                 ___start_pci_fixups_enable = . ;                              \
  56                         *(.pci_fixup_enable)                                  \
  57                 ___end_pci_fixups_enable = . ;                                \
  58                 /* Kernel symbol table: Normal symbols */                     \
  59                 ___start___ksymtab = .;                                       \
  60                         *(__ksymtab)                                          \
  61                 ___stop___ksymtab = .;                                        \
  62                 /* Kernel symbol table: GPL-only symbols */                   \
  63                 ___start___ksymtab_gpl = .;                                   \
  64                         *(__ksymtab_gpl)                                      \
  65                 ___stop___ksymtab_gpl = .;                                    \
  66                 /* Kernel symbol table: GPL-future symbols */                 \
  67                 ___start___ksymtab_gpl_future = .;                            \
  68                         *(__ksymtab_gpl_future)                               \
  69                 ___stop___ksymtab_gpl_future = .;                             \
  70                 /* Kernel symbol table: strings */                            \
  71                         *(__ksymtab_strings)                                  \
  72                 /* Kernel symbol table: Normal symbols */                     \
  73                 ___start___kcrctab = .;                                       \
  74                         *(__kcrctab)                                          \
  75                 ___stop___kcrctab = .;                                        \
  76                 /* Kernel symbol table: GPL-only symbols */                   \
  77                 ___start___kcrctab_gpl = .;                                   \
  78                         *(__kcrctab_gpl)                                      \
  79                 ___stop___kcrctab_gpl = .;                                    \
  80                 /* Kernel symbol table: GPL-future symbols */                 \
  81                 ___start___kcrctab_gpl_future = .;                            \
  82                         *(__kcrctab_gpl_future)                               \
  83                 ___stop___kcrctab_gpl_future = .;                             \
  84                 /* Built-in module parameters */                              \
  85                 . = ALIGN (4) ;                                               \
  86                 ___start___param = .;                                         \
  87                 *(__param)                                                    \
  88                 ___stop___param = .;
  89
  90
  91 /* Kernel text segment, and some constant data areas.  */
  92 #define TEXT_CONTENTS                                                         \
  93                 __stext = . ;                                                 \
  94                 *(.text)                                                      \
  95                 SCHED_TEXT                                                    \
  96                         *(.exit.text)   /* 2.5 convention */                  \
  97                         *(.text.exit)   /* 2.4 convention */                  \
  98                         *(.text.lock)                                         \
  99                         *(.exitcall.exit)                                     \
 100                 __real_etext = . ;      /* There may be data after here.  */  \
 101                 RODATA_CONTENTS                                               \
 102                 . = ALIGN (4) ;                                               \
 103                         *(.call_table_data)                                   \
 104                         *(.call_table_text)                                   \
 105                 . = ALIGN (16) ;        /* Exception table.  */               \
 106                 ___start___ex_table = . ;                                     \
 107                         *(__ex_table)                                         \
 108                 ___stop___ex_table = . ;                                      \
 109                 . = ALIGN (4) ;                                               \
 110                 __etext = . ;
 111
 112 /* Kernel data segment.  */
 113 #define DATA_CONTENTS                                                         \
 114                 __sdata = . ;                                                 \
 115                 *(.data)                                                      \
 116                         *(.exit.data)   /* 2.5 convention */                  \
 117                         *(.data.exit)   /* 2.4 convention */                  \
 118                 . = ALIGN (16) ;                                              \
 119                 *(.data.cacheline_aligned)                                    \
 120                 . = ALIGN (0x2000) ;                                          \
 121                 *(.data.init_task)                                            \
 122                 . = ALIGN (0x2000) ;                                          \
 123                 __edata = . ;
 124
 125 /* Kernel BSS segment.  */
 126 #define BSS_CONTENTS                                                          \
 127                 __sbss = . ;                                                  \
 128                         *(.bss)                                               \
 129                         *(COMMON)                                             \
 130                 . = ALIGN (4) ;                                               \
 131                 __init_stack_end = . ;                                        \
 132                 __ebss = . ;
 133
 134 /* `initcall' tables.  */
 135 #define INITCALL_CONTENTS                                                     \
 136                 . = ALIGN (16) ;                                              \
 137                 ___setup_start = . ;                                          \
 138                         *(.init.setup)  /* 2.5 convention */                  \
 139                         *(.setup.init)  /* 2.4 convention */                  \
 140                 ___setup_end = . ;                                            \
 141                 ___initcall_start = . ;                                       \
 142                         *(.initcall.init)                                     \
 143                         INITCALLS                                             \
 144                 . = ALIGN (4) ;                                               \
 145                 ___initcall_end = . ;                                         \
 146                 ___con_initcall_start = .;                                    \
 147                         *(.con_initcall.init)                                 \
 148                 ___con_initcall_end = .;
 149
 150 /* Contents of `init' section for a kernel that's loaded into RAM.  */
 151 #define RAMK_INIT_CONTENTS                                                    \
 152                 RAMK_INIT_CONTENTS_NO_END                                     \
 153                 __init_end = . ;
 154 /* Same as RAMK_INIT_CONTENTS, but doesn't define the `__init_end' symbol.  */
 155 #define RAMK_INIT_CONTENTS_NO_END                                             \
 156                 . = ALIGN (4096) ;                                            \
 157                 __init_start = . ;                                            \
 158                         __sinittext = .;                                      \
 159                         *(.init.text)   /* 2.5 convention */                  \
 160                         __einittext = .;                                      \
 161                         *(.init.data)                                         \
 162                         *(.text.init)   /* 2.4 convention */                  \
 163                         *(.data.init)                                         \
 164                 INITCALL_CONTENTS                                             \
 165                 INITRAMFS_CONTENTS
 166
 167 /* The contents of `init' section for a ROM-resident kernel which
 168    should go into RAM.  */
 169 #define ROMK_INIT_RAM_CONTENTS                                                \
 170                 . = ALIGN (4096) ;                                            \
 171                 __init_start = . ;                                            \
 172                         *(.init.data)   /* 2.5 convention */                  \
 173                         *(.data.init)   /* 2.4 convention */                  \
 174                 __init_end = . ;                                              \
 175                 . = ALIGN (4096) ;
 176
 177 /* The contents of `init' section for a ROM-resident kernel which
 178    should go into ROM.  */
 179 #define ROMK_INIT_ROM_CONTENTS                                                \
 180                         _sinittext = .;                                       \
 181                         *(.init.text)   /* 2.5 convention */                  \
 182                         _einittext = .;                                       \
 183                         *(.text.init)   /* 2.4 convention */                  \
 184                 INITCALL_CONTENTS                                             \
 185                 INITRAMFS_CONTENTS
 186
 187 /* A root filesystem image, for kernels with an embedded root filesystem.  */
 188 #define ROOT_FS_CONTENTS                                                      \
 189                 __root_fs_image_start = . ;                                   \
 190                 *(.root)                                                      \
 191                 __root_fs_image_end = . ;
 192 /* The initramfs archive.  */
 193 #define INITRAMFS_CONTENTS                                                    \
 194                 . = ALIGN (4) ;                                               \
 195                 ___initramfs_start = . ;                                      \
 196                         *(.init.ramfs)                                        \
 197                 ___initramfs_end = . ;
 198 /* Where the initial bootmap (bitmap for the boot-time memory allocator)
 199    should be place.  */
 200 #define BOOTMAP_CONTENTS                                                      \
 201                 . = ALIGN (4096) ;                                            \
 202                 __bootmap = . ;                                               \
 203                 . = . + 4096 ;          /* enough for 128MB.   */
 204
 205 /* The contents of a `typical' kram area for a kernel in RAM.  */
 206 #define RAMK_KRAM_CONTENTS                                                    \
 207                 __kram_start = . ;                                            \
 208                 TEXT_CONTENTS                                                 \
 209                 DATA_CONTENTS                                                 \
 210                 BSS_CONTENTS                                                  \
 211                 RAMK_INIT_CONTENTS                                            \
 212                 __kram_end = . ;                                              \
 213                 BOOTMAP_CONTENTS
 214
 215
 216 /* Define output sections normally used for a ROM-resident kernel.
 217    ROM and RAM should be appropriate memory areas to use for kernel
 218    ROM and RAM data.  This assumes that ROM starts at 0 (and thus can
 219    hold the interrupt vectors).  */
 220 #define ROMK_SECTIONS(ROM, RAM)                                               \
 221         .rom : {                                                              \
 222                 INTV_CONTENTS                                                 \
 223                 TEXT_CONTENTS                                                 \
 224                 ROMK_INIT_ROM_CONTENTS                                        \
 225                 ROOT_FS_CONTENTS                                              \
 226         } > ROM                                                               \
 227                                                                               \
 228         __rom_copy_src_start = . ;                                            \
 229                                                                               \
 230         .data : {                                                             \
 231                 __kram_start = . ;                                            \
 232                 __rom_copy_dst_start = . ;                                    \
 233                 DATA_CONTENTS                                                 \
 234                 ROMK_INIT_RAM_CONTENTS                                        \
 235                 __rom_copy_dst_end = . ;                                      \
 236         } > RAM  AT> ROM                                                      \
 237                                                                               \
 238         .bss ALIGN (4) : {                                                    \
 239                 BSS_CONTENTS                                                  \
 240                 __kram_end = . ;                                              \
 241                 BOOTMAP_CONTENTS                                              \
 242         } > RAM
 243
 244
 245 /* The 32-bit variable `jiffies' is just the lower 32-bits of `jiffies_64'.  */
 246 _jiffies = _jiffies_64 ;
 247
 248
 249 /* Include an appropriate platform-dependent linker-script (which
 250    usually should use the above macros to do most of the work).  */
 251
 252 #ifdef CONFIG_V850E_SIM
 253 # include "sim.ld"
 254 #endif
 255
 256 #ifdef CONFIG_V850E2_SIM85E2
 257 # include "sim85e2.ld"
 258 #endif
 259
 260 #ifdef CONFIG_V850E2_FPGA85E2C
 261 # include "fpga85e2c.ld"
 262 #endif
 263
 264 #ifdef CONFIG_V850E2_ANNA
 265 # ifdef CONFIG_ROM_KERNEL
 266 #  include "anna-rom.ld"
 267 # else
 268 #  include "anna.ld"
 269 # endif
 270 #endif
 271
 272 #ifdef CONFIG_V850E_AS85EP1
 273 # ifdef CONFIG_ROM_KERNEL
 274 #  include "as85ep1-rom.ld"
 275 # else
 276 #  include "as85ep1.ld"
 277 # endif
 278 #endif
 279
 280 #ifdef CONFIG_RTE_CB_MA1
 281 # ifdef CONFIG_ROM_KERNEL
 282 #  include "rte_ma1_cb-rom.ld"
 283 # else
 284 #  include "rte_ma1_cb.ld"
 285 # endif
 286 #endif
 287
 288 #ifdef CONFIG_RTE_CB_NB85E
 289 # ifdef CONFIG_ROM_KERNEL
 290 #  include "rte_nb85e_cb-rom.ld"
 291 # elif defined(CONFIG_RTE_CB_MULTI)
 292 #  include "rte_nb85e_cb-multi.ld"
 293 # else
 294 #  include "rte_nb85e_cb.ld"
 295 # endif
 296 #endif
 297
 298 #ifdef CONFIG_RTE_CB_ME2
 299 #  include "rte_me2_cb.ld"
 300 #endif
 301