git.oblomov.eu Git - linux-2.6/blob - arch/x86/kernel/acpi/realmode/wakeup.lds.S

   1 /*
   2  * wakeup.ld
   3  *
   4  * Linker script for the real-mode wakeup code
   5  */
   6 #undef i386
   7 #include "wakeup.h"
   8
   9 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  10 OUTPUT_ARCH(i386)
  11 ENTRY(_start)
  12
  13 SECTIONS
  14 {
  15         . = 0;
  16         .text : {
  17                  *(.text*)
  18         }
  19
  20         . = ALIGN(16);
  21         .rodata : {
  22                 *(.rodata*)
  23         }
  24
  25         .videocards : {
  26                 video_cards = .;
  27                 *(.videocards)
  28                 video_cards_end = .;
  29         }
  30
  31         . = ALIGN(16);
  32         .data : {
  33                  *(.data*)
  34         }
  35
  36         .signature : {
  37                 end_signature = .;
  38                 LONG(0x65a22c82)
  39         }
  40
  41         . = ALIGN(16);
  42         .bss :  {
  43                 __bss_start = .;
  44                 *(.bss)
  45                 __bss_end = .;
  46         }
  47
  48         . = HEADER_OFFSET;
  49         .header : {
  50                 *(.header)
  51         }
  52
  53         . = ALIGN(16);
  54         _end = .;
  55
  56         /DISCARD/ : {
  57                 *(.note*)
  58         }
  59
  60         . = ASSERT(_end <= WAKEUP_SIZE, "Wakeup too big!");
  61 }