git.oblomov.eu Git - linux-2.6/blob - arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 .globl ftrace_call
  81 ftrace_call:
  82         call ftrace_stub
  83
  84         MCOUNT_RESTORE_FRAME
  85
  86 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  87 .globl ftrace_graph_call
  88 ftrace_graph_call:
  89         jmp ftrace_stub
  90 #endif
  91
  92 .globl ftrace_stub
  93 ftrace_stub:
  94         retq
  95 END(ftrace_caller)
  96
  97 #else /* ! CONFIG_DYNAMIC_FTRACE */
  98 ENTRY(mcount)
  99         cmpl $0, function_trace_stop
 100         jne  ftrace_stub
 101
 102         cmpq $ftrace_stub, ftrace_trace_function
 103         jnz trace
 104
 105 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 106         cmpq $ftrace_stub, ftrace_graph_return
 107         jnz ftrace_graph_caller
 108
 109         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 110         jnz ftrace_graph_caller
 111 #endif
 112
 113 .globl ftrace_stub
 114 ftrace_stub:
 115         retq
 116
 117 trace:
 118         MCOUNT_SAVE_FRAME
 119
 120         movq 0x38(%rsp), %rdi
 121         movq 8(%rbp), %rsi
 122         subq $MCOUNT_INSN_SIZE, %rdi
 123
 124         call   *ftrace_trace_function
 125
 126         MCOUNT_RESTORE_FRAME
 127
 128         jmp ftrace_stub
 129 END(mcount)
 130 #endif /* CONFIG_DYNAMIC_FTRACE */
 131 #endif /* CONFIG_FUNCTION_TRACER */
 132
 133 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 134 ENTRY(ftrace_graph_caller)
 135         cmpl $0, function_trace_stop
 136         jne ftrace_stub
 137
 138         MCOUNT_SAVE_FRAME
 139
 140         leaq 8(%rbp), %rdi
 141         movq 0x38(%rsp), %rsi
 142         subq $MCOUNT_INSN_SIZE, %rsi
 143
 144         call    prepare_ftrace_return
 145
 146         MCOUNT_RESTORE_FRAME
 147
 148         retq
 149 END(ftrace_graph_caller)
 150
 151
 152 .globl return_to_handler
 153 return_to_handler:
 154         subq  $80, %rsp
 155
 156         movq %rax, (%rsp)
 157         movq %rcx, 8(%rsp)
 158         movq %rdx, 16(%rsp)
 159         movq %rsi, 24(%rsp)
 160         movq %rdi, 32(%rsp)
 161         movq %r8, 40(%rsp)
 162         movq %r9, 48(%rsp)
 163         movq %r10, 56(%rsp)
 164         movq %r11, 64(%rsp)
 165
 166         call ftrace_return_to_handler
 167
 168         movq %rax, 72(%rsp)
 169         movq 64(%rsp), %r11
 170         movq 56(%rsp), %r10
 171         movq 48(%rsp), %r9
 172         movq 40(%rsp), %r8
 173         movq 32(%rsp), %rdi
 174         movq 24(%rsp), %rsi
 175         movq 16(%rsp), %rdx
 176         movq 8(%rsp), %rcx
 177         movq (%rsp), %rax
 178         addq $72, %rsp
 179         retq
 180 #endif
 181
 182
 183 #ifndef CONFIG_PREEMPT
 184 #define retint_kernel retint_restore_args
 185 #endif
 186
 187 #ifdef CONFIG_PARAVIRT
 188 ENTRY(native_usergs_sysret64)
 189         swapgs
 190         sysretq
 191 #endif /* CONFIG_PARAVIRT */
 192
 193
 194 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 195 #ifdef CONFIG_TRACE_IRQFLAGS
 196         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 197         jnc  1f
 198         TRACE_IRQS_ON
 199 1:
 200 #endif
 201 .endm
 202
 203 /*
 204  * C code is not supposed to know about undefined top of stack. Every time
 205  * a C function with an pt_regs argument is called from the SYSCALL based
 206  * fast path FIXUP_TOP_OF_STACK is needed.
 207  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 208  * manipulation.
 209  */
 210
 211         /* %rsp:at FRAMEEND */
 212         .macro FIXUP_TOP_OF_STACK tmp offset=0
 213         movq PER_CPU_VAR(old_rsp),\tmp
 214         movq \tmp,RSP+\offset(%rsp)
 215         movq $__USER_DS,SS+\offset(%rsp)
 216         movq $__USER_CS,CS+\offset(%rsp)
 217         movq $-1,RCX+\offset(%rsp)
 218         movq R11+\offset(%rsp),\tmp  /* get eflags */
 219         movq \tmp,EFLAGS+\offset(%rsp)
 220         .endm
 221
 222         .macro RESTORE_TOP_OF_STACK tmp offset=0
 223         movq RSP+\offset(%rsp),\tmp
 224         movq \tmp,PER_CPU_VAR(old_rsp)
 225         movq EFLAGS+\offset(%rsp),\tmp
 226         movq \tmp,R11+\offset(%rsp)
 227         .endm
 228
 229         .macro FAKE_STACK_FRAME child_rip
 230         /* push in order ss, rsp, eflags, cs, rip */
 231         xorl %eax, %eax
 232         pushq $__KERNEL_DS /* ss */
 233         CFI_ADJUST_CFA_OFFSET   8
 234         /*CFI_REL_OFFSET        ss,0*/
 235         pushq %rax /* rsp */
 236         CFI_ADJUST_CFA_OFFSET   8
 237         CFI_REL_OFFSET  rsp,0
 238         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 239         CFI_ADJUST_CFA_OFFSET   8
 240         /*CFI_REL_OFFSET        rflags,0*/
 241         pushq $__KERNEL_CS /* cs */
 242         CFI_ADJUST_CFA_OFFSET   8
 243         /*CFI_REL_OFFSET        cs,0*/
 244         pushq \child_rip /* rip */
 245         CFI_ADJUST_CFA_OFFSET   8
 246         CFI_REL_OFFSET  rip,0
 247         pushq   %rax /* orig rax */
 248         CFI_ADJUST_CFA_OFFSET   8
 249         .endm
 250
 251         .macro UNFAKE_STACK_FRAME
 252         addq $8*6, %rsp
 253         CFI_ADJUST_CFA_OFFSET   -(6*8)
 254         .endm
 255
 256 /*
 257  * initial frame state for interrupts (and exceptions without error code)
 258  */
 259         .macro EMPTY_FRAME start=1 offset=0
 260         .if \start
 261         CFI_STARTPROC simple
 262         CFI_SIGNAL_FRAME
 263         CFI_DEF_CFA rsp,8+\offset
 264         .else
 265         CFI_DEF_CFA_OFFSET 8+\offset
 266         .endif
 267         .endm
 268
 269 /*
 270  * initial frame state for interrupts (and exceptions without error code)
 271  */
 272         .macro INTR_FRAME start=1 offset=0
 273         EMPTY_FRAME \start, SS+8+\offset-RIP
 274         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 275         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 276         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 277         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 278         CFI_REL_OFFSET rip, RIP+\offset-RIP
 279         .endm
 280
 281 /*
 282  * initial frame state for exceptions with error code (and interrupts
 283  * with vector already pushed)
 284  */
 285         .macro XCPT_FRAME start=1 offset=0
 286         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 287         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 288         .endm
 289
 290 /*
 291  * frame that enables calling into C.
 292  */
 293         .macro PARTIAL_FRAME start=1 offset=0
 294         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 295         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 296         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 297         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 298         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 299         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 300         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 301         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 302         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 303         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 304         .endm
 305
 306 /*
 307  * frame that enables passing a complete pt_regs to a C function.
 308  */
 309         .macro DEFAULT_FRAME start=1 offset=0
 310         PARTIAL_FRAME \start, R11+\offset-R15
 311         CFI_REL_OFFSET rbx, RBX+\offset
 312         CFI_REL_OFFSET rbp, RBP+\offset
 313         CFI_REL_OFFSET r12, R12+\offset
 314         CFI_REL_OFFSET r13, R13+\offset
 315         CFI_REL_OFFSET r14, R14+\offset
 316         CFI_REL_OFFSET r15, R15+\offset
 317         .endm
 318
 319 /* save partial stack frame */
 320 ENTRY(save_args)
 321         XCPT_FRAME
 322         cld
 323         movq_cfi rdi, RDI+16-ARGOFFSET
 324         movq_cfi rsi, RSI+16-ARGOFFSET
 325         movq_cfi rdx, RDX+16-ARGOFFSET
 326         movq_cfi rcx, RCX+16-ARGOFFSET
 327         movq_cfi rax, RAX+16-ARGOFFSET
 328         movq_cfi  r8,  R8+16-ARGOFFSET
 329         movq_cfi  r9,  R9+16-ARGOFFSET
 330         movq_cfi r10, R10+16-ARGOFFSET
 331         movq_cfi r11, R11+16-ARGOFFSET
 332
 333         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 334         movq_cfi rbp, 8         /* push %rbp */
 335         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 336         testl $3, CS(%rdi)
 337         je 1f
 338         SWAPGS
 339         /*
 340          * irq_count is used to check if a CPU is already on an interrupt stack
 341          * or not. While this is essentially redundant with preempt_count it is
 342          * a little cheaper to use a separate counter in the PDA (short of
 343          * moving irq_enter into assembly, which would be too much work)
 344          */
 345 1:      incl PER_CPU_VAR(irq_count)
 346         jne 2f
 347         popq_cfi %rax                   /* move return address... */
 348         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 349         EMPTY_FRAME 0
 350         pushq_cfi %rax                  /* ... to the new stack */
 351         /*
 352          * We entered an interrupt context - irqs are off:
 353          */
 354 2:      TRACE_IRQS_OFF
 355         ret
 356         CFI_ENDPROC
 357 END(save_args)
 358
 359 ENTRY(save_rest)
 360         PARTIAL_FRAME 1 REST_SKIP+8
 361         movq 5*8+16(%rsp), %r11 /* save return address */
 362         movq_cfi rbx, RBX+16
 363         movq_cfi rbp, RBP+16
 364         movq_cfi r12, R12+16
 365         movq_cfi r13, R13+16
 366         movq_cfi r14, R14+16
 367         movq_cfi r15, R15+16
 368         movq %r11, 8(%rsp)      /* return address */
 369         FIXUP_TOP_OF_STACK %r11, 16
 370         ret
 371         CFI_ENDPROC
 372 END(save_rest)
 373
 374 /* save complete stack frame */
 375 ENTRY(save_paranoid)
 376         XCPT_FRAME 1 RDI+8
 377         cld
 378         movq_cfi rdi, RDI+8
 379         movq_cfi rsi, RSI+8
 380         movq_cfi rdx, RDX+8
 381         movq_cfi rcx, RCX+8
 382         movq_cfi rax, RAX+8
 383         movq_cfi r8, R8+8
 384         movq_cfi r9, R9+8
 385         movq_cfi r10, R10+8
 386         movq_cfi r11, R11+8
 387         movq_cfi rbx, RBX+8
 388         movq_cfi rbp, RBP+8
 389         movq_cfi r12, R12+8
 390         movq_cfi r13, R13+8
 391         movq_cfi r14, R14+8
 392         movq_cfi r15, R15+8
 393         movl $1,%ebx
 394         movl $MSR_GS_BASE,%ecx
 395         rdmsr
 396         testl %edx,%edx
 397         js 1f   /* negative -> in kernel */
 398         SWAPGS
 399         xorl %ebx,%ebx
 400 1:      ret
 401         CFI_ENDPROC
 402 END(save_paranoid)
 403
 404 /*
 405  * A newly forked process directly context switches into this address.
 406  *
 407  * rdi: prev task we switched from
 408  */
 409 ENTRY(ret_from_fork)
 410         DEFAULT_FRAME
 411
 412         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 413
 414         push kernel_eflags(%rip)
 415         CFI_ADJUST_CFA_OFFSET 8
 416         popf                                    # reset kernel eflags
 417         CFI_ADJUST_CFA_OFFSET -8
 418
 419         call schedule_tail                      # rdi: 'prev' task parameter
 420
 421         GET_THREAD_INFO(%rcx)
 422
 423         CFI_REMEMBER_STATE
 424         RESTORE_REST
 425
 426         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 427         je   int_ret_from_sys_call
 428
 429         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 430         jnz  int_ret_from_sys_call
 431
 432         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 433         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 434
 435         CFI_RESTORE_STATE
 436         CFI_ENDPROC
 437 END(ret_from_fork)
 438
 439 /*
 440  * System call entry. Upto 6 arguments in registers are supported.
 441  *
 442  * SYSCALL does not save anything on the stack and does not change the
 443  * stack pointer.
 444  */
 445
 446 /*
 447  * Register setup:
 448  * rax  system call number
 449  * rdi  arg0
 450  * rcx  return address for syscall/sysret, C arg3
 451  * rsi  arg1
 452  * rdx  arg2
 453  * r10  arg3    (--> moved to rcx for C)
 454  * r8   arg4
 455  * r9   arg5
 456  * r11  eflags for syscall/sysret, temporary for C
 457  * r12-r15,rbp,rbx saved by C code, not touched.
 458  *
 459  * Interrupts are off on entry.
 460  * Only called from user space.
 461  *
 462  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 463  *      and report it properly in ps. Unfortunately we haven't.
 464  *
 465  * When user can change the frames always force IRET. That is because
 466  * it deals with uncanonical addresses better. SYSRET has trouble
 467  * with them due to bugs in both AMD and Intel CPUs.
 468  */
 469
 470 ENTRY(system_call)
 471         CFI_STARTPROC   simple
 472         CFI_SIGNAL_FRAME
 473         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 474         CFI_REGISTER    rip,rcx
 475         /*CFI_REGISTER  rflags,r11*/
 476         SWAPGS_UNSAFE_STACK
 477         /*
 478          * A hypervisor implementation might want to use a label
 479          * after the swapgs, so that it can do the swapgs
 480          * for the guest and jump here on syscall.
 481          */
 482 ENTRY(system_call_after_swapgs)
 483
 484         movq    %rsp,PER_CPU_VAR(old_rsp)
 485         movq    PER_CPU_VAR(kernel_stack),%rsp
 486         /*
 487          * No need to follow this irqs off/on section - it's straight
 488          * and short:
 489          */
 490         ENABLE_INTERRUPTS(CLBR_NONE)
 491         SAVE_ARGS 8,1
 492         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 493         movq  %rcx,RIP-ARGOFFSET(%rsp)
 494         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 495         GET_THREAD_INFO(%rcx)
 496         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 497         jnz tracesys
 498 system_call_fastpath:
 499         cmpq $__NR_syscall_max,%rax
 500         ja badsys
 501         movq %r10,%rcx
 502         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 503         movq %rax,RAX-ARGOFFSET(%rsp)
 504 /*
 505  * Syscall return path ending with SYSRET (fast path)
 506  * Has incomplete stack frame and undefined top of stack.
 507  */
 508 ret_from_sys_call:
 509         movl $_TIF_ALLWORK_MASK,%edi
 510         /* edi: flagmask */
 511 sysret_check:
 512         LOCKDEP_SYS_EXIT
 513         GET_THREAD_INFO(%rcx)
 514         DISABLE_INTERRUPTS(CLBR_NONE)
 515         TRACE_IRQS_OFF
 516         movl TI_flags(%rcx),%edx
 517         andl %edi,%edx
 518         jnz  sysret_careful
 519         CFI_REMEMBER_STATE
 520         /*
 521          * sysretq will re-enable interrupts:
 522          */
 523         TRACE_IRQS_ON
 524         movq RIP-ARGOFFSET(%rsp),%rcx
 525         CFI_REGISTER    rip,rcx
 526         RESTORE_ARGS 0,-ARG_SKIP,1
 527         /*CFI_REGISTER  rflags,r11*/
 528         movq    PER_CPU_VAR(old_rsp), %rsp
 529         USERGS_SYSRET64
 530
 531         CFI_RESTORE_STATE
 532         /* Handle reschedules */
 533         /* edx: work, edi: workmask */
 534 sysret_careful:
 535         bt $TIF_NEED_RESCHED,%edx
 536         jnc sysret_signal
 537         TRACE_IRQS_ON
 538         ENABLE_INTERRUPTS(CLBR_NONE)
 539         pushq %rdi
 540         CFI_ADJUST_CFA_OFFSET 8
 541         call schedule
 542         popq  %rdi
 543         CFI_ADJUST_CFA_OFFSET -8
 544         jmp sysret_check
 545
 546         /* Handle a signal */
 547 sysret_signal:
 548         TRACE_IRQS_ON
 549         ENABLE_INTERRUPTS(CLBR_NONE)
 550 #ifdef CONFIG_AUDITSYSCALL
 551         bt $TIF_SYSCALL_AUDIT,%edx
 552         jc sysret_audit
 553 #endif
 554         /* edx: work flags (arg3) */
 555         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 556         xorl %esi,%esi # oldset -> arg2
 557         SAVE_REST
 558         FIXUP_TOP_OF_STACK %r11
 559         call do_notify_resume
 560         RESTORE_TOP_OF_STACK %r11
 561         RESTORE_REST
 562         movl $_TIF_WORK_MASK,%edi
 563         /* Use IRET because user could have changed frame. This
 564            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 565         DISABLE_INTERRUPTS(CLBR_NONE)
 566         TRACE_IRQS_OFF
 567         jmp int_with_check
 568
 569 badsys:
 570         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 571         jmp ret_from_sys_call
 572
 573 #ifdef CONFIG_AUDITSYSCALL
 574         /*
 575          * Fast path for syscall audit without full syscall trace.
 576          * We just call audit_syscall_entry() directly, and then
 577          * jump back to the normal fast path.
 578          */
 579 auditsys:
 580         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 581         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 582         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 583         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 584         movq %rax,%rsi                  /* 2nd arg: syscall number */
 585         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 586         call audit_syscall_entry
 587         LOAD_ARGS 0             /* reload call-clobbered registers */
 588         jmp system_call_fastpath
 589
 590         /*
 591          * Return fast path for syscall audit.  Call audit_syscall_exit()
 592          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 593          * masked off.
 594          */
 595 sysret_audit:
 596         movq %rax,%rsi          /* second arg, syscall return value */
 597         cmpq $0,%rax            /* is it < 0? */
 598         setl %al                /* 1 if so, 0 if not */
 599         movzbl %al,%edi         /* zero-extend that into %edi */
 600         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 601         call audit_syscall_exit
 602         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 603         jmp sysret_check
 604 #endif  /* CONFIG_AUDITSYSCALL */
 605
 606         /* Do syscall tracing */
 607 tracesys:
 608 #ifdef CONFIG_AUDITSYSCALL
 609         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 610         jz auditsys
 611 #endif
 612         SAVE_REST
 613         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 614         FIXUP_TOP_OF_STACK %rdi
 615         movq %rsp,%rdi
 616         call syscall_trace_enter
 617         /*
 618          * Reload arg registers from stack in case ptrace changed them.
 619          * We don't reload %rax because syscall_trace_enter() returned
 620          * the value it wants us to use in the table lookup.
 621          */
 622         LOAD_ARGS ARGOFFSET, 1
 623         RESTORE_REST
 624         cmpq $__NR_syscall_max,%rax
 625         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 626         movq %r10,%rcx  /* fixup for C */
 627         call *sys_call_table(,%rax,8)
 628         movq %rax,RAX-ARGOFFSET(%rsp)
 629         /* Use IRET because user could have changed frame */
 630
 631 /*
 632  * Syscall return path ending with IRET.
 633  * Has correct top of stack, but partial stack frame.
 634  */
 635         .globl int_ret_from_sys_call
 636         .globl int_with_check
 637 int_ret_from_sys_call:
 638         DISABLE_INTERRUPTS(CLBR_NONE)
 639         TRACE_IRQS_OFF
 640         testl $3,CS-ARGOFFSET(%rsp)
 641         je retint_restore_args
 642         movl $_TIF_ALLWORK_MASK,%edi
 643         /* edi: mask to check */
 644 int_with_check:
 645         LOCKDEP_SYS_EXIT_IRQ
 646         GET_THREAD_INFO(%rcx)
 647         movl TI_flags(%rcx),%edx
 648         andl %edi,%edx
 649         jnz   int_careful
 650         andl    $~TS_COMPAT,TI_status(%rcx)
 651         jmp   retint_swapgs
 652
 653         /* Either reschedule or signal or syscall exit tracking needed. */
 654         /* First do a reschedule test. */
 655         /* edx: work, edi: workmask */
 656 int_careful:
 657         bt $TIF_NEED_RESCHED,%edx
 658         jnc  int_very_careful
 659         TRACE_IRQS_ON
 660         ENABLE_INTERRUPTS(CLBR_NONE)
 661         pushq %rdi
 662         CFI_ADJUST_CFA_OFFSET 8
 663         call schedule
 664         popq %rdi
 665         CFI_ADJUST_CFA_OFFSET -8
 666         DISABLE_INTERRUPTS(CLBR_NONE)
 667         TRACE_IRQS_OFF
 668         jmp int_with_check
 669
 670         /* handle signals and tracing -- both require a full stack frame */
 671 int_very_careful:
 672         TRACE_IRQS_ON
 673         ENABLE_INTERRUPTS(CLBR_NONE)
 674         SAVE_REST
 675         /* Check for syscall exit trace */
 676         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 677         jz int_signal
 678         pushq %rdi
 679         CFI_ADJUST_CFA_OFFSET 8
 680         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 681         call syscall_trace_leave
 682         popq %rdi
 683         CFI_ADJUST_CFA_OFFSET -8
 684         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 685         jmp int_restore_rest
 686
 687 int_signal:
 688         testl $_TIF_DO_NOTIFY_MASK,%edx
 689         jz 1f
 690         movq %rsp,%rdi          # &ptregs -> arg1
 691         xorl %esi,%esi          # oldset -> arg2
 692         call do_notify_resume
 693 1:      movl $_TIF_WORK_MASK,%edi
 694 int_restore_rest:
 695         RESTORE_REST
 696         DISABLE_INTERRUPTS(CLBR_NONE)
 697         TRACE_IRQS_OFF
 698         jmp int_with_check
 699         CFI_ENDPROC
 700 END(system_call)
 701
 702 /*
 703  * Certain special system calls that need to save a complete full stack frame.
 704  */
 705         .macro PTREGSCALL label,func,arg
 706 ENTRY(\label)
 707         PARTIAL_FRAME 1 8               /* offset 8: return address */
 708         subq $REST_SKIP, %rsp
 709         CFI_ADJUST_CFA_OFFSET REST_SKIP
 710         call save_rest
 711         DEFAULT_FRAME 0 8               /* offset 8: return address */
 712         leaq 8(%rsp), \arg      /* pt_regs pointer */
 713         call \func
 714         jmp ptregscall_common
 715         CFI_ENDPROC
 716 END(\label)
 717         .endm
 718
 719         PTREGSCALL stub_clone, sys_clone, %r8
 720         PTREGSCALL stub_fork, sys_fork, %rdi
 721         PTREGSCALL stub_vfork, sys_vfork, %rdi
 722         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 723         PTREGSCALL stub_iopl, sys_iopl, %rsi
 724
 725 ENTRY(ptregscall_common)
 726         DEFAULT_FRAME 1 8       /* offset 8: return address */
 727         RESTORE_TOP_OF_STACK %r11, 8
 728         movq_cfi_restore R15+8, r15
 729         movq_cfi_restore R14+8, r14
 730         movq_cfi_restore R13+8, r13
 731         movq_cfi_restore R12+8, r12
 732         movq_cfi_restore RBP+8, rbp
 733         movq_cfi_restore RBX+8, rbx
 734         ret $REST_SKIP          /* pop extended registers */
 735         CFI_ENDPROC
 736 END(ptregscall_common)
 737
 738 ENTRY(stub_execve)
 739         CFI_STARTPROC
 740         popq %r11
 741         CFI_ADJUST_CFA_OFFSET -8
 742         CFI_REGISTER rip, r11
 743         SAVE_REST
 744         FIXUP_TOP_OF_STACK %r11
 745         movq %rsp, %rcx
 746         call sys_execve
 747         RESTORE_TOP_OF_STACK %r11
 748         movq %rax,RAX(%rsp)
 749         RESTORE_REST
 750         jmp int_ret_from_sys_call
 751         CFI_ENDPROC
 752 END(stub_execve)
 753
 754 /*
 755  * sigreturn is special because it needs to restore all registers on return.
 756  * This cannot be done with SYSRET, so use the IRET return path instead.
 757  */
 758 ENTRY(stub_rt_sigreturn)
 759         CFI_STARTPROC
 760         addq $8, %rsp
 761         CFI_ADJUST_CFA_OFFSET   -8
 762         SAVE_REST
 763         movq %rsp,%rdi
 764         FIXUP_TOP_OF_STACK %r11
 765         call sys_rt_sigreturn
 766         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 767         RESTORE_REST
 768         jmp int_ret_from_sys_call
 769         CFI_ENDPROC
 770 END(stub_rt_sigreturn)
 771
 772 /*
 773  * Build the entry stubs and pointer table with some assembler magic.
 774  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 775  * single cache line on all modern x86 implementations.
 776  */
 777         .section .init.rodata,"a"
 778 ENTRY(interrupt)
 779         .text
 780         .p2align 5
 781         .p2align CONFIG_X86_L1_CACHE_SHIFT
 782 ENTRY(irq_entries_start)
 783         INTR_FRAME
 784 vector=FIRST_EXTERNAL_VECTOR
 785 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 786         .balign 32
 787   .rept 7
 788     .if vector < NR_VECTORS
 789       .if vector <> FIRST_EXTERNAL_VECTOR
 790         CFI_ADJUST_CFA_OFFSET -8
 791       .endif
 792 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 793         CFI_ADJUST_CFA_OFFSET 8
 794       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 795         jmp 2f
 796       .endif
 797       .previous
 798         .quad 1b
 799       .text
 800 vector=vector+1
 801     .endif
 802   .endr
 803 2:      jmp common_interrupt
 804 .endr
 805         CFI_ENDPROC
 806 END(irq_entries_start)
 807
 808 .previous
 809 END(interrupt)
 810 .previous
 811
 812 /*
 813  * Interrupt entry/exit.
 814  *
 815  * Interrupt entry points save only callee clobbered registers in fast path.
 816  *
 817  * Entry runs with interrupts off.
 818  */
 819
 820 /* 0(%rsp): ~(interrupt number) */
 821         .macro interrupt func
 822         subq $10*8, %rsp
 823         CFI_ADJUST_CFA_OFFSET 10*8
 824         call save_args
 825         PARTIAL_FRAME 0
 826         call \func
 827         .endm
 828
 829         /*
 830          * The interrupt stubs push (~vector+0x80) onto the stack and
 831          * then jump to common_interrupt.
 832          */
 833         .p2align CONFIG_X86_L1_CACHE_SHIFT
 834 common_interrupt:
 835         XCPT_FRAME
 836         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 837         interrupt do_IRQ
 838         /* 0(%rsp): old_rsp-ARGOFFSET */
 839 ret_from_intr:
 840         DISABLE_INTERRUPTS(CLBR_NONE)
 841         TRACE_IRQS_OFF
 842         decl PER_CPU_VAR(irq_count)
 843         leaveq
 844         CFI_DEF_CFA_REGISTER    rsp
 845         CFI_ADJUST_CFA_OFFSET   -8
 846 exit_intr:
 847         GET_THREAD_INFO(%rcx)
 848         testl $3,CS-ARGOFFSET(%rsp)
 849         je retint_kernel
 850
 851         /* Interrupt came from user space */
 852         /*
 853          * Has a correct top of stack, but a partial stack frame
 854          * %rcx: thread info. Interrupts off.
 855          */
 856 retint_with_reschedule:
 857         movl $_TIF_WORK_MASK,%edi
 858 retint_check:
 859         LOCKDEP_SYS_EXIT_IRQ
 860         movl TI_flags(%rcx),%edx
 861         andl %edi,%edx
 862         CFI_REMEMBER_STATE
 863         jnz  retint_careful
 864
 865 retint_swapgs:          /* return to user-space */
 866         /*
 867          * The iretq could re-enable interrupts:
 868          */
 869         DISABLE_INTERRUPTS(CLBR_ANY)
 870         TRACE_IRQS_IRETQ
 871         SWAPGS
 872         jmp restore_args
 873
 874 retint_restore_args:    /* return to kernel space */
 875         DISABLE_INTERRUPTS(CLBR_ANY)
 876         /*
 877          * The iretq could re-enable interrupts:
 878          */
 879         TRACE_IRQS_IRETQ
 880 restore_args:
 881         RESTORE_ARGS 0,8,0
 882
 883 irq_return:
 884         INTERRUPT_RETURN
 885
 886         .section __ex_table, "a"
 887         .quad irq_return, bad_iret
 888         .previous
 889
 890 #ifdef CONFIG_PARAVIRT
 891 ENTRY(native_iret)
 892         iretq
 893
 894         .section __ex_table,"a"
 895         .quad native_iret, bad_iret
 896         .previous
 897 #endif
 898
 899         .section .fixup,"ax"
 900 bad_iret:
 901         /*
 902          * The iret traps when the %cs or %ss being restored is bogus.
 903          * We've lost the original trap vector and error code.
 904          * #GPF is the most likely one to get for an invalid selector.
 905          * So pretend we completed the iret and took the #GPF in user mode.
 906          *
 907          * We are now running with the kernel GS after exception recovery.
 908          * But error_entry expects us to have user GS to match the user %cs,
 909          * so swap back.
 910          */
 911         pushq $0
 912
 913         SWAPGS
 914         jmp general_protection
 915
 916         .previous
 917
 918         /* edi: workmask, edx: work */
 919 retint_careful:
 920         CFI_RESTORE_STATE
 921         bt    $TIF_NEED_RESCHED,%edx
 922         jnc   retint_signal
 923         TRACE_IRQS_ON
 924         ENABLE_INTERRUPTS(CLBR_NONE)
 925         pushq %rdi
 926         CFI_ADJUST_CFA_OFFSET   8
 927         call  schedule
 928         popq %rdi
 929         CFI_ADJUST_CFA_OFFSET   -8
 930         GET_THREAD_INFO(%rcx)
 931         DISABLE_INTERRUPTS(CLBR_NONE)
 932         TRACE_IRQS_OFF
 933         jmp retint_check
 934
 935 retint_signal:
 936         testl $_TIF_DO_NOTIFY_MASK,%edx
 937         jz    retint_swapgs
 938         TRACE_IRQS_ON
 939         ENABLE_INTERRUPTS(CLBR_NONE)
 940         SAVE_REST
 941         movq $-1,ORIG_RAX(%rsp)
 942         xorl %esi,%esi          # oldset
 943         movq %rsp,%rdi          # &pt_regs
 944         call do_notify_resume
 945         RESTORE_REST
 946         DISABLE_INTERRUPTS(CLBR_NONE)
 947         TRACE_IRQS_OFF
 948         GET_THREAD_INFO(%rcx)
 949         jmp retint_with_reschedule
 950
 951 #ifdef CONFIG_PREEMPT
 952         /* Returning to kernel space. Check if we need preemption */
 953         /* rcx:  threadinfo. interrupts off. */
 954 ENTRY(retint_kernel)
 955         cmpl $0,TI_preempt_count(%rcx)
 956         jnz  retint_restore_args
 957         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 958         jnc  retint_restore_args
 959         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 960         jnc  retint_restore_args
 961         call preempt_schedule_irq
 962         jmp exit_intr
 963 #endif
 964
 965         CFI_ENDPROC
 966 END(common_interrupt)
 967
 968 /*
 969  * APIC interrupts.
 970  */
 971 .macro apicinterrupt num sym do_sym
 972 ENTRY(\sym)
 973         INTR_FRAME
 974         pushq $~(\num)
 975         CFI_ADJUST_CFA_OFFSET 8
 976         interrupt \do_sym
 977         jmp ret_from_intr
 978         CFI_ENDPROC
 979 END(\sym)
 980 .endm
 981
 982 #ifdef CONFIG_SMP
 983 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 984         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 985 #endif
 986
 987 #ifdef CONFIG_X86_UV
 988 apicinterrupt UV_BAU_MESSAGE \
 989         uv_bau_message_intr1 uv_bau_message_interrupt
 990 #endif
 991 apicinterrupt LOCAL_TIMER_VECTOR \
 992         apic_timer_interrupt smp_apic_timer_interrupt
 993
 994 #ifdef CONFIG_SMP
 995 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 996         invalidate_interrupt0 smp_invalidate_interrupt
 997 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 998         invalidate_interrupt1 smp_invalidate_interrupt
 999 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
1000         invalidate_interrupt2 smp_invalidate_interrupt
1001 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
1002         invalidate_interrupt3 smp_invalidate_interrupt
1003 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
1004         invalidate_interrupt4 smp_invalidate_interrupt
1005 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
1006         invalidate_interrupt5 smp_invalidate_interrupt
1007 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
1008         invalidate_interrupt6 smp_invalidate_interrupt
1009 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
1010         invalidate_interrupt7 smp_invalidate_interrupt
1011 #endif
1012
1013 apicinterrupt THRESHOLD_APIC_VECTOR \
1014         threshold_interrupt mce_threshold_interrupt
1015 apicinterrupt THERMAL_APIC_VECTOR \
1016         thermal_interrupt smp_thermal_interrupt
1017
1018 #ifdef CONFIG_SMP
1019 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1020         call_function_single_interrupt smp_call_function_single_interrupt
1021 apicinterrupt CALL_FUNCTION_VECTOR \
1022         call_function_interrupt smp_call_function_interrupt
1023 apicinterrupt RESCHEDULE_VECTOR \
1024         reschedule_interrupt smp_reschedule_interrupt
1025 #endif
1026
1027 apicinterrupt ERROR_APIC_VECTOR \
1028         error_interrupt smp_error_interrupt
1029 apicinterrupt SPURIOUS_APIC_VECTOR \
1030         spurious_interrupt smp_spurious_interrupt
1031
1032 /*
1033  * Exception entry points.
1034  */
1035 .macro zeroentry sym do_sym
1036 ENTRY(\sym)
1037         INTR_FRAME
1038         PARAVIRT_ADJUST_EXCEPTION_FRAME
1039         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1040         subq $15*8,%rsp
1041         CFI_ADJUST_CFA_OFFSET 15*8
1042         call error_entry
1043         DEFAULT_FRAME 0
1044         movq %rsp,%rdi          /* pt_regs pointer */
1045         xorl %esi,%esi          /* no error code */
1046         call \do_sym
1047         jmp error_exit          /* %ebx: no swapgs flag */
1048         CFI_ENDPROC
1049 END(\sym)
1050 .endm
1051
1052 .macro paranoidzeroentry sym do_sym
1053 ENTRY(\sym)
1054         INTR_FRAME
1055         PARAVIRT_ADJUST_EXCEPTION_FRAME
1056         pushq $-1               /* ORIG_RAX: no syscall to restart */
1057         CFI_ADJUST_CFA_OFFSET 8
1058         subq $15*8, %rsp
1059         call save_paranoid
1060         TRACE_IRQS_OFF
1061         movq %rsp,%rdi          /* pt_regs pointer */
1062         xorl %esi,%esi          /* no error code */
1063         call \do_sym
1064         jmp paranoid_exit       /* %ebx: no swapgs flag */
1065         CFI_ENDPROC
1066 END(\sym)
1067 .endm
1068
1069 .macro paranoidzeroentry_ist sym do_sym ist
1070 ENTRY(\sym)
1071         INTR_FRAME
1072         PARAVIRT_ADJUST_EXCEPTION_FRAME
1073         pushq $-1               /* ORIG_RAX: no syscall to restart */
1074         CFI_ADJUST_CFA_OFFSET 8
1075         subq $15*8, %rsp
1076         call save_paranoid
1077         TRACE_IRQS_OFF
1078         movq %rsp,%rdi          /* pt_regs pointer */
1079         xorl %esi,%esi          /* no error code */
1080         PER_CPU(init_tss, %rbp)
1081         subq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1082         call \do_sym
1083         addq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1084         jmp paranoid_exit       /* %ebx: no swapgs flag */
1085         CFI_ENDPROC
1086 END(\sym)
1087 .endm
1088
1089 .macro errorentry sym do_sym
1090 ENTRY(\sym)
1091         XCPT_FRAME
1092         PARAVIRT_ADJUST_EXCEPTION_FRAME
1093         subq $15*8,%rsp
1094         CFI_ADJUST_CFA_OFFSET 15*8
1095         call error_entry
1096         DEFAULT_FRAME 0
1097         movq %rsp,%rdi                  /* pt_regs pointer */
1098         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1099         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1100         call \do_sym
1101         jmp error_exit                  /* %ebx: no swapgs flag */
1102         CFI_ENDPROC
1103 END(\sym)
1104 .endm
1105
1106         /* error code is on the stack already */
1107 .macro paranoiderrorentry sym do_sym
1108 ENTRY(\sym)
1109         XCPT_FRAME
1110         PARAVIRT_ADJUST_EXCEPTION_FRAME
1111         subq $15*8,%rsp
1112         CFI_ADJUST_CFA_OFFSET 15*8
1113         call save_paranoid
1114         DEFAULT_FRAME 0
1115         TRACE_IRQS_OFF
1116         movq %rsp,%rdi                  /* pt_regs pointer */
1117         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1118         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1119         call \do_sym
1120         jmp paranoid_exit               /* %ebx: no swapgs flag */
1121         CFI_ENDPROC
1122 END(\sym)
1123 .endm
1124
1125 zeroentry divide_error do_divide_error
1126 zeroentry overflow do_overflow
1127 zeroentry bounds do_bounds
1128 zeroentry invalid_op do_invalid_op
1129 zeroentry device_not_available do_device_not_available
1130 paranoiderrorentry double_fault do_double_fault
1131 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1132 errorentry invalid_TSS do_invalid_TSS
1133 errorentry segment_not_present do_segment_not_present
1134 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1135 zeroentry coprocessor_error do_coprocessor_error
1136 errorentry alignment_check do_alignment_check
1137 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1138
1139         /* Reload gs selector with exception handling */
1140         /* edi:  new selector */
1141 ENTRY(native_load_gs_index)
1142         CFI_STARTPROC
1143         pushf
1144         CFI_ADJUST_CFA_OFFSET 8
1145         DISABLE_INTERRUPTS(CLBR_ANY | ~(CLBR_RDI))
1146         SWAPGS
1147 gs_change:
1148         movl %edi,%gs
1149 2:      mfence          /* workaround */
1150         SWAPGS
1151         popf
1152         CFI_ADJUST_CFA_OFFSET -8
1153         ret
1154         CFI_ENDPROC
1155 END(native_load_gs_index)
1156
1157         .section __ex_table,"a"
1158         .align 8
1159         .quad gs_change,bad_gs
1160         .previous
1161         .section .fixup,"ax"
1162         /* running with kernelgs */
1163 bad_gs:
1164         SWAPGS                  /* switch back to user gs */
1165         xorl %eax,%eax
1166         movl %eax,%gs
1167         jmp  2b
1168         .previous
1169
1170 /*
1171  * Create a kernel thread.
1172  *
1173  * C extern interface:
1174  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1175  *
1176  * asm input arguments:
1177  *      rdi: fn, rsi: arg, rdx: flags
1178  */
1179 ENTRY(kernel_thread)
1180         CFI_STARTPROC
1181         FAKE_STACK_FRAME $child_rip
1182         SAVE_ALL
1183
1184         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1185         movq %rdx,%rdi
1186         orq  kernel_thread_flags(%rip),%rdi
1187         movq $-1, %rsi
1188         movq %rsp, %rdx
1189
1190         xorl %r8d,%r8d
1191         xorl %r9d,%r9d
1192
1193         # clone now
1194         call do_fork
1195         movq %rax,RAX(%rsp)
1196         xorl %edi,%edi
1197
1198         /*
1199          * It isn't worth to check for reschedule here,
1200          * so internally to the x86_64 port you can rely on kernel_thread()
1201          * not to reschedule the child before returning, this avoids the need
1202          * of hacks for example to fork off the per-CPU idle tasks.
1203          * [Hopefully no generic code relies on the reschedule -AK]
1204          */
1205         RESTORE_ALL
1206         UNFAKE_STACK_FRAME
1207         ret
1208         CFI_ENDPROC
1209 END(kernel_thread)
1210
1211 ENTRY(child_rip)
1212         pushq $0                # fake return address
1213         CFI_STARTPROC
1214         /*
1215          * Here we are in the child and the registers are set as they were
1216          * at kernel_thread() invocation in the parent.
1217          */
1218         movq %rdi, %rax
1219         movq %rsi, %rdi
1220         call *%rax
1221         # exit
1222         mov %eax, %edi
1223         call do_exit
1224         ud2                     # padding for call trace
1225         CFI_ENDPROC
1226 END(child_rip)
1227
1228 /*
1229  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1230  *
1231  * C extern interface:
1232  *       extern long execve(char *name, char **argv, char **envp)
1233  *
1234  * asm input arguments:
1235  *      rdi: name, rsi: argv, rdx: envp
1236  *
1237  * We want to fallback into:
1238  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1239  *
1240  * do_sys_execve asm fallback arguments:
1241  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1242  */
1243 ENTRY(kernel_execve)
1244         CFI_STARTPROC
1245         FAKE_STACK_FRAME $0
1246         SAVE_ALL
1247         movq %rsp,%rcx
1248         call sys_execve
1249         movq %rax, RAX(%rsp)
1250         RESTORE_REST
1251         testq %rax,%rax
1252         je int_ret_from_sys_call
1253         RESTORE_ARGS
1254         UNFAKE_STACK_FRAME
1255         ret
1256         CFI_ENDPROC
1257 END(kernel_execve)
1258
1259 /* Call softirq on interrupt stack. Interrupts are off. */
1260 ENTRY(call_softirq)
1261         CFI_STARTPROC
1262         push %rbp
1263         CFI_ADJUST_CFA_OFFSET   8
1264         CFI_REL_OFFSET rbp,0
1265         mov  %rsp,%rbp
1266         CFI_DEF_CFA_REGISTER rbp
1267         incl PER_CPU_VAR(irq_count)
1268         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1269         push  %rbp                      # backlink for old unwinder
1270         call __do_softirq
1271         leaveq
1272         CFI_DEF_CFA_REGISTER    rsp
1273         CFI_ADJUST_CFA_OFFSET   -8
1274         decl PER_CPU_VAR(irq_count)
1275         ret
1276         CFI_ENDPROC
1277 END(call_softirq)
1278
1279 #ifdef CONFIG_XEN
1280 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1281
1282 /*
1283  * A note on the "critical region" in our callback handler.
1284  * We want to avoid stacking callback handlers due to events occurring
1285  * during handling of the last event. To do this, we keep events disabled
1286  * until we've done all processing. HOWEVER, we must enable events before
1287  * popping the stack frame (can't be done atomically) and so it would still
1288  * be possible to get enough handler activations to overflow the stack.
1289  * Although unlikely, bugs of that kind are hard to track down, so we'd
1290  * like to avoid the possibility.
1291  * So, on entry to the handler we detect whether we interrupted an
1292  * existing activation in its critical region -- if so, we pop the current
1293  * activation and restart the handler using the previous one.
1294  */
1295 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1296         CFI_STARTPROC
1297 /*
1298  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1299  * see the correct pointer to the pt_regs
1300  */
1301         movq %rdi, %rsp            # we don't return, adjust the stack frame
1302         CFI_ENDPROC
1303         DEFAULT_FRAME
1304 11:     incl PER_CPU_VAR(irq_count)
1305         movq %rsp,%rbp
1306         CFI_DEF_CFA_REGISTER rbp
1307         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1308         pushq %rbp                      # backlink for old unwinder
1309         call xen_evtchn_do_upcall
1310         popq %rsp
1311         CFI_DEF_CFA_REGISTER rsp
1312         decl PER_CPU_VAR(irq_count)
1313         jmp  error_exit
1314         CFI_ENDPROC
1315 END(do_hypervisor_callback)
1316
1317 /*
1318  * Hypervisor uses this for application faults while it executes.
1319  * We get here for two reasons:
1320  *  1. Fault while reloading DS, ES, FS or GS
1321  *  2. Fault while executing IRET
1322  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1323  * registers that could be reloaded and zeroed the others.
1324  * Category 2 we fix up by killing the current process. We cannot use the
1325  * normal Linux return path in this case because if we use the IRET hypercall
1326  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1327  * We distinguish between categories by comparing each saved segment register
1328  * with its current contents: any discrepancy means we in category 1.
1329  */
1330 ENTRY(xen_failsafe_callback)
1331         INTR_FRAME 1 (6*8)
1332         /*CFI_REL_OFFSET gs,GS*/
1333         /*CFI_REL_OFFSET fs,FS*/
1334         /*CFI_REL_OFFSET es,ES*/
1335         /*CFI_REL_OFFSET ds,DS*/
1336         CFI_REL_OFFSET r11,8
1337         CFI_REL_OFFSET rcx,0
1338         movw %ds,%cx
1339         cmpw %cx,0x10(%rsp)
1340         CFI_REMEMBER_STATE
1341         jne 1f
1342         movw %es,%cx
1343         cmpw %cx,0x18(%rsp)
1344         jne 1f
1345         movw %fs,%cx
1346         cmpw %cx,0x20(%rsp)
1347         jne 1f
1348         movw %gs,%cx
1349         cmpw %cx,0x28(%rsp)
1350         jne 1f
1351         /* All segments match their saved values => Category 2 (Bad IRET). */
1352         movq (%rsp),%rcx
1353         CFI_RESTORE rcx
1354         movq 8(%rsp),%r11
1355         CFI_RESTORE r11
1356         addq $0x30,%rsp
1357         CFI_ADJUST_CFA_OFFSET -0x30
1358         pushq_cfi $0    /* RIP */
1359         pushq_cfi %r11
1360         pushq_cfi %rcx
1361         jmp general_protection
1362         CFI_RESTORE_STATE
1363 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1364         movq (%rsp),%rcx
1365         CFI_RESTORE rcx
1366         movq 8(%rsp),%r11
1367         CFI_RESTORE r11
1368         addq $0x30,%rsp
1369         CFI_ADJUST_CFA_OFFSET -0x30
1370         pushq_cfi $0
1371         SAVE_ALL
1372         jmp error_exit
1373         CFI_ENDPROC
1374 END(xen_failsafe_callback)
1375
1376 #endif /* CONFIG_XEN */
1377
1378 /*
1379  * Some functions should be protected against kprobes
1380  */
1381         .pushsection .kprobes.text, "ax"
1382
1383 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1384 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1385 paranoiderrorentry stack_segment do_stack_segment
1386 errorentry general_protection do_general_protection
1387 errorentry page_fault do_page_fault
1388 #ifdef CONFIG_X86_MCE
1389 paranoidzeroentry machine_check do_machine_check
1390 #endif
1391
1392         /*
1393          * "Paranoid" exit path from exception stack.
1394          * Paranoid because this is used by NMIs and cannot take
1395          * any kernel state for granted.
1396          * We don't do kernel preemption checks here, because only
1397          * NMI should be common and it does not enable IRQs and
1398          * cannot get reschedule ticks.
1399          *
1400          * "trace" is 0 for the NMI handler only, because irq-tracing
1401          * is fundamentally NMI-unsafe. (we cannot change the soft and
1402          * hard flags at once, atomically)
1403          */
1404
1405         /* ebx: no swapgs flag */
1406 ENTRY(paranoid_exit)
1407         INTR_FRAME
1408         DISABLE_INTERRUPTS(CLBR_NONE)
1409         TRACE_IRQS_OFF
1410         testl %ebx,%ebx                         /* swapgs needed? */
1411         jnz paranoid_restore
1412         testl $3,CS(%rsp)
1413         jnz   paranoid_userspace
1414 paranoid_swapgs:
1415         TRACE_IRQS_IRETQ 0
1416         SWAPGS_UNSAFE_STACK
1417 paranoid_restore:
1418         RESTORE_ALL 8
1419         jmp irq_return
1420 paranoid_userspace:
1421         GET_THREAD_INFO(%rcx)
1422         movl TI_flags(%rcx),%ebx
1423         andl $_TIF_WORK_MASK,%ebx
1424         jz paranoid_swapgs
1425         movq %rsp,%rdi                  /* &pt_regs */
1426         call sync_regs
1427         movq %rax,%rsp                  /* switch stack for scheduling */
1428         testl $_TIF_NEED_RESCHED,%ebx
1429         jnz paranoid_schedule
1430         movl %ebx,%edx                  /* arg3: thread flags */
1431         TRACE_IRQS_ON
1432         ENABLE_INTERRUPTS(CLBR_NONE)
1433         xorl %esi,%esi                  /* arg2: oldset */
1434         movq %rsp,%rdi                  /* arg1: &pt_regs */
1435         call do_notify_resume
1436         DISABLE_INTERRUPTS(CLBR_NONE)
1437         TRACE_IRQS_OFF
1438         jmp paranoid_userspace
1439 paranoid_schedule:
1440         TRACE_IRQS_ON
1441         ENABLE_INTERRUPTS(CLBR_ANY)
1442         call schedule
1443         DISABLE_INTERRUPTS(CLBR_ANY)
1444         TRACE_IRQS_OFF
1445         jmp paranoid_userspace
1446         CFI_ENDPROC
1447 END(paranoid_exit)
1448
1449 /*
1450  * Exception entry point. This expects an error code/orig_rax on the stack.
1451  * returns in "no swapgs flag" in %ebx.
1452  */
1453 ENTRY(error_entry)
1454         XCPT_FRAME
1455         CFI_ADJUST_CFA_OFFSET 15*8
1456         /* oldrax contains error code */
1457         cld
1458         movq_cfi rdi, RDI+8
1459         movq_cfi rsi, RSI+8
1460         movq_cfi rdx, RDX+8
1461         movq_cfi rcx, RCX+8
1462         movq_cfi rax, RAX+8
1463         movq_cfi  r8,  R8+8
1464         movq_cfi  r9,  R9+8
1465         movq_cfi r10, R10+8
1466         movq_cfi r11, R11+8
1467         movq_cfi rbx, RBX+8
1468         movq_cfi rbp, RBP+8
1469         movq_cfi r12, R12+8
1470         movq_cfi r13, R13+8
1471         movq_cfi r14, R14+8
1472         movq_cfi r15, R15+8
1473         xorl %ebx,%ebx
1474         testl $3,CS+8(%rsp)
1475         je error_kernelspace
1476 error_swapgs:
1477         SWAPGS
1478 error_sti:
1479         TRACE_IRQS_OFF
1480         ret
1481         CFI_ENDPROC
1482
1483 /*
1484  * There are two places in the kernel that can potentially fault with
1485  * usergs. Handle them here. The exception handlers after iret run with
1486  * kernel gs again, so don't set the user space flag. B stepping K8s
1487  * sometimes report an truncated RIP for IRET exceptions returning to
1488  * compat mode. Check for these here too.
1489  */
1490 error_kernelspace:
1491         incl %ebx
1492         leaq irq_return(%rip),%rcx
1493         cmpq %rcx,RIP+8(%rsp)
1494         je error_swapgs
1495         movl %ecx,%ecx  /* zero extend */
1496         cmpq %rcx,RIP+8(%rsp)
1497         je error_swapgs
1498         cmpq $gs_change,RIP+8(%rsp)
1499         je error_swapgs
1500         jmp error_sti
1501 END(error_entry)
1502
1503
1504 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1505 ENTRY(error_exit)
1506         DEFAULT_FRAME
1507         movl %ebx,%eax
1508         RESTORE_REST
1509         DISABLE_INTERRUPTS(CLBR_NONE)
1510         TRACE_IRQS_OFF
1511         GET_THREAD_INFO(%rcx)
1512         testl %eax,%eax
1513         jne retint_kernel
1514         LOCKDEP_SYS_EXIT_IRQ
1515         movl TI_flags(%rcx),%edx
1516         movl $_TIF_WORK_MASK,%edi
1517         andl %edi,%edx
1518         jnz retint_careful
1519         jmp retint_swapgs
1520         CFI_ENDPROC
1521 END(error_exit)
1522
1523
1524         /* runs on exception stack */
1525 ENTRY(nmi)
1526         INTR_FRAME
1527         PARAVIRT_ADJUST_EXCEPTION_FRAME
1528         pushq_cfi $-1
1529         subq $15*8, %rsp
1530         CFI_ADJUST_CFA_OFFSET 15*8
1531         call save_paranoid
1532         DEFAULT_FRAME 0
1533         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1534         movq %rsp,%rdi
1535         movq $-1,%rsi
1536         call do_nmi
1537 #ifdef CONFIG_TRACE_IRQFLAGS
1538         /* paranoidexit; without TRACE_IRQS_OFF */
1539         /* ebx: no swapgs flag */
1540         DISABLE_INTERRUPTS(CLBR_NONE)
1541         testl %ebx,%ebx                         /* swapgs needed? */
1542         jnz nmi_restore
1543         testl $3,CS(%rsp)
1544         jnz nmi_userspace
1545 nmi_swapgs:
1546         SWAPGS_UNSAFE_STACK
1547 nmi_restore:
1548         RESTORE_ALL 8
1549         jmp irq_return
1550 nmi_userspace:
1551         GET_THREAD_INFO(%rcx)
1552         movl TI_flags(%rcx),%ebx
1553         andl $_TIF_WORK_MASK,%ebx
1554         jz nmi_swapgs
1555         movq %rsp,%rdi                  /* &pt_regs */
1556         call sync_regs
1557         movq %rax,%rsp                  /* switch stack for scheduling */
1558         testl $_TIF_NEED_RESCHED,%ebx
1559         jnz nmi_schedule
1560         movl %ebx,%edx                  /* arg3: thread flags */
1561         ENABLE_INTERRUPTS(CLBR_NONE)
1562         xorl %esi,%esi                  /* arg2: oldset */
1563         movq %rsp,%rdi                  /* arg1: &pt_regs */
1564         call do_notify_resume
1565         DISABLE_INTERRUPTS(CLBR_NONE)
1566         jmp nmi_userspace
1567 nmi_schedule:
1568         ENABLE_INTERRUPTS(CLBR_ANY)
1569         call schedule
1570         DISABLE_INTERRUPTS(CLBR_ANY)
1571         jmp nmi_userspace
1572         CFI_ENDPROC
1573 #else
1574         jmp paranoid_exit
1575         CFI_ENDPROC
1576 #endif
1577 END(nmi)
1578
1579 ENTRY(ignore_sysret)
1580         CFI_STARTPROC
1581         mov $-ENOSYS,%eax
1582         sysret
1583         CFI_ENDPROC
1584 END(ignore_sysret)
1585
1586 /*
1587  * End of kprobes section
1588  */
1589         .popsection