git.oblomov.eu Git - linux-2.6/blob - arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - orig_eax
  34  *      2C(%esp) - %eip
  35  *      30(%esp) - %cs
  36  *      34(%esp) - %eflags
  37  *      38(%esp) - %oldesp
  38  *      3C(%esp) - %oldss
  39  *
  40  * "current" is in register %ebx during any slow entries.
  41  */
  42
  43 #include <linux/linkage.h>
  44 #include <asm/thread_info.h>
  45 #include <asm/irqflags.h>
  46 #include <asm/errno.h>
  47 #include <asm/segment.h>
  48 #include <asm/smp.h>
  49 #include <asm/page.h>
  50 #include <asm/desc.h>
  51 #include <asm/percpu.h>
  52 #include <asm/dwarf2.h>
  53 #include <asm/processor-flags.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/irq_vectors.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_LE    0x40000000
  61
  62 #ifndef CONFIG_AUDITSYSCALL
  63 #define sysenter_audit  syscall_trace_entry
  64 #define sysexit_audit   syscall_exit_work
  65 #endif
  66
  67 /*
  68  * We use macros for low-level operations which need to be overridden
  69  * for paravirtualization.  The following will never clobber any registers:
  70  *   INTERRUPT_RETURN (aka. "iret")
  71  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  72  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  73  *
  74  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  75  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  76  * Allowing a register to be clobbered can shrink the paravirt replacement
  77  * enough to patch inline, increasing performance.
  78  */
  79
  80 #define nr_syscalls ((syscall_table_size)/4)
  81
  82 #ifdef CONFIG_PREEMPT
  83 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  84 #else
  85 #define preempt_stop(clobbers)
  86 #define resume_kernel           restore_nocheck
  87 #endif
  88
  89 .macro TRACE_IRQS_IRET
  90 #ifdef CONFIG_TRACE_IRQFLAGS
  91         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  92         jz 1f
  93         TRACE_IRQS_ON
  94 1:
  95 #endif
  96 .endm
  97
  98 #ifdef CONFIG_VM86
  99 #define resume_userspace_sig    check_userspace
 100 #else
 101 #define resume_userspace_sig    resume_userspace
 102 #endif
 103
 104 #define SAVE_ALL \
 105         cld; \
 106         pushl %fs; \
 107         CFI_ADJUST_CFA_OFFSET 4;\
 108         /*CFI_REL_OFFSET fs, 0;*/\
 109         pushl %es; \
 110         CFI_ADJUST_CFA_OFFSET 4;\
 111         /*CFI_REL_OFFSET es, 0;*/\
 112         pushl %ds; \
 113         CFI_ADJUST_CFA_OFFSET 4;\
 114         /*CFI_REL_OFFSET ds, 0;*/\
 115         pushl %eax; \
 116         CFI_ADJUST_CFA_OFFSET 4;\
 117         CFI_REL_OFFSET eax, 0;\
 118         pushl %ebp; \
 119         CFI_ADJUST_CFA_OFFSET 4;\
 120         CFI_REL_OFFSET ebp, 0;\
 121         pushl %edi; \
 122         CFI_ADJUST_CFA_OFFSET 4;\
 123         CFI_REL_OFFSET edi, 0;\
 124         pushl %esi; \
 125         CFI_ADJUST_CFA_OFFSET 4;\
 126         CFI_REL_OFFSET esi, 0;\
 127         pushl %edx; \
 128         CFI_ADJUST_CFA_OFFSET 4;\
 129         CFI_REL_OFFSET edx, 0;\
 130         pushl %ecx; \
 131         CFI_ADJUST_CFA_OFFSET 4;\
 132         CFI_REL_OFFSET ecx, 0;\
 133         pushl %ebx; \
 134         CFI_ADJUST_CFA_OFFSET 4;\
 135         CFI_REL_OFFSET ebx, 0;\
 136         movl $(__USER_DS), %edx; \
 137         movl %edx, %ds; \
 138         movl %edx, %es; \
 139         movl $(__KERNEL_PERCPU), %edx; \
 140         movl %edx, %fs
 141
 142 #define RESTORE_INT_REGS \
 143         popl %ebx;      \
 144         CFI_ADJUST_CFA_OFFSET -4;\
 145         CFI_RESTORE ebx;\
 146         popl %ecx;      \
 147         CFI_ADJUST_CFA_OFFSET -4;\
 148         CFI_RESTORE ecx;\
 149         popl %edx;      \
 150         CFI_ADJUST_CFA_OFFSET -4;\
 151         CFI_RESTORE edx;\
 152         popl %esi;      \
 153         CFI_ADJUST_CFA_OFFSET -4;\
 154         CFI_RESTORE esi;\
 155         popl %edi;      \
 156         CFI_ADJUST_CFA_OFFSET -4;\
 157         CFI_RESTORE edi;\
 158         popl %ebp;      \
 159         CFI_ADJUST_CFA_OFFSET -4;\
 160         CFI_RESTORE ebp;\
 161         popl %eax;      \
 162         CFI_ADJUST_CFA_OFFSET -4;\
 163         CFI_RESTORE eax
 164
 165 #define RESTORE_REGS    \
 166         RESTORE_INT_REGS; \
 167 1:      popl %ds;       \
 168         CFI_ADJUST_CFA_OFFSET -4;\
 169         /*CFI_RESTORE ds;*/\
 170 2:      popl %es;       \
 171         CFI_ADJUST_CFA_OFFSET -4;\
 172         /*CFI_RESTORE es;*/\
 173 3:      popl %fs;       \
 174         CFI_ADJUST_CFA_OFFSET -4;\
 175         /*CFI_RESTORE fs;*/\
 176 .pushsection .fixup,"ax";       \
 177 4:      movl $0,(%esp); \
 178         jmp 1b;         \
 179 5:      movl $0,(%esp); \
 180         jmp 2b;         \
 181 6:      movl $0,(%esp); \
 182         jmp 3b;         \
 183 .section __ex_table,"a";\
 184         .align 4;       \
 185         .long 1b,4b;    \
 186         .long 2b,5b;    \
 187         .long 3b,6b;    \
 188 .popsection
 189
 190 #define RING0_INT_FRAME \
 191         CFI_STARTPROC simple;\
 192         CFI_SIGNAL_FRAME;\
 193         CFI_DEF_CFA esp, 3*4;\
 194         /*CFI_OFFSET cs, -2*4;*/\
 195         CFI_OFFSET eip, -3*4
 196
 197 #define RING0_EC_FRAME \
 198         CFI_STARTPROC simple;\
 199         CFI_SIGNAL_FRAME;\
 200         CFI_DEF_CFA esp, 4*4;\
 201         /*CFI_OFFSET cs, -2*4;*/\
 202         CFI_OFFSET eip, -3*4
 203
 204 #define RING0_PTREGS_FRAME \
 205         CFI_STARTPROC simple;\
 206         CFI_SIGNAL_FRAME;\
 207         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX;\
 208         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/\
 209         CFI_OFFSET eip, PT_EIP-PT_OLDESP;\
 210         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/\
 211         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/\
 212         CFI_OFFSET eax, PT_EAX-PT_OLDESP;\
 213         CFI_OFFSET ebp, PT_EBP-PT_OLDESP;\
 214         CFI_OFFSET edi, PT_EDI-PT_OLDESP;\
 215         CFI_OFFSET esi, PT_ESI-PT_OLDESP;\
 216         CFI_OFFSET edx, PT_EDX-PT_OLDESP;\
 217         CFI_OFFSET ecx, PT_ECX-PT_OLDESP;\
 218         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 219
 220 ENTRY(ret_from_fork)
 221         CFI_STARTPROC
 222         pushl %eax
 223         CFI_ADJUST_CFA_OFFSET 4
 224         call schedule_tail
 225         GET_THREAD_INFO(%ebp)
 226         popl %eax
 227         CFI_ADJUST_CFA_OFFSET -4
 228         pushl $0x0202                   # Reset kernel eflags
 229         CFI_ADJUST_CFA_OFFSET 4
 230         popfl
 231         CFI_ADJUST_CFA_OFFSET -4
 232         jmp syscall_exit
 233         CFI_ENDPROC
 234 END(ret_from_fork)
 235
 236 /*
 237  * Return to user mode is not as complex as all this looks,
 238  * but we want the default path for a system call return to
 239  * go as quickly as possible which is why some of this is
 240  * less clear than it otherwise should be.
 241  */
 242
 243         # userspace resumption stub bypassing syscall exit tracing
 244         ALIGN
 245         RING0_PTREGS_FRAME
 246 ret_from_exception:
 247         preempt_stop(CLBR_ANY)
 248 ret_from_intr:
 249         GET_THREAD_INFO(%ebp)
 250 check_userspace:
 251         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 252         movb PT_CS(%esp), %al
 253         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 254         cmpl $USER_RPL, %eax
 255         jb resume_kernel                # not returning to v8086 or userspace
 256
 257 ENTRY(resume_userspace)
 258         LOCKDEP_SYS_EXIT
 259         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 260                                         # setting need_resched or sigpending
 261                                         # between sampling and the iret
 262         TRACE_IRQS_OFF
 263         movl TI_flags(%ebp), %ecx
 264         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 265                                         # int/exception return?
 266         jne work_pending
 267         jmp restore_all
 268 END(ret_from_exception)
 269
 270 #ifdef CONFIG_PREEMPT
 271 ENTRY(resume_kernel)
 272         DISABLE_INTERRUPTS(CLBR_ANY)
 273         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 274         jnz restore_nocheck
 275 need_resched:
 276         movl TI_flags(%ebp), %ecx       # need_resched set ?
 277         testb $_TIF_NEED_RESCHED, %cl
 278         jz restore_all
 279         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 280         jz restore_all
 281         call preempt_schedule_irq
 282         jmp need_resched
 283 END(resume_kernel)
 284 #endif
 285         CFI_ENDPROC
 286
 287 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 288    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 289
 290         # sysenter call handler stub
 291 ENTRY(ia32_sysenter_target)
 292         CFI_STARTPROC simple
 293         CFI_SIGNAL_FRAME
 294         CFI_DEF_CFA esp, 0
 295         CFI_REGISTER esp, ebp
 296         movl TSS_sysenter_sp0(%esp),%esp
 297 sysenter_past_esp:
 298         /*
 299          * Interrupts are disabled here, but we can't trace it until
 300          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 301          * we immediately enable interrupts at that point anyway.
 302          */
 303         pushl $(__USER_DS)
 304         CFI_ADJUST_CFA_OFFSET 4
 305         /*CFI_REL_OFFSET ss, 0*/
 306         pushl %ebp
 307         CFI_ADJUST_CFA_OFFSET 4
 308         CFI_REL_OFFSET esp, 0
 309         pushfl
 310         orl $X86_EFLAGS_IF, (%esp)
 311         CFI_ADJUST_CFA_OFFSET 4
 312         pushl $(__USER_CS)
 313         CFI_ADJUST_CFA_OFFSET 4
 314         /*CFI_REL_OFFSET cs, 0*/
 315         /*
 316          * Push current_thread_info()->sysenter_return to the stack.
 317          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 318          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 319          */
 320         pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
 321         CFI_ADJUST_CFA_OFFSET 4
 322         CFI_REL_OFFSET eip, 0
 323
 324         pushl %eax
 325         CFI_ADJUST_CFA_OFFSET 4
 326         SAVE_ALL
 327         ENABLE_INTERRUPTS(CLBR_NONE)
 328
 329 /*
 330  * Load the potential sixth argument from user stack.
 331  * Careful about security.
 332  */
 333         cmpl $__PAGE_OFFSET-3,%ebp
 334         jae syscall_fault
 335 1:      movl (%ebp),%ebp
 336         movl %ebp,PT_EBP(%esp)
 337 .section __ex_table,"a"
 338         .align 4
 339         .long 1b,syscall_fault
 340 .previous
 341
 342         GET_THREAD_INFO(%ebp)
 343
 344         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 345         testw $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 346         jnz sysenter_audit
 347 sysenter_do_call:
 348         cmpl $(nr_syscalls), %eax
 349         jae syscall_badsys
 350         call *sys_call_table(,%eax,4)
 351         movl %eax,PT_EAX(%esp)
 352         LOCKDEP_SYS_EXIT
 353         DISABLE_INTERRUPTS(CLBR_ANY)
 354         TRACE_IRQS_OFF
 355         movl TI_flags(%ebp), %ecx
 356         testw $_TIF_ALLWORK_MASK, %cx
 357         jne sysexit_audit
 358 sysenter_exit:
 359 /* if something modifies registers it must also disable sysexit */
 360         movl PT_EIP(%esp), %edx
 361         movl PT_OLDESP(%esp), %ecx
 362         xorl %ebp,%ebp
 363         TRACE_IRQS_ON
 364 1:      mov  PT_FS(%esp), %fs
 365         ENABLE_INTERRUPTS_SYSEXIT
 366
 367 #ifdef CONFIG_AUDITSYSCALL
 368 sysenter_audit:
 369         testw $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 370         jnz syscall_trace_entry
 371         addl $4,%esp
 372         CFI_ADJUST_CFA_OFFSET -4
 373         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 374         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 375         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 376         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 377         movl %eax,%edx                  /* 2nd arg: syscall number */
 378         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 379         call audit_syscall_entry
 380         pushl %ebx
 381         CFI_ADJUST_CFA_OFFSET 4
 382         movl PT_EAX(%esp),%eax          /* reload syscall number */
 383         jmp sysenter_do_call
 384
 385 sysexit_audit:
 386         testw $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %cx
 387         jne syscall_exit_work
 388         TRACE_IRQS_ON
 389         ENABLE_INTERRUPTS(CLBR_ANY)
 390         movl %eax,%edx          /* second arg, syscall return value */
 391         cmpl $0,%eax            /* is it < 0? */
 392         setl %al                /* 1 if so, 0 if not */
 393         movzbl %al,%eax         /* zero-extend that */
 394         inc %eax /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 395         call audit_syscall_exit
 396         DISABLE_INTERRUPTS(CLBR_ANY)
 397         TRACE_IRQS_OFF
 398         movl TI_flags(%ebp), %ecx
 399         testw $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %cx
 400         jne syscall_exit_work
 401         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 402         jmp sysenter_exit
 403 #endif
 404
 405         CFI_ENDPROC
 406 .pushsection .fixup,"ax"
 407 2:      movl $0,PT_FS(%esp)
 408         jmp 1b
 409 .section __ex_table,"a"
 410         .align 4
 411         .long 1b,2b
 412 .popsection
 413 ENDPROC(ia32_sysenter_target)
 414
 415         # system call handler stub
 416 ENTRY(system_call)
 417         RING0_INT_FRAME                 # can't unwind into user space anyway
 418         pushl %eax                      # save orig_eax
 419         CFI_ADJUST_CFA_OFFSET 4
 420         SAVE_ALL
 421         GET_THREAD_INFO(%ebp)
 422                                         # system call tracing in operation / emulation
 423         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 424         testw $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 425         jnz syscall_trace_entry
 426         cmpl $(nr_syscalls), %eax
 427         jae syscall_badsys
 428 syscall_call:
 429         call *sys_call_table(,%eax,4)
 430         movl %eax,PT_EAX(%esp)          # store the return value
 431 syscall_exit:
 432         LOCKDEP_SYS_EXIT
 433         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 434                                         # setting need_resched or sigpending
 435                                         # between sampling and the iret
 436         TRACE_IRQS_OFF
 437         movl TI_flags(%ebp), %ecx
 438         testw $_TIF_ALLWORK_MASK, %cx   # current->work
 439         jne syscall_exit_work
 440
 441 restore_all:
 442         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 443         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 444         # are returning to the kernel.
 445         # See comments in process.c:copy_thread() for details.
 446         movb PT_OLDSS(%esp), %ah
 447         movb PT_CS(%esp), %al
 448         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 449         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 450         CFI_REMEMBER_STATE
 451         je ldt_ss                       # returning to user-space with LDT SS
 452 restore_nocheck:
 453         TRACE_IRQS_IRET
 454 restore_nocheck_notrace:
 455         RESTORE_REGS
 456         addl $4, %esp                   # skip orig_eax/error_code
 457         CFI_ADJUST_CFA_OFFSET -4
 458 irq_return:
 459         INTERRUPT_RETURN
 460 .section .fixup,"ax"
 461 ENTRY(iret_exc)
 462         pushl $0                        # no error code
 463         pushl $do_iret_error
 464         jmp error_code
 465 .previous
 466 .section __ex_table,"a"
 467         .align 4
 468         .long irq_return,iret_exc
 469 .previous
 470
 471         CFI_RESTORE_STATE
 472 ldt_ss:
 473         larl PT_OLDSS(%esp), %eax
 474         jnz restore_nocheck
 475         testl $0x00400000, %eax         # returning to 32bit stack?
 476         jnz restore_nocheck             # allright, normal return
 477
 478 #ifdef CONFIG_PARAVIRT
 479         /*
 480          * The kernel can't run on a non-flat stack if paravirt mode
 481          * is active.  Rather than try to fixup the high bits of
 482          * ESP, bypass this code entirely.  This may break DOSemu
 483          * and/or Wine support in a paravirt VM, although the option
 484          * is still available to implement the setting of the high
 485          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 486          */
 487         cmpl $0, pv_info+PARAVIRT_enabled
 488         jne restore_nocheck
 489 #endif
 490
 491         /* If returning to userspace with 16bit stack,
 492          * try to fix the higher word of ESP, as the CPU
 493          * won't restore it.
 494          * This is an "official" bug of all the x86-compatible
 495          * CPUs, which we can try to work around to make
 496          * dosemu and wine happy. */
 497         movl PT_OLDESP(%esp), %eax
 498         movl %esp, %edx
 499         call patch_espfix_desc
 500         pushl $__ESPFIX_SS
 501         CFI_ADJUST_CFA_OFFSET 4
 502         pushl %eax
 503         CFI_ADJUST_CFA_OFFSET 4
 504         DISABLE_INTERRUPTS(CLBR_EAX)
 505         TRACE_IRQS_OFF
 506         lss (%esp), %esp
 507         CFI_ADJUST_CFA_OFFSET -8
 508         jmp restore_nocheck
 509         CFI_ENDPROC
 510 ENDPROC(system_call)
 511
 512         # perform work that needs to be done immediately before resumption
 513         ALIGN
 514         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 515 work_pending:
 516         testb $_TIF_NEED_RESCHED, %cl
 517         jz work_notifysig
 518 work_resched:
 519         call schedule
 520         LOCKDEP_SYS_EXIT
 521         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 522                                         # setting need_resched or sigpending
 523                                         # between sampling and the iret
 524         TRACE_IRQS_OFF
 525         movl TI_flags(%ebp), %ecx
 526         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 527                                         # than syscall tracing?
 528         jz restore_all
 529         testb $_TIF_NEED_RESCHED, %cl
 530         jnz work_resched
 531
 532 work_notifysig:                         # deal with pending signals and
 533                                         # notify-resume requests
 534 #ifdef CONFIG_VM86
 535         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 536         movl %esp, %eax
 537         jne work_notifysig_v86          # returning to kernel-space or
 538                                         # vm86-space
 539         xorl %edx, %edx
 540         call do_notify_resume
 541         jmp resume_userspace_sig
 542
 543         ALIGN
 544 work_notifysig_v86:
 545         pushl %ecx                      # save ti_flags for do_notify_resume
 546         CFI_ADJUST_CFA_OFFSET 4
 547         call save_v86_state             # %eax contains pt_regs pointer
 548         popl %ecx
 549         CFI_ADJUST_CFA_OFFSET -4
 550         movl %eax, %esp
 551 #else
 552         movl %esp, %eax
 553 #endif
 554         xorl %edx, %edx
 555         call do_notify_resume
 556         jmp resume_userspace_sig
 557 END(work_pending)
 558
 559         # perform syscall exit tracing
 560         ALIGN
 561 syscall_trace_entry:
 562         movl $-ENOSYS,PT_EAX(%esp)
 563         movl %esp, %eax
 564         call syscall_trace_enter
 565         /* What it returned is what we'll actually use.  */
 566         cmpl $(nr_syscalls), %eax
 567         jnae syscall_call
 568         jmp syscall_exit
 569 END(syscall_trace_entry)
 570
 571         # perform syscall exit tracing
 572         ALIGN
 573 syscall_exit_work:
 574         testb $_TIF_WORK_SYSCALL_EXIT, %cl
 575         jz work_pending
 576         TRACE_IRQS_ON
 577         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 578                                         # schedule() instead
 579         movl %esp, %eax
 580         call syscall_trace_leave
 581         jmp resume_userspace
 582 END(syscall_exit_work)
 583         CFI_ENDPROC
 584
 585         RING0_INT_FRAME                 # can't unwind into user space anyway
 586 syscall_fault:
 587         GET_THREAD_INFO(%ebp)
 588         movl $-EFAULT,PT_EAX(%esp)
 589         jmp resume_userspace
 590 END(syscall_fault)
 591
 592 syscall_badsys:
 593         movl $-ENOSYS,PT_EAX(%esp)
 594         jmp resume_userspace
 595 END(syscall_badsys)
 596         CFI_ENDPROC
 597
 598 #define FIXUP_ESPFIX_STACK \
 599         /* since we are on a wrong stack, we cant make it a C code :( */ \
 600         PER_CPU(gdt_page, %ebx); \
 601         GET_DESC_BASE(GDT_ENTRY_ESPFIX_SS, %ebx, %eax, %ax, %al, %ah); \
 602         addl %esp, %eax; \
 603         pushl $__KERNEL_DS; \
 604         CFI_ADJUST_CFA_OFFSET 4; \
 605         pushl %eax; \
 606         CFI_ADJUST_CFA_OFFSET 4; \
 607         lss (%esp), %esp; \
 608         CFI_ADJUST_CFA_OFFSET -8;
 609 #define UNWIND_ESPFIX_STACK \
 610         movl %ss, %eax; \
 611         /* see if on espfix stack */ \
 612         cmpw $__ESPFIX_SS, %ax; \
 613         jne 27f; \
 614         movl $__KERNEL_DS, %eax; \
 615         movl %eax, %ds; \
 616         movl %eax, %es; \
 617         /* switch to normal stack */ \
 618         FIXUP_ESPFIX_STACK; \
 619 27:;
 620
 621 /*
 622  * Build the entry stubs and pointer table with some assembler magic.
 623  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 624  * single cache line on all modern x86 implementations.
 625  */
 626 .section .init.rodata,"a"
 627 ENTRY(interrupt)
 628 .text
 629         .p2align 5
 630         .p2align CONFIG_X86_L1_CACHE_SHIFT
 631 ENTRY(irq_entries_start)
 632         RING0_INT_FRAME
 633 vector=FIRST_EXTERNAL_VECTOR
 634 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 635         .balign 32
 636   .rept 7
 637     .if vector < NR_VECTORS
 638       .if vector <> FIRST_EXTERNAL_VECTOR
 639         CFI_ADJUST_CFA_OFFSET -4
 640       .endif
 641 1:      pushl $(~vector+0x80)   /* Note: always in signed byte range */
 642         CFI_ADJUST_CFA_OFFSET 4
 643       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 644         jmp 2f
 645       .endif
 646       .previous
 647         .long 1b
 648       .text
 649 vector=vector+1
 650     .endif
 651   .endr
 652 2:      jmp common_interrupt
 653 .endr
 654 END(irq_entries_start)
 655
 656 .previous
 657 END(interrupt)
 658 .previous
 659
 660 /*
 661  * the CPU automatically disables interrupts when executing an IRQ vector,
 662  * so IRQ-flags tracing has to follow that:
 663  */
 664         .p2align CONFIG_X86_L1_CACHE_SHIFT
 665 common_interrupt:
 666         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 667         SAVE_ALL
 668         TRACE_IRQS_OFF
 669         movl %esp,%eax
 670         call do_IRQ
 671         jmp ret_from_intr
 672 ENDPROC(common_interrupt)
 673         CFI_ENDPROC
 674
 675 #define BUILD_INTERRUPT3(name, nr, fn)  \
 676 ENTRY(name)                             \
 677         RING0_INT_FRAME;                \
 678         pushl $~(nr);                   \
 679         CFI_ADJUST_CFA_OFFSET 4;        \
 680         SAVE_ALL;                       \
 681         TRACE_IRQS_OFF                  \
 682         movl %esp,%eax;                 \
 683         call fn;                        \
 684         jmp ret_from_intr;              \
 685         CFI_ENDPROC;                    \
 686 ENDPROC(name)
 687
 688 #define BUILD_INTERRUPT(name, nr)       BUILD_INTERRUPT3(name, nr, smp_##name)
 689
 690 /* The include is where all of the SMP etc. interrupts come from */
 691 #include "entry_arch.h"
 692
 693 ENTRY(coprocessor_error)
 694         RING0_INT_FRAME
 695         pushl $0
 696         CFI_ADJUST_CFA_OFFSET 4
 697         pushl $do_coprocessor_error
 698         CFI_ADJUST_CFA_OFFSET 4
 699         jmp error_code
 700         CFI_ENDPROC
 701 END(coprocessor_error)
 702
 703 ENTRY(simd_coprocessor_error)
 704         RING0_INT_FRAME
 705         pushl $0
 706         CFI_ADJUST_CFA_OFFSET 4
 707         pushl $do_simd_coprocessor_error
 708         CFI_ADJUST_CFA_OFFSET 4
 709         jmp error_code
 710         CFI_ENDPROC
 711 END(simd_coprocessor_error)
 712
 713 ENTRY(device_not_available)
 714         RING0_INT_FRAME
 715         pushl $-1                       # mark this as an int
 716         CFI_ADJUST_CFA_OFFSET 4
 717         pushl $do_device_not_available
 718         CFI_ADJUST_CFA_OFFSET 4
 719         jmp error_code
 720         CFI_ENDPROC
 721 END(device_not_available)
 722
 723 #ifdef CONFIG_PARAVIRT
 724 ENTRY(native_iret)
 725         iret
 726 .section __ex_table,"a"
 727         .align 4
 728         .long native_iret, iret_exc
 729 .previous
 730 END(native_iret)
 731
 732 ENTRY(native_irq_enable_sysexit)
 733         sti
 734         sysexit
 735 END(native_irq_enable_sysexit)
 736 #endif
 737
 738 ENTRY(overflow)
 739         RING0_INT_FRAME
 740         pushl $0
 741         CFI_ADJUST_CFA_OFFSET 4
 742         pushl $do_overflow
 743         CFI_ADJUST_CFA_OFFSET 4
 744         jmp error_code
 745         CFI_ENDPROC
 746 END(overflow)
 747
 748 ENTRY(bounds)
 749         RING0_INT_FRAME
 750         pushl $0
 751         CFI_ADJUST_CFA_OFFSET 4
 752         pushl $do_bounds
 753         CFI_ADJUST_CFA_OFFSET 4
 754         jmp error_code
 755         CFI_ENDPROC
 756 END(bounds)
 757
 758 ENTRY(invalid_op)
 759         RING0_INT_FRAME
 760         pushl $0
 761         CFI_ADJUST_CFA_OFFSET 4
 762         pushl $do_invalid_op
 763         CFI_ADJUST_CFA_OFFSET 4
 764         jmp error_code
 765         CFI_ENDPROC
 766 END(invalid_op)
 767
 768 ENTRY(coprocessor_segment_overrun)
 769         RING0_INT_FRAME
 770         pushl $0
 771         CFI_ADJUST_CFA_OFFSET 4
 772         pushl $do_coprocessor_segment_overrun
 773         CFI_ADJUST_CFA_OFFSET 4
 774         jmp error_code
 775         CFI_ENDPROC
 776 END(coprocessor_segment_overrun)
 777
 778 ENTRY(invalid_TSS)
 779         RING0_EC_FRAME
 780         pushl $do_invalid_TSS
 781         CFI_ADJUST_CFA_OFFSET 4
 782         jmp error_code
 783         CFI_ENDPROC
 784 END(invalid_TSS)
 785
 786 ENTRY(segment_not_present)
 787         RING0_EC_FRAME
 788         pushl $do_segment_not_present
 789         CFI_ADJUST_CFA_OFFSET 4
 790         jmp error_code
 791         CFI_ENDPROC
 792 END(segment_not_present)
 793
 794 ENTRY(stack_segment)
 795         RING0_EC_FRAME
 796         pushl $do_stack_segment
 797         CFI_ADJUST_CFA_OFFSET 4
 798         jmp error_code
 799         CFI_ENDPROC
 800 END(stack_segment)
 801
 802 ENTRY(alignment_check)
 803         RING0_EC_FRAME
 804         pushl $do_alignment_check
 805         CFI_ADJUST_CFA_OFFSET 4
 806         jmp error_code
 807         CFI_ENDPROC
 808 END(alignment_check)
 809
 810 ENTRY(divide_error)
 811         RING0_INT_FRAME
 812         pushl $0                        # no error code
 813         CFI_ADJUST_CFA_OFFSET 4
 814         pushl $do_divide_error
 815         CFI_ADJUST_CFA_OFFSET 4
 816         jmp error_code
 817         CFI_ENDPROC
 818 END(divide_error)
 819
 820 #ifdef CONFIG_X86_MCE
 821 ENTRY(machine_check)
 822         RING0_INT_FRAME
 823         pushl $0
 824         CFI_ADJUST_CFA_OFFSET 4
 825         pushl machine_check_vector
 826         CFI_ADJUST_CFA_OFFSET 4
 827         jmp error_code
 828         CFI_ENDPROC
 829 END(machine_check)
 830 #endif
 831
 832 ENTRY(spurious_interrupt_bug)
 833         RING0_INT_FRAME
 834         pushl $0
 835         CFI_ADJUST_CFA_OFFSET 4
 836         pushl $do_spurious_interrupt_bug
 837         CFI_ADJUST_CFA_OFFSET 4
 838         jmp error_code
 839         CFI_ENDPROC
 840 END(spurious_interrupt_bug)
 841
 842 ENTRY(kernel_thread_helper)
 843         pushl $0                # fake return address for unwinder
 844         CFI_STARTPROC
 845         movl %edx,%eax
 846         push %edx
 847         CFI_ADJUST_CFA_OFFSET 4
 848         call *%ebx
 849         push %eax
 850         CFI_ADJUST_CFA_OFFSET 4
 851         call do_exit
 852         ud2                     # padding for call trace
 853         CFI_ENDPROC
 854 ENDPROC(kernel_thread_helper)
 855
 856 #ifdef CONFIG_XEN
 857 /* Xen doesn't set %esp to be precisely what the normal sysenter
 858    entrypoint expects, so fix it up before using the normal path. */
 859 ENTRY(xen_sysenter_target)
 860         RING0_INT_FRAME
 861         addl $5*4, %esp         /* remove xen-provided frame */
 862         CFI_ADJUST_CFA_OFFSET -5*4
 863         jmp sysenter_past_esp
 864         CFI_ENDPROC
 865
 866 ENTRY(xen_hypervisor_callback)
 867         CFI_STARTPROC
 868         pushl $0
 869         CFI_ADJUST_CFA_OFFSET 4
 870         SAVE_ALL
 871         TRACE_IRQS_OFF
 872
 873         /* Check to see if we got the event in the critical
 874            region in xen_iret_direct, after we've reenabled
 875            events and checked for pending events.  This simulates
 876            iret instruction's behaviour where it delivers a
 877            pending interrupt when enabling interrupts. */
 878         movl PT_EIP(%esp),%eax
 879         cmpl $xen_iret_start_crit,%eax
 880         jb   1f
 881         cmpl $xen_iret_end_crit,%eax
 882         jae  1f
 883
 884         jmp  xen_iret_crit_fixup
 885
 886 ENTRY(xen_do_upcall)
 887 1:      mov %esp, %eax
 888         call xen_evtchn_do_upcall
 889         jmp  ret_from_intr
 890         CFI_ENDPROC
 891 ENDPROC(xen_hypervisor_callback)
 892
 893 # Hypervisor uses this for application faults while it executes.
 894 # We get here for two reasons:
 895 #  1. Fault while reloading DS, ES, FS or GS
 896 #  2. Fault while executing IRET
 897 # Category 1 we fix up by reattempting the load, and zeroing the segment
 898 # register if the load fails.
 899 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
 900 # normal Linux return path in this case because if we use the IRET hypercall
 901 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
 902 # We distinguish between categories by maintaining a status value in EAX.
 903 ENTRY(xen_failsafe_callback)
 904         CFI_STARTPROC
 905         pushl %eax
 906         CFI_ADJUST_CFA_OFFSET 4
 907         movl $1,%eax
 908 1:      mov 4(%esp),%ds
 909 2:      mov 8(%esp),%es
 910 3:      mov 12(%esp),%fs
 911 4:      mov 16(%esp),%gs
 912         testl %eax,%eax
 913         popl %eax
 914         CFI_ADJUST_CFA_OFFSET -4
 915         lea 16(%esp),%esp
 916         CFI_ADJUST_CFA_OFFSET -16
 917         jz 5f
 918         addl $16,%esp
 919         jmp iret_exc            # EAX != 0 => Category 2 (Bad IRET)
 920 5:      pushl $0                # EAX == 0 => Category 1 (Bad segment)
 921         CFI_ADJUST_CFA_OFFSET 4
 922         SAVE_ALL
 923         jmp ret_from_exception
 924         CFI_ENDPROC
 925
 926 .section .fixup,"ax"
 927 6:      xorl %eax,%eax
 928         movl %eax,4(%esp)
 929         jmp 1b
 930 7:      xorl %eax,%eax
 931         movl %eax,8(%esp)
 932         jmp 2b
 933 8:      xorl %eax,%eax
 934         movl %eax,12(%esp)
 935         jmp 3b
 936 9:      xorl %eax,%eax
 937         movl %eax,16(%esp)
 938         jmp 4b
 939 .previous
 940 .section __ex_table,"a"
 941         .align 4
 942         .long 1b,6b
 943         .long 2b,7b
 944         .long 3b,8b
 945         .long 4b,9b
 946 .previous
 947 ENDPROC(xen_failsafe_callback)
 948
 949 #endif  /* CONFIG_XEN */
 950
 951 #ifdef CONFIG_FUNCTION_TRACER
 952 #ifdef CONFIG_DYNAMIC_FTRACE
 953
 954 ENTRY(mcount)
 955         ret
 956 END(mcount)
 957
 958 ENTRY(ftrace_caller)
 959         cmpl $0, function_trace_stop
 960         jne  ftrace_stub
 961
 962         pushl %eax
 963         pushl %ecx
 964         pushl %edx
 965         movl 0xc(%esp), %eax
 966         movl 0x4(%ebp), %edx
 967         subl $MCOUNT_INSN_SIZE, %eax
 968
 969 .globl ftrace_call
 970 ftrace_call:
 971         call ftrace_stub
 972
 973         popl %edx
 974         popl %ecx
 975         popl %eax
 976 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 977 .globl ftrace_graph_call
 978 ftrace_graph_call:
 979         jmp ftrace_stub
 980 #endif
 981
 982 .globl ftrace_stub
 983 ftrace_stub:
 984         ret
 985 END(ftrace_caller)
 986
 987 #else /* ! CONFIG_DYNAMIC_FTRACE */
 988
 989 ENTRY(mcount)
 990         cmpl $0, function_trace_stop
 991         jne  ftrace_stub
 992
 993         cmpl $ftrace_stub, ftrace_trace_function
 994         jnz trace
 995 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 996         cmpl $ftrace_stub, ftrace_graph_return
 997         jnz ftrace_graph_caller
 998
 999         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1000         jnz ftrace_graph_caller
1001 #endif
1002 .globl ftrace_stub
1003 ftrace_stub:
1004         ret
1005
1006         /* taken from glibc */
1007 trace:
1008         pushl %eax
1009         pushl %ecx
1010         pushl %edx
1011         movl 0xc(%esp), %eax
1012         movl 0x4(%ebp), %edx
1013         subl $MCOUNT_INSN_SIZE, %eax
1014
1015         call *ftrace_trace_function
1016
1017         popl %edx
1018         popl %ecx
1019         popl %eax
1020         jmp ftrace_stub
1021 END(mcount)
1022 #endif /* CONFIG_DYNAMIC_FTRACE */
1023 #endif /* CONFIG_FUNCTION_TRACER */
1024
1025 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1026 ENTRY(ftrace_graph_caller)
1027         cmpl $0, function_trace_stop
1028         jne ftrace_stub
1029
1030         pushl %eax
1031         pushl %ecx
1032         pushl %edx
1033         movl 0xc(%esp), %edx
1034         lea 0x4(%ebp), %eax
1035         subl $MCOUNT_INSN_SIZE, %edx
1036         call prepare_ftrace_return
1037         popl %edx
1038         popl %ecx
1039         popl %eax
1040         ret
1041 END(ftrace_graph_caller)
1042
1043 .globl return_to_handler
1044 return_to_handler:
1045         pushl $0
1046         pushl %eax
1047         pushl %ecx
1048         pushl %edx
1049         call ftrace_return_to_handler
1050         movl %eax, 0xc(%esp)
1051         popl %edx
1052         popl %ecx
1053         popl %eax
1054         ret
1055 #endif
1056
1057 .section .rodata,"a"
1058 #include "syscall_table_32.S"
1059
1060 syscall_table_size=(.-sys_call_table)
1061
1062 /*
1063  * Some functions should be protected against kprobes
1064  */
1065         .pushsection .kprobes.text, "ax"
1066
1067 ENTRY(page_fault)
1068         RING0_EC_FRAME
1069         pushl $do_page_fault
1070         CFI_ADJUST_CFA_OFFSET 4
1071         ALIGN
1072 error_code:
1073         /* the function address is in %fs's slot on the stack */
1074         pushl %es
1075         CFI_ADJUST_CFA_OFFSET 4
1076         /*CFI_REL_OFFSET es, 0*/
1077         pushl %ds
1078         CFI_ADJUST_CFA_OFFSET 4
1079         /*CFI_REL_OFFSET ds, 0*/
1080         pushl %eax
1081         CFI_ADJUST_CFA_OFFSET 4
1082         CFI_REL_OFFSET eax, 0
1083         pushl %ebp
1084         CFI_ADJUST_CFA_OFFSET 4
1085         CFI_REL_OFFSET ebp, 0
1086         pushl %edi
1087         CFI_ADJUST_CFA_OFFSET 4
1088         CFI_REL_OFFSET edi, 0
1089         pushl %esi
1090         CFI_ADJUST_CFA_OFFSET 4
1091         CFI_REL_OFFSET esi, 0
1092         pushl %edx
1093         CFI_ADJUST_CFA_OFFSET 4
1094         CFI_REL_OFFSET edx, 0
1095         pushl %ecx
1096         CFI_ADJUST_CFA_OFFSET 4
1097         CFI_REL_OFFSET ecx, 0
1098         pushl %ebx
1099         CFI_ADJUST_CFA_OFFSET 4
1100         CFI_REL_OFFSET ebx, 0
1101         cld
1102         pushl %fs
1103         CFI_ADJUST_CFA_OFFSET 4
1104         /*CFI_REL_OFFSET fs, 0*/
1105         movl $(__KERNEL_PERCPU), %ecx
1106         movl %ecx, %fs
1107         UNWIND_ESPFIX_STACK
1108         popl %ecx
1109         CFI_ADJUST_CFA_OFFSET -4
1110         /*CFI_REGISTER es, ecx*/
1111         movl PT_FS(%esp), %edi          # get the function address
1112         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1113         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1114         mov  %ecx, PT_FS(%esp)
1115         /*CFI_REL_OFFSET fs, ES*/
1116         movl $(__USER_DS), %ecx
1117         movl %ecx, %ds
1118         movl %ecx, %es
1119         TRACE_IRQS_OFF
1120         movl %esp,%eax                  # pt_regs pointer
1121         call *%edi
1122         jmp ret_from_exception
1123         CFI_ENDPROC
1124 END(page_fault)
1125
1126 /*
1127  * Debug traps and NMI can happen at the one SYSENTER instruction
1128  * that sets up the real kernel stack. Check here, since we can't
1129  * allow the wrong stack to be used.
1130  *
1131  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1132  * already pushed 3 words if it hits on the sysenter instruction:
1133  * eflags, cs and eip.
1134  *
1135  * We just load the right stack, and push the three (known) values
1136  * by hand onto the new stack - while updating the return eip past
1137  * the instruction that would have done it for sysenter.
1138  */
1139 #define FIX_STACK(offset, ok, label)            \
1140         cmpw $__KERNEL_CS,4(%esp);              \
1141         jne ok;                                 \
1142 label:                                          \
1143         movl TSS_sysenter_sp0+offset(%esp),%esp;        \
1144         CFI_DEF_CFA esp, 0;                     \
1145         CFI_UNDEFINED eip;                      \
1146         pushfl;                                 \
1147         CFI_ADJUST_CFA_OFFSET 4;                \
1148         pushl $__KERNEL_CS;                     \
1149         CFI_ADJUST_CFA_OFFSET 4;                \
1150         pushl $sysenter_past_esp;               \
1151         CFI_ADJUST_CFA_OFFSET 4;                \
1152         CFI_REL_OFFSET eip, 0
1153
1154 ENTRY(debug)
1155         RING0_INT_FRAME
1156         cmpl $ia32_sysenter_target,(%esp)
1157         jne debug_stack_correct
1158         FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
1159 debug_stack_correct:
1160         pushl $-1                       # mark this as an int
1161         CFI_ADJUST_CFA_OFFSET 4
1162         SAVE_ALL
1163         TRACE_IRQS_OFF
1164         xorl %edx,%edx                  # error code 0
1165         movl %esp,%eax                  # pt_regs pointer
1166         call do_debug
1167         jmp ret_from_exception
1168         CFI_ENDPROC
1169 END(debug)
1170
1171 /*
1172  * NMI is doubly nasty. It can happen _while_ we're handling
1173  * a debug fault, and the debug fault hasn't yet been able to
1174  * clear up the stack. So we first check whether we got  an
1175  * NMI on the sysenter entry path, but after that we need to
1176  * check whether we got an NMI on the debug path where the debug
1177  * fault happened on the sysenter path.
1178  */
1179 ENTRY(nmi)
1180         RING0_INT_FRAME
1181         pushl %eax
1182         CFI_ADJUST_CFA_OFFSET 4
1183         movl %ss, %eax
1184         cmpw $__ESPFIX_SS, %ax
1185         popl %eax
1186         CFI_ADJUST_CFA_OFFSET -4
1187         je nmi_espfix_stack
1188         cmpl $ia32_sysenter_target,(%esp)
1189         je nmi_stack_fixup
1190         pushl %eax
1191         CFI_ADJUST_CFA_OFFSET 4
1192         movl %esp,%eax
1193         /* Do not access memory above the end of our stack page,
1194          * it might not exist.
1195          */
1196         andl $(THREAD_SIZE-1),%eax
1197         cmpl $(THREAD_SIZE-20),%eax
1198         popl %eax
1199         CFI_ADJUST_CFA_OFFSET -4
1200         jae nmi_stack_correct
1201         cmpl $ia32_sysenter_target,12(%esp)
1202         je nmi_debug_stack_check
1203 nmi_stack_correct:
1204         /* We have a RING0_INT_FRAME here */
1205         pushl %eax
1206         CFI_ADJUST_CFA_OFFSET 4
1207         SAVE_ALL
1208         xorl %edx,%edx          # zero error code
1209         movl %esp,%eax          # pt_regs pointer
1210         call do_nmi
1211         jmp restore_nocheck_notrace
1212         CFI_ENDPROC
1213
1214 nmi_stack_fixup:
1215         RING0_INT_FRAME
1216         FIX_STACK(12,nmi_stack_correct, 1)
1217         jmp nmi_stack_correct
1218
1219 nmi_debug_stack_check:
1220         /* We have a RING0_INT_FRAME here */
1221         cmpw $__KERNEL_CS,16(%esp)
1222         jne nmi_stack_correct
1223         cmpl $debug,(%esp)
1224         jb nmi_stack_correct
1225         cmpl $debug_esp_fix_insn,(%esp)
1226         ja nmi_stack_correct
1227         FIX_STACK(24,nmi_stack_correct, 1)
1228         jmp nmi_stack_correct
1229
1230 nmi_espfix_stack:
1231         /* We have a RING0_INT_FRAME here.
1232          *
1233          * create the pointer to lss back
1234          */
1235         pushl %ss
1236         CFI_ADJUST_CFA_OFFSET 4
1237         pushl %esp
1238         CFI_ADJUST_CFA_OFFSET 4
1239         addw $4, (%esp)
1240         /* copy the iret frame of 12 bytes */
1241         .rept 3
1242         pushl 16(%esp)
1243         CFI_ADJUST_CFA_OFFSET 4
1244         .endr
1245         pushl %eax
1246         CFI_ADJUST_CFA_OFFSET 4
1247         SAVE_ALL
1248         FIXUP_ESPFIX_STACK              # %eax == %esp
1249         xorl %edx,%edx                  # zero error code
1250         call do_nmi
1251         RESTORE_REGS
1252         lss 12+4(%esp), %esp            # back to espfix stack
1253         CFI_ADJUST_CFA_OFFSET -24
1254         jmp irq_return
1255         CFI_ENDPROC
1256 END(nmi)
1257
1258 ENTRY(int3)
1259         RING0_INT_FRAME
1260         pushl $-1                       # mark this as an int
1261         CFI_ADJUST_CFA_OFFSET 4
1262         SAVE_ALL
1263         TRACE_IRQS_OFF
1264         xorl %edx,%edx          # zero error code
1265         movl %esp,%eax          # pt_regs pointer
1266         call do_int3
1267         jmp ret_from_exception
1268         CFI_ENDPROC
1269 END(int3)
1270
1271 ENTRY(general_protection)
1272         RING0_EC_FRAME
1273         pushl $do_general_protection
1274         CFI_ADJUST_CFA_OFFSET 4
1275         jmp error_code
1276         CFI_ENDPROC
1277 END(general_protection)
1278
1279 /*
1280  * End of kprobes section
1281  */
1282         .popsection