git.oblomov.eu Git - linux-2.6/blob - arch/sh/kernel/vmlinux.lds.S

   1 /* $Id: vmlinux.lds.S,v 1.8 2003/05/16 17:18:14 lethal Exp $
   2  * ld script to make SuperH Linux kernel
   3  * Written by Niibe Yutaka
   4  */
   5 #include <asm/thread_info.h>
   6 #include <asm-generic/vmlinux.lds.h>
   7
   8 #ifdef CONFIG_CPU_LITTLE_ENDIAN
   9 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  10 #else
  11 OUTPUT_FORMAT("elf32-shbig-linux", "elf32-shbig-linux", "elf32-shbig-linux")
  12 #endif
  13 OUTPUT_ARCH(sh)
  14 ENTRY(_start)
  15 SECTIONS
  16 {
  17   . = CONFIG_PAGE_OFFSET + CONFIG_MEMORY_START + CONFIG_ZERO_PAGE_OFFSET;
  18   _text = .;                    /* Text and read-only data */
  19   text = .;                     /* Text and read-only data */
  20   .empty_zero_page : {
  21         *(.empty_zero_page)
  22         } = 0
  23   .text : {
  24         *(.text)
  25         SCHED_TEXT
  26         LOCK_TEXT
  27         *(.fixup)
  28         *(.gnu.warning)
  29         } = 0x0009
  30
  31   . = ALIGN(16);                /* Exception table */
  32   __start___ex_table = .;
  33   __ex_table : { *(__ex_table) }
  34   __stop___ex_table = .;
  35
  36   RODATA
  37
  38   _etext = .;                   /* End of text section */
  39
  40   .data : {                     /* Data */
  41         *(.data)
  42
  43          /* Align the initial ramdisk image (INITRD) on page boundaries. */
  44          . = ALIGN(PAGE_SIZE);
  45          __rd_start = .;
  46          *(.initrd)
  47          . = ALIGN(PAGE_SIZE);
  48          __rd_end = .;
  49
  50         CONSTRUCTORS
  51         }
  52
  53   . = ALIGN(PAGE_SIZE);
  54   .data.page_aligned : { *(.data.page_aligned) }
  55
  56   . = ALIGN(32);
  57   __per_cpu_start = .;
  58   .data.percpu : { *(.data.percpu) }
  59   __per_cpu_end = .;
  60   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  61
  62   _edata = .;                   /* End of data section */
  63
  64   . = ALIGN(THREAD_SIZE);               /* init_task */
  65   .data.init_task : { *(.data.init_task) }
  66
  67   . = ALIGN(PAGE_SIZE);         /* Init code and data */
  68   __init_begin = .;
  69   _sinittext = .;
  70   .init.text : { *(.init.text) }
  71   _einittext = .;
  72   .init.data : { *(.init.data) }
  73   . = ALIGN(16);
  74   __setup_start = .;
  75   .init.setup : { *(.init.setup) }
  76   __setup_end = .;
  77   __initcall_start = .;
  78   .initcall.init : {
  79         INITCALLS
  80   }
  81   __initcall_end = .;
  82   __con_initcall_start = .;
  83   .con_initcall.init : { *(.con_initcall.init) }
  84   __con_initcall_end = .;
  85   SECURITY_INIT
  86
  87 #ifdef CONFIG_BLK_DEV_INITRD
  88   __initramfs_start = .;
  89   .init.ramfs : { *(.init.ramfs) }
  90   __initramfs_end = .;
  91 #endif
  92
  93   __machvec_start = .;
  94   .init.machvec : { *(.init.machvec) }
  95   __machvec_end = .;
  96   . = ALIGN(PAGE_SIZE);
  97   __init_end = .;
  98
  99   . = ALIGN(4);
 100   __bss_start = .;              /* BSS */
 101   .bss : { *(.bss) }
 102
 103   . = ALIGN(4);
 104   _end = . ;
 105
 106   /* When something in the kernel is NOT compiled as a module, the
 107    * module cleanup code and data are put into these segments.  Both
 108    * can then be thrown away, as cleanup code is never called unless
 109    * it's a module.
 110    */
 111   /DISCARD/ : {
 112         *(.exit.text)
 113         *(.exit.data)
 114         *(.exitcall.exit)
 115         }
 116
 117   /* Stabs debugging sections.  */
 118   .stab 0 : { *(.stab) }
 119   .stabstr 0 : { *(.stabstr) }
 120   .stab.excl 0 : { *(.stab.excl) }
 121   .stab.exclstr 0 : { *(.stab.exclstr) }
 122   .stab.index 0 : { *(.stab.index) }
 123   .stab.indexstr 0 : { *(.stab.indexstr) }
 124   .comment 0 : { *(.comment) }
 125   /* DWARF debug sections.
 126      Symbols in the DWARF debugging section are relative to the beginning
 127      of the section so we begin .debug at 0.  */
 128   /* DWARF 1 */
 129   .debug          0 : { *(.debug) }
 130   .line           0 : { *(.line) }
 131   /* GNU DWARF 1 extensions */
 132   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 133   .debug_sfnames  0 : { *(.debug_sfnames) }
 134   /* DWARF 1.1 and DWARF 2 */
 135   .debug_aranges  0 : { *(.debug_aranges) }
 136   .debug_pubnames 0 : { *(.debug_pubnames) }
 137   /* DWARF 2 */
 138   .debug_info     0 : { *(.debug_info) }
 139   .debug_abbrev   0 : { *(.debug_abbrev) }
 140   .debug_line     0 : { *(.debug_line) }
 141   .debug_frame    0 : { *(.debug_frame) }
 142   .debug_str      0 : { *(.debug_str) }
 143   .debug_loc      0 : { *(.debug_loc) }
 144   .debug_macinfo  0 : { *(.debug_macinfo) }
 145   /* SGI/MIPS DWARF 2 extensions */
 146   .debug_weaknames 0 : { *(.debug_weaknames) }
 147   .debug_funcnames 0 : { *(.debug_funcnames) }
 148   .debug_typenames 0 : { *(.debug_typenames) }
 149   .debug_varnames  0 : { *(.debug_varnames) }
 150   /* These must appear regardless of  .  */
 151 }