git.oblomov.eu Git - linux-2.6/blob - arch/parisc/kernel/real2.S

   1 /*
   2  *
   3  * This file is subject to the terms and conditions of the GNU General Public
   4  * License.  See the file "COPYING" in the main directory of this archive
   5  * for more details.
   6  *
   7  * Copyright (C) 2000 Hewlett Packard (Paul Bame bame@puffin.external.hp.com)
   8  *
   9  */
  10 #include <linux/config.h>
  11
  12 #include <asm/psw.h>
  13 #include <asm/assembly.h>
  14
  15         .section        .bss
  16         .export real_stack
  17         .export real32_stack
  18         .export real64_stack
  19         .align  64
  20 real_stack:
  21 real32_stack:
  22 real64_stack:
  23         .block  8192
  24
  25 #ifdef CONFIG_64BIT
  26 #  define REG_SZ 8
  27 #else
  28 #  define REG_SZ 4
  29 #endif
  30
  31 #define N_SAVED_REGS 9
  32
  33 save_cr_space:
  34         .block  REG_SZ * N_SAVED_REGS
  35 save_cr_end:
  36
  37
  38 /************************ 32-bit real-mode calls ***********************/
  39 /* This can be called in both narrow and wide kernels */
  40
  41         .text
  42
  43         .export real32_call_asm
  44
  45         /* unsigned long real32_call_asm(unsigned int *sp,
  46          *              unsigned int *arg0p,
  47          *              unsigned int iodc_fn)
  48          *      sp is value of stack pointer to adopt before calling PDC (virt)
  49          *      arg0p points to where saved arg values may be found
  50          *      iodc_fn is the IODC function to call
  51          */
  52
  53 real32_call_asm:
  54         STREG   %rp, -RP_OFFSET(%sp)    /* save RP */
  55 #ifdef CONFIG_64BIT
  56         callee_save
  57         ldo     2*REG_SZ(%sp), %sp      /* room for a couple more saves */
  58         STREG   %r27, -1*REG_SZ(%sp)
  59         STREG   %r29, -2*REG_SZ(%sp)
  60 #endif
  61         STREG   %sp, -REG_SZ(%arg0)     /* save SP on real-mode stack */
  62         copy    %arg0, %sp              /* adopt the real-mode SP */
  63
  64         /* save iodc_fn */
  65         copy    %arg2, %r31
  66
  67         /* load up the arg registers from the saved arg area */
  68         /* 32-bit calling convention passes first 4 args in registers */
  69         ldw     0(%arg1), %arg0         /* note overwriting arg0 */
  70         ldw     -8(%arg1), %arg2
  71         ldw     -12(%arg1), %arg3
  72         ldw     -4(%arg1), %arg1        /* obviously must do this one last! */
  73
  74         tophys_r1  %sp
  75
  76         b,l     rfi_virt2real,%r2
  77         nop
  78
  79         b,l     save_control_regs,%r2           /* modifies r1, r2, r28 */
  80         nop
  81
  82 #ifdef CONFIG_64BIT
  83         rsm     PSW_SM_W, %r0           /* go narrow */
  84 #endif
  85
  86         load32  PA(ric_ret), %r2
  87         bv      0(%r31)
  88         nop
  89 ric_ret:
  90 #ifdef CONFIG_64BIT
  91         ssm     PSW_SM_W, %r0           /* go wide */
  92 #endif
  93         /* restore CRs before going virtual in case we page fault */
  94         b,l     restore_control_regs, %r2       /* modifies r1, r2, r26 */
  95         nop
  96
  97         b,l     rfi_real2virt,%r2
  98         nop
  99
 100         tovirt_r1 %sp
 101         LDREG   -REG_SZ(%sp), %sp       /* restore SP */
 102 #ifdef CONFIG_64BIT
 103         LDREG   -1*REG_SZ(%sp), %r27
 104         LDREG   -2*REG_SZ(%sp), %r29
 105         ldo     -2*REG_SZ(%sp), %sp
 106         callee_rest
 107 #endif
 108         LDREG   -RP_OFFSET(%sp), %rp    /* restore RP */
 109         bv      0(%rp)
 110         nop
 111
 112
 113 #  define PUSH_CR(r, where) mfctl r, %r1 ! STREG,ma %r1, REG_SZ(where)
 114 #  define POP_CR(r, where) LDREG,mb -REG_SZ(where), %r1 ! mtctl %r1, r
 115
 116         .text
 117 save_control_regs:
 118         load32  PA(save_cr_space), %r28
 119         PUSH_CR(%cr24, %r28)
 120         PUSH_CR(%cr25, %r28)
 121         PUSH_CR(%cr26, %r28)
 122         PUSH_CR(%cr27, %r28)
 123         PUSH_CR(%cr28, %r28)
 124         PUSH_CR(%cr29, %r28)
 125         PUSH_CR(%cr30, %r28)
 126         PUSH_CR(%cr31, %r28)
 127         PUSH_CR(%cr15, %r28)
 128         bv 0(%r2)
 129         nop
 130
 131 restore_control_regs:
 132         load32  PA(save_cr_end), %r26
 133         POP_CR(%cr15, %r26)
 134         POP_CR(%cr31, %r26)
 135         POP_CR(%cr30, %r26)
 136         POP_CR(%cr29, %r26)
 137         POP_CR(%cr28, %r26)
 138         POP_CR(%cr27, %r26)
 139         POP_CR(%cr26, %r26)
 140         POP_CR(%cr25, %r26)
 141         POP_CR(%cr24, %r26)
 142         bv 0(%r2)
 143         nop
 144
 145 /* rfi_virt2real() and rfi_real2virt() could perhaps be adapted for
 146  * more general-purpose use by the several places which need RFIs
 147  */
 148         .text
 149         .align 128
 150 rfi_virt2real:
 151         /* switch to real mode... */
 152         rsm             PSW_SM_I,%r0
 153         load32          PA(rfi_v2r_1), %r1
 154         nop
 155         nop
 156         nop
 157         nop
 158         nop
 159
 160         rsm             PSW_SM_Q,%r0  /* disable Q & I bits to load iia queue */
 161         mtctl           %r0, %cr17      /* Clear IIASQ tail */
 162         mtctl           %r0, %cr17      /* Clear IIASQ head */
 163         mtctl           %r1, %cr18      /* IIAOQ head */
 164         ldo             4(%r1), %r1
 165         mtctl           %r1, %cr18      /* IIAOQ tail */
 166         load32          REAL_MODE_PSW, %r1
 167         mtctl           %r1, %cr22
 168         rfi
 169
 170         nop
 171         nop
 172         nop
 173         nop
 174         nop
 175         nop
 176         nop
 177         nop
 178 rfi_v2r_1:
 179         tophys_r1 %r2
 180         bv      0(%r2)
 181         nop
 182
 183         .text
 184         .align 128
 185 rfi_real2virt:
 186         rsm             PSW_SM_I,%r0
 187         load32          (rfi_r2v_1), %r1
 188         nop
 189         nop
 190         nop
 191         nop
 192         nop
 193
 194         rsm             PSW_SM_Q,%r0    /* disable Q bit to load iia queue */
 195         mtctl           %r0, %cr17      /* Clear IIASQ tail */
 196         mtctl           %r0, %cr17      /* Clear IIASQ head */
 197         mtctl           %r1, %cr18      /* IIAOQ head */
 198         ldo             4(%r1), %r1
 199         mtctl           %r1, %cr18      /* IIAOQ tail */
 200         load32          KERNEL_PSW, %r1
 201         mtctl           %r1, %cr22
 202         rfi
 203
 204         nop
 205         nop
 206         nop
 207         nop
 208         nop
 209         nop
 210         nop
 211         nop
 212 rfi_r2v_1:
 213         tovirt_r1 %r2
 214         bv      0(%r2)
 215         nop
 216
 217 #ifdef CONFIG_64BIT
 218
 219 /************************ 64-bit real-mode calls ***********************/
 220 /* This is only usable in wide kernels right now and will probably stay so */
 221         .text
 222         .export real64_call_asm
 223         /* unsigned long real64_call_asm(unsigned long *sp,
 224          *              unsigned long *arg0p,
 225          *              unsigned long fn)
 226          *      sp is value of stack pointer to adopt before calling PDC (virt)
 227          *      arg0p points to where saved arg values may be found
 228          *      iodc_fn is the IODC function to call
 229          */
 230 real64_call_asm:
 231         std     %rp, -0x10(%sp)         /* save RP */
 232         std     %sp, -8(%arg0)          /* save SP on real-mode stack */
 233         copy    %arg0, %sp              /* adopt the real-mode SP */
 234
 235         /* save fn */
 236         copy    %arg2, %r31
 237
 238         /* set up the new ap */
 239         ldo     64(%arg1), %r29
 240
 241         /* load up the arg registers from the saved arg area */
 242         /* 32-bit calling convention passes first 4 args in registers */
 243         ldd     0*REG_SZ(%arg1), %arg0          /* note overwriting arg0 */
 244         ldd     2*REG_SZ(%arg1), %arg2
 245         ldd     3*REG_SZ(%arg1), %arg3
 246         ldd     4*REG_SZ(%arg1), %r22
 247         ldd     5*REG_SZ(%arg1), %r21
 248         ldd     6*REG_SZ(%arg1), %r20
 249         ldd     7*REG_SZ(%arg1), %r19
 250         ldd     1*REG_SZ(%arg1), %arg1          /* do this one last! */
 251
 252         tophys_r1 %sp
 253
 254         b,l     rfi_virt2real,%r2
 255         nop
 256
 257         b,l     save_control_regs,%r2           /* modifies r1, r2, r28 */
 258         nop
 259
 260         load32  PA(r64_ret), %r2
 261         bv      0(%r31)
 262         nop
 263 r64_ret:
 264         /* restore CRs before going virtual in case we page fault */
 265         b,l     restore_control_regs, %r2       /* modifies r1, r2, r26 */
 266         nop
 267
 268         b,l     rfi_real2virt,%r2
 269         nop
 270
 271         tovirt_r1 %sp
 272         ldd     -8(%sp), %sp            /* restore SP */
 273         ldd     -0x10(%sp), %rp         /* restore RP */
 274         bv      0(%rp)
 275         nop
 276
 277 #endif
 278
 279         .export pc_in_user_space
 280         .text
 281         /* Doesn't belong here but I couldn't find a nicer spot. */
 282         /* Should never get called, only used by profile stuff in time.c */
 283 pc_in_user_space:
 284         bv,n    0(%rp)
 285         nop
 286
 287
 288         .export __canonicalize_funcptr_for_compare
 289         .text
 290         /* http://lists.parisc-linux.org/hypermail/parisc-linux/10916.html
 291         **      GCC 3.3 and later has a new function in libgcc.a for
 292         **      comparing function pointers.
 293         */
 294 __canonicalize_funcptr_for_compare:
 295 #ifdef CONFIG_64BIT
 296         bve (%r2)
 297 #else
 298         bv %r0(%r2)
 299 #endif
 300         copy %r26,%r28