git.oblomov.eu Git - linux-2.6/blob - arch/x86_64/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/vsyscall32.h>
  16 #include <linux/linkage.h>
  17
  18 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  19
  20         .macro IA32_ARG_FIXUP noebp=0
  21         movl    %edi,%r8d
  22         .if \noebp
  23         .else
  24         movl    %ebp,%r9d
  25         .endif
  26         xchg    %ecx,%esi
  27         movl    %ebx,%edi
  28         movl    %edx,%edx       /* zero extension */
  29         .endm
  30
  31         /* clobbers %eax */
  32         .macro  CLEAR_RREGS
  33         xorl    %eax,%eax
  34         movq    %rax,R11(%rsp)
  35         movq    %rax,R10(%rsp)
  36         movq    %rax,R9(%rsp)
  37         movq    %rax,R8(%rsp)
  38         .endm
  39
  40         .macro CFI_STARTPROC32 simple
  41         CFI_STARTPROC   \simple
  42         CFI_UNDEFINED   r8
  43         CFI_UNDEFINED   r9
  44         CFI_UNDEFINED   r10
  45         CFI_UNDEFINED   r11
  46         CFI_UNDEFINED   r12
  47         CFI_UNDEFINED   r13
  48         CFI_UNDEFINED   r14
  49         CFI_UNDEFINED   r15
  50         .endm
  51
  52 /*
  53  * 32bit SYSENTER instruction entry.
  54  *
  55  * Arguments:
  56  * %eax System call number.
  57  * %ebx Arg1
  58  * %ecx Arg2
  59  * %edx Arg3
  60  * %esi Arg4
  61  * %edi Arg5
  62  * %ebp user stack
  63  * 0(%ebp) Arg6
  64  *
  65  * Interrupts off.
  66  *
  67  * This is purely a fast path. For anything complicated we use the int 0x80
  68  * path below.  Set up a complete hardware stack frame to share code
  69  * with the int 0x80 path.
  70  */
  71 ENTRY(ia32_sysenter_target)
  72         CFI_STARTPROC32 simple
  73         CFI_DEF_CFA     rsp,0
  74         CFI_REGISTER    rsp,rbp
  75         swapgs
  76         movq    %gs:pda_kernelstack, %rsp
  77         addq    $(PDA_STACKOFFSET),%rsp
  78         sti
  79         movl    %ebp,%ebp               /* zero extension */
  80         pushq   $__USER32_DS
  81         CFI_ADJUST_CFA_OFFSET 8
  82         /*CFI_REL_OFFSET ss,0*/
  83         pushq   %rbp
  84         CFI_ADJUST_CFA_OFFSET 8
  85         CFI_REL_OFFSET rsp,0
  86         pushfq
  87         CFI_ADJUST_CFA_OFFSET 8
  88         /*CFI_REL_OFFSET rflags,0*/
  89         movl    $VSYSCALL32_SYSEXIT, %r10d
  90         CFI_REGISTER rip,r10
  91         pushq   $__USER32_CS
  92         CFI_ADJUST_CFA_OFFSET 8
  93         /*CFI_REL_OFFSET cs,0*/
  94         movl    %eax, %eax
  95         pushq   %r10
  96         CFI_ADJUST_CFA_OFFSET 8
  97         CFI_REL_OFFSET rip,0
  98         pushq   %rax
  99         CFI_ADJUST_CFA_OFFSET 8
 100         cld
 101         SAVE_ARGS 0,0,1
 102         /* no need to do an access_ok check here because rbp has been
 103            32bit zero extended */
 104 1:      movl    (%rbp),%r9d
 105         .section __ex_table,"a"
 106         .quad 1b,ia32_badarg
 107         .previous
 108         GET_THREAD_INFO(%r10)
 109         orl    $TS_COMPAT,threadinfo_status(%r10)
 110         testl  $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 111         CFI_REMEMBER_STATE
 112         jnz  sysenter_tracesys
 113 sysenter_do_call:
 114         cmpl    $(IA32_NR_syscalls-1),%eax
 115         ja      ia32_badsys
 116         IA32_ARG_FIXUP 1
 117         call    *ia32_sys_call_table(,%rax,8)
 118         movq    %rax,RAX-ARGOFFSET(%rsp)
 119         GET_THREAD_INFO(%r10)
 120         cli
 121         testl   $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 122         jnz     int_ret_from_sys_call
 123         andl    $~TS_COMPAT,threadinfo_status(%r10)
 124         /* clear IF, that popfq doesn't enable interrupts early */
 125         andl  $~0x200,EFLAGS-R11(%rsp)
 126         RESTORE_ARGS 1,24,1,1,1,1
 127         popfq
 128         CFI_ADJUST_CFA_OFFSET -8
 129         /*CFI_RESTORE rflags*/
 130         popq    %rcx                            /* User %esp */
 131         CFI_ADJUST_CFA_OFFSET -8
 132         CFI_REGISTER rsp,rcx
 133         movl    $VSYSCALL32_SYSEXIT,%edx        /* User %eip */
 134         CFI_REGISTER rip,rdx
 135         swapgs
 136         sti             /* sti only takes effect after the next instruction */
 137         /* sysexit */
 138         .byte   0xf, 0x35
 139
 140 sysenter_tracesys:
 141         CFI_RESTORE_STATE
 142         SAVE_REST
 143         CLEAR_RREGS
 144         movq    $-ENOSYS,RAX(%rsp)      /* really needed? */
 145         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 146         call    syscall_trace_enter
 147         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 148         RESTORE_REST
 149         movl    %ebp, %ebp
 150         /* no need to do an access_ok check here because rbp has been
 151            32bit zero extended */
 152 1:      movl    (%rbp),%r9d
 153         .section __ex_table,"a"
 154         .quad 1b,ia32_badarg
 155         .previous
 156         jmp     sysenter_do_call
 157         CFI_ENDPROC
 158 ENDPROC(ia32_sysenter_target)
 159
 160 /*
 161  * 32bit SYSCALL instruction entry.
 162  *
 163  * Arguments:
 164  * %eax System call number.
 165  * %ebx Arg1
 166  * %ecx return EIP
 167  * %edx Arg3
 168  * %esi Arg4
 169  * %edi Arg5
 170  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 171  * %esp user stack
 172  * 0(%esp) Arg6
 173  *
 174  * Interrupts off.
 175  *
 176  * This is purely a fast path. For anything complicated we use the int 0x80
 177  * path below.  Set up a complete hardware stack frame to share code
 178  * with the int 0x80 path.
 179  */
 180 ENTRY(ia32_cstar_target)
 181         CFI_STARTPROC32 simple
 182         CFI_DEF_CFA     rsp,0
 183         CFI_REGISTER    rip,rcx
 184         /*CFI_REGISTER  rflags,r11*/
 185         swapgs
 186         movl    %esp,%r8d
 187         CFI_REGISTER    rsp,r8
 188         movq    %gs:pda_kernelstack,%rsp
 189         sti
 190         SAVE_ARGS 8,1,1
 191         movl    %eax,%eax       /* zero extension */
 192         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 193         movq    %rcx,RIP-ARGOFFSET(%rsp)
 194         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 195         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 196         movl    %ebp,%ecx
 197         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 198         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 199         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 200         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 201         movq    %r8,RSP-ARGOFFSET(%rsp)
 202         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 203         /* no need to do an access_ok check here because r8 has been
 204            32bit zero extended */
 205         /* hardware stack frame is complete now */
 206 1:      movl    (%r8),%r9d
 207         .section __ex_table,"a"
 208         .quad 1b,ia32_badarg
 209         .previous
 210         GET_THREAD_INFO(%r10)
 211         orl   $TS_COMPAT,threadinfo_status(%r10)
 212         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 213         CFI_REMEMBER_STATE
 214         jnz   cstar_tracesys
 215 cstar_do_call:
 216         cmpl $IA32_NR_syscalls-1,%eax
 217         ja  ia32_badsys
 218         IA32_ARG_FIXUP 1
 219         call *ia32_sys_call_table(,%rax,8)
 220         movq %rax,RAX-ARGOFFSET(%rsp)
 221         GET_THREAD_INFO(%r10)
 222         cli
 223         testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 224         jnz  int_ret_from_sys_call
 225         andl $~TS_COMPAT,threadinfo_status(%r10)
 226         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
 227         movl RIP-ARGOFFSET(%rsp),%ecx
 228         CFI_REGISTER rip,rcx
 229         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 230         /*CFI_REGISTER rflags,r11*/
 231         movl RSP-ARGOFFSET(%rsp),%esp
 232         CFI_RESTORE rsp
 233         swapgs
 234         sysretl
 235
 236 cstar_tracesys:
 237         CFI_RESTORE_STATE
 238         SAVE_REST
 239         CLEAR_RREGS
 240         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 241         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 242         call syscall_trace_enter
 243         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 244         RESTORE_REST
 245         movl RSP-ARGOFFSET(%rsp), %r8d
 246         /* no need to do an access_ok check here because r8 has been
 247            32bit zero extended */
 248 1:      movl    (%r8),%r9d
 249         .section __ex_table,"a"
 250         .quad 1b,ia32_badarg
 251         .previous
 252         jmp cstar_do_call
 253 END(ia32_cstar_target)
 254
 255 ia32_badarg:
 256         movq $-EFAULT,%rax
 257         jmp ia32_sysret
 258         CFI_ENDPROC
 259
 260 /*
 261  * Emulated IA32 system calls via int 0x80.
 262  *
 263  * Arguments:
 264  * %eax System call number.
 265  * %ebx Arg1
 266  * %ecx Arg2
 267  * %edx Arg3
 268  * %esi Arg4
 269  * %edi Arg5
 270  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 271  *
 272  * Notes:
 273  * Uses the same stack frame as the x86-64 version.
 274  * All registers except %eax must be saved (but ptrace may violate that)
 275  * Arguments are zero extended. For system calls that want sign extension and
 276  * take long arguments a wrapper is needed. Most calls can just be called
 277  * directly.
 278  * Assumes it is only called from user space and entered with interrupts off.
 279  */
 280
 281 ENTRY(ia32_syscall)
 282         CFI_STARTPROC   simple
 283         CFI_DEF_CFA     rsp,SS+8-RIP
 284         /*CFI_REL_OFFSET        ss,SS-RIP*/
 285         CFI_REL_OFFSET  rsp,RSP-RIP
 286         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 287         /*CFI_REL_OFFSET        cs,CS-RIP*/
 288         CFI_REL_OFFSET  rip,RIP-RIP
 289         swapgs
 290         sti
 291         movl %eax,%eax
 292         pushq %rax
 293         CFI_ADJUST_CFA_OFFSET 8
 294         cld
 295         /* note the registers are not zero extended to the sf.
 296            this could be a problem. */
 297         SAVE_ARGS 0,0,1
 298         GET_THREAD_INFO(%r10)
 299         orl   $TS_COMPAT,threadinfo_status(%r10)
 300         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 301         jnz ia32_tracesys
 302 ia32_do_syscall:
 303         cmpl $(IA32_NR_syscalls-1),%eax
 304         ja  ia32_badsys
 305         IA32_ARG_FIXUP
 306         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 307 ia32_sysret:
 308         movq %rax,RAX-ARGOFFSET(%rsp)
 309         jmp int_ret_from_sys_call
 310
 311 ia32_tracesys:
 312         SAVE_REST
 313         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 314         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 315         call syscall_trace_enter
 316         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 317         RESTORE_REST
 318         jmp ia32_do_syscall
 319 END(ia32_syscall)
 320
 321 ia32_badsys:
 322         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 323         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 324         jmp int_ret_from_sys_call
 325
 326 ni_syscall:
 327         movq %rax,%rdi
 328         jmp  sys32_ni_syscall
 329
 330 quiet_ni_syscall:
 331         movq $-ENOSYS,%rax
 332         ret
 333         CFI_ENDPROC
 334
 335         .macro PTREGSCALL label, func, arg
 336         .globl \label
 337 \label:
 338         leaq \func(%rip),%rax
 339         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 340         jmp  ia32_ptregs_common
 341         .endm
 342
 343         CFI_STARTPROC32
 344
 345         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 346         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 347         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 348         PTREGSCALL stub32_sigsuspend, sys32_sigsuspend, %rcx
 349         PTREGSCALL stub32_execve, sys32_execve, %rcx
 350         PTREGSCALL stub32_fork, sys_fork, %rdi
 351         PTREGSCALL stub32_clone, sys32_clone, %rdx
 352         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 353         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 354         PTREGSCALL stub32_rt_sigsuspend, sys_rt_sigsuspend, %rdx
 355
 356 ENTRY(ia32_ptregs_common)
 357         popq %r11
 358         CFI_ENDPROC
 359         CFI_STARTPROC32 simple
 360         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 361         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 362         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 363         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 364         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 365         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 366         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 367 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 368 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 369         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 370 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 371         SAVE_REST
 372         call *%rax
 373         RESTORE_REST
 374         jmp  ia32_sysret        /* misbalances the return cache */
 375         CFI_ENDPROC
 376 END(ia32_ptregs_common)
 377
 378         .section .rodata,"a"
 379         .align 8
 380 ia32_sys_call_table:
 381         .quad sys_restart_syscall
 382         .quad sys_exit
 383         .quad stub32_fork
 384         .quad sys_read
 385         .quad sys_write
 386         .quad compat_sys_open           /* 5 */
 387         .quad sys_close
 388         .quad sys32_waitpid
 389         .quad sys_creat
 390         .quad sys_link
 391         .quad sys_unlink                /* 10 */
 392         .quad stub32_execve
 393         .quad sys_chdir
 394         .quad compat_sys_time
 395         .quad sys_mknod
 396         .quad sys_chmod         /* 15 */
 397         .quad sys_lchown16
 398         .quad quiet_ni_syscall                  /* old break syscall holder */
 399         .quad sys_stat
 400         .quad sys32_lseek
 401         .quad sys_getpid                /* 20 */
 402         .quad compat_sys_mount  /* mount  */
 403         .quad sys_oldumount     /* old_umount  */
 404         .quad sys_setuid16
 405         .quad sys_getuid16
 406         .quad compat_sys_stime  /* stime */             /* 25 */
 407         .quad sys32_ptrace      /* ptrace */
 408         .quad sys_alarm
 409         .quad sys_fstat /* (old)fstat */
 410         .quad sys_pause
 411         .quad compat_sys_utime  /* 30 */
 412         .quad quiet_ni_syscall  /* old stty syscall holder */
 413         .quad quiet_ni_syscall  /* old gtty syscall holder */
 414         .quad sys_access
 415         .quad sys_nice
 416         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 417         .quad sys_sync
 418         .quad sys32_kill
 419         .quad sys_rename
 420         .quad sys_mkdir
 421         .quad sys_rmdir         /* 40 */
 422         .quad sys_dup
 423         .quad sys32_pipe
 424         .quad compat_sys_times
 425         .quad quiet_ni_syscall                  /* old prof syscall holder */
 426         .quad sys_brk           /* 45 */
 427         .quad sys_setgid16
 428         .quad sys_getgid16
 429         .quad sys_signal
 430         .quad sys_geteuid16
 431         .quad sys_getegid16     /* 50 */
 432         .quad sys_acct
 433         .quad sys_umount                        /* new_umount */
 434         .quad quiet_ni_syscall                  /* old lock syscall holder */
 435         .quad compat_sys_ioctl
 436         .quad compat_sys_fcntl64                /* 55 */
 437         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 438         .quad sys_setpgid
 439         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 440         .quad sys32_olduname
 441         .quad sys_umask         /* 60 */
 442         .quad sys_chroot
 443         .quad sys32_ustat
 444         .quad sys_dup2
 445         .quad sys_getppid
 446         .quad sys_getpgrp               /* 65 */
 447         .quad sys_setsid
 448         .quad sys32_sigaction
 449         .quad sys_sgetmask
 450         .quad sys_ssetmask
 451         .quad sys_setreuid16    /* 70 */
 452         .quad sys_setregid16
 453         .quad stub32_sigsuspend
 454         .quad compat_sys_sigpending
 455         .quad sys_sethostname
 456         .quad compat_sys_setrlimit      /* 75 */
 457         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 458         .quad compat_sys_getrusage
 459         .quad sys32_gettimeofday
 460         .quad sys32_settimeofday
 461         .quad sys_getgroups16   /* 80 */
 462         .quad sys_setgroups16
 463         .quad sys32_old_select
 464         .quad sys_symlink
 465         .quad sys_lstat
 466         .quad sys_readlink              /* 85 */
 467 #ifdef CONFIG_IA32_AOUT
 468         .quad sys_uselib
 469 #else
 470         .quad quiet_ni_syscall
 471 #endif
 472         .quad sys_swapon
 473         .quad sys_reboot
 474         .quad compat_sys_old_readdir
 475         .quad sys32_mmap                /* 90 */
 476         .quad sys_munmap
 477         .quad sys_truncate
 478         .quad sys_ftruncate
 479         .quad sys_fchmod
 480         .quad sys_fchown16              /* 95 */
 481         .quad sys_getpriority
 482         .quad sys_setpriority
 483         .quad quiet_ni_syscall                  /* old profil syscall holder */
 484         .quad compat_sys_statfs
 485         .quad compat_sys_fstatfs                /* 100 */
 486         .quad sys_ioperm
 487         .quad compat_sys_socketcall
 488         .quad sys_syslog
 489         .quad compat_sys_setitimer
 490         .quad compat_sys_getitimer      /* 105 */
 491         .quad compat_sys_newstat
 492         .quad compat_sys_newlstat
 493         .quad compat_sys_newfstat
 494         .quad sys32_uname
 495         .quad stub32_iopl               /* 110 */
 496         .quad sys_vhangup
 497         .quad quiet_ni_syscall  /* old "idle" system call */
 498         .quad sys32_vm86_warning        /* vm86old */
 499         .quad compat_sys_wait4
 500         .quad sys_swapoff               /* 115 */
 501         .quad sys32_sysinfo
 502         .quad sys32_ipc
 503         .quad sys_fsync
 504         .quad stub32_sigreturn
 505         .quad stub32_clone              /* 120 */
 506         .quad sys_setdomainname
 507         .quad sys_uname
 508         .quad sys_modify_ldt
 509         .quad compat_sys_adjtimex
 510         .quad sys32_mprotect            /* 125 */
 511         .quad compat_sys_sigprocmask
 512         .quad quiet_ni_syscall          /* create_module */
 513         .quad sys_init_module
 514         .quad sys_delete_module
 515         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 516         .quad sys_quotactl
 517         .quad sys_getpgid
 518         .quad sys_fchdir
 519         .quad quiet_ni_syscall  /* bdflush */
 520         .quad sys_sysfs         /* 135 */
 521         .quad sys_personality
 522         .quad quiet_ni_syscall  /* for afs_syscall */
 523         .quad sys_setfsuid16
 524         .quad sys_setfsgid16
 525         .quad sys_llseek                /* 140 */
 526         .quad compat_sys_getdents
 527         .quad compat_sys_select
 528         .quad sys_flock
 529         .quad sys_msync
 530         .quad compat_sys_readv          /* 145 */
 531         .quad compat_sys_writev
 532         .quad sys_getsid
 533         .quad sys_fdatasync
 534         .quad sys32_sysctl      /* sysctl */
 535         .quad sys_mlock         /* 150 */
 536         .quad sys_munlock
 537         .quad sys_mlockall
 538         .quad sys_munlockall
 539         .quad sys_sched_setparam
 540         .quad sys_sched_getparam   /* 155 */
 541         .quad sys_sched_setscheduler
 542         .quad sys_sched_getscheduler
 543         .quad sys_sched_yield
 544         .quad sys_sched_get_priority_max
 545         .quad sys_sched_get_priority_min  /* 160 */
 546         .quad sys_sched_rr_get_interval
 547         .quad compat_sys_nanosleep
 548         .quad sys_mremap
 549         .quad sys_setresuid16
 550         .quad sys_getresuid16   /* 165 */
 551         .quad sys32_vm86_warning        /* vm86 */
 552         .quad quiet_ni_syscall  /* query_module */
 553         .quad sys_poll
 554         .quad compat_sys_nfsservctl
 555         .quad sys_setresgid16   /* 170 */
 556         .quad sys_getresgid16
 557         .quad sys_prctl
 558         .quad stub32_rt_sigreturn
 559         .quad sys32_rt_sigaction
 560         .quad sys32_rt_sigprocmask      /* 175 */
 561         .quad sys32_rt_sigpending
 562         .quad compat_sys_rt_sigtimedwait
 563         .quad sys32_rt_sigqueueinfo
 564         .quad stub32_rt_sigsuspend
 565         .quad sys32_pread               /* 180 */
 566         .quad sys32_pwrite
 567         .quad sys_chown16
 568         .quad sys_getcwd
 569         .quad sys_capget
 570         .quad sys_capset
 571         .quad stub32_sigaltstack
 572         .quad sys32_sendfile
 573         .quad quiet_ni_syscall          /* streams1 */
 574         .quad quiet_ni_syscall          /* streams2 */
 575         .quad stub32_vfork            /* 190 */
 576         .quad compat_sys_getrlimit
 577         .quad sys32_mmap2
 578         .quad sys32_truncate64
 579         .quad sys32_ftruncate64
 580         .quad sys32_stat64              /* 195 */
 581         .quad sys32_lstat64
 582         .quad sys32_fstat64
 583         .quad sys_lchown
 584         .quad sys_getuid
 585         .quad sys_getgid                /* 200 */
 586         .quad sys_geteuid
 587         .quad sys_getegid
 588         .quad sys_setreuid
 589         .quad sys_setregid
 590         .quad sys_getgroups     /* 205 */
 591         .quad sys_setgroups
 592         .quad sys_fchown
 593         .quad sys_setresuid
 594         .quad sys_getresuid
 595         .quad sys_setresgid     /* 210 */
 596         .quad sys_getresgid
 597         .quad sys_chown
 598         .quad sys_setuid
 599         .quad sys_setgid
 600         .quad sys_setfsuid              /* 215 */
 601         .quad sys_setfsgid
 602         .quad sys_pivot_root
 603         .quad sys_mincore
 604         .quad sys_madvise
 605         .quad compat_sys_getdents64     /* 220 getdents64 */
 606         .quad compat_sys_fcntl64
 607         .quad quiet_ni_syscall          /* tux */
 608         .quad quiet_ni_syscall          /* security */
 609         .quad sys_gettid
 610         .quad sys_readahead     /* 225 */
 611         .quad sys_setxattr
 612         .quad sys_lsetxattr
 613         .quad sys_fsetxattr
 614         .quad sys_getxattr
 615         .quad sys_lgetxattr     /* 230 */
 616         .quad sys_fgetxattr
 617         .quad sys_listxattr
 618         .quad sys_llistxattr
 619         .quad sys_flistxattr
 620         .quad sys_removexattr   /* 235 */
 621         .quad sys_lremovexattr
 622         .quad sys_fremovexattr
 623         .quad sys_tkill
 624         .quad sys_sendfile64
 625         .quad compat_sys_futex          /* 240 */
 626         .quad compat_sys_sched_setaffinity
 627         .quad compat_sys_sched_getaffinity
 628         .quad sys32_set_thread_area
 629         .quad sys32_get_thread_area
 630         .quad compat_sys_io_setup       /* 245 */
 631         .quad sys_io_destroy
 632         .quad compat_sys_io_getevents
 633         .quad compat_sys_io_submit
 634         .quad sys_io_cancel
 635         .quad sys_fadvise64             /* 250 */
 636         .quad quiet_ni_syscall  /* free_huge_pages */
 637         .quad sys_exit_group
 638         .quad sys32_lookup_dcookie
 639         .quad sys_epoll_create
 640         .quad sys_epoll_ctl             /* 255 */
 641         .quad sys_epoll_wait
 642         .quad sys_remap_file_pages
 643         .quad sys_set_tid_address
 644         .quad compat_sys_timer_create
 645         .quad compat_sys_timer_settime  /* 260 */
 646         .quad compat_sys_timer_gettime
 647         .quad sys_timer_getoverrun
 648         .quad sys_timer_delete
 649         .quad compat_sys_clock_settime
 650         .quad compat_sys_clock_gettime  /* 265 */
 651         .quad compat_sys_clock_getres
 652         .quad compat_sys_clock_nanosleep
 653         .quad compat_sys_statfs64
 654         .quad compat_sys_fstatfs64
 655         .quad sys_tgkill                /* 270 */
 656         .quad compat_sys_utimes
 657         .quad sys32_fadvise64_64
 658         .quad quiet_ni_syscall  /* sys_vserver */
 659         .quad sys_mbind
 660         .quad compat_sys_get_mempolicy  /* 275 */
 661         .quad sys_set_mempolicy
 662         .quad compat_sys_mq_open
 663         .quad sys_mq_unlink
 664         .quad compat_sys_mq_timedsend
 665         .quad compat_sys_mq_timedreceive        /* 280 */
 666         .quad compat_sys_mq_notify
 667         .quad compat_sys_mq_getsetattr
 668         .quad compat_sys_kexec_load     /* reserved for kexec */
 669         .quad compat_sys_waitid
 670         .quad quiet_ni_syscall          /* 285: sys_altroot */
 671         .quad sys_add_key
 672         .quad sys_request_key
 673         .quad sys_keyctl
 674         .quad sys_ioprio_set
 675         .quad sys_ioprio_get            /* 290 */
 676         .quad sys_inotify_init
 677         .quad sys_inotify_add_watch
 678         .quad sys_inotify_rm_watch
 679         .quad sys_migrate_pages
 680         .quad compat_sys_openat         /* 295 */
 681         .quad sys_mkdirat
 682         .quad sys_mknodat
 683         .quad sys_fchownat
 684         .quad compat_sys_futimesat
 685         .quad sys32_fstatat             /* 300 */
 686         .quad sys_unlinkat
 687         .quad sys_renameat
 688         .quad sys_linkat
 689         .quad sys_symlinkat
 690         .quad sys_readlinkat            /* 305 */
 691         .quad sys_fchmodat
 692         .quad sys_faccessat
 693         .quad quiet_ni_syscall          /* pselect6 for now */
 694         .quad quiet_ni_syscall          /* ppoll for now */
 695         .quad sys_unshare               /* 310 */
 696         .quad compat_sys_set_robust_list
 697         .quad compat_sys_get_robust_list
 698         .quad sys_splice
 699         .quad sys_sync_file_range
 700         .quad sys_tee
 701         .quad compat_sys_vmsplice
 702         .quad compat_sys_move_pages
 703 ia32_syscall_end: