git.oblomov.eu Git - linux-2.6/blob - arch/x86/kernel/trampoline_64.S

   1 /*
   2  *
   3  *      Trampoline.S    Derived from Setup.S by Linus Torvalds
   4  *
   5  *      4 Jan 1997 Michael Chastain: changed to gnu as.
   6  *      15 Sept 2005 Eric Biederman: 64bit PIC support
   7  *
   8  *      Entry: CS:IP point to the start of our code, we are
   9  *      in real mode with no stack, but the rest of the
  10  *      trampoline page to make our stack and everything else
  11  *      is a mystery.
  12  *
  13  *      On entry to trampoline_data, the processor is in real mode
  14  *      with 16-bit addressing and 16-bit data.  CS has some value
  15  *      and IP is zero.  Thus, data addresses need to be absolute
  16  *      (no relocation) and are taken with regard to r_base.
  17  *
  18  *      With the addition of trampoline_level4_pgt this code can
  19  *      now enter a 64bit kernel that lives at arbitrary 64bit
  20  *      physical addresses.
  21  *
  22  *      If you work on this file, check the object module with objdump
  23  *      --full-contents --reloc to make sure there are no relocation
  24  *      entries.
  25  */
  26
  27 #include <linux/linkage.h>
  28 #include <asm/pgtable.h>
  29 #include <asm/page.h>
  30 #include <asm/msr.h>
  31 #include <asm/segment.h>
  32
  33 /* We can free up trampoline after bootup if cpu hotplug is not supported. */
  34 #ifndef CONFIG_HOTPLUG_CPU
  35 .section .init.data, "aw", @progbits
  36 #else
  37 .section .rodata, "a", @progbits
  38 #endif
  39
  40 .code16
  41
  42 ENTRY(trampoline_data)
  43 r_base = .
  44         cli                     # We should be safe anyway
  45         wbinvd
  46         mov     %cs, %ax        # Code and data in the same place
  47         mov     %ax, %ds
  48         mov     %ax, %es
  49         mov     %ax, %ss
  50
  51
  52         movl    $0xA5A5A5A5, trampoline_data - r_base
  53                                 # write marker for master knows we're running
  54
  55                                         # Setup stack
  56         movw    $(trampoline_stack_end - r_base), %sp
  57
  58         call    verify_cpu              # Verify the cpu supports long mode
  59         testl   %eax, %eax              # Check for return code
  60         jnz     no_longmode
  61
  62         mov     %cs, %ax
  63         movzx   %ax, %esi               # Find the 32bit trampoline location
  64         shll    $4, %esi
  65
  66                                         # Fixup the vectors
  67         addl    %esi, startup_32_vector - r_base
  68         addl    %esi, startup_64_vector - r_base
  69         addl    %esi, tgdt + 2 - r_base # Fixup the gdt pointer
  70
  71         /*
  72          * GDT tables in non default location kernel can be beyond 16MB and
  73          * lgdt will not be able to load the address as in real mode default
  74          * operand size is 16bit. Use lgdtl instead to force operand size
  75          * to 32 bit.
  76          */
  77
  78         lidtl   tidt - r_base   # load idt with 0, 0
  79         lgdtl   tgdt - r_base   # load gdt with whatever is appropriate
  80
  81         xor     %ax, %ax
  82         inc     %ax             # protected mode (PE) bit
  83         lmsw    %ax             # into protected mode
  84
  85         # flush prefetch and jump to startup_32
  86         ljmpl   *(startup_32_vector - r_base)
  87
  88         .code32
  89         .balign 4
  90 startup_32:
  91         movl    $__KERNEL_DS, %eax      # Initialize the %ds segment register
  92         movl    %eax, %ds
  93
  94         xorl    %eax, %eax
  95         btsl    $5, %eax                # Enable PAE mode
  96         movl    %eax, %cr4
  97
  98                                         # Setup trampoline 4 level pagetables
  99         leal    (trampoline_level4_pgt - r_base)(%esi), %eax
 100         movl    %eax, %cr3
 101
 102         movl    $MSR_EFER, %ecx
 103         movl    $(1 << _EFER_LME), %eax # Enable Long Mode
 104         xorl    %edx, %edx
 105         wrmsr
 106
 107         xorl    %eax, %eax
 108         btsl    $31, %eax               # Enable paging and in turn activate Long Mode
 109         btsl    $0, %eax                # Enable protected mode
 110         movl    %eax, %cr0
 111
 112         /*
 113          * At this point we're in long mode but in 32bit compatibility mode
 114          * with EFER.LME = 1, CS.L = 0, CS.D = 1 (and in turn
 115          * EFER.LMA = 1). Now we want to jump in 64bit mode, to do that we use
 116          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
 117          */
 118         ljmp    *(startup_64_vector - r_base)(%esi)
 119
 120         .code64
 121         .balign 4
 122 startup_64:
 123         # Now jump into the kernel using virtual addresses
 124         movq    $secondary_startup_64, %rax
 125         jmp     *%rax
 126
 127         .code16
 128 no_longmode:
 129         hlt
 130         jmp no_longmode
 131 #include "verify_cpu_64.S"
 132
 133         # Careful these need to be in the same 64K segment as the above;
 134 tidt:
 135         .word   0                       # idt limit = 0
 136         .word   0, 0                    # idt base = 0L
 137
 138         # Duplicate the global descriptor table
 139         # so the kernel can live anywhere
 140         .balign 4
 141 tgdt:
 142         .short  tgdt_end - tgdt         # gdt limit
 143         .long   tgdt - r_base
 144         .short 0
 145         .quad   0x00cf9b000000ffff      # __KERNEL32_CS
 146         .quad   0x00af9b000000ffff      # __KERNEL_CS
 147         .quad   0x00cf93000000ffff      # __KERNEL_DS
 148 tgdt_end:
 149
 150         .balign 4
 151 startup_32_vector:
 152         .long   startup_32 - r_base
 153         .word   __KERNEL32_CS, 0
 154
 155         .balign 4
 156 startup_64_vector:
 157         .long   startup_64 - r_base
 158         .word   __KERNEL_CS, 0
 159
 160 trampoline_stack:
 161         .org 0x1000
 162 trampoline_stack_end:
 163 ENTRY(trampoline_level4_pgt)
 164         .quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 165         .fill   510,8,0
 166         .quad   level3_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
 167
 168 ENTRY(trampoline_end)