git.oblomov.eu Git - linux-2.6/blob - arch/x86/kernel/acpi/realmode/wakeup.lds.S

   1 /*
   2  * wakeup.ld
   3  *
   4  * Linker script for the real-mode wakeup code
   5  */
   6 #undef i386
   7 #include "wakeup.h"
   8
   9 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  10 OUTPUT_ARCH(i386)
  11 ENTRY(_start)
  12
  13 SECTIONS
  14 {
  15         . = HEADER_OFFSET;
  16         .header : {
  17                  *(.header)
  18         }
  19
  20         . = 0;
  21         .text : {
  22                  *(.text*)
  23         }
  24
  25         . = ALIGN(16);
  26         .rodata : {
  27                 *(.rodata*)
  28         }
  29
  30         .videocards : {
  31                 video_cards = .;
  32                 *(.videocards)
  33                 video_cards_end = .;
  34         }
  35
  36         . = ALIGN(16);
  37         .data : {
  38                  *(.data*)
  39         }
  40
  41         .signature : {
  42                 end_signature = .;
  43                 LONG(0x65a22c82)
  44         }
  45
  46         . = ALIGN(16);
  47         .bss :  {
  48                 __bss_start = .;
  49                 *(.bss)
  50                 __bss_end = .;
  51         }
  52
  53         . = ALIGN(16);
  54         _end = .;
  55
  56         /DISCARD/ : {
  57                 *(.note*)
  58         }
  59
  60         . = ASSERT(_end <= WAKEUP_SIZE, "Wakeup too big!");
  61 }