git.oblomov.eu Git - linux-2.6/blob - arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55
  56 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  57 #include <linux/elf-em.h>
  58 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  59 #define __AUDIT_ARCH_64BIT 0x80000000
  60 #define __AUDIT_ARCH_LE    0x40000000
  61
  62         .code64
  63
  64 #ifdef CONFIG_FTRACE
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67
  68         subq $0x38, %rsp
  69         movq %rax, (%rsp)
  70         movq %rcx, 8(%rsp)
  71         movq %rdx, 16(%rsp)
  72         movq %rsi, 24(%rsp)
  73         movq %rdi, 32(%rsp)
  74         movq %r8, 40(%rsp)
  75         movq %r9, 48(%rsp)
  76
  77         movq 0x38(%rsp), %rdi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 .globl mcount_call
  81 mcount_call:
  82         call ftrace_stub
  83
  84         movq 48(%rsp), %r9
  85         movq 40(%rsp), %r8
  86         movq 32(%rsp), %rdi
  87         movq 24(%rsp), %rsi
  88         movq 16(%rsp), %rdx
  89         movq 8(%rsp), %rcx
  90         movq (%rsp), %rax
  91         addq $0x38, %rsp
  92
  93         retq
  94 END(mcount)
  95
  96 ENTRY(ftrace_caller)
  97
  98         /* taken from glibc */
  99         subq $0x38, %rsp
 100         movq %rax, (%rsp)
 101         movq %rcx, 8(%rsp)
 102         movq %rdx, 16(%rsp)
 103         movq %rsi, 24(%rsp)
 104         movq %rdi, 32(%rsp)
 105         movq %r8, 40(%rsp)
 106         movq %r9, 48(%rsp)
 107
 108         movq 0x38(%rsp), %rdi
 109         movq 8(%rbp), %rsi
 110         subq $MCOUNT_INSN_SIZE, %rdi
 111
 112 .globl ftrace_call
 113 ftrace_call:
 114         call ftrace_stub
 115
 116         movq 48(%rsp), %r9
 117         movq 40(%rsp), %r8
 118         movq 32(%rsp), %rdi
 119         movq 24(%rsp), %rsi
 120         movq 16(%rsp), %rdx
 121         movq 8(%rsp), %rcx
 122         movq (%rsp), %rax
 123         addq $0x38, %rsp
 124
 125 .globl ftrace_stub
 126 ftrace_stub:
 127         retq
 128 END(ftrace_caller)
 129
 130 #else /* ! CONFIG_DYNAMIC_FTRACE */
 131 ENTRY(mcount)
 132         cmpq $ftrace_stub, ftrace_trace_function
 133         jnz trace
 134 .globl ftrace_stub
 135 ftrace_stub:
 136         retq
 137
 138 trace:
 139         /* taken from glibc */
 140         subq $0x38, %rsp
 141         movq %rax, (%rsp)
 142         movq %rcx, 8(%rsp)
 143         movq %rdx, 16(%rsp)
 144         movq %rsi, 24(%rsp)
 145         movq %rdi, 32(%rsp)
 146         movq %r8, 40(%rsp)
 147         movq %r9, 48(%rsp)
 148
 149         movq 0x38(%rsp), %rdi
 150         movq 8(%rbp), %rsi
 151         subq $MCOUNT_INSN_SIZE, %rdi
 152
 153         call   *ftrace_trace_function
 154
 155         movq 48(%rsp), %r9
 156         movq 40(%rsp), %r8
 157         movq 32(%rsp), %rdi
 158         movq 24(%rsp), %rsi
 159         movq 16(%rsp), %rdx
 160         movq 8(%rsp), %rcx
 161         movq (%rsp), %rax
 162         addq $0x38, %rsp
 163
 164         jmp ftrace_stub
 165 END(mcount)
 166 #endif /* CONFIG_DYNAMIC_FTRACE */
 167 #endif /* CONFIG_FTRACE */
 168
 169 #ifndef CONFIG_PREEMPT
 170 #define retint_kernel retint_restore_args
 171 #endif
 172
 173 #ifdef CONFIG_PARAVIRT
 174 ENTRY(native_usergs_sysret64)
 175         swapgs
 176         sysretq
 177 #endif /* CONFIG_PARAVIRT */
 178
 179
 180 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 181 #ifdef CONFIG_TRACE_IRQFLAGS
 182         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 183         jnc  1f
 184         TRACE_IRQS_ON
 185 1:
 186 #endif
 187 .endm
 188
 189 /*
 190  * C code is not supposed to know about undefined top of stack. Every time
 191  * a C function with an pt_regs argument is called from the SYSCALL based
 192  * fast path FIXUP_TOP_OF_STACK is needed.
 193  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 194  * manipulation.
 195  */
 196
 197         /* %rsp:at FRAMEEND */
 198         .macro FIXUP_TOP_OF_STACK tmp
 199         movq    %gs:pda_oldrsp,\tmp
 200         movq    \tmp,RSP(%rsp)
 201         movq    $__USER_DS,SS(%rsp)
 202         movq    $__USER_CS,CS(%rsp)
 203         movq    $-1,RCX(%rsp)
 204         movq    R11(%rsp),\tmp  /* get eflags */
 205         movq    \tmp,EFLAGS(%rsp)
 206         .endm
 207
 208         .macro RESTORE_TOP_OF_STACK tmp,offset=0
 209         movq   RSP-\offset(%rsp),\tmp
 210         movq   \tmp,%gs:pda_oldrsp
 211         movq   EFLAGS-\offset(%rsp),\tmp
 212         movq   \tmp,R11-\offset(%rsp)
 213         .endm
 214
 215         .macro FAKE_STACK_FRAME child_rip
 216         /* push in order ss, rsp, eflags, cs, rip */
 217         xorl %eax, %eax
 218         pushq $__KERNEL_DS /* ss */
 219         CFI_ADJUST_CFA_OFFSET   8
 220         /*CFI_REL_OFFSET        ss,0*/
 221         pushq %rax /* rsp */
 222         CFI_ADJUST_CFA_OFFSET   8
 223         CFI_REL_OFFSET  rsp,0
 224         pushq $(1<<9) /* eflags - interrupts on */
 225         CFI_ADJUST_CFA_OFFSET   8
 226         /*CFI_REL_OFFSET        rflags,0*/
 227         pushq $__KERNEL_CS /* cs */
 228         CFI_ADJUST_CFA_OFFSET   8
 229         /*CFI_REL_OFFSET        cs,0*/
 230         pushq \child_rip /* rip */
 231         CFI_ADJUST_CFA_OFFSET   8
 232         CFI_REL_OFFSET  rip,0
 233         pushq   %rax /* orig rax */
 234         CFI_ADJUST_CFA_OFFSET   8
 235         .endm
 236
 237         .macro UNFAKE_STACK_FRAME
 238         addq $8*6, %rsp
 239         CFI_ADJUST_CFA_OFFSET   -(6*8)
 240         .endm
 241
 242         .macro  CFI_DEFAULT_STACK start=1
 243         .if \start
 244         CFI_STARTPROC   simple
 245         CFI_SIGNAL_FRAME
 246         CFI_DEF_CFA     rsp,SS+8
 247         .else
 248         CFI_DEF_CFA_OFFSET SS+8
 249         .endif
 250         CFI_REL_OFFSET  r15,R15
 251         CFI_REL_OFFSET  r14,R14
 252         CFI_REL_OFFSET  r13,R13
 253         CFI_REL_OFFSET  r12,R12
 254         CFI_REL_OFFSET  rbp,RBP
 255         CFI_REL_OFFSET  rbx,RBX
 256         CFI_REL_OFFSET  r11,R11
 257         CFI_REL_OFFSET  r10,R10
 258         CFI_REL_OFFSET  r9,R9
 259         CFI_REL_OFFSET  r8,R8
 260         CFI_REL_OFFSET  rax,RAX
 261         CFI_REL_OFFSET  rcx,RCX
 262         CFI_REL_OFFSET  rdx,RDX
 263         CFI_REL_OFFSET  rsi,RSI
 264         CFI_REL_OFFSET  rdi,RDI
 265         CFI_REL_OFFSET  rip,RIP
 266         /*CFI_REL_OFFSET        cs,CS*/
 267         /*CFI_REL_OFFSET        rflags,EFLAGS*/
 268         CFI_REL_OFFSET  rsp,RSP
 269         /*CFI_REL_OFFSET        ss,SS*/
 270         .endm
 271 /*
 272  * A newly forked process directly context switches into this.
 273  */
 274 /* rdi: prev */
 275 ENTRY(ret_from_fork)
 276         CFI_DEFAULT_STACK
 277         push kernel_eflags(%rip)
 278         CFI_ADJUST_CFA_OFFSET 8
 279         popf                            # reset kernel eflags
 280         CFI_ADJUST_CFA_OFFSET -8
 281         call schedule_tail
 282         GET_THREAD_INFO(%rcx)
 283         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 284         jnz rff_trace
 285 rff_action:
 286         RESTORE_REST
 287         testl $3,CS-ARGOFFSET(%rsp)     # from kernel_thread?
 288         je   int_ret_from_sys_call
 289         testl $_TIF_IA32,TI_flags(%rcx)
 290         jnz  int_ret_from_sys_call
 291         RESTORE_TOP_OF_STACK %rdi,ARGOFFSET
 292         jmp ret_from_sys_call
 293 rff_trace:
 294         movq %rsp,%rdi
 295         call syscall_trace_leave
 296         GET_THREAD_INFO(%rcx)
 297         jmp rff_action
 298         CFI_ENDPROC
 299 END(ret_from_fork)
 300
 301 /*
 302  * System call entry. Upto 6 arguments in registers are supported.
 303  *
 304  * SYSCALL does not save anything on the stack and does not change the
 305  * stack pointer.
 306  */
 307
 308 /*
 309  * Register setup:
 310  * rax  system call number
 311  * rdi  arg0
 312  * rcx  return address for syscall/sysret, C arg3
 313  * rsi  arg1
 314  * rdx  arg2
 315  * r10  arg3    (--> moved to rcx for C)
 316  * r8   arg4
 317  * r9   arg5
 318  * r11  eflags for syscall/sysret, temporary for C
 319  * r12-r15,rbp,rbx saved by C code, not touched.
 320  *
 321  * Interrupts are off on entry.
 322  * Only called from user space.
 323  *
 324  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 325  *      and report it properly in ps. Unfortunately we haven't.
 326  *
 327  * When user can change the frames always force IRET. That is because
 328  * it deals with uncanonical addresses better. SYSRET has trouble
 329  * with them due to bugs in both AMD and Intel CPUs.
 330  */
 331
 332 ENTRY(system_call)
 333         CFI_STARTPROC   simple
 334         CFI_SIGNAL_FRAME
 335         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 336         CFI_REGISTER    rip,rcx
 337         /*CFI_REGISTER  rflags,r11*/
 338         SWAPGS_UNSAFE_STACK
 339         /*
 340          * A hypervisor implementation might want to use a label
 341          * after the swapgs, so that it can do the swapgs
 342          * for the guest and jump here on syscall.
 343          */
 344 ENTRY(system_call_after_swapgs)
 345
 346         movq    %rsp,%gs:pda_oldrsp
 347         movq    %gs:pda_kernelstack,%rsp
 348         /*
 349          * No need to follow this irqs off/on section - it's straight
 350          * and short:
 351          */
 352         ENABLE_INTERRUPTS(CLBR_NONE)
 353         SAVE_ARGS 8,1
 354         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 355         movq  %rcx,RIP-ARGOFFSET(%rsp)
 356         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 357         GET_THREAD_INFO(%rcx)
 358         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 359         jnz tracesys
 360 system_call_fastpath:
 361         cmpq $__NR_syscall_max,%rax
 362         ja badsys
 363         movq %r10,%rcx
 364         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 365         movq %rax,RAX-ARGOFFSET(%rsp)
 366 /*
 367  * Syscall return path ending with SYSRET (fast path)
 368  * Has incomplete stack frame and undefined top of stack.
 369  */
 370 ret_from_sys_call:
 371         movl $_TIF_ALLWORK_MASK,%edi
 372         /* edi: flagmask */
 373 sysret_check:
 374         LOCKDEP_SYS_EXIT
 375         GET_THREAD_INFO(%rcx)
 376         DISABLE_INTERRUPTS(CLBR_NONE)
 377         TRACE_IRQS_OFF
 378         movl TI_flags(%rcx),%edx
 379         andl %edi,%edx
 380         jnz  sysret_careful
 381         CFI_REMEMBER_STATE
 382         /*
 383          * sysretq will re-enable interrupts:
 384          */
 385         TRACE_IRQS_ON
 386         movq RIP-ARGOFFSET(%rsp),%rcx
 387         CFI_REGISTER    rip,rcx
 388         RESTORE_ARGS 0,-ARG_SKIP,1
 389         /*CFI_REGISTER  rflags,r11*/
 390         movq    %gs:pda_oldrsp, %rsp
 391         USERGS_SYSRET64
 392
 393         CFI_RESTORE_STATE
 394         /* Handle reschedules */
 395         /* edx: work, edi: workmask */
 396 sysret_careful:
 397         bt $TIF_NEED_RESCHED,%edx
 398         jnc sysret_signal
 399         TRACE_IRQS_ON
 400         ENABLE_INTERRUPTS(CLBR_NONE)
 401         pushq %rdi
 402         CFI_ADJUST_CFA_OFFSET 8
 403         call schedule
 404         popq  %rdi
 405         CFI_ADJUST_CFA_OFFSET -8
 406         jmp sysret_check
 407
 408         /* Handle a signal */
 409 sysret_signal:
 410         TRACE_IRQS_ON
 411         ENABLE_INTERRUPTS(CLBR_NONE)
 412 #ifdef CONFIG_AUDITSYSCALL
 413         bt $TIF_SYSCALL_AUDIT,%edx
 414         jc sysret_audit
 415 #endif
 416         /* edx: work flags (arg3) */
 417         leaq do_notify_resume(%rip),%rax
 418         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 419         xorl %esi,%esi # oldset -> arg2
 420         call ptregscall_common
 421         movl $_TIF_WORK_MASK,%edi
 422         /* Use IRET because user could have changed frame. This
 423            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 424         DISABLE_INTERRUPTS(CLBR_NONE)
 425         TRACE_IRQS_OFF
 426         jmp int_with_check
 427
 428 badsys:
 429         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 430         jmp ret_from_sys_call
 431
 432 #ifdef CONFIG_AUDITSYSCALL
 433         /*
 434          * Fast path for syscall audit without full syscall trace.
 435          * We just call audit_syscall_entry() directly, and then
 436          * jump back to the normal fast path.
 437          */
 438 auditsys:
 439         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 440         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 441         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 442         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 443         movq %rax,%rsi                  /* 2nd arg: syscall number */
 444         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 445         call audit_syscall_entry
 446         LOAD_ARGS 0             /* reload call-clobbered registers */
 447         jmp system_call_fastpath
 448
 449         /*
 450          * Return fast path for syscall audit.  Call audit_syscall_exit()
 451          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 452          * masked off.
 453          */
 454 sysret_audit:
 455         movq %rax,%rsi          /* second arg, syscall return value */
 456         cmpq $0,%rax            /* is it < 0? */
 457         setl %al                /* 1 if so, 0 if not */
 458         movzbl %al,%edi         /* zero-extend that into %edi */
 459         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 460         call audit_syscall_exit
 461         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 462         jmp sysret_check
 463 #endif  /* CONFIG_AUDITSYSCALL */
 464
 465         /* Do syscall tracing */
 466 tracesys:
 467 #ifdef CONFIG_AUDITSYSCALL
 468         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 469         jz auditsys
 470 #endif
 471         SAVE_REST
 472         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 473         FIXUP_TOP_OF_STACK %rdi
 474         movq %rsp,%rdi
 475         call syscall_trace_enter
 476         /*
 477          * Reload arg registers from stack in case ptrace changed them.
 478          * We don't reload %rax because syscall_trace_enter() returned
 479          * the value it wants us to use in the table lookup.
 480          */
 481         LOAD_ARGS ARGOFFSET, 1
 482         RESTORE_REST
 483         cmpq $__NR_syscall_max,%rax
 484         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 485         movq %r10,%rcx  /* fixup for C */
 486         call *sys_call_table(,%rax,8)
 487         movq %rax,RAX-ARGOFFSET(%rsp)
 488         /* Use IRET because user could have changed frame */
 489
 490 /*
 491  * Syscall return path ending with IRET.
 492  * Has correct top of stack, but partial stack frame.
 493  */
 494         .globl int_ret_from_sys_call
 495         .globl int_with_check
 496 int_ret_from_sys_call:
 497         DISABLE_INTERRUPTS(CLBR_NONE)
 498         TRACE_IRQS_OFF
 499         testl $3,CS-ARGOFFSET(%rsp)
 500         je retint_restore_args
 501         movl $_TIF_ALLWORK_MASK,%edi
 502         /* edi: mask to check */
 503 int_with_check:
 504         LOCKDEP_SYS_EXIT_IRQ
 505         GET_THREAD_INFO(%rcx)
 506         movl TI_flags(%rcx),%edx
 507         andl %edi,%edx
 508         jnz   int_careful
 509         andl    $~TS_COMPAT,TI_status(%rcx)
 510         jmp   retint_swapgs
 511
 512         /* Either reschedule or signal or syscall exit tracking needed. */
 513         /* First do a reschedule test. */
 514         /* edx: work, edi: workmask */
 515 int_careful:
 516         bt $TIF_NEED_RESCHED,%edx
 517         jnc  int_very_careful
 518         TRACE_IRQS_ON
 519         ENABLE_INTERRUPTS(CLBR_NONE)
 520         pushq %rdi
 521         CFI_ADJUST_CFA_OFFSET 8
 522         call schedule
 523         popq %rdi
 524         CFI_ADJUST_CFA_OFFSET -8
 525         DISABLE_INTERRUPTS(CLBR_NONE)
 526         TRACE_IRQS_OFF
 527         jmp int_with_check
 528
 529         /* handle signals and tracing -- both require a full stack frame */
 530 int_very_careful:
 531         TRACE_IRQS_ON
 532         ENABLE_INTERRUPTS(CLBR_NONE)
 533         SAVE_REST
 534         /* Check for syscall exit trace */
 535         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 536         jz int_signal
 537         pushq %rdi
 538         CFI_ADJUST_CFA_OFFSET 8
 539         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 540         call syscall_trace_leave
 541         popq %rdi
 542         CFI_ADJUST_CFA_OFFSET -8
 543         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 544         jmp int_restore_rest
 545
 546 int_signal:
 547         testl $_TIF_DO_NOTIFY_MASK,%edx
 548         jz 1f
 549         movq %rsp,%rdi          # &ptregs -> arg1
 550         xorl %esi,%esi          # oldset -> arg2
 551         call do_notify_resume
 552 1:      movl $_TIF_WORK_MASK,%edi
 553 int_restore_rest:
 554         RESTORE_REST
 555         DISABLE_INTERRUPTS(CLBR_NONE)
 556         TRACE_IRQS_OFF
 557         jmp int_with_check
 558         CFI_ENDPROC
 559 END(system_call)
 560
 561 /*
 562  * Certain special system calls that need to save a complete full stack frame.
 563  */
 564
 565         .macro PTREGSCALL label,func,arg
 566         .globl \label
 567 \label:
 568         leaq    \func(%rip),%rax
 569         leaq    -ARGOFFSET+8(%rsp),\arg /* 8 for return address */
 570         jmp     ptregscall_common
 571 END(\label)
 572         .endm
 573
 574         CFI_STARTPROC
 575
 576         PTREGSCALL stub_clone, sys_clone, %r8
 577         PTREGSCALL stub_fork, sys_fork, %rdi
 578         PTREGSCALL stub_vfork, sys_vfork, %rdi
 579         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 580         PTREGSCALL stub_iopl, sys_iopl, %rsi
 581
 582 ENTRY(ptregscall_common)
 583         popq %r11
 584         CFI_ADJUST_CFA_OFFSET -8
 585         CFI_REGISTER rip, r11
 586         SAVE_REST
 587         movq %r11, %r15
 588         CFI_REGISTER rip, r15
 589         FIXUP_TOP_OF_STACK %r11
 590         call *%rax
 591         RESTORE_TOP_OF_STACK %r11
 592         movq %r15, %r11
 593         CFI_REGISTER rip, r11
 594         RESTORE_REST
 595         pushq %r11
 596         CFI_ADJUST_CFA_OFFSET 8
 597         CFI_REL_OFFSET rip, 0
 598         ret
 599         CFI_ENDPROC
 600 END(ptregscall_common)
 601
 602 ENTRY(stub_execve)
 603         CFI_STARTPROC
 604         popq %r11
 605         CFI_ADJUST_CFA_OFFSET -8
 606         CFI_REGISTER rip, r11
 607         SAVE_REST
 608         FIXUP_TOP_OF_STACK %r11
 609         movq %rsp, %rcx
 610         call sys_execve
 611         RESTORE_TOP_OF_STACK %r11
 612         movq %rax,RAX(%rsp)
 613         RESTORE_REST
 614         jmp int_ret_from_sys_call
 615         CFI_ENDPROC
 616 END(stub_execve)
 617
 618 /*
 619  * sigreturn is special because it needs to restore all registers on return.
 620  * This cannot be done with SYSRET, so use the IRET return path instead.
 621  */
 622 ENTRY(stub_rt_sigreturn)
 623         CFI_STARTPROC
 624         addq $8, %rsp
 625         CFI_ADJUST_CFA_OFFSET   -8
 626         SAVE_REST
 627         movq %rsp,%rdi
 628         FIXUP_TOP_OF_STACK %r11
 629         call sys_rt_sigreturn
 630         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 631         RESTORE_REST
 632         jmp int_ret_from_sys_call
 633         CFI_ENDPROC
 634 END(stub_rt_sigreturn)
 635
 636 /*
 637  * initial frame state for interrupts and exceptions
 638  */
 639         .macro _frame ref
 640         CFI_STARTPROC simple
 641         CFI_SIGNAL_FRAME
 642         CFI_DEF_CFA rsp,SS+8-\ref
 643         /*CFI_REL_OFFSET ss,SS-\ref*/
 644         CFI_REL_OFFSET rsp,RSP-\ref
 645         /*CFI_REL_OFFSET rflags,EFLAGS-\ref*/
 646         /*CFI_REL_OFFSET cs,CS-\ref*/
 647         CFI_REL_OFFSET rip,RIP-\ref
 648         .endm
 649
 650 /* initial frame state for interrupts (and exceptions without error code) */
 651 #define INTR_FRAME _frame RIP
 652 /* initial frame state for exceptions with error code (and interrupts with
 653    vector already pushed) */
 654 #define XCPT_FRAME _frame ORIG_RAX
 655
 656 /*
 657  * Interrupt entry/exit.
 658  *
 659  * Interrupt entry points save only callee clobbered registers in fast path.
 660  *
 661  * Entry runs with interrupts off.
 662  */
 663
 664 /* 0(%rsp): interrupt number */
 665         .macro interrupt func
 666         cld
 667         SAVE_ARGS
 668         leaq -ARGOFFSET(%rsp),%rdi      # arg1 for handler
 669         pushq %rbp
 670         CFI_ADJUST_CFA_OFFSET   8
 671         CFI_REL_OFFSET          rbp, 0
 672         movq %rsp,%rbp
 673         CFI_DEF_CFA_REGISTER    rbp
 674         testl $3,CS(%rdi)
 675         je 1f
 676         SWAPGS
 677         /* irqcount is used to check if a CPU is already on an interrupt
 678            stack or not. While this is essentially redundant with preempt_count
 679            it is a little cheaper to use a separate counter in the PDA
 680            (short of moving irq_enter into assembly, which would be too
 681             much work) */
 682 1:      incl    %gs:pda_irqcount
 683         cmoveq %gs:pda_irqstackptr,%rsp
 684         push    %rbp                    # backlink for old unwinder
 685         /*
 686          * We entered an interrupt context - irqs are off:
 687          */
 688         TRACE_IRQS_OFF
 689         call \func
 690         .endm
 691
 692 ENTRY(common_interrupt)
 693         XCPT_FRAME
 694         interrupt do_IRQ
 695         /* 0(%rsp): oldrsp-ARGOFFSET */
 696 ret_from_intr:
 697         DISABLE_INTERRUPTS(CLBR_NONE)
 698         TRACE_IRQS_OFF
 699         decl %gs:pda_irqcount
 700         leaveq
 701         CFI_DEF_CFA_REGISTER    rsp
 702         CFI_ADJUST_CFA_OFFSET   -8
 703 exit_intr:
 704         GET_THREAD_INFO(%rcx)
 705         testl $3,CS-ARGOFFSET(%rsp)
 706         je retint_kernel
 707
 708         /* Interrupt came from user space */
 709         /*
 710          * Has a correct top of stack, but a partial stack frame
 711          * %rcx: thread info. Interrupts off.
 712          */
 713 retint_with_reschedule:
 714         movl $_TIF_WORK_MASK,%edi
 715 retint_check:
 716         LOCKDEP_SYS_EXIT_IRQ
 717         movl TI_flags(%rcx),%edx
 718         andl %edi,%edx
 719         CFI_REMEMBER_STATE
 720         jnz  retint_careful
 721
 722 retint_swapgs:          /* return to user-space */
 723         /*
 724          * The iretq could re-enable interrupts:
 725          */
 726         DISABLE_INTERRUPTS(CLBR_ANY)
 727         TRACE_IRQS_IRETQ
 728         SWAPGS
 729         jmp restore_args
 730
 731 retint_restore_args:    /* return to kernel space */
 732         DISABLE_INTERRUPTS(CLBR_ANY)
 733         /*
 734          * The iretq could re-enable interrupts:
 735          */
 736         TRACE_IRQS_IRETQ
 737 restore_args:
 738         RESTORE_ARGS 0,8,0
 739
 740 irq_return:
 741         INTERRUPT_RETURN
 742
 743         .section __ex_table, "a"
 744         .quad irq_return, bad_iret
 745         .previous
 746
 747 #ifdef CONFIG_PARAVIRT
 748 ENTRY(native_iret)
 749         iretq
 750
 751         .section __ex_table,"a"
 752         .quad native_iret, bad_iret
 753         .previous
 754 #endif
 755
 756         .section .fixup,"ax"
 757 bad_iret:
 758         /*
 759          * The iret traps when the %cs or %ss being restored is bogus.
 760          * We've lost the original trap vector and error code.
 761          * #GPF is the most likely one to get for an invalid selector.
 762          * So pretend we completed the iret and took the #GPF in user mode.
 763          *
 764          * We are now running with the kernel GS after exception recovery.
 765          * But error_entry expects us to have user GS to match the user %cs,
 766          * so swap back.
 767          */
 768         pushq $0
 769
 770         SWAPGS
 771         jmp general_protection
 772
 773         .previous
 774
 775         /* edi: workmask, edx: work */
 776 retint_careful:
 777         CFI_RESTORE_STATE
 778         bt    $TIF_NEED_RESCHED,%edx
 779         jnc   retint_signal
 780         TRACE_IRQS_ON
 781         ENABLE_INTERRUPTS(CLBR_NONE)
 782         pushq %rdi
 783         CFI_ADJUST_CFA_OFFSET   8
 784         call  schedule
 785         popq %rdi
 786         CFI_ADJUST_CFA_OFFSET   -8
 787         GET_THREAD_INFO(%rcx)
 788         DISABLE_INTERRUPTS(CLBR_NONE)
 789         TRACE_IRQS_OFF
 790         jmp retint_check
 791
 792 retint_signal:
 793         testl $_TIF_DO_NOTIFY_MASK,%edx
 794         jz    retint_swapgs
 795         TRACE_IRQS_ON
 796         ENABLE_INTERRUPTS(CLBR_NONE)
 797         SAVE_REST
 798         movq $-1,ORIG_RAX(%rsp)
 799         xorl %esi,%esi          # oldset
 800         movq %rsp,%rdi          # &pt_regs
 801         call do_notify_resume
 802         RESTORE_REST
 803         DISABLE_INTERRUPTS(CLBR_NONE)
 804         TRACE_IRQS_OFF
 805         GET_THREAD_INFO(%rcx)
 806         jmp retint_with_reschedule
 807
 808 #ifdef CONFIG_PREEMPT
 809         /* Returning to kernel space. Check if we need preemption */
 810         /* rcx:  threadinfo. interrupts off. */
 811 ENTRY(retint_kernel)
 812         cmpl $0,TI_preempt_count(%rcx)
 813         jnz  retint_restore_args
 814         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 815         jnc  retint_restore_args
 816         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 817         jnc  retint_restore_args
 818         call preempt_schedule_irq
 819         jmp exit_intr
 820 #endif
 821
 822         CFI_ENDPROC
 823 END(common_interrupt)
 824
 825 /*
 826  * APIC interrupts.
 827  */
 828         .macro apicinterrupt num,func
 829         INTR_FRAME
 830         pushq $~(\num)
 831         CFI_ADJUST_CFA_OFFSET 8
 832         interrupt \func
 833         jmp ret_from_intr
 834         CFI_ENDPROC
 835         .endm
 836
 837 ENTRY(thermal_interrupt)
 838         apicinterrupt THERMAL_APIC_VECTOR,smp_thermal_interrupt
 839 END(thermal_interrupt)
 840
 841 ENTRY(threshold_interrupt)
 842         apicinterrupt THRESHOLD_APIC_VECTOR,mce_threshold_interrupt
 843 END(threshold_interrupt)
 844
 845 #ifdef CONFIG_SMP
 846 ENTRY(reschedule_interrupt)
 847         apicinterrupt RESCHEDULE_VECTOR,smp_reschedule_interrupt
 848 END(reschedule_interrupt)
 849
 850         .macro INVALIDATE_ENTRY num
 851 ENTRY(invalidate_interrupt\num)
 852         apicinterrupt INVALIDATE_TLB_VECTOR_START+\num,smp_invalidate_interrupt
 853 END(invalidate_interrupt\num)
 854         .endm
 855
 856         INVALIDATE_ENTRY 0
 857         INVALIDATE_ENTRY 1
 858         INVALIDATE_ENTRY 2
 859         INVALIDATE_ENTRY 3
 860         INVALIDATE_ENTRY 4
 861         INVALIDATE_ENTRY 5
 862         INVALIDATE_ENTRY 6
 863         INVALIDATE_ENTRY 7
 864
 865 ENTRY(call_function_interrupt)
 866         apicinterrupt CALL_FUNCTION_VECTOR,smp_call_function_interrupt
 867 END(call_function_interrupt)
 868 ENTRY(call_function_single_interrupt)
 869         apicinterrupt CALL_FUNCTION_SINGLE_VECTOR,smp_call_function_single_interrupt
 870 END(call_function_single_interrupt)
 871 ENTRY(irq_move_cleanup_interrupt)
 872         apicinterrupt IRQ_MOVE_CLEANUP_VECTOR,smp_irq_move_cleanup_interrupt
 873 END(irq_move_cleanup_interrupt)
 874 #endif
 875
 876 ENTRY(apic_timer_interrupt)
 877         apicinterrupt LOCAL_TIMER_VECTOR,smp_apic_timer_interrupt
 878 END(apic_timer_interrupt)
 879
 880 ENTRY(uv_bau_message_intr1)
 881         apicinterrupt 220,uv_bau_message_interrupt
 882 END(uv_bau_message_intr1)
 883
 884 ENTRY(error_interrupt)
 885         apicinterrupt ERROR_APIC_VECTOR,smp_error_interrupt
 886 END(error_interrupt)
 887
 888 ENTRY(spurious_interrupt)
 889         apicinterrupt SPURIOUS_APIC_VECTOR,smp_spurious_interrupt
 890 END(spurious_interrupt)
 891
 892 /*
 893  * Exception entry points.
 894  */
 895         .macro zeroentry sym
 896         INTR_FRAME
 897         PARAVIRT_ADJUST_EXCEPTION_FRAME
 898         pushq $0        /* push error code/oldrax */
 899         CFI_ADJUST_CFA_OFFSET 8
 900         pushq %rax      /* push real oldrax to the rdi slot */
 901         CFI_ADJUST_CFA_OFFSET 8
 902         CFI_REL_OFFSET rax,0
 903         leaq  \sym(%rip),%rax
 904         jmp error_entry
 905         CFI_ENDPROC
 906         .endm
 907
 908         .macro errorentry sym
 909         XCPT_FRAME
 910         PARAVIRT_ADJUST_EXCEPTION_FRAME
 911         pushq %rax
 912         CFI_ADJUST_CFA_OFFSET 8
 913         CFI_REL_OFFSET rax,0
 914         leaq  \sym(%rip),%rax
 915         jmp error_entry
 916         CFI_ENDPROC
 917         .endm
 918
 919         /* error code is on the stack already */
 920         /* handle NMI like exceptions that can happen everywhere */
 921         .macro paranoidentry sym, ist=0, irqtrace=1
 922         SAVE_ALL
 923         cld
 924         movl $1,%ebx
 925         movl  $MSR_GS_BASE,%ecx
 926         rdmsr
 927         testl %edx,%edx
 928         js    1f
 929         SWAPGS
 930         xorl  %ebx,%ebx
 931 1:
 932         .if \ist
 933         movq    %gs:pda_data_offset, %rbp
 934         .endif
 935         movq %rsp,%rdi
 936         movq ORIG_RAX(%rsp),%rsi
 937         movq $-1,ORIG_RAX(%rsp)
 938         .if \ist
 939         subq    $EXCEPTION_STKSZ, per_cpu__init_tss + TSS_ist + (\ist - 1) * 8(%rbp)
 940         .endif
 941         call \sym
 942         .if \ist
 943         addq    $EXCEPTION_STKSZ, per_cpu__init_tss + TSS_ist + (\ist - 1) * 8(%rbp)
 944         .endif
 945         DISABLE_INTERRUPTS(CLBR_NONE)
 946         .if \irqtrace
 947         TRACE_IRQS_OFF
 948         .endif
 949         .endm
 950
 951         /*
 952          * "Paranoid" exit path from exception stack.
 953          * Paranoid because this is used by NMIs and cannot take
 954          * any kernel state for granted.
 955          * We don't do kernel preemption checks here, because only
 956          * NMI should be common and it does not enable IRQs and
 957          * cannot get reschedule ticks.
 958          *
 959          * "trace" is 0 for the NMI handler only, because irq-tracing
 960          * is fundamentally NMI-unsafe. (we cannot change the soft and
 961          * hard flags at once, atomically)
 962          */
 963         .macro paranoidexit trace=1
 964         /* ebx: no swapgs flag */
 965 paranoid_exit\trace:
 966         testl %ebx,%ebx                         /* swapgs needed? */
 967         jnz paranoid_restore\trace
 968         testl $3,CS(%rsp)
 969         jnz   paranoid_userspace\trace
 970 paranoid_swapgs\trace:
 971         .if \trace
 972         TRACE_IRQS_IRETQ 0
 973         .endif
 974         SWAPGS_UNSAFE_STACK
 975 paranoid_restore\trace:
 976         RESTORE_ALL 8
 977         jmp irq_return
 978 paranoid_userspace\trace:
 979         GET_THREAD_INFO(%rcx)
 980         movl TI_flags(%rcx),%ebx
 981         andl $_TIF_WORK_MASK,%ebx
 982         jz paranoid_swapgs\trace
 983         movq %rsp,%rdi                  /* &pt_regs */
 984         call sync_regs
 985         movq %rax,%rsp                  /* switch stack for scheduling */
 986         testl $_TIF_NEED_RESCHED,%ebx
 987         jnz paranoid_schedule\trace
 988         movl %ebx,%edx                  /* arg3: thread flags */
 989         .if \trace
 990         TRACE_IRQS_ON
 991         .endif
 992         ENABLE_INTERRUPTS(CLBR_NONE)
 993         xorl %esi,%esi                  /* arg2: oldset */
 994         movq %rsp,%rdi                  /* arg1: &pt_regs */
 995         call do_notify_resume
 996         DISABLE_INTERRUPTS(CLBR_NONE)
 997         .if \trace
 998         TRACE_IRQS_OFF
 999         .endif
1000         jmp paranoid_userspace\trace
1001 paranoid_schedule\trace:
1002         .if \trace
1003         TRACE_IRQS_ON
1004         .endif
1005         ENABLE_INTERRUPTS(CLBR_ANY)
1006         call schedule
1007         DISABLE_INTERRUPTS(CLBR_ANY)
1008         .if \trace
1009         TRACE_IRQS_OFF
1010         .endif
1011         jmp paranoid_userspace\trace
1012         CFI_ENDPROC
1013         .endm
1014
1015 /*
1016  * Exception entry point. This expects an error code/orig_rax on the stack
1017  * and the exception handler in %rax.
1018  */
1019 KPROBE_ENTRY(error_entry)
1020         _frame RDI
1021         CFI_REL_OFFSET rax,0
1022         /* rdi slot contains rax, oldrax contains error code */
1023         cld
1024         subq  $14*8,%rsp
1025         CFI_ADJUST_CFA_OFFSET   (14*8)
1026         movq %rsi,13*8(%rsp)
1027         CFI_REL_OFFSET  rsi,RSI
1028         movq 14*8(%rsp),%rsi    /* load rax from rdi slot */
1029         CFI_REGISTER    rax,rsi
1030         movq %rdx,12*8(%rsp)
1031         CFI_REL_OFFSET  rdx,RDX
1032         movq %rcx,11*8(%rsp)
1033         CFI_REL_OFFSET  rcx,RCX
1034         movq %rsi,10*8(%rsp)    /* store rax */
1035         CFI_REL_OFFSET  rax,RAX
1036         movq %r8, 9*8(%rsp)
1037         CFI_REL_OFFSET  r8,R8
1038         movq %r9, 8*8(%rsp)
1039         CFI_REL_OFFSET  r9,R9
1040         movq %r10,7*8(%rsp)
1041         CFI_REL_OFFSET  r10,R10
1042         movq %r11,6*8(%rsp)
1043         CFI_REL_OFFSET  r11,R11
1044         movq %rbx,5*8(%rsp)
1045         CFI_REL_OFFSET  rbx,RBX
1046         movq %rbp,4*8(%rsp)
1047         CFI_REL_OFFSET  rbp,RBP
1048         movq %r12,3*8(%rsp)
1049         CFI_REL_OFFSET  r12,R12
1050         movq %r13,2*8(%rsp)
1051         CFI_REL_OFFSET  r13,R13
1052         movq %r14,1*8(%rsp)
1053         CFI_REL_OFFSET  r14,R14
1054         movq %r15,(%rsp)
1055         CFI_REL_OFFSET  r15,R15
1056         xorl %ebx,%ebx
1057         testl $3,CS(%rsp)
1058         je  error_kernelspace
1059 error_swapgs:
1060         SWAPGS
1061 error_sti:
1062         movq %rdi,RDI(%rsp)
1063         CFI_REL_OFFSET  rdi,RDI
1064         movq %rsp,%rdi
1065         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1066         movq $-1,ORIG_RAX(%rsp)
1067         call *%rax
1068         /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1069 error_exit:
1070         movl %ebx,%eax
1071         RESTORE_REST
1072         DISABLE_INTERRUPTS(CLBR_NONE)
1073         TRACE_IRQS_OFF
1074         GET_THREAD_INFO(%rcx)
1075         testl %eax,%eax
1076         jne  retint_kernel
1077         LOCKDEP_SYS_EXIT_IRQ
1078         movl  TI_flags(%rcx),%edx
1079         movl  $_TIF_WORK_MASK,%edi
1080         andl  %edi,%edx
1081         jnz  retint_careful
1082         jmp retint_swapgs
1083         CFI_ENDPROC
1084
1085 error_kernelspace:
1086         incl %ebx
1087        /* There are two places in the kernel that can potentially fault with
1088           usergs. Handle them here. The exception handlers after
1089            iret run with kernel gs again, so don't set the user space flag.
1090            B stepping K8s sometimes report an truncated RIP for IRET
1091            exceptions returning to compat mode. Check for these here too. */
1092         leaq irq_return(%rip),%rcx
1093         cmpq %rcx,RIP(%rsp)
1094         je   error_swapgs
1095         movl %ecx,%ecx  /* zero extend */
1096         cmpq %rcx,RIP(%rsp)
1097         je   error_swapgs
1098         cmpq $gs_change,RIP(%rsp)
1099         je   error_swapgs
1100         jmp  error_sti
1101 KPROBE_END(error_entry)
1102
1103        /* Reload gs selector with exception handling */
1104        /* edi:  new selector */
1105 ENTRY(native_load_gs_index)
1106         CFI_STARTPROC
1107         pushf
1108         CFI_ADJUST_CFA_OFFSET 8
1109         DISABLE_INTERRUPTS(CLBR_ANY | ~(CLBR_RDI))
1110         SWAPGS
1111 gs_change:
1112         movl %edi,%gs
1113 2:      mfence          /* workaround */
1114         SWAPGS
1115         popf
1116         CFI_ADJUST_CFA_OFFSET -8
1117         ret
1118         CFI_ENDPROC
1119 ENDPROC(native_load_gs_index)
1120
1121         .section __ex_table,"a"
1122         .align 8
1123         .quad gs_change,bad_gs
1124         .previous
1125         .section .fixup,"ax"
1126         /* running with kernelgs */
1127 bad_gs:
1128         SWAPGS                  /* switch back to user gs */
1129         xorl %eax,%eax
1130         movl %eax,%gs
1131         jmp  2b
1132         .previous
1133
1134 /*
1135  * Create a kernel thread.
1136  *
1137  * C extern interface:
1138  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1139  *
1140  * asm input arguments:
1141  *      rdi: fn, rsi: arg, rdx: flags
1142  */
1143 ENTRY(kernel_thread)
1144         CFI_STARTPROC
1145         FAKE_STACK_FRAME $child_rip
1146         SAVE_ALL
1147
1148         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1149         movq %rdx,%rdi
1150         orq  kernel_thread_flags(%rip),%rdi
1151         movq $-1, %rsi
1152         movq %rsp, %rdx
1153
1154         xorl %r8d,%r8d
1155         xorl %r9d,%r9d
1156
1157         # clone now
1158         call do_fork
1159         movq %rax,RAX(%rsp)
1160         xorl %edi,%edi
1161
1162         /*
1163          * It isn't worth to check for reschedule here,
1164          * so internally to the x86_64 port you can rely on kernel_thread()
1165          * not to reschedule the child before returning, this avoids the need
1166          * of hacks for example to fork off the per-CPU idle tasks.
1167          * [Hopefully no generic code relies on the reschedule -AK]
1168          */
1169         RESTORE_ALL
1170         UNFAKE_STACK_FRAME
1171         ret
1172         CFI_ENDPROC
1173 ENDPROC(kernel_thread)
1174
1175 child_rip:
1176         pushq $0                # fake return address
1177         CFI_STARTPROC
1178         /*
1179          * Here we are in the child and the registers are set as they were
1180          * at kernel_thread() invocation in the parent.
1181          */
1182         movq %rdi, %rax
1183         movq %rsi, %rdi
1184         call *%rax
1185         # exit
1186         mov %eax, %edi
1187         call do_exit
1188         CFI_ENDPROC
1189 ENDPROC(child_rip)
1190
1191 /*
1192  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1193  *
1194  * C extern interface:
1195  *       extern long execve(char *name, char **argv, char **envp)
1196  *
1197  * asm input arguments:
1198  *      rdi: name, rsi: argv, rdx: envp
1199  *
1200  * We want to fallback into:
1201  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1202  *
1203  * do_sys_execve asm fallback arguments:
1204  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1205  */
1206 ENTRY(kernel_execve)
1207         CFI_STARTPROC
1208         FAKE_STACK_FRAME $0
1209         SAVE_ALL
1210         movq %rsp,%rcx
1211         call sys_execve
1212         movq %rax, RAX(%rsp)
1213         RESTORE_REST
1214         testq %rax,%rax
1215         je int_ret_from_sys_call
1216         RESTORE_ARGS
1217         UNFAKE_STACK_FRAME
1218         ret
1219         CFI_ENDPROC
1220 ENDPROC(kernel_execve)
1221
1222 KPROBE_ENTRY(page_fault)
1223         errorentry do_page_fault
1224 KPROBE_END(page_fault)
1225
1226 ENTRY(coprocessor_error)
1227         zeroentry do_coprocessor_error
1228 END(coprocessor_error)
1229
1230 ENTRY(simd_coprocessor_error)
1231         zeroentry do_simd_coprocessor_error
1232 END(simd_coprocessor_error)
1233
1234 ENTRY(device_not_available)
1235         zeroentry math_state_restore
1236 END(device_not_available)
1237
1238         /* runs on exception stack */
1239 KPROBE_ENTRY(debug)
1240         INTR_FRAME
1241         PARAVIRT_ADJUST_EXCEPTION_FRAME
1242         pushq $0
1243         CFI_ADJUST_CFA_OFFSET 8
1244         paranoidentry do_debug, DEBUG_STACK
1245         paranoidexit
1246 KPROBE_END(debug)
1247
1248         /* runs on exception stack */
1249 KPROBE_ENTRY(nmi)
1250         INTR_FRAME
1251         PARAVIRT_ADJUST_EXCEPTION_FRAME
1252         pushq $-1
1253         CFI_ADJUST_CFA_OFFSET 8
1254         paranoidentry do_nmi, 0, 0
1255 #ifdef CONFIG_TRACE_IRQFLAGS
1256         paranoidexit 0
1257 #else
1258         jmp paranoid_exit1
1259         CFI_ENDPROC
1260 #endif
1261 KPROBE_END(nmi)
1262
1263 KPROBE_ENTRY(int3)
1264         INTR_FRAME
1265         PARAVIRT_ADJUST_EXCEPTION_FRAME
1266         pushq $0
1267         CFI_ADJUST_CFA_OFFSET 8
1268         paranoidentry do_int3, DEBUG_STACK
1269         jmp paranoid_exit1
1270         CFI_ENDPROC
1271 KPROBE_END(int3)
1272
1273 ENTRY(overflow)
1274         zeroentry do_overflow
1275 END(overflow)
1276
1277 ENTRY(bounds)
1278         zeroentry do_bounds
1279 END(bounds)
1280
1281 ENTRY(invalid_op)
1282         zeroentry do_invalid_op
1283 END(invalid_op)
1284
1285 ENTRY(coprocessor_segment_overrun)
1286         zeroentry do_coprocessor_segment_overrun
1287 END(coprocessor_segment_overrun)
1288
1289         /* runs on exception stack */
1290 ENTRY(double_fault)
1291         XCPT_FRAME
1292         PARAVIRT_ADJUST_EXCEPTION_FRAME
1293         paranoidentry do_double_fault
1294         jmp paranoid_exit1
1295         CFI_ENDPROC
1296 END(double_fault)
1297
1298 ENTRY(invalid_TSS)
1299         errorentry do_invalid_TSS
1300 END(invalid_TSS)
1301
1302 ENTRY(segment_not_present)
1303         errorentry do_segment_not_present
1304 END(segment_not_present)
1305
1306         /* runs on exception stack */
1307 ENTRY(stack_segment)
1308         XCPT_FRAME
1309         PARAVIRT_ADJUST_EXCEPTION_FRAME
1310         paranoidentry do_stack_segment
1311         jmp paranoid_exit1
1312         CFI_ENDPROC
1313 END(stack_segment)
1314
1315 KPROBE_ENTRY(general_protection)
1316         errorentry do_general_protection
1317 KPROBE_END(general_protection)
1318
1319 ENTRY(alignment_check)
1320         errorentry do_alignment_check
1321 END(alignment_check)
1322
1323 ENTRY(divide_error)
1324         zeroentry do_divide_error
1325 END(divide_error)
1326
1327 ENTRY(spurious_interrupt_bug)
1328         zeroentry do_spurious_interrupt_bug
1329 END(spurious_interrupt_bug)
1330
1331 #ifdef CONFIG_X86_MCE
1332         /* runs on exception stack */
1333 ENTRY(machine_check)
1334         INTR_FRAME
1335         PARAVIRT_ADJUST_EXCEPTION_FRAME
1336         pushq $0
1337         CFI_ADJUST_CFA_OFFSET 8
1338         paranoidentry do_machine_check
1339         jmp paranoid_exit1
1340         CFI_ENDPROC
1341 END(machine_check)
1342 #endif
1343
1344 /* Call softirq on interrupt stack. Interrupts are off. */
1345 ENTRY(call_softirq)
1346         CFI_STARTPROC
1347         push %rbp
1348         CFI_ADJUST_CFA_OFFSET   8
1349         CFI_REL_OFFSET rbp,0
1350         mov  %rsp,%rbp
1351         CFI_DEF_CFA_REGISTER rbp
1352         incl %gs:pda_irqcount
1353         cmove %gs:pda_irqstackptr,%rsp
1354         push  %rbp                      # backlink for old unwinder
1355         call __do_softirq
1356         leaveq
1357         CFI_DEF_CFA_REGISTER    rsp
1358         CFI_ADJUST_CFA_OFFSET   -8
1359         decl %gs:pda_irqcount
1360         ret
1361         CFI_ENDPROC
1362 ENDPROC(call_softirq)
1363
1364 KPROBE_ENTRY(ignore_sysret)
1365         CFI_STARTPROC
1366         mov $-ENOSYS,%eax
1367         sysret
1368         CFI_ENDPROC
1369 ENDPROC(ignore_sysret)
1370
1371 #ifdef CONFIG_XEN
1372 ENTRY(xen_hypervisor_callback)
1373         zeroentry xen_do_hypervisor_callback
1374 END(xen_hypervisor_callback)
1375
1376 /*
1377 # A note on the "critical region" in our callback handler.
1378 # We want to avoid stacking callback handlers due to events occurring
1379 # during handling of the last event. To do this, we keep events disabled
1380 # until we've done all processing. HOWEVER, we must enable events before
1381 # popping the stack frame (can't be done atomically) and so it would still
1382 # be possible to get enough handler activations to overflow the stack.
1383 # Although unlikely, bugs of that kind are hard to track down, so we'd
1384 # like to avoid the possibility.
1385 # So, on entry to the handler we detect whether we interrupted an
1386 # existing activation in its critical region -- if so, we pop the current
1387 # activation and restart the handler using the previous one.
1388 */
1389 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1390         CFI_STARTPROC
1391 /* Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1392    see the correct pointer to the pt_regs */
1393         movq %rdi, %rsp            # we don't return, adjust the stack frame
1394         CFI_ENDPROC
1395         CFI_DEFAULT_STACK
1396 11:     incl %gs:pda_irqcount
1397         movq %rsp,%rbp
1398         CFI_DEF_CFA_REGISTER rbp
1399         cmovzq %gs:pda_irqstackptr,%rsp
1400         pushq %rbp                      # backlink for old unwinder
1401         call xen_evtchn_do_upcall
1402         popq %rsp
1403         CFI_DEF_CFA_REGISTER rsp
1404         decl %gs:pda_irqcount
1405         jmp  error_exit
1406         CFI_ENDPROC
1407 END(do_hypervisor_callback)
1408
1409 /*
1410 # Hypervisor uses this for application faults while it executes.
1411 # We get here for two reasons:
1412 #  1. Fault while reloading DS, ES, FS or GS
1413 #  2. Fault while executing IRET
1414 # Category 1 we do not need to fix up as Xen has already reloaded all segment
1415 # registers that could be reloaded and zeroed the others.
1416 # Category 2 we fix up by killing the current process. We cannot use the
1417 # normal Linux return path in this case because if we use the IRET hypercall
1418 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1419 # We distinguish between categories by comparing each saved segment register
1420 # with its current contents: any discrepancy means we in category 1.
1421 */
1422 ENTRY(xen_failsafe_callback)
1423         framesz = (RIP-0x30)    /* workaround buggy gas */
1424         _frame framesz
1425         CFI_REL_OFFSET rcx, 0
1426         CFI_REL_OFFSET r11, 8
1427         movw %ds,%cx
1428         cmpw %cx,0x10(%rsp)
1429         CFI_REMEMBER_STATE
1430         jne 1f
1431         movw %es,%cx
1432         cmpw %cx,0x18(%rsp)
1433         jne 1f
1434         movw %fs,%cx
1435         cmpw %cx,0x20(%rsp)
1436         jne 1f
1437         movw %gs,%cx
1438         cmpw %cx,0x28(%rsp)
1439         jne 1f
1440         /* All segments match their saved values => Category 2 (Bad IRET). */
1441         movq (%rsp),%rcx
1442         CFI_RESTORE rcx
1443         movq 8(%rsp),%r11
1444         CFI_RESTORE r11
1445         addq $0x30,%rsp
1446         CFI_ADJUST_CFA_OFFSET -0x30
1447         pushq $0
1448         CFI_ADJUST_CFA_OFFSET 8
1449         pushq %r11
1450         CFI_ADJUST_CFA_OFFSET 8
1451         pushq %rcx
1452         CFI_ADJUST_CFA_OFFSET 8
1453         jmp general_protection
1454         CFI_RESTORE_STATE
1455 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1456         movq (%rsp),%rcx
1457         CFI_RESTORE rcx
1458         movq 8(%rsp),%r11
1459         CFI_RESTORE r11
1460         addq $0x30,%rsp
1461         CFI_ADJUST_CFA_OFFSET -0x30
1462         pushq $0
1463         CFI_ADJUST_CFA_OFFSET 8
1464         SAVE_ALL
1465         jmp error_exit
1466         CFI_ENDPROC
1467 END(xen_failsafe_callback)
1468
1469 #endif /* CONFIG_XEN */