git.oblomov.eu Git - linux-2.6/blob - arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 PHDRS {
  17         text PT_LOAD FLAGS(5);  /* R_E */
  18         data PT_LOAD FLAGS(7);  /* RWE */
  19         user PT_LOAD FLAGS(7);  /* RWE */
  20         note PT_NOTE FLAGS(4);  /* R__ */
  21 }
  22 SECTIONS
  23 {
  24   . = __START_KERNEL;
  25   phys_startup_64 = startup_64 - LOAD_OFFSET;
  26   _text = .;                    /* Text and read-only data */
  27   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  28         /* First the code that has to be first for bootstrapping */
  29         *(.bootstrap.text)
  30         /* Then all the functions that are "hot" in profiles, to group them
  31            onto the same hugetlb entry */
  32         #include "functionlist"
  33         /* Then the rest */
  34         *(.text)
  35         SCHED_TEXT
  36         LOCK_TEXT
  37         KPROBES_TEXT
  38         *(.fixup)
  39         *(.gnu.warning)
  40         } :text = 0x9090
  41                                 /* out-of-line lock text */
  42   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  43
  44   _etext = .;                   /* End of text section */
  45
  46   . = ALIGN(16);                /* Exception table */
  47   __start___ex_table = .;
  48   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  49   __stop___ex_table = .;
  50
  51   RODATA
  52
  53 #ifdef CONFIG_STACK_UNWIND
  54   . = ALIGN(8);
  55   .eh_frame : AT(ADDR(.eh_frame) - LOAD_OFFSET) {
  56         __start_unwind = .;
  57         *(.eh_frame)
  58         __end_unwind = .;
  59   }
  60 #endif
  61
  62                                 /* Data */
  63   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  64         *(.data)
  65         CONSTRUCTORS
  66         } :data
  67
  68   _edata = .;                   /* End of data section */
  69
  70   . = ALIGN(PAGE_SIZE);
  71   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  72   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  73         *(.data.cacheline_aligned)
  74   }
  75   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  76   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  77         *(.data.read_mostly)
  78   }
  79
  80 #define VSYSCALL_ADDR (-10*1024*1024)
  81 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  82 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  83
  84 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  85 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  86
  87 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  88 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  89
  90   . = VSYSCALL_ADDR;
  91   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  92   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  93
  94   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  95   .xtime_lock : AT(VLOAD(.xtime_lock)) { *(.xtime_lock) }
  96   xtime_lock = VVIRT(.xtime_lock);
  97
  98   .vxtime : AT(VLOAD(.vxtime)) { *(.vxtime) }
  99   vxtime = VVIRT(.vxtime);
 100
 101   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
 102   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 103
 104   .wall_jiffies : AT(VLOAD(.wall_jiffies)) { *(.wall_jiffies) }
 105   wall_jiffies = VVIRT(.wall_jiffies);
 106
 107   .sys_tz : AT(VLOAD(.sys_tz)) { *(.sys_tz) }
 108   sys_tz = VVIRT(.sys_tz);
 109
 110   .sysctl_vsyscall : AT(VLOAD(.sysctl_vsyscall)) { *(.sysctl_vsyscall) }
 111   sysctl_vsyscall = VVIRT(.sysctl_vsyscall);
 112
 113   .xtime : AT(VLOAD(.xtime)) { *(.xtime) }
 114   xtime = VVIRT(.xtime);
 115
 116   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 117   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 118   jiffies = VVIRT(.jiffies);
 119
 120   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) { *(.vsyscall_1) }
 121   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) { *(.vsyscall_2) }
 122   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) { *(.vsyscall_3) }
 123
 124   . = VSYSCALL_VIRT_ADDR + 4096;
 125
 126 #undef VSYSCALL_ADDR
 127 #undef VSYSCALL_PHYS_ADDR
 128 #undef VSYSCALL_VIRT_ADDR
 129 #undef VLOAD_OFFSET
 130 #undef VLOAD
 131 #undef VVIRT_OFFSET
 132 #undef VVIRT
 133
 134   . = ALIGN(8192);              /* init_task */
 135   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 136         *(.data.init_task)
 137   } :data
 138
 139   . = ALIGN(4096);
 140   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 141         *(.data.page_aligned)
 142   }
 143
 144   /* might get freed after init */
 145   . = ALIGN(4096);
 146   __smp_alt_begin = .;
 147   __smp_alt_instructions = .;
 148   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 149         *(.smp_altinstructions)
 150   }
 151   __smp_alt_instructions_end = .;
 152   . = ALIGN(8);
 153   __smp_locks = .;
 154   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 155         *(.smp_locks)
 156   }
 157   __smp_locks_end = .;
 158   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 159         *(.smp_altinstr_replacement)
 160   }
 161   . = ALIGN(4096);
 162   __smp_alt_end = .;
 163
 164   . = ALIGN(4096);              /* Init code and data */
 165   __init_begin = .;
 166   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 167         _sinittext = .;
 168         *(.init.text)
 169         _einittext = .;
 170   }
 171   __initdata_begin = .;
 172   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 173   __initdata_end = .;
 174   . = ALIGN(16);
 175   __setup_start = .;
 176   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 177   __setup_end = .;
 178   __initcall_start = .;
 179   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 180         *(.initcall1.init)
 181         *(.initcall2.init)
 182         *(.initcall3.init)
 183         *(.initcall4.init)
 184         *(.initcall5.init)
 185         *(.initcall6.init)
 186         *(.initcall7.init)
 187   }
 188   __initcall_end = .;
 189   __con_initcall_start = .;
 190   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 191         *(.con_initcall.init)
 192   }
 193   __con_initcall_end = .;
 194   SECURITY_INIT
 195   . = ALIGN(8);
 196   __alt_instructions = .;
 197   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 198         *(.altinstructions)
 199   }
 200   __alt_instructions_end = .;
 201   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 202         *(.altinstr_replacement)
 203   }
 204   /* .exit.text is discard at runtime, not link time, to deal with references
 205      from .altinstructions and .eh_frame */
 206   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 207   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 208   . = ALIGN(4096);
 209   __initramfs_start = .;
 210   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 211   __initramfs_end = .;
 212     . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 213   __per_cpu_start = .;
 214   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 215   __per_cpu_end = .;
 216   . = ALIGN(4096);
 217   __init_end = .;
 218
 219   . = ALIGN(4096);
 220   __nosave_begin = .;
 221   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 222   . = ALIGN(4096);
 223   __nosave_end = .;
 224
 225   __bss_start = .;              /* BSS */
 226   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 227         *(.bss.page_aligned)
 228         *(.bss)
 229         }
 230   __bss_stop = .;
 231
 232   _end = . ;
 233
 234   /* Sections to be discarded */
 235   /DISCARD/ : {
 236         *(.exitcall.exit)
 237 #ifndef CONFIG_UNWIND_INFO
 238         *(.eh_frame)
 239 #endif
 240         }
 241
 242   STABS_DEBUG
 243
 244   DWARF_DEBUG
 245 }