git.oblomov.eu Git - linux-2.6/blob - arch/arm/mach-s3c2410/sleep.S

   1 /* linux/arch/arm/mach-s3c2410/sleep.S
   2  *
   3  * Copyright (c) 2004 Simtec Electronics
   4  *      Ben Dooks <ben@simtec.co.uk>
   5  *
   6  * S3C2410 Power Manager (Suspend-To-RAM) support
   7  *
   8  * Based on PXA/SA1100 sleep code by:
   9  *      Nicolas Pitre, (c) 2002 Monta Vista Software Inc
  10  *      Cliff Brake, (c) 2001
  11  *
  12  * This program is free software; you can redistribute it and/or modify
  13  * it under the terms of the GNU General Public License as published by
  14  * the Free Software Foundation; either version 2 of the License, or
  15  * (at your option) any later version.
  16  *
  17  * This program is distributed in the hope that it will be useful,
  18  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  19  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20  * GNU General Public License for more details.
  21  *
  22  * You should have received a copy of the GNU General Public License
  23  * along with this program; if not, write to the Free Software
  24  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  25 */
  26
  27 #include <linux/config.h>
  28 #include <linux/linkage.h>
  29 #include <asm/assembler.h>
  30 #include <asm/hardware.h>
  31 #include <asm/arch/map.h>
  32
  33 #include <asm/arch/regs-gpio.h>
  34 #include <asm/arch/regs-clock.h>
  35 #include <asm/arch/regs-mem.h>
  36 #include <asm/arch/regs-serial.h>
  37
  38 /* CONFIG_DEBUG_RESUME is dangerous if your bootloader does not
  39  * reset the UART configuration, only enable if you really need this!
  40 */
  41 //#define CONFIG_DEBUG_RESUME
  42
  43         .text
  44
  45         /* s3c2410_cpu_suspend
  46          *
  47          * put the cpu into sleep mode
  48          *
  49          * entry:
  50          *      r0 = sleep save block
  51         */
  52
  53 ENTRY(s3c2410_cpu_suspend)
  54         stmfd   sp!, { r4 - r12, lr }
  55
  56         @@ store co-processor registers
  57
  58         mrc     p15, 0, r4, c15, c1, 0  @ CP access register
  59         mrc     p15, 0, r5, c13, c0, 0  @ PID
  60         mrc     p15, 0, r6, c3, c0, 0   @ Domain ID
  61         mrc     p15, 0, r7, c2, c0, 0   @ translation table base address
  62         mrc     p15, 0, r8, c1, c0, 0   @ control register
  63
  64         stmia   r0, { r4 - r13 }
  65
  66         @@ flush the caches to ensure everything is back out to
  67         @@ SDRAM before the core powers down
  68
  69 #ifndef CONFIG_CPU_DCACHE_WRITETHROUGH
  70         bl      arm920_flush_kern_cache_all
  71 #endif
  72
  73         @@ prepare cpu to sleep
  74
  75         ldr     r4, =S3C2410_REFRESH
  76         ldr     r5, =S3C24XX_MISCCR
  77         ldr     r6, =S3C2410_CLKCON
  78         ldr     r7, [ r4 ]              @ get REFRESH (and ensure in TLB)
  79         ldr     r8, [ r5 ]              @ get MISCCR (and ensure in TLB)
  80         ldr     r9, [ r6 ]              @ get CLKCON (and ensure in TLB)
  81
  82         orr     r7, r7, #S3C2410_REFRESH_SELF   @ SDRAM sleep command
  83         orr     r8, r8, #S3C2410_MISCCR_SDSLEEP @ SDRAM power-down signals
  84         orr     r9, r9, #S3C2410_CLKCON_POWER   @ power down command
  85
  86         teq     pc, #0                  @ first as a trial-run to load cache
  87         bl      s3c2410_do_sleep
  88         teq     r0, r0                  @ now do it for real
  89         b       s3c2410_do_sleep        @
  90
  91         @@ align next bit of code to cache line
  92         .align  8
  93 s3c2410_do_sleep:
  94         streq   r7, [ r4 ]                      @ SDRAM sleep command
  95         streq   r8, [ r5 ]                      @ SDRAM power-down config
  96         streq   r9, [ r6 ]                      @ CPU sleep
  97 1:      beq     1b
  98         mov     pc, r14
  99
 100         @@ return to the caller, after having the MMU
 101         @@ turned on, this restores the last bits from the
 102         @@ stack
 103 resume_with_mmu:
 104         ldmfd   sp!, { r4 - r12, pc }
 105
 106         .ltorg
 107
 108         @@ the next bits sit in the .data segment, even though they
 109         @@ happen to be code... the s3c2410_sleep_save_phys needs to be
 110         @@ accessed by the resume code before it can restore the MMU.
 111         @@ This means that the variable has to be close enough for the
 112         @@ code to read it... since the .text segment needs to be RO,
 113         @@ the data segment can be the only place to put this code.
 114
 115         .data
 116
 117         .global s3c2410_sleep_save_phys
 118 s3c2410_sleep_save_phys:
 119         .word   0
 120
 121         /* s3c2410_cpu_resume
 122          *
 123          * resume code entry for bootloader to call
 124          *
 125          * we must put this code here in the data segment as we have no
 126          * other way of restoring the stack pointer after sleep, and we
 127          * must not write to the code segment (code is read-only)
 128         */
 129
 130 ENTRY(s3c2410_cpu_resume)
 131         mov     r0, #PSR_I_BIT | PSR_F_BIT | SVC_MODE
 132         msr     cpsr_c, r0
 133
 134         @@ load UART to allow us to print the two characters for
 135         @@ resume debug
 136
 137         mov     r2, #S3C24XX_PA_UART & 0xff000000
 138         orr     r2, r2, #S3C24XX_PA_UART & 0xff000
 139
 140 #if 0
 141         /* SMDK2440 LED set */
 142         mov     r14, #S3C24XX_PA_GPIO
 143         ldr     r12, [ r14, #0x54 ]
 144         bic     r12, r12, #3<<4
 145         orr     r12, r12, #1<<7
 146         str     r12, [ r14, #0x54 ]
 147 #endif
 148
 149 #ifdef CONFIG_DEBUG_RESUME
 150         mov     r3, #'L'
 151         strb    r3, [ r2, #S3C2410_UTXH ]
 152 1001:
 153         ldrb    r14, [ r3, #S3C2410_UTRSTAT ]
 154         tst     r14, #S3C2410_UTRSTAT_TXE
 155         beq     1001b
 156 #endif /* CONFIG_DEBUG_RESUME */
 157
 158         mov     r1, #0
 159         mcr     p15, 0, r1, c8, c7, 0           @@ invalidate I & D TLBs
 160         mcr     p15, 0, r1, c7, c7, 0           @@ invalidate I & D caches
 161
 162         ldr     r0, s3c2410_sleep_save_phys     @ address of restore block
 163         ldmia   r0, { r4 - r13 }
 164
 165         mcr     p15, 0, r4, c15, c1, 0          @ CP access register
 166         mcr     p15, 0, r5, c13, c0, 0          @ PID
 167         mcr     p15, 0, r6, c3, c0, 0           @ Domain ID
 168         mcr     p15, 0, r7, c2, c0, 0           @ translation table base
 169
 170 #ifdef CONFIG_DEBUG_RESUME
 171         mov     r3, #'R'
 172         strb    r3, [ r2, #S3C2410_UTXH ]
 173 #endif
 174
 175         ldr     r2, =resume_with_mmu
 176         mcr     p15, 0, r8, c1, c0, 0           @ turn on MMU, etc
 177         nop                                     @ second-to-last before mmu
 178         mov     pc, r2                          @ go back to virtual address
 179
 180         .ltorg