git.oblomov.eu Git - linux-2.6/blob - arch/powerpc/kernel/vdso64/gettimeofday.S

   1
   2         /*
   3  * Userland implementation of gettimeofday() for 64 bits processes in a
   4  * ppc64 kernel for use in the vDSO
   5  *
   6  * Copyright (C) 2004 Benjamin Herrenschmuidt (benh@kernel.crashing.org),
   7  *                    IBM Corp.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License
  11  * as published by the Free Software Foundation; either version
  12  * 2 of the License, or (at your option) any later version.
  13  */
  14 #include <linux/config.h>
  15 #include <asm/processor.h>
  16 #include <asm/ppc_asm.h>
  17 #include <asm/vdso.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/unistd.h>
  20
  21         .text
  22 /*
  23  * Exact prototype of gettimeofday
  24  *
  25  * int __kernel_gettimeofday(struct timeval *tv, struct timezone *tz);
  26  *
  27  */
  28 V_FUNCTION_BEGIN(__kernel_gettimeofday)
  29   .cfi_startproc
  30         mflr    r12
  31   .cfi_register lr,r12
  32
  33         mr      r11,r3                  /* r11 holds tv */
  34         mr      r10,r4                  /* r10 holds tz */
  35         bl      V_LOCAL_FUNC(__get_datapage)    /* get data page */
  36         bl      V_LOCAL_FUNC(__do_get_xsec)     /* get xsec from tb & kernel */
  37         lis     r7,15                   /* r7 = 1000000 = USEC_PER_SEC */
  38         ori     r7,r7,16960
  39         rldicl  r5,r4,44,20             /* r5 = sec = xsec / XSEC_PER_SEC */
  40         rldicr  r6,r5,20,43             /* r6 = sec * XSEC_PER_SEC */
  41         std     r5,TVAL64_TV_SEC(r11)   /* store sec in tv */
  42         subf    r0,r6,r4                /* r0 = xsec = (xsec - r6) */
  43         mulld   r0,r0,r7                /* usec = (xsec * USEC_PER_SEC) /
  44                                          * XSEC_PER_SEC
  45                                          */
  46         rldicl  r0,r0,44,20
  47         cmpldi  cr0,r10,0               /* check if tz is NULL */
  48         std     r0,TVAL64_TV_USEC(r11)  /* store usec in tv */
  49         beq     1f
  50         lwz     r4,CFG_TZ_MINUTEWEST(r3)/* fill tz */
  51         lwz     r5,CFG_TZ_DSTTIME(r3)
  52         stw     r4,TZONE_TZ_MINWEST(r10)
  53         stw     r5,TZONE_TZ_DSTTIME(r10)
  54 1:      mtlr    r12
  55         li      r3,0                    /* always success */
  56         blr
  57   .cfi_endproc
  58 V_FUNCTION_END(__kernel_gettimeofday)
  59
  60
  61 /*
  62  * Exact prototype of clock_gettime()
  63  *
  64  * int __kernel_clock_gettime(clockid_t clock_id, struct timespec *tp);
  65  *
  66  */
  67 V_FUNCTION_BEGIN(__kernel_clock_gettime)
  68   .cfi_startproc
  69         /* Check for supported clock IDs */
  70         cmpwi   cr0,r3,CLOCK_REALTIME
  71         cmpwi   cr1,r3,CLOCK_MONOTONIC
  72         cror    cr0*4+eq,cr0*4+eq,cr1*4+eq
  73         bne     cr0,99f
  74
  75         mflr    r12                     /* r12 saves lr */
  76   .cfi_register lr,r12
  77         mr      r10,r3                  /* r10 saves id */
  78         mr      r11,r4                  /* r11 saves tp */
  79         bl      V_LOCAL_FUNC(__get_datapage)    /* get data page */
  80         beq     cr1,50f                 /* if monotonic -> jump there */
  81
  82         /*
  83          * CLOCK_REALTIME
  84          */
  85
  86         bl      V_LOCAL_FUNC(__do_get_xsec)     /* get xsec from tb & kernel */
  87
  88         lis     r7,15                   /* r7 = 1000000 = USEC_PER_SEC */
  89         ori     r7,r7,16960
  90         rldicl  r5,r4,44,20             /* r5 = sec = xsec / XSEC_PER_SEC */
  91         rldicr  r6,r5,20,43             /* r6 = sec * XSEC_PER_SEC */
  92         std     r5,TSPC64_TV_SEC(r11)   /* store sec in tv */
  93         subf    r0,r6,r4                /* r0 = xsec = (xsec - r6) */
  94         mulld   r0,r0,r7                /* usec = (xsec * USEC_PER_SEC) /
  95                                          * XSEC_PER_SEC
  96                                          */
  97         rldicl  r0,r0,44,20
  98         mulli   r0,r0,1000              /* nsec = usec * 1000 */
  99         std     r0,TSPC64_TV_NSEC(r11)  /* store nsec in tp */
 100
 101         mtlr    r12
 102         li      r3,0
 103         blr
 104
 105         /*
 106          * CLOCK_MONOTONIC
 107          */
 108
 109 50:     bl      V_LOCAL_FUNC(__do_get_xsec)     /* get xsec from tb & kernel */
 110
 111         lis     r7,15                   /* r7 = 1000000 = USEC_PER_SEC */
 112         ori     r7,r7,16960
 113         rldicl  r5,r4,44,20             /* r5 = sec = xsec / XSEC_PER_SEC */
 114         rldicr  r6,r5,20,43             /* r6 = sec * XSEC_PER_SEC */
 115         subf    r0,r6,r4                /* r0 = xsec = (xsec - r6) */
 116         mulld   r0,r0,r7                /* usec = (xsec * USEC_PER_SEC) /
 117                                          * XSEC_PER_SEC
 118                                          */
 119         rldicl  r6,r0,44,20
 120         mulli   r6,r6,1000              /* nsec = usec * 1000 */
 121
 122         /* now we must fixup using wall to monotonic. We need to snapshot
 123          * that value and do the counter trick again. Fortunately, we still
 124          * have the counter value in r8 that was returned by __do_get_xsec.
 125          * At this point, r5,r6 contain our sec/nsec values.
 126          * can be used
 127          */
 128
 129         lwa     r4,WTOM_CLOCK_SEC(r3)
 130         lwa     r7,WTOM_CLOCK_NSEC(r3)
 131
 132         /* We now have our result in r4,r7. We create a fake dependency
 133          * on that result and re-check the counter
 134          */
 135         or      r9,r4,r7
 136         xor     r0,r9,r9
 137         add     r3,r3,r0
 138         ld      r0,CFG_TB_UPDATE_COUNT(r3)
 139         cmpld   cr0,r0,r8               /* check if updated */
 140         bne-    50b
 141
 142         /* Calculate and store result. Note that this mimmics the C code,
 143          * which may cause funny results if nsec goes negative... is that
 144          * possible at all ?
 145          */
 146         add     r4,r4,r5
 147         add     r7,r7,r6
 148         lis     r9,NSEC_PER_SEC@h
 149         ori     r9,r9,NSEC_PER_SEC@l
 150         cmpl    cr0,r7,r9
 151         cmpli   cr1,r7,0
 152         blt     1f
 153         subf    r7,r9,r7
 154         addi    r4,r4,1
 155 1:      bge     cr1,1f
 156         addi    r4,r4,-1
 157         add     r7,r7,r9
 158 1:      std     r4,TSPC64_TV_SEC(r11)
 159         std     r7,TSPC64_TV_NSEC(r11)
 160
 161         mtlr    r12
 162         li      r3,0
 163         blr
 164
 165         /*
 166          * syscall fallback
 167          */
 168 98:
 169         mtlr    r12
 170         mr      r3,r10
 171         mr      r4,r11
 172 99:
 173         li      r0,__NR_clock_gettime
 174         sc
 175         blr
 176   .cfi_endproc
 177 V_FUNCTION_END(__kernel_clock_gettime)
 178
 179
 180 /*
 181  * Exact prototype of clock_getres()
 182  *
 183  * int __kernel_clock_getres(clockid_t clock_id, struct timespec *res);
 184  *
 185  */
 186 V_FUNCTION_BEGIN(__kernel_clock_getres)
 187   .cfi_startproc
 188         /* Check for supported clock IDs */
 189         cmpwi   cr0,r3,CLOCK_REALTIME
 190         cmpwi   cr1,r3,CLOCK_MONOTONIC
 191         cror    cr0*4+eq,cr0*4+eq,cr1*4+eq
 192         bne     cr0,99f
 193
 194         li      r3,0
 195         cmpli   cr0,r4,0
 196         beqlr
 197         lis     r5,CLOCK_REALTIME_RES@h
 198         ori     r5,r5,CLOCK_REALTIME_RES@l
 199         std     r3,TSPC64_TV_SEC(r4)
 200         std     r5,TSPC64_TV_NSEC(r4)
 201         blr
 202
 203         /*
 204          * syscall fallback
 205          */
 206 99:
 207         li      r0,__NR_clock_getres
 208         sc
 209         blr
 210   .cfi_endproc
 211 V_FUNCTION_END(__kernel_clock_getres)
 212
 213
 214 /*
 215  * This is the core of gettimeofday(), it returns the xsec
 216  * value in r4 and expects the datapage ptr (non clobbered)
 217  * in r3. clobbers r0,r4,r5,r6,r7,r8
 218  * When returning, r8 contains the counter value that can be reused
 219  */
 220 V_FUNCTION_BEGIN(__do_get_xsec)
 221   .cfi_startproc
 222         /* check for update count & load values */
 223 1:      ld      r8,CFG_TB_UPDATE_COUNT(r3)
 224         andi.   r0,r4,1                 /* pending update ? loop */
 225         bne-    1b
 226         xor     r0,r4,r4                /* create dependency */
 227         add     r3,r3,r0
 228
 229         /* Get TB & offset it */
 230         mftb    r7
 231         ld      r9,CFG_TB_ORIG_STAMP(r3)
 232         subf    r7,r9,r7
 233
 234         /* Scale result */
 235         ld      r5,CFG_TB_TO_XS(r3)
 236         mulhdu  r7,r7,r5
 237
 238         /* Add stamp since epoch */
 239         ld      r6,CFG_STAMP_XSEC(r3)
 240         add     r4,r6,r7
 241
 242         xor     r0,r4,r4
 243         add     r3,r3,r0
 244         ld      r0,CFG_TB_UPDATE_COUNT(r3)
 245         cmpld   cr0,r0,r8               /* check if updated */
 246         bne-    1b
 247         blr
 248   .cfi_endproc
 249 V_FUNCTION_END(__do_get_xsec)