git.oblomov.eu Git - linux-2.6/blob - arch/powerpc/kernel/cpu_setup_ppc970.S

   1 /*
   2  * This file contains low level CPU setup functions.
   3  *    Copyright (C) 2003 Benjamin Herrenschmidt (benh@kernel.crashing.org)
   4  *
   5  * This program is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU General Public License
   7  * as published by the Free Software Foundation; either version
   8  * 2 of the License, or (at your option) any later version.
   9  *
  10  */
  11
  12 #include <asm/processor.h>
  13 #include <asm/page.h>
  14 #include <asm/cputable.h>
  15 #include <asm/ppc_asm.h>
  16 #include <asm/asm-offsets.h>
  17 #include <asm/cache.h>
  18
  19 _GLOBAL(__cpu_preinit_ppc970)
  20         /* Do nothing if not running in HV mode */
  21         mfmsr   r0
  22         rldicl. r0,r0,4,63
  23         beqlr
  24
  25         /* Make sure HID4:rm_ci is off before MMU is turned off, that large
  26          * pages are enabled with HID4:61 and clear HID5:DCBZ_size and
  27          * HID5:DCBZ32_ill
  28          */
  29         li      r0,0
  30         mfspr   r3,SPRN_HID4
  31         rldimi  r3,r0,40,23     /* clear bit 23 (rm_ci) */
  32         rldimi  r3,r0,2,61      /* clear bit 61 (lg_pg_en) */
  33         sync
  34         mtspr   SPRN_HID4,r3
  35         isync
  36         sync
  37         mfspr   r3,SPRN_HID5
  38         rldimi  r3,r0,6,56      /* clear bits 56 & 57 (DCBZ*) */
  39         sync
  40         mtspr   SPRN_HID5,r3
  41         isync
  42         sync
  43
  44         /* Setup some basic HID1 features */
  45         mfspr   r0,SPRN_HID1
  46         li      r3,0x1200               /* enable i-fetch cacheability */
  47         sldi    r3,r3,44                /* and prefetch */
  48         or      r0,r0,r3
  49         mtspr   SPRN_HID1,r0
  50         mtspr   SPRN_HID1,r0
  51         isync
  52
  53         /* Clear HIOR */
  54         li      r0,0
  55         sync
  56         mtspr   SPRN_HIOR,0             /* Clear interrupt prefix */
  57         isync
  58         blr
  59
  60 /* Definitions for the table use to save CPU states */
  61 #define CS_HID0         0
  62 #define CS_HID1         8
  63 #define CS_HID4         16
  64 #define CS_HID5         24
  65 #define CS_SIZE         32
  66
  67         .data
  68         .balign L1_CACHE_BYTES,0
  69 cpu_state_storage:
  70         .space  CS_SIZE
  71         .balign L1_CACHE_BYTES,0
  72         .text
  73
  74
  75 _GLOBAL(__setup_cpu_ppc970)
  76         /* Do nothing if not running in HV mode */
  77         mfmsr   r0
  78         rldicl. r0,r0,4,63
  79         beqlr
  80
  81         mfspr   r0,SPRN_HID0
  82         li      r11,5                   /* clear DOZE and SLEEP */
  83         rldimi  r0,r11,52,8             /* set NAP and DPM */
  84         li      r11,0
  85         rldimi  r0,r11,32,31            /* clear EN_ATTN */
  86         mtspr   SPRN_HID0,r0
  87         mfspr   r0,SPRN_HID0
  88         mfspr   r0,SPRN_HID0
  89         mfspr   r0,SPRN_HID0
  90         mfspr   r0,SPRN_HID0
  91         mfspr   r0,SPRN_HID0
  92         mfspr   r0,SPRN_HID0
  93         sync
  94         isync
  95
  96         /* Save away cpu state */
  97         LOAD_REG_IMMEDIATE(r5,cpu_state_storage)
  98
  99         /* Save HID0,1,4 and 5 */
 100         mfspr   r3,SPRN_HID0
 101         std     r3,CS_HID0(r5)
 102         mfspr   r3,SPRN_HID1
 103         std     r3,CS_HID1(r5)
 104         mfspr   r3,SPRN_HID4
 105         std     r3,CS_HID4(r5)
 106         mfspr   r3,SPRN_HID5
 107         std     r3,CS_HID5(r5)
 108
 109         blr
 110
 111 /* Called with no MMU context (typically MSR:IR/DR off) to
 112  * restore CPU state as backed up by the previous
 113  * function. This does not include cache setting
 114  */
 115 _GLOBAL(__restore_cpu_ppc970)
 116         /* Do nothing if not running in HV mode */
 117         mfmsr   r0
 118         rldicl. r0,r0,4,63
 119         beqlr
 120
 121         LOAD_REG_IMMEDIATE(r5,cpu_state_storage)
 122         /* Before accessing memory, we make sure rm_ci is clear */
 123         li      r0,0
 124         mfspr   r3,SPRN_HID4
 125         rldimi  r3,r0,40,23     /* clear bit 23 (rm_ci) */
 126         sync
 127         mtspr   SPRN_HID4,r3
 128         isync
 129         sync
 130
 131         /* Clear interrupt prefix */
 132         li      r0,0
 133         sync
 134         mtspr   SPRN_HIOR,0
 135         isync
 136
 137         /* Restore HID0 */
 138         ld      r3,CS_HID0(r5)
 139         sync
 140         isync
 141         mtspr   SPRN_HID0,r3
 142         mfspr   r3,SPRN_HID0
 143         mfspr   r3,SPRN_HID0
 144         mfspr   r3,SPRN_HID0
 145         mfspr   r3,SPRN_HID0
 146         mfspr   r3,SPRN_HID0
 147         mfspr   r3,SPRN_HID0
 148         sync
 149         isync
 150
 151         /* Restore HID1 */
 152         ld      r3,CS_HID1(r5)
 153         sync
 154         isync
 155         mtspr   SPRN_HID1,r3
 156         mtspr   SPRN_HID1,r3
 157         sync
 158         isync
 159
 160         /* Restore HID4 */
 161         ld      r3,CS_HID4(r5)
 162         sync
 163         isync
 164         mtspr   SPRN_HID4,r3
 165         sync
 166         isync
 167
 168         /* Restore HID5 */
 169         ld      r3,CS_HID5(r5)
 170         sync
 171         isync
 172         mtspr   SPRN_HID5,r3
 173         sync
 174         isync
 175         blr
 176