git.oblomov.eu Git - linux-2.6/blob - arch/i386/kernel/entry.S

   1 /*
   2  *  linux/arch/i386/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  */
   6
   7 /*
   8  * entry.S contains the system-call and fault low-level handling routines.
   9  * This also contains the timer-interrupt handler, as well as all interrupts
  10  * and faults that can result in a task-switch.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after a timer-interrupt and after each system call.
  14  *
  15  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  16  * on a 486.
  17  *
  18  * Stack layout in 'ret_from_system_call':
  19  *      ptrace needs to have all regs on the stack.
  20  *      if the order here is changed, it needs to be
  21  *      updated in fork.c:copy_process, signal.c:do_signal,
  22  *      ptrace.c and ptrace.h
  23  *
  24  *       0(%esp) - %ebx
  25  *       4(%esp) - %ecx
  26  *       8(%esp) - %edx
  27  *       C(%esp) - %esi
  28  *      10(%esp) - %edi
  29  *      14(%esp) - %ebp
  30  *      18(%esp) - %eax
  31  *      1C(%esp) - %ds
  32  *      20(%esp) - %es
  33  *      24(%esp) - %fs
  34  *      28(%esp) - orig_eax
  35  *      2C(%esp) - %eip
  36  *      30(%esp) - %cs
  37  *      34(%esp) - %eflags
  38  *      38(%esp) - %oldesp
  39  *      3C(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/irqflags.h>
  47 #include <asm/errno.h>
  48 #include <asm/segment.h>
  49 #include <asm/smp.h>
  50 #include <asm/page.h>
  51 #include <asm/desc.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include "irq_vectors.h"
  55
  56 /*
  57  * We use macros for low-level operations which need to be overridden
  58  * for paravirtualization.  The following will never clobber any registers:
  59  *   INTERRUPT_RETURN (aka. "iret")
  60  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  61  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  62  *
  63  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  64  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  65  * Allowing a register to be clobbered can shrink the paravirt replacement
  66  * enough to patch inline, increasing performance.
  67  */
  68
  69 #define nr_syscalls ((syscall_table_size)/4)
  70
  71 CF_MASK         = 0x00000001
  72 TF_MASK         = 0x00000100
  73 IF_MASK         = 0x00000200
  74 DF_MASK         = 0x00000400
  75 NT_MASK         = 0x00004000
  76 VM_MASK         = 0x00020000
  77
  78 #ifdef CONFIG_PREEMPT
  79 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  80 #else
  81 #define preempt_stop(clobbers)
  82 #define resume_kernel           restore_nocheck
  83 #endif
  84
  85 .macro TRACE_IRQS_IRET
  86 #ifdef CONFIG_TRACE_IRQFLAGS
  87         testl $IF_MASK,PT_EFLAGS(%esp)     # interrupts off?
  88         jz 1f
  89         TRACE_IRQS_ON
  90 1:
  91 #endif
  92 .endm
  93
  94 #ifdef CONFIG_VM86
  95 #define resume_userspace_sig    check_userspace
  96 #else
  97 #define resume_userspace_sig    resume_userspace
  98 #endif
  99
 100 #define SAVE_ALL \
 101         cld; \
 102         pushl %fs; \
 103         CFI_ADJUST_CFA_OFFSET 4;\
 104         /*CFI_REL_OFFSET fs, 0;*/\
 105         pushl %es; \
 106         CFI_ADJUST_CFA_OFFSET 4;\
 107         /*CFI_REL_OFFSET es, 0;*/\
 108         pushl %ds; \
 109         CFI_ADJUST_CFA_OFFSET 4;\
 110         /*CFI_REL_OFFSET ds, 0;*/\
 111         pushl %eax; \
 112         CFI_ADJUST_CFA_OFFSET 4;\
 113         CFI_REL_OFFSET eax, 0;\
 114         pushl %ebp; \
 115         CFI_ADJUST_CFA_OFFSET 4;\
 116         CFI_REL_OFFSET ebp, 0;\
 117         pushl %edi; \
 118         CFI_ADJUST_CFA_OFFSET 4;\
 119         CFI_REL_OFFSET edi, 0;\
 120         pushl %esi; \
 121         CFI_ADJUST_CFA_OFFSET 4;\
 122         CFI_REL_OFFSET esi, 0;\
 123         pushl %edx; \
 124         CFI_ADJUST_CFA_OFFSET 4;\
 125         CFI_REL_OFFSET edx, 0;\
 126         pushl %ecx; \
 127         CFI_ADJUST_CFA_OFFSET 4;\
 128         CFI_REL_OFFSET ecx, 0;\
 129         pushl %ebx; \
 130         CFI_ADJUST_CFA_OFFSET 4;\
 131         CFI_REL_OFFSET ebx, 0;\
 132         movl $(__USER_DS), %edx; \
 133         movl %edx, %ds; \
 134         movl %edx, %es; \
 135         movl $(__KERNEL_PDA), %edx; \
 136         movl %edx, %fs
 137
 138 #define RESTORE_INT_REGS \
 139         popl %ebx;      \
 140         CFI_ADJUST_CFA_OFFSET -4;\
 141         CFI_RESTORE ebx;\
 142         popl %ecx;      \
 143         CFI_ADJUST_CFA_OFFSET -4;\
 144         CFI_RESTORE ecx;\
 145         popl %edx;      \
 146         CFI_ADJUST_CFA_OFFSET -4;\
 147         CFI_RESTORE edx;\
 148         popl %esi;      \
 149         CFI_ADJUST_CFA_OFFSET -4;\
 150         CFI_RESTORE esi;\
 151         popl %edi;      \
 152         CFI_ADJUST_CFA_OFFSET -4;\
 153         CFI_RESTORE edi;\
 154         popl %ebp;      \
 155         CFI_ADJUST_CFA_OFFSET -4;\
 156         CFI_RESTORE ebp;\
 157         popl %eax;      \
 158         CFI_ADJUST_CFA_OFFSET -4;\
 159         CFI_RESTORE eax
 160
 161 #define RESTORE_REGS    \
 162         RESTORE_INT_REGS; \
 163 1:      popl %ds;       \
 164         CFI_ADJUST_CFA_OFFSET -4;\
 165         /*CFI_RESTORE ds;*/\
 166 2:      popl %es;       \
 167         CFI_ADJUST_CFA_OFFSET -4;\
 168         /*CFI_RESTORE es;*/\
 169 3:      popl %fs;       \
 170         CFI_ADJUST_CFA_OFFSET -4;\
 171         /*CFI_RESTORE fs;*/\
 172 .pushsection .fixup,"ax";       \
 173 4:      movl $0,(%esp); \
 174         jmp 1b;         \
 175 5:      movl $0,(%esp); \
 176         jmp 2b;         \
 177 6:      movl $0,(%esp); \
 178         jmp 3b;         \
 179 .section __ex_table,"a";\
 180         .align 4;       \
 181         .long 1b,4b;    \
 182         .long 2b,5b;    \
 183         .long 3b,6b;    \
 184 .popsection
 185
 186 #define RING0_INT_FRAME \
 187         CFI_STARTPROC simple;\
 188         CFI_SIGNAL_FRAME;\
 189         CFI_DEF_CFA esp, 3*4;\
 190         /*CFI_OFFSET cs, -2*4;*/\
 191         CFI_OFFSET eip, -3*4
 192
 193 #define RING0_EC_FRAME \
 194         CFI_STARTPROC simple;\
 195         CFI_SIGNAL_FRAME;\
 196         CFI_DEF_CFA esp, 4*4;\
 197         /*CFI_OFFSET cs, -2*4;*/\
 198         CFI_OFFSET eip, -3*4
 199
 200 #define RING0_PTREGS_FRAME \
 201         CFI_STARTPROC simple;\
 202         CFI_SIGNAL_FRAME;\
 203         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX;\
 204         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/\
 205         CFI_OFFSET eip, PT_EIP-PT_OLDESP;\
 206         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/\
 207         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/\
 208         CFI_OFFSET eax, PT_EAX-PT_OLDESP;\
 209         CFI_OFFSET ebp, PT_EBP-PT_OLDESP;\
 210         CFI_OFFSET edi, PT_EDI-PT_OLDESP;\
 211         CFI_OFFSET esi, PT_ESI-PT_OLDESP;\
 212         CFI_OFFSET edx, PT_EDX-PT_OLDESP;\
 213         CFI_OFFSET ecx, PT_ECX-PT_OLDESP;\
 214         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 215
 216 ENTRY(ret_from_fork)
 217         CFI_STARTPROC
 218         pushl %eax
 219         CFI_ADJUST_CFA_OFFSET 4
 220         call schedule_tail
 221         GET_THREAD_INFO(%ebp)
 222         popl %eax
 223         CFI_ADJUST_CFA_OFFSET -4
 224         pushl $0x0202                   # Reset kernel eflags
 225         CFI_ADJUST_CFA_OFFSET 4
 226         popfl
 227         CFI_ADJUST_CFA_OFFSET -4
 228         jmp syscall_exit
 229         CFI_ENDPROC
 230 END(ret_from_fork)
 231
 232 /*
 233  * Return to user mode is not as complex as all this looks,
 234  * but we want the default path for a system call return to
 235  * go as quickly as possible which is why some of this is
 236  * less clear than it otherwise should be.
 237  */
 238
 239         # userspace resumption stub bypassing syscall exit tracing
 240         ALIGN
 241         RING0_PTREGS_FRAME
 242 ret_from_exception:
 243         preempt_stop(CLBR_ANY)
 244 ret_from_intr:
 245         GET_THREAD_INFO(%ebp)
 246 check_userspace:
 247         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 248         movb PT_CS(%esp), %al
 249         andl $(VM_MASK | SEGMENT_RPL_MASK), %eax
 250         cmpl $USER_RPL, %eax
 251         jb resume_kernel                # not returning to v8086 or userspace
 252
 253 ENTRY(resume_userspace)
 254         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 255                                         # setting need_resched or sigpending
 256                                         # between sampling and the iret
 257         movl TI_flags(%ebp), %ecx
 258         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 259                                         # int/exception return?
 260         jne work_pending
 261         jmp restore_all
 262 END(ret_from_exception)
 263
 264 #ifdef CONFIG_PREEMPT
 265 ENTRY(resume_kernel)
 266         DISABLE_INTERRUPTS(CLBR_ANY)
 267         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 268         jnz restore_nocheck
 269 need_resched:
 270         movl TI_flags(%ebp), %ecx       # need_resched set ?
 271         testb $_TIF_NEED_RESCHED, %cl
 272         jz restore_all
 273         testl $IF_MASK,PT_EFLAGS(%esp)  # interrupts off (exception path) ?
 274         jz restore_all
 275         call preempt_schedule_irq
 276         jmp need_resched
 277 END(resume_kernel)
 278 #endif
 279         CFI_ENDPROC
 280
 281 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 282    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 283
 284         # sysenter call handler stub
 285 ENTRY(sysenter_entry)
 286         CFI_STARTPROC simple
 287         CFI_SIGNAL_FRAME
 288         CFI_DEF_CFA esp, 0
 289         CFI_REGISTER esp, ebp
 290         movl TSS_sysenter_esp0(%esp),%esp
 291 sysenter_past_esp:
 292         /*
 293          * No need to follow this irqs on/off section: the syscall
 294          * disabled irqs and here we enable it straight after entry:
 295          */
 296         ENABLE_INTERRUPTS(CLBR_NONE)
 297         pushl $(__USER_DS)
 298         CFI_ADJUST_CFA_OFFSET 4
 299         /*CFI_REL_OFFSET ss, 0*/
 300         pushl %ebp
 301         CFI_ADJUST_CFA_OFFSET 4
 302         CFI_REL_OFFSET esp, 0
 303         pushfl
 304         CFI_ADJUST_CFA_OFFSET 4
 305         pushl $(__USER_CS)
 306         CFI_ADJUST_CFA_OFFSET 4
 307         /*CFI_REL_OFFSET cs, 0*/
 308 #ifndef CONFIG_COMPAT_VDSO
 309         /*
 310          * Push current_thread_info()->sysenter_return to the stack.
 311          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 312          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 313          */
 314         pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
 315 #else
 316         pushl $SYSENTER_RETURN
 317 #endif
 318         CFI_ADJUST_CFA_OFFSET 4
 319         CFI_REL_OFFSET eip, 0
 320
 321 /*
 322  * Load the potential sixth argument from user stack.
 323  * Careful about security.
 324  */
 325         cmpl $__PAGE_OFFSET-3,%ebp
 326         jae syscall_fault
 327 1:      movl (%ebp),%ebp
 328 .section __ex_table,"a"
 329         .align 4
 330         .long 1b,syscall_fault
 331 .previous
 332
 333         pushl %eax
 334         CFI_ADJUST_CFA_OFFSET 4
 335         SAVE_ALL
 336         GET_THREAD_INFO(%ebp)
 337
 338         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 339         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 340         jnz syscall_trace_entry
 341         cmpl $(nr_syscalls), %eax
 342         jae syscall_badsys
 343         call *sys_call_table(,%eax,4)
 344         movl %eax,PT_EAX(%esp)
 345         DISABLE_INTERRUPTS(CLBR_ECX|CLBR_EDX)
 346         TRACE_IRQS_OFF
 347         movl TI_flags(%ebp), %ecx
 348         testw $_TIF_ALLWORK_MASK, %cx
 349         jne syscall_exit_work
 350 /* if something modifies registers it must also disable sysexit */
 351         movl PT_EIP(%esp), %edx
 352         movl PT_OLDESP(%esp), %ecx
 353         xorl %ebp,%ebp
 354         TRACE_IRQS_ON
 355 1:      mov  PT_FS(%esp), %fs
 356         ENABLE_INTERRUPTS_SYSEXIT
 357         CFI_ENDPROC
 358 .pushsection .fixup,"ax"
 359 2:      movl $0,PT_FS(%esp)
 360         jmp 1b
 361 .section __ex_table,"a"
 362         .align 4
 363         .long 1b,2b
 364 .popsection
 365 ENDPROC(sysenter_entry)
 366
 367         # system call handler stub
 368 ENTRY(system_call)
 369         RING0_INT_FRAME                 # can't unwind into user space anyway
 370         pushl %eax                      # save orig_eax
 371         CFI_ADJUST_CFA_OFFSET 4
 372         SAVE_ALL
 373         GET_THREAD_INFO(%ebp)
 374         testl $TF_MASK,PT_EFLAGS(%esp)
 375         jz no_singlestep
 376         orl $_TIF_SINGLESTEP,TI_flags(%ebp)
 377 no_singlestep:
 378                                         # system call tracing in operation / emulation
 379         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 380         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 381         jnz syscall_trace_entry
 382         cmpl $(nr_syscalls), %eax
 383         jae syscall_badsys
 384 syscall_call:
 385         call *sys_call_table(,%eax,4)
 386         movl %eax,PT_EAX(%esp)          # store the return value
 387 syscall_exit:
 388         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 389                                         # setting need_resched or sigpending
 390                                         # between sampling and the iret
 391         TRACE_IRQS_OFF
 392         movl TI_flags(%ebp), %ecx
 393         testw $_TIF_ALLWORK_MASK, %cx   # current->work
 394         jne syscall_exit_work
 395
 396 restore_all:
 397         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 398         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 399         # are returning to the kernel.
 400         # See comments in process.c:copy_thread() for details.
 401         movb PT_OLDSS(%esp), %ah
 402         movb PT_CS(%esp), %al
 403         andl $(VM_MASK | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 404         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 405         CFI_REMEMBER_STATE
 406         je ldt_ss                       # returning to user-space with LDT SS
 407 restore_nocheck:
 408         TRACE_IRQS_IRET
 409 restore_nocheck_notrace:
 410         RESTORE_REGS
 411         addl $4, %esp                   # skip orig_eax/error_code
 412         CFI_ADJUST_CFA_OFFSET -4
 413 1:      INTERRUPT_RETURN
 414 .section .fixup,"ax"
 415 iret_exc:
 416         TRACE_IRQS_ON
 417         ENABLE_INTERRUPTS(CLBR_NONE)
 418         pushl $0                        # no error code
 419         pushl $do_iret_error
 420         jmp error_code
 421 .previous
 422 .section __ex_table,"a"
 423         .align 4
 424         .long 1b,iret_exc
 425 .previous
 426
 427         CFI_RESTORE_STATE
 428 ldt_ss:
 429         larl PT_OLDSS(%esp), %eax
 430         jnz restore_nocheck
 431         testl $0x00400000, %eax         # returning to 32bit stack?
 432         jnz restore_nocheck             # allright, normal return
 433
 434 #ifdef CONFIG_PARAVIRT
 435         /*
 436          * The kernel can't run on a non-flat stack if paravirt mode
 437          * is active.  Rather than try to fixup the high bits of
 438          * ESP, bypass this code entirely.  This may break DOSemu
 439          * and/or Wine support in a paravirt VM, although the option
 440          * is still available to implement the setting of the high
 441          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 442          */
 443         cmpl $0, paravirt_ops+PARAVIRT_enabled
 444         jne restore_nocheck
 445 #endif
 446
 447         /* If returning to userspace with 16bit stack,
 448          * try to fix the higher word of ESP, as the CPU
 449          * won't restore it.
 450          * This is an "official" bug of all the x86-compatible
 451          * CPUs, which we can try to work around to make
 452          * dosemu and wine happy. */
 453         movl PT_OLDESP(%esp), %eax
 454         movl %esp, %edx
 455         call patch_espfix_desc
 456         pushl $__ESPFIX_SS
 457         CFI_ADJUST_CFA_OFFSET 4
 458         pushl %eax
 459         CFI_ADJUST_CFA_OFFSET 4
 460         DISABLE_INTERRUPTS(CLBR_EAX)
 461         TRACE_IRQS_OFF
 462         lss (%esp), %esp
 463         CFI_ADJUST_CFA_OFFSET -8
 464         jmp restore_nocheck
 465         CFI_ENDPROC
 466 ENDPROC(system_call)
 467
 468         # perform work that needs to be done immediately before resumption
 469         ALIGN
 470         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 471 work_pending:
 472         testb $_TIF_NEED_RESCHED, %cl
 473         jz work_notifysig
 474 work_resched:
 475         call schedule
 476         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 477                                         # setting need_resched or sigpending
 478                                         # between sampling and the iret
 479         TRACE_IRQS_OFF
 480         movl TI_flags(%ebp), %ecx
 481         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 482                                         # than syscall tracing?
 483         jz restore_all
 484         testb $_TIF_NEED_RESCHED, %cl
 485         jnz work_resched
 486
 487 work_notifysig:                         # deal with pending signals and
 488                                         # notify-resume requests
 489 #ifdef CONFIG_VM86
 490         testl $VM_MASK, PT_EFLAGS(%esp)
 491         movl %esp, %eax
 492         jne work_notifysig_v86          # returning to kernel-space or
 493                                         # vm86-space
 494         xorl %edx, %edx
 495         call do_notify_resume
 496         jmp resume_userspace_sig
 497
 498         ALIGN
 499 work_notifysig_v86:
 500         pushl %ecx                      # save ti_flags for do_notify_resume
 501         CFI_ADJUST_CFA_OFFSET 4
 502         call save_v86_state             # %eax contains pt_regs pointer
 503         popl %ecx
 504         CFI_ADJUST_CFA_OFFSET -4
 505         movl %eax, %esp
 506 #else
 507         movl %esp, %eax
 508 #endif
 509         xorl %edx, %edx
 510         call do_notify_resume
 511         jmp resume_userspace_sig
 512 END(work_pending)
 513
 514         # perform syscall exit tracing
 515         ALIGN
 516 syscall_trace_entry:
 517         movl $-ENOSYS,PT_EAX(%esp)
 518         movl %esp, %eax
 519         xorl %edx,%edx
 520         call do_syscall_trace
 521         cmpl $0, %eax
 522         jne resume_userspace            # ret != 0 -> running under PTRACE_SYSEMU,
 523                                         # so must skip actual syscall
 524         movl PT_ORIG_EAX(%esp), %eax
 525         cmpl $(nr_syscalls), %eax
 526         jnae syscall_call
 527         jmp syscall_exit
 528 END(syscall_trace_entry)
 529
 530         # perform syscall exit tracing
 531         ALIGN
 532 syscall_exit_work:
 533         testb $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP), %cl
 534         jz work_pending
 535         TRACE_IRQS_ON
 536         ENABLE_INTERRUPTS(CLBR_ANY)     # could let do_syscall_trace() call
 537                                         # schedule() instead
 538         movl %esp, %eax
 539         movl $1, %edx
 540         call do_syscall_trace
 541         jmp resume_userspace
 542 END(syscall_exit_work)
 543         CFI_ENDPROC
 544
 545         RING0_INT_FRAME                 # can't unwind into user space anyway
 546 syscall_fault:
 547         pushl %eax                      # save orig_eax
 548         CFI_ADJUST_CFA_OFFSET 4
 549         SAVE_ALL
 550         GET_THREAD_INFO(%ebp)
 551         movl $-EFAULT,PT_EAX(%esp)
 552         jmp resume_userspace
 553 END(syscall_fault)
 554
 555 syscall_badsys:
 556         movl $-ENOSYS,PT_EAX(%esp)
 557         jmp resume_userspace
 558 END(syscall_badsys)
 559         CFI_ENDPROC
 560
 561 #define FIXUP_ESPFIX_STACK \
 562         /* since we are on a wrong stack, we cant make it a C code :( */ \
 563         movl %fs:PDA_cpu, %ebx; \
 564         PER_CPU(cpu_gdt_descr, %ebx); \
 565         movl GDS_address(%ebx), %ebx; \
 566         GET_DESC_BASE(GDT_ENTRY_ESPFIX_SS, %ebx, %eax, %ax, %al, %ah); \
 567         addl %esp, %eax; \
 568         pushl $__KERNEL_DS; \
 569         CFI_ADJUST_CFA_OFFSET 4; \
 570         pushl %eax; \
 571         CFI_ADJUST_CFA_OFFSET 4; \
 572         lss (%esp), %esp; \
 573         CFI_ADJUST_CFA_OFFSET -8;
 574 #define UNWIND_ESPFIX_STACK \
 575         movl %ss, %eax; \
 576         /* see if on espfix stack */ \
 577         cmpw $__ESPFIX_SS, %ax; \
 578         jne 27f; \
 579         movl $__KERNEL_DS, %eax; \
 580         movl %eax, %ds; \
 581         movl %eax, %es; \
 582         /* switch to normal stack */ \
 583         FIXUP_ESPFIX_STACK; \
 584 27:;
 585
 586 /*
 587  * Build the entry stubs and pointer table with
 588  * some assembler magic.
 589  */
 590 .data
 591 ENTRY(interrupt)
 592 .text
 593
 594 ENTRY(irq_entries_start)
 595         RING0_INT_FRAME
 596 vector=0
 597 .rept NR_IRQS
 598         ALIGN
 599  .if vector
 600         CFI_ADJUST_CFA_OFFSET -4
 601  .endif
 602 1:      pushl $~(vector)
 603         CFI_ADJUST_CFA_OFFSET 4
 604         jmp common_interrupt
 605  .previous
 606         .long 1b
 607  .text
 608 vector=vector+1
 609 .endr
 610 END(irq_entries_start)
 611
 612 .previous
 613 END(interrupt)
 614 .previous
 615
 616 /*
 617  * the CPU automatically disables interrupts when executing an IRQ vector,
 618  * so IRQ-flags tracing has to follow that:
 619  */
 620         ALIGN
 621 common_interrupt:
 622         SAVE_ALL
 623         TRACE_IRQS_OFF
 624         movl %esp,%eax
 625         call do_IRQ
 626         jmp ret_from_intr
 627 ENDPROC(common_interrupt)
 628         CFI_ENDPROC
 629
 630 #define BUILD_INTERRUPT(name, nr)       \
 631 ENTRY(name)                             \
 632         RING0_INT_FRAME;                \
 633         pushl $~(nr);                   \
 634         CFI_ADJUST_CFA_OFFSET 4;        \
 635         SAVE_ALL;                       \
 636         TRACE_IRQS_OFF                  \
 637         movl %esp,%eax;                 \
 638         call smp_/**/name;              \
 639         jmp ret_from_intr;              \
 640         CFI_ENDPROC;                    \
 641 ENDPROC(name)
 642
 643 /* The include is where all of the SMP etc. interrupts come from */
 644 #include "entry_arch.h"
 645
 646 /* This alternate entry is needed because we hijack the apic LVTT */
 647 #if defined(CONFIG_VMI) && defined(CONFIG_X86_LOCAL_APIC)
 648 BUILD_INTERRUPT(apic_vmi_timer_interrupt,LOCAL_TIMER_VECTOR)
 649 #endif
 650
 651 KPROBE_ENTRY(page_fault)
 652         RING0_EC_FRAME
 653         pushl $do_page_fault
 654         CFI_ADJUST_CFA_OFFSET 4
 655         ALIGN
 656 error_code:
 657         /* the function address is in %fs's slot on the stack */
 658         pushl %es
 659         CFI_ADJUST_CFA_OFFSET 4
 660         /*CFI_REL_OFFSET es, 0*/
 661         pushl %ds
 662         CFI_ADJUST_CFA_OFFSET 4
 663         /*CFI_REL_OFFSET ds, 0*/
 664         pushl %eax
 665         CFI_ADJUST_CFA_OFFSET 4
 666         CFI_REL_OFFSET eax, 0
 667         pushl %ebp
 668         CFI_ADJUST_CFA_OFFSET 4
 669         CFI_REL_OFFSET ebp, 0
 670         pushl %edi
 671         CFI_ADJUST_CFA_OFFSET 4
 672         CFI_REL_OFFSET edi, 0
 673         pushl %esi
 674         CFI_ADJUST_CFA_OFFSET 4
 675         CFI_REL_OFFSET esi, 0
 676         pushl %edx
 677         CFI_ADJUST_CFA_OFFSET 4
 678         CFI_REL_OFFSET edx, 0
 679         pushl %ecx
 680         CFI_ADJUST_CFA_OFFSET 4
 681         CFI_REL_OFFSET ecx, 0
 682         pushl %ebx
 683         CFI_ADJUST_CFA_OFFSET 4
 684         CFI_REL_OFFSET ebx, 0
 685         cld
 686         pushl %fs
 687         CFI_ADJUST_CFA_OFFSET 4
 688         /*CFI_REL_OFFSET fs, 0*/
 689         movl $(__KERNEL_PDA), %ecx
 690         movl %ecx, %fs
 691         UNWIND_ESPFIX_STACK
 692         popl %ecx
 693         CFI_ADJUST_CFA_OFFSET -4
 694         /*CFI_REGISTER es, ecx*/
 695         movl PT_FS(%esp), %edi          # get the function address
 696         movl PT_ORIG_EAX(%esp), %edx    # get the error code
 697         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
 698         mov  %ecx, PT_FS(%esp)
 699         /*CFI_REL_OFFSET fs, ES*/
 700         movl $(__USER_DS), %ecx
 701         movl %ecx, %ds
 702         movl %ecx, %es
 703         movl %esp,%eax                  # pt_regs pointer
 704         call *%edi
 705         jmp ret_from_exception
 706         CFI_ENDPROC
 707 KPROBE_END(page_fault)
 708
 709 ENTRY(coprocessor_error)
 710         RING0_INT_FRAME
 711         pushl $0
 712         CFI_ADJUST_CFA_OFFSET 4
 713         pushl $do_coprocessor_error
 714         CFI_ADJUST_CFA_OFFSET 4
 715         jmp error_code
 716         CFI_ENDPROC
 717 END(coprocessor_error)
 718
 719 ENTRY(simd_coprocessor_error)
 720         RING0_INT_FRAME
 721         pushl $0
 722         CFI_ADJUST_CFA_OFFSET 4
 723         pushl $do_simd_coprocessor_error
 724         CFI_ADJUST_CFA_OFFSET 4
 725         jmp error_code
 726         CFI_ENDPROC
 727 END(simd_coprocessor_error)
 728
 729 ENTRY(device_not_available)
 730         RING0_INT_FRAME
 731         pushl $-1                       # mark this as an int
 732         CFI_ADJUST_CFA_OFFSET 4
 733         SAVE_ALL
 734         GET_CR0_INTO_EAX
 735         testl $0x4, %eax                # EM (math emulation bit)
 736         jne device_not_available_emulate
 737         preempt_stop(CLBR_ANY)
 738         call math_state_restore
 739         jmp ret_from_exception
 740 device_not_available_emulate:
 741         pushl $0                        # temporary storage for ORIG_EIP
 742         CFI_ADJUST_CFA_OFFSET 4
 743         call math_emulate
 744         addl $4, %esp
 745         CFI_ADJUST_CFA_OFFSET -4
 746         jmp ret_from_exception
 747         CFI_ENDPROC
 748 END(device_not_available)
 749
 750 /*
 751  * Debug traps and NMI can happen at the one SYSENTER instruction
 752  * that sets up the real kernel stack. Check here, since we can't
 753  * allow the wrong stack to be used.
 754  *
 755  * "TSS_sysenter_esp0+12" is because the NMI/debug handler will have
 756  * already pushed 3 words if it hits on the sysenter instruction:
 757  * eflags, cs and eip.
 758  *
 759  * We just load the right stack, and push the three (known) values
 760  * by hand onto the new stack - while updating the return eip past
 761  * the instruction that would have done it for sysenter.
 762  */
 763 #define FIX_STACK(offset, ok, label)            \
 764         cmpw $__KERNEL_CS,4(%esp);              \
 765         jne ok;                                 \
 766 label:                                          \
 767         movl TSS_sysenter_esp0+offset(%esp),%esp;       \
 768         CFI_DEF_CFA esp, 0;                     \
 769         CFI_UNDEFINED eip;                      \
 770         pushfl;                                 \
 771         CFI_ADJUST_CFA_OFFSET 4;                \
 772         pushl $__KERNEL_CS;                     \
 773         CFI_ADJUST_CFA_OFFSET 4;                \
 774         pushl $sysenter_past_esp;               \
 775         CFI_ADJUST_CFA_OFFSET 4;                \
 776         CFI_REL_OFFSET eip, 0
 777
 778 KPROBE_ENTRY(debug)
 779         RING0_INT_FRAME
 780         cmpl $sysenter_entry,(%esp)
 781         jne debug_stack_correct
 782         FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
 783 debug_stack_correct:
 784         pushl $-1                       # mark this as an int
 785         CFI_ADJUST_CFA_OFFSET 4
 786         SAVE_ALL
 787         xorl %edx,%edx                  # error code 0
 788         movl %esp,%eax                  # pt_regs pointer
 789         call do_debug
 790         jmp ret_from_exception
 791         CFI_ENDPROC
 792 KPROBE_END(debug)
 793
 794 /*
 795  * NMI is doubly nasty. It can happen _while_ we're handling
 796  * a debug fault, and the debug fault hasn't yet been able to
 797  * clear up the stack. So we first check whether we got  an
 798  * NMI on the sysenter entry path, but after that we need to
 799  * check whether we got an NMI on the debug path where the debug
 800  * fault happened on the sysenter path.
 801  */
 802 KPROBE_ENTRY(nmi)
 803         RING0_INT_FRAME
 804         pushl %eax
 805         CFI_ADJUST_CFA_OFFSET 4
 806         movl %ss, %eax
 807         cmpw $__ESPFIX_SS, %ax
 808         popl %eax
 809         CFI_ADJUST_CFA_OFFSET -4
 810         je nmi_espfix_stack
 811         cmpl $sysenter_entry,(%esp)
 812         je nmi_stack_fixup
 813         pushl %eax
 814         CFI_ADJUST_CFA_OFFSET 4
 815         movl %esp,%eax
 816         /* Do not access memory above the end of our stack page,
 817          * it might not exist.
 818          */
 819         andl $(THREAD_SIZE-1),%eax
 820         cmpl $(THREAD_SIZE-20),%eax
 821         popl %eax
 822         CFI_ADJUST_CFA_OFFSET -4
 823         jae nmi_stack_correct
 824         cmpl $sysenter_entry,12(%esp)
 825         je nmi_debug_stack_check
 826 nmi_stack_correct:
 827         /* We have a RING0_INT_FRAME here */
 828         pushl %eax
 829         CFI_ADJUST_CFA_OFFSET 4
 830         SAVE_ALL
 831         xorl %edx,%edx          # zero error code
 832         movl %esp,%eax          # pt_regs pointer
 833         call do_nmi
 834         jmp restore_nocheck_notrace
 835         CFI_ENDPROC
 836
 837 nmi_stack_fixup:
 838         RING0_INT_FRAME
 839         FIX_STACK(12,nmi_stack_correct, 1)
 840         jmp nmi_stack_correct
 841
 842 nmi_debug_stack_check:
 843         /* We have a RING0_INT_FRAME here */
 844         cmpw $__KERNEL_CS,16(%esp)
 845         jne nmi_stack_correct
 846         cmpl $debug,(%esp)
 847         jb nmi_stack_correct
 848         cmpl $debug_esp_fix_insn,(%esp)
 849         ja nmi_stack_correct
 850         FIX_STACK(24,nmi_stack_correct, 1)
 851         jmp nmi_stack_correct
 852
 853 nmi_espfix_stack:
 854         /* We have a RING0_INT_FRAME here.
 855          *
 856          * create the pointer to lss back
 857          */
 858         pushl %ss
 859         CFI_ADJUST_CFA_OFFSET 4
 860         pushl %esp
 861         CFI_ADJUST_CFA_OFFSET 4
 862         addw $4, (%esp)
 863         /* copy the iret frame of 12 bytes */
 864         .rept 3
 865         pushl 16(%esp)
 866         CFI_ADJUST_CFA_OFFSET 4
 867         .endr
 868         pushl %eax
 869         CFI_ADJUST_CFA_OFFSET 4
 870         SAVE_ALL
 871         FIXUP_ESPFIX_STACK              # %eax == %esp
 872         xorl %edx,%edx                  # zero error code
 873         call do_nmi
 874         RESTORE_REGS
 875         lss 12+4(%esp), %esp            # back to espfix stack
 876         CFI_ADJUST_CFA_OFFSET -24
 877 1:      INTERRUPT_RETURN
 878         CFI_ENDPROC
 879 .section __ex_table,"a"
 880         .align 4
 881         .long 1b,iret_exc
 882 .previous
 883 KPROBE_END(nmi)
 884
 885 #ifdef CONFIG_PARAVIRT
 886 ENTRY(native_iret)
 887 1:      iret
 888 .section __ex_table,"a"
 889         .align 4
 890         .long 1b,iret_exc
 891 .previous
 892 END(native_iret)
 893
 894 ENTRY(native_irq_enable_sysexit)
 895         sti
 896         sysexit
 897 END(native_irq_enable_sysexit)
 898 #endif
 899
 900 KPROBE_ENTRY(int3)
 901         RING0_INT_FRAME
 902         pushl $-1                       # mark this as an int
 903         CFI_ADJUST_CFA_OFFSET 4
 904         SAVE_ALL
 905         xorl %edx,%edx          # zero error code
 906         movl %esp,%eax          # pt_regs pointer
 907         call do_int3
 908         jmp ret_from_exception
 909         CFI_ENDPROC
 910 KPROBE_END(int3)
 911
 912 ENTRY(overflow)
 913         RING0_INT_FRAME
 914         pushl $0
 915         CFI_ADJUST_CFA_OFFSET 4
 916         pushl $do_overflow
 917         CFI_ADJUST_CFA_OFFSET 4
 918         jmp error_code
 919         CFI_ENDPROC
 920 END(overflow)
 921
 922 ENTRY(bounds)
 923         RING0_INT_FRAME
 924         pushl $0
 925         CFI_ADJUST_CFA_OFFSET 4
 926         pushl $do_bounds
 927         CFI_ADJUST_CFA_OFFSET 4
 928         jmp error_code
 929         CFI_ENDPROC
 930 END(bounds)
 931
 932 ENTRY(invalid_op)
 933         RING0_INT_FRAME
 934         pushl $0
 935         CFI_ADJUST_CFA_OFFSET 4
 936         pushl $do_invalid_op
 937         CFI_ADJUST_CFA_OFFSET 4
 938         jmp error_code
 939         CFI_ENDPROC
 940 END(invalid_op)
 941
 942 ENTRY(coprocessor_segment_overrun)
 943         RING0_INT_FRAME
 944         pushl $0
 945         CFI_ADJUST_CFA_OFFSET 4
 946         pushl $do_coprocessor_segment_overrun
 947         CFI_ADJUST_CFA_OFFSET 4
 948         jmp error_code
 949         CFI_ENDPROC
 950 END(coprocessor_segment_overrun)
 951
 952 ENTRY(invalid_TSS)
 953         RING0_EC_FRAME
 954         pushl $do_invalid_TSS
 955         CFI_ADJUST_CFA_OFFSET 4
 956         jmp error_code
 957         CFI_ENDPROC
 958 END(invalid_TSS)
 959
 960 ENTRY(segment_not_present)
 961         RING0_EC_FRAME
 962         pushl $do_segment_not_present
 963         CFI_ADJUST_CFA_OFFSET 4
 964         jmp error_code
 965         CFI_ENDPROC
 966 END(segment_not_present)
 967
 968 ENTRY(stack_segment)
 969         RING0_EC_FRAME
 970         pushl $do_stack_segment
 971         CFI_ADJUST_CFA_OFFSET 4
 972         jmp error_code
 973         CFI_ENDPROC
 974 END(stack_segment)
 975
 976 KPROBE_ENTRY(general_protection)
 977         RING0_EC_FRAME
 978         pushl $do_general_protection
 979         CFI_ADJUST_CFA_OFFSET 4
 980         jmp error_code
 981         CFI_ENDPROC
 982 KPROBE_END(general_protection)
 983
 984 ENTRY(alignment_check)
 985         RING0_EC_FRAME
 986         pushl $do_alignment_check
 987         CFI_ADJUST_CFA_OFFSET 4
 988         jmp error_code
 989         CFI_ENDPROC
 990 END(alignment_check)
 991
 992 ENTRY(divide_error)
 993         RING0_INT_FRAME
 994         pushl $0                        # no error code
 995         CFI_ADJUST_CFA_OFFSET 4
 996         pushl $do_divide_error
 997         CFI_ADJUST_CFA_OFFSET 4
 998         jmp error_code
 999         CFI_ENDPROC
1000 END(divide_error)
1001
1002 #ifdef CONFIG_X86_MCE
1003 ENTRY(machine_check)
1004         RING0_INT_FRAME
1005         pushl $0
1006         CFI_ADJUST_CFA_OFFSET 4
1007         pushl machine_check_vector
1008         CFI_ADJUST_CFA_OFFSET 4
1009         jmp error_code
1010         CFI_ENDPROC
1011 END(machine_check)
1012 #endif
1013
1014 ENTRY(spurious_interrupt_bug)
1015         RING0_INT_FRAME
1016         pushl $0
1017         CFI_ADJUST_CFA_OFFSET 4
1018         pushl $do_spurious_interrupt_bug
1019         CFI_ADJUST_CFA_OFFSET 4
1020         jmp error_code
1021         CFI_ENDPROC
1022 END(spurious_interrupt_bug)
1023
1024 ENTRY(kernel_thread_helper)
1025         pushl $0                # fake return address for unwinder
1026         CFI_STARTPROC
1027         movl %edx,%eax
1028         push %edx
1029         CFI_ADJUST_CFA_OFFSET 4
1030         call *%ebx
1031         push %eax
1032         CFI_ADJUST_CFA_OFFSET 4
1033         call do_exit
1034         CFI_ENDPROC
1035 ENDPROC(kernel_thread_helper)
1036
1037 .section .rodata,"a"
1038 #include "syscall_table.S"
1039
1040 syscall_table_size=(.-sys_call_table)