git.oblomov.eu Git - linux-2.6/blob - arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9 #include <linux/config.h>
  10
  11 #undef i386     /* in case the preprocessor is a 32bit one */
  12
  13 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  14 OUTPUT_ARCH(i386:x86-64)
  15 ENTRY(phys_startup_64)
  16 jiffies_64 = jiffies;
  17 SECTIONS
  18 {
  19   . = __START_KERNEL;
  20   phys_startup_64 = startup_64 - LOAD_OFFSET;
  21   _text = .;                    /* Text and read-only data */
  22   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  23         /* First the code that has to be first for bootstrapping */
  24         *(.bootstrap.text)
  25         /* Then all the functions that are "hot" in profiles, to group them
  26            onto the same hugetlb entry */
  27         #include "functionlist"
  28         /* Then the rest */
  29         *(.text)
  30         SCHED_TEXT
  31         LOCK_TEXT
  32         KPROBES_TEXT
  33         *(.fixup)
  34         *(.gnu.warning)
  35         } = 0x9090
  36                                 /* out-of-line lock text */
  37   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  38
  39   _etext = .;                   /* End of text section */
  40
  41   . = ALIGN(16);                /* Exception table */
  42   __start___ex_table = .;
  43   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  44   __stop___ex_table = .;
  45
  46   RODATA
  47
  48                                 /* Data */
  49   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  50         *(.data)
  51         CONSTRUCTORS
  52         }
  53
  54   _edata = .;                   /* End of data section */
  55
  56   __bss_start = .;              /* BSS */
  57   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
  58         *(.bss.page_aligned)
  59         *(.bss)
  60         }
  61   __bss_stop = .;
  62
  63   . = ALIGN(PAGE_SIZE);
  64   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  65   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  66         *(.data.cacheline_aligned)
  67   }
  68   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  69   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  70         *(.data.read_mostly)
  71   }
  72
  73 #define VSYSCALL_ADDR (-10*1024*1024)
  74 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  75 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  76
  77 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  78 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  79
  80 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  81 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  82
  83   . = VSYSCALL_ADDR;
  84   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) }
  85   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  86
  87   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  88   .xtime_lock : AT(VLOAD(.xtime_lock)) { *(.xtime_lock) }
  89   xtime_lock = VVIRT(.xtime_lock);
  90
  91   .vxtime : AT(VLOAD(.vxtime)) { *(.vxtime) }
  92   vxtime = VVIRT(.vxtime);
  93
  94   .wall_jiffies : AT(VLOAD(.wall_jiffies)) { *(.wall_jiffies) }
  95   wall_jiffies = VVIRT(.wall_jiffies);
  96
  97   .sys_tz : AT(VLOAD(.sys_tz)) { *(.sys_tz) }
  98   sys_tz = VVIRT(.sys_tz);
  99
 100   .sysctl_vsyscall : AT(VLOAD(.sysctl_vsyscall)) { *(.sysctl_vsyscall) }
 101   sysctl_vsyscall = VVIRT(.sysctl_vsyscall);
 102
 103   .xtime : AT(VLOAD(.xtime)) { *(.xtime) }
 104   xtime = VVIRT(.xtime);
 105
 106   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 107   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 108   jiffies = VVIRT(.jiffies);
 109
 110   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) { *(.vsyscall_1) }
 111   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) { *(.vsyscall_2) }
 112   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) { *(.vsyscall_3) }
 113
 114   . = VSYSCALL_VIRT_ADDR + 4096;
 115
 116 #undef VSYSCALL_ADDR
 117 #undef VSYSCALL_PHYS_ADDR
 118 #undef VSYSCALL_VIRT_ADDR
 119 #undef VLOAD_OFFSET
 120 #undef VLOAD
 121 #undef VVIRT_OFFSET
 122 #undef VVIRT
 123
 124   . = ALIGN(8192);              /* init_task */
 125   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 126         *(.data.init_task)
 127   }
 128
 129   . = ALIGN(4096);
 130   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 131         *(.data.page_aligned)
 132   }
 133
 134   . = ALIGN(4096);              /* Init code and data */
 135   __init_begin = .;
 136   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 137         _sinittext = .;
 138         *(.init.text)
 139         _einittext = .;
 140   }
 141   __initdata_begin = .;
 142   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 143   __initdata_end = .;
 144   . = ALIGN(16);
 145   __setup_start = .;
 146   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 147   __setup_end = .;
 148   __initcall_start = .;
 149   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 150         *(.initcall1.init)
 151         *(.initcall2.init)
 152         *(.initcall3.init)
 153         *(.initcall4.init)
 154         *(.initcall5.init)
 155         *(.initcall6.init)
 156         *(.initcall7.init)
 157   }
 158   __initcall_end = .;
 159   __con_initcall_start = .;
 160   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 161         *(.con_initcall.init)
 162   }
 163   __con_initcall_end = .;
 164   SECURITY_INIT
 165   . = ALIGN(8);
 166   __alt_instructions = .;
 167   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 168         *(.altinstructions)
 169   }
 170   __alt_instructions_end = .;
 171   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 172         *(.altinstr_replacement)
 173   }
 174   /* .exit.text is discard at runtime, not link time, to deal with references
 175      from .altinstructions and .eh_frame */
 176   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 177   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 178   . = ALIGN(4096);
 179   __initramfs_start = .;
 180   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 181   __initramfs_end = .;
 182   /* temporary here to work around NR_CPUS. If you see this comment in 2.6.17+
 183    complain */
 184   . = ALIGN(4096);
 185   __init_end = .;
 186   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 187   __per_cpu_start = .;
 188   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 189   __per_cpu_end = .;
 190
 191   . = ALIGN(4096);
 192   __nosave_begin = .;
 193   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 194   . = ALIGN(4096);
 195   __nosave_end = .;
 196
 197   _end = . ;
 198
 199   /* Sections to be discarded */
 200   /DISCARD/ : {
 201         *(.exitcall.exit)
 202 #ifndef CONFIG_UNWIND_INFO
 203         *(.eh_frame)
 204 #endif
 205         }
 206
 207   STABS_DEBUG
 208
 209   DWARF_DEBUG
 210 }