git.oblomov.eu Git - linux-2.6/blob - arch/x86/kernel/vmlinux_64.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 _proxy_pda = 1;
  17 PHDRS {
  18         text PT_LOAD FLAGS(5);  /* R_E */
  19         data PT_LOAD FLAGS(7);  /* RWE */
  20         user PT_LOAD FLAGS(7);  /* RWE */
  21         data.init PT_LOAD FLAGS(7);     /* RWE */
  22         note PT_NOTE FLAGS(4);  /* R__ */
  23 }
  24 SECTIONS
  25 {
  26   . = __START_KERNEL;
  27   phys_startup_64 = startup_64 - LOAD_OFFSET;
  28   _text = .;                    /* Text and read-only data */
  29   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  30         /* First the code that has to be first for bootstrapping */
  31         *(.text.head)
  32         _stext = .;
  33         /* Then the rest */
  34         TEXT_TEXT
  35         SCHED_TEXT
  36         LOCK_TEXT
  37         KPROBES_TEXT
  38         *(.fixup)
  39         *(.gnu.warning)
  40         _etext = .;             /* End of text section */
  41   } :text = 0x9090
  42
  43   . = ALIGN(16);                /* Exception table */
  44   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
  45         __start___ex_table = .;
  46          *(__ex_table)
  47         __stop___ex_table = .;
  48   }
  49
  50   NOTES :text :note
  51
  52   BUG_TABLE :text
  53
  54   RODATA
  55
  56   . = ALIGN(PAGE_SIZE);         /* Align data segment to page size boundary */
  57                                 /* Data */
  58   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  59         DATA_DATA
  60         CONSTRUCTORS
  61         } :data
  62
  63   _edata = .;                   /* End of data section */
  64
  65   . = ALIGN(PAGE_SIZE);
  66   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  67   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  68         *(.data.cacheline_aligned)
  69   }
  70   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  71   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  72         *(.data.read_mostly)
  73   }
  74
  75 #define VSYSCALL_ADDR (-10*1024*1024)
  76 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  77 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  78
  79 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  80 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  81
  82 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  83 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  84
  85   . = VSYSCALL_ADDR;
  86   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  87   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  88
  89   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  90   .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) { *(.vsyscall_fn) }
  91   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  92   .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data))
  93                 { *(.vsyscall_gtod_data) }
  94   vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
  95   .vsyscall_clock : AT(VLOAD(.vsyscall_clock))
  96                 { *(.vsyscall_clock) }
  97   vsyscall_clock = VVIRT(.vsyscall_clock);
  98
  99
 100   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1))
 101                 { *(.vsyscall_1) }
 102   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2))
 103                 { *(.vsyscall_2) }
 104
 105   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
 106   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 107
 108   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 109   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 110   jiffies = VVIRT(.jiffies);
 111
 112   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3))
 113                 { *(.vsyscall_3) }
 114
 115   . = VSYSCALL_VIRT_ADDR + PAGE_SIZE;
 116
 117 #undef VSYSCALL_ADDR
 118 #undef VSYSCALL_PHYS_ADDR
 119 #undef VSYSCALL_VIRT_ADDR
 120 #undef VLOAD_OFFSET
 121 #undef VLOAD
 122 #undef VVIRT_OFFSET
 123 #undef VVIRT
 124
 125   . = ALIGN(THREAD_SIZE);       /* init_task */
 126   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 127         *(.data.init_task)
 128   }:data.init
 129
 130   . = ALIGN(PAGE_SIZE);
 131   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 132         *(.data.page_aligned)
 133   }
 134
 135   /* might get freed after init */
 136   . = ALIGN(PAGE_SIZE);
 137   __smp_alt_begin = .;
 138   __smp_locks = .;
 139   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 140         *(.smp_locks)
 141   }
 142   __smp_locks_end = .;
 143   . = ALIGN(PAGE_SIZE);
 144   __smp_alt_end = .;
 145
 146   . = ALIGN(PAGE_SIZE);         /* Init code and data */
 147   __init_begin = .;
 148   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 149         _sinittext = .;
 150         INIT_TEXT
 151         _einittext = .;
 152   }
 153   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 154         __initdata_begin = .;
 155         INIT_DATA
 156         __initdata_end = .;
 157    }
 158
 159   . = ALIGN(16);
 160   __setup_start = .;
 161   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 162   __setup_end = .;
 163   __initcall_start = .;
 164   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 165         INITCALLS
 166   }
 167   __initcall_end = .;
 168   __con_initcall_start = .;
 169   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 170         *(.con_initcall.init)
 171   }
 172   __con_initcall_end = .;
 173   . = ALIGN(16);
 174   __x86cpuvendor_start = .;
 175   .x86cpuvendor.init : AT(ADDR(.x86cpuvendor.init) - LOAD_OFFSET) {
 176         *(.x86cpuvendor.init)
 177   }
 178   __x86cpuvendor_end = .;
 179   SECURITY_INIT
 180
 181   . = ALIGN(8);
 182   .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 183   __parainstructions = .;
 184        *(.parainstructions)
 185   __parainstructions_end = .;
 186   }
 187
 188   . = ALIGN(8);
 189   __alt_instructions = .;
 190   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 191         *(.altinstructions)
 192   }
 193   __alt_instructions_end = .;
 194   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 195         *(.altinstr_replacement)
 196   }
 197   /* .exit.text is discard at runtime, not link time, to deal with references
 198      from .altinstructions and .eh_frame */
 199   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 200         EXIT_TEXT
 201   }
 202   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 203         EXIT_DATA
 204   }
 205
 206 #ifdef CONFIG_BLK_DEV_INITRD
 207   . = ALIGN(PAGE_SIZE);
 208   __initramfs_start = .;
 209   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 210   __initramfs_end = .;
 211 #endif
 212
 213   PERCPU(PAGE_SIZE)
 214
 215   . = ALIGN(PAGE_SIZE);
 216   __init_end = .;
 217
 218   . = ALIGN(PAGE_SIZE);
 219   __nosave_begin = .;
 220   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 221   . = ALIGN(PAGE_SIZE);
 222   __nosave_end = .;
 223
 224   __bss_start = .;              /* BSS */
 225   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 226         *(.bss.page_aligned)
 227         *(.bss)
 228         }
 229   __bss_stop = .;
 230
 231   _end = . ;
 232
 233   /* Sections to be discarded */
 234   /DISCARD/ : {
 235         *(.exitcall.exit)
 236         *(.eh_frame)
 237         }
 238
 239   STABS_DEBUG
 240
 241   DWARF_DEBUG
 242 }
 243
 244 /*
 245  * Build-time check on the image size:
 246  */
 247 ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 248         "kernel image bigger than KERNEL_IMAGE_SIZE")