git.oblomov.eu Git - linux-2.6/blob - arch/x86/ia32/vsyscall.lds

   1 /*
   2  * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
   3  * object prelinked to its virtual address. This script controls its layout.
   4  */
   5
   6 /* This must match <asm/fixmap.h>.  */
   7 VSYSCALL_BASE = 0xffffe000;
   8
   9 SECTIONS
  10 {
  11   . = VSYSCALL_BASE + SIZEOF_HEADERS;
  12
  13   .hash           : { *(.hash) }                :text
  14   .gnu.hash       : { *(.gnu.hash) }
  15   .dynsym         : { *(.dynsym) }
  16   .dynstr         : { *(.dynstr) }
  17   .gnu.version    : { *(.gnu.version) }
  18   .gnu.version_d  : { *(.gnu.version_d) }
  19   .gnu.version_r  : { *(.gnu.version_r) }
  20
  21   /* This linker script is used both with -r and with -shared.
  22      For the layouts to match, we need to skip more than enough
  23      space for the dynamic symbol table et al.  If this amount
  24      is insufficient, ld -shared will barf.  Just increase it here.  */
  25   . = VSYSCALL_BASE + 0x400;
  26
  27   .text.vsyscall   : { *(.text.vsyscall) }      :text =0x90909090
  28
  29   /* This is an 32bit object and we cannot easily get the offsets
  30      into the 64bit kernel. Just hardcode them here. This assumes
  31      that all the stubs don't need more than 0x100 bytes. */
  32   . = VSYSCALL_BASE + 0x500;
  33
  34   .text.sigreturn  : { *(.text.sigreturn) }     :text =0x90909090
  35
  36   . = VSYSCALL_BASE + 0x600;
  37
  38   .text.rtsigreturn : { *(.text.rtsigreturn) }   :text =0x90909090
  39
  40   .note           : { *(.note.*) }              :text :note
  41   .eh_frame_hdr   : { *(.eh_frame_hdr) }        :text :eh_frame_hdr
  42   .eh_frame       : { KEEP (*(.eh_frame)) }     :text
  43   .dynamic        : { *(.dynamic) }             :text :dynamic
  44   .useless        : {
  45         *(.got.plt) *(.got)
  46         *(.data .data.* .gnu.linkonce.d.*)
  47         *(.dynbss)
  48         *(.bss .bss.* .gnu.linkonce.b.*)
  49   }                                             :text
  50 }
  51
  52 /*
  53  * We must supply the ELF program headers explicitly to get just one
  54  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  55  */
  56 PHDRS
  57 {
  58   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  59   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  60   note PT_NOTE FLAGS(4); /* PF_R */
  61   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
  62 }
  63
  64 /*
  65  * This controls what symbols we export from the DSO.
  66  */
  67 VERSION
  68 {
  69   LINUX_2.5 {
  70     global:
  71         __kernel_vsyscall;
  72         __kernel_sigreturn;
  73         __kernel_rt_sigreturn;
  74
  75     local: *;
  76   };
  77 }
  78
  79 /* The ELF entry point can be used to set the AT_SYSINFO value.  */
  80 ENTRY(__kernel_vsyscall);