git.oblomov.eu Git - linux-2.6/blob - arch/ppc/kernel/head_8xx.S

   1 /*
   2  *  arch/ppc/kernel/except_8xx.S
   3  *
   4  *  PowerPC version
   5  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   6  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   7  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   8  *  Low-level exception handlers and MMU support
   9  *  rewritten by Paul Mackerras.
  10  *    Copyright (C) 1996 Paul Mackerras.
  11  *  MPC8xx modifications by Dan Malek
  12  *    Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  13  *
  14  *  This file contains low-level support and setup for PowerPC 8xx
  15  *  embedded processors, including trap and interrupt dispatch.
  16  *
  17  *  This program is free software; you can redistribute it and/or
  18  *  modify it under the terms of the GNU General Public License
  19  *  as published by the Free Software Foundation; either version
  20  *  2 of the License, or (at your option) any later version.
  21  *
  22  */
  23
  24 #include <linux/config.h>
  25 #include <asm/processor.h>
  26 #include <asm/page.h>
  27 #include <asm/mmu.h>
  28 #include <asm/cache.h>
  29 #include <asm/pgtable.h>
  30 #include <asm/cputable.h>
  31 #include <asm/thread_info.h>
  32 #include <asm/ppc_asm.h>
  33 #include <asm/asm-offsets.h>
  34
  35 /* Macro to make the code more readable. */
  36 #ifdef CONFIG_8xx_CPU6
  37 #define DO_8xx_CPU6(val, reg)   \
  38         li      reg, val;       \
  39         stw     reg, 12(r0);    \
  40         lwz     reg, 12(r0);
  41 #else
  42 #define DO_8xx_CPU6(val, reg)
  43 #endif
  44         .text
  45         .globl  _stext
  46 _stext:
  47         .text
  48         .globl  _start
  49 _start:
  50
  51 /* MPC8xx
  52  * This port was done on an MBX board with an 860.  Right now I only
  53  * support an ELF compressed (zImage) boot from EPPC-Bug because the
  54  * code there loads up some registers before calling us:
  55  *   r3: ptr to board info data
  56  *   r4: initrd_start or if no initrd then 0
  57  *   r5: initrd_end - unused if r4 is 0
  58  *   r6: Start of command line string
  59  *   r7: End of command line string
  60  *
  61  * I decided to use conditional compilation instead of checking PVR and
  62  * adding more processor specific branches around code I don't need.
  63  * Since this is an embedded processor, I also appreciate any memory
  64  * savings I can get.
  65  *
  66  * The MPC8xx does not have any BATs, but it supports large page sizes.
  67  * We first initialize the MMU to support 8M byte pages, then load one
  68  * entry into each of the instruction and data TLBs to map the first
  69  * 8M 1:1.  I also mapped an additional I/O space 1:1 so we can get to
  70  * the "internal" processor registers before MMU_init is called.
  71  *
  72  * The TLB code currently contains a major hack.  Since I use the condition
  73  * code register, I have to save and restore it.  I am out of registers, so
  74  * I just store it in memory location 0 (the TLB handlers are not reentrant).
  75  * To avoid making any decisions, I need to use the "segment" valid bit
  76  * in the first level table, but that would require many changes to the
  77  * Linux page directory/table functions that I don't want to do right now.
  78  *
  79  * I used to use SPRG2 for a temporary register in the TLB handler, but it
  80  * has since been put to other uses.  I now use a hack to save a register
  81  * and the CCR at memory location 0.....Someday I'll fix this.....
  82  *      -- Dan
  83  */
  84         .globl  __start
  85 __start:
  86         mr      r31,r3                  /* save parameters */
  87         mr      r30,r4
  88         mr      r29,r5
  89         mr      r28,r6
  90         mr      r27,r7
  91
  92         /* We have to turn on the MMU right away so we get cache modes
  93          * set correctly.
  94          */
  95         bl      initial_mmu
  96
  97 /* We now have the lower 8 Meg mapped into TLB entries, and the caches
  98  * ready to work.
  99  */
 100
 101 turn_on_mmu:
 102         mfmsr   r0
 103         ori     r0,r0,MSR_DR|MSR_IR
 104         mtspr   SPRN_SRR1,r0
 105         lis     r0,start_here@h
 106         ori     r0,r0,start_here@l
 107         mtspr   SPRN_SRR0,r0
 108         SYNC
 109         rfi                             /* enables MMU */
 110
 111 /*
 112  * Exception entry code.  This code runs with address translation
 113  * turned off, i.e. using physical addresses.
 114  * We assume sprg3 has the physical address of the current
 115  * task's thread_struct.
 116  */
 117 #define EXCEPTION_PROLOG        \
 118         mtspr   SPRN_SPRG0,r10; \
 119         mtspr   SPRN_SPRG1,r11; \
 120         mfcr    r10;            \
 121         EXCEPTION_PROLOG_1;     \
 122         EXCEPTION_PROLOG_2
 123
 124 #define EXCEPTION_PROLOG_1      \
 125         mfspr   r11,SPRN_SRR1;          /* check whether user or kernel */ \
 126         andi.   r11,r11,MSR_PR; \
 127         tophys(r11,r1);                 /* use tophys(r1) if kernel */ \
 128         beq     1f;             \
 129         mfspr   r11,SPRN_SPRG3; \
 130         lwz     r11,THREAD_INFO-THREAD(r11);    \
 131         addi    r11,r11,THREAD_SIZE;    \
 132         tophys(r11,r11);        \
 133 1:      subi    r11,r11,INT_FRAME_SIZE  /* alloc exc. frame */
 134
 135
 136 #define EXCEPTION_PROLOG_2      \
 137         CLR_TOP32(r11);         \
 138         stw     r10,_CCR(r11);          /* save registers */ \
 139         stw     r12,GPR12(r11); \
 140         stw     r9,GPR9(r11);   \
 141         mfspr   r10,SPRN_SPRG0; \
 142         stw     r10,GPR10(r11); \
 143         mfspr   r12,SPRN_SPRG1; \
 144         stw     r12,GPR11(r11); \
 145         mflr    r10;            \
 146         stw     r10,_LINK(r11); \
 147         mfspr   r12,SPRN_SRR0;  \
 148         mfspr   r9,SPRN_SRR1;   \
 149         stw     r1,GPR1(r11);   \
 150         stw     r1,0(r11);      \
 151         tovirt(r1,r11);                 /* set new kernel sp */ \
 152         li      r10,MSR_KERNEL & ~(MSR_IR|MSR_DR); /* can take exceptions */ \
 153         MTMSRD(r10);                    /* (except for mach check in rtas) */ \
 154         stw     r0,GPR0(r11);   \
 155         SAVE_4GPRS(3, r11);     \
 156         SAVE_2GPRS(7, r11)
 157
 158 /*
 159  * Note: code which follows this uses cr0.eq (set if from kernel),
 160  * r11, r12 (SRR0), and r9 (SRR1).
 161  *
 162  * Note2: once we have set r1 we are in a position to take exceptions
 163  * again, and we could thus set MSR:RI at that point.
 164  */
 165
 166 /*
 167  * Exception vectors.
 168  */
 169 #define EXCEPTION(n, label, hdlr, xfer)         \
 170         . = n;                                  \
 171 label:                                          \
 172         EXCEPTION_PROLOG;                       \
 173         addi    r3,r1,STACK_FRAME_OVERHEAD;     \
 174         xfer(n, hdlr)
 175
 176 #define EXC_XFER_TEMPLATE(n, hdlr, trap, copyee, tfer, ret)     \
 177         li      r10,trap;                                       \
 178         stw     r10,TRAP(r11);                                  \
 179         li      r10,MSR_KERNEL;                                 \
 180         copyee(r10, r9);                                        \
 181         bl      tfer;                                           \
 182 i##n:                                                           \
 183         .long   hdlr;                                           \
 184         .long   ret
 185
 186 #define COPY_EE(d, s)           rlwimi d,s,0,16,16
 187 #define NOCOPY(d, s)
 188
 189 #define EXC_XFER_STD(n, hdlr)           \
 190         EXC_XFER_TEMPLATE(n, hdlr, n, NOCOPY, transfer_to_handler_full, \
 191                           ret_from_except_full)
 192
 193 #define EXC_XFER_LITE(n, hdlr)          \
 194         EXC_XFER_TEMPLATE(n, hdlr, n+1, NOCOPY, transfer_to_handler, \
 195                           ret_from_except)
 196
 197 #define EXC_XFER_EE(n, hdlr)            \
 198         EXC_XFER_TEMPLATE(n, hdlr, n, COPY_EE, transfer_to_handler_full, \
 199                           ret_from_except_full)
 200
 201 #define EXC_XFER_EE_LITE(n, hdlr)       \
 202         EXC_XFER_TEMPLATE(n, hdlr, n+1, COPY_EE, transfer_to_handler, \
 203                           ret_from_except)
 204
 205 /* System reset */
 206         EXCEPTION(0x100, Reset, unknown_exception, EXC_XFER_STD)
 207
 208 /* Machine check */
 209         . = 0x200
 210 MachineCheck:
 211         EXCEPTION_PROLOG
 212         mfspr r4,SPRN_DAR
 213         stw r4,_DAR(r11)
 214         mfspr r5,SPRN_DSISR
 215         stw r5,_DSISR(r11)
 216         addi r3,r1,STACK_FRAME_OVERHEAD
 217         EXC_XFER_STD(0x200, machine_check_exception)
 218
 219 /* Data access exception.
 220  * This is "never generated" by the MPC8xx.  We jump to it for other
 221  * translation errors.
 222  */
 223         . = 0x300
 224 DataAccess:
 225         EXCEPTION_PROLOG
 226         mfspr   r10,SPRN_DSISR
 227         stw     r10,_DSISR(r11)
 228         mr      r5,r10
 229         mfspr   r4,SPRN_DAR
 230         EXC_XFER_EE_LITE(0x300, handle_page_fault)
 231
 232 /* Instruction access exception.
 233  * This is "never generated" by the MPC8xx.  We jump to it for other
 234  * translation errors.
 235  */
 236         . = 0x400
 237 InstructionAccess:
 238         EXCEPTION_PROLOG
 239         mr      r4,r12
 240         mr      r5,r9
 241         EXC_XFER_EE_LITE(0x400, handle_page_fault)
 242
 243 /* External interrupt */
 244         EXCEPTION(0x500, HardwareInterrupt, do_IRQ, EXC_XFER_LITE)
 245
 246 /* Alignment exception */
 247         . = 0x600
 248 Alignment:
 249         EXCEPTION_PROLOG
 250         mfspr   r4,SPRN_DAR
 251         stw     r4,_DAR(r11)
 252         mfspr   r5,SPRN_DSISR
 253         stw     r5,_DSISR(r11)
 254         addi    r3,r1,STACK_FRAME_OVERHEAD
 255         EXC_XFER_EE(0x600, alignment_exception)
 256
 257 /* Program check exception */
 258         EXCEPTION(0x700, ProgramCheck, program_check_exception, EXC_XFER_STD)
 259
 260 /* No FPU on MPC8xx.  This exception is not supposed to happen.
 261 */
 262         EXCEPTION(0x800, FPUnavailable, unknown_exception, EXC_XFER_STD)
 263
 264 /* Decrementer */
 265         EXCEPTION(0x900, Decrementer, timer_interrupt, EXC_XFER_LITE)
 266
 267         EXCEPTION(0xa00, Trap_0a, unknown_exception, EXC_XFER_EE)
 268         EXCEPTION(0xb00, Trap_0b, unknown_exception, EXC_XFER_EE)
 269
 270 /* System call */
 271         . = 0xc00
 272 SystemCall:
 273         EXCEPTION_PROLOG
 274         EXC_XFER_EE_LITE(0xc00, DoSyscall)
 275
 276 /* Single step - not used on 601 */
 277         EXCEPTION(0xd00, SingleStep, single_step_exception, EXC_XFER_STD)
 278         EXCEPTION(0xe00, Trap_0e, unknown_exception, EXC_XFER_EE)
 279         EXCEPTION(0xf00, Trap_0f, unknown_exception, EXC_XFER_EE)
 280
 281 /* On the MPC8xx, this is a software emulation interrupt.  It occurs
 282  * for all unimplemented and illegal instructions.
 283  */
 284         EXCEPTION(0x1000, SoftEmu, SoftwareEmulation, EXC_XFER_STD)
 285
 286         . = 0x1100
 287 /*
 288  * For the MPC8xx, this is a software tablewalk to load the instruction
 289  * TLB.  It is modelled after the example in the Motorola manual.  The task
 290  * switch loads the M_TWB register with the pointer to the first level table.
 291  * If we discover there is no second level table (value is zero) or if there
 292  * is an invalid pte, we load that into the TLB, which causes another fault
 293  * into the TLB Error interrupt where we can handle such problems.
 294  * We have to use the MD_xxx registers for the tablewalk because the
 295  * equivalent MI_xxx registers only perform the attribute functions.
 296  */
 297 InstructionTLBMiss:
 298 #ifdef CONFIG_8xx_CPU6
 299         stw     r3, 8(r0)
 300 #endif
 301         DO_8xx_CPU6(0x3f80, r3)
 302         mtspr   SPRN_M_TW, r10  /* Save a couple of working registers */
 303         mfcr    r10
 304         stw     r10, 0(r0)
 305         stw     r11, 4(r0)
 306         mfspr   r10, SPRN_SRR0  /* Get effective address of fault */
 307         DO_8xx_CPU6(0x3780, r3)
 308         mtspr   SPRN_MD_EPN, r10        /* Have to use MD_EPN for walk, MI_EPN can't */
 309         mfspr   r10, SPRN_M_TWB /* Get level 1 table entry address */
 310
 311         /* If we are faulting a kernel address, we have to use the
 312          * kernel page tables.
 313          */
 314         andi.   r11, r10, 0x0800        /* Address >= 0x80000000 */
 315         beq     3f
 316         lis     r11, swapper_pg_dir@h
 317         ori     r11, r11, swapper_pg_dir@l
 318         rlwimi  r10, r11, 0, 2, 19
 319 3:
 320         lwz     r11, 0(r10)     /* Get the level 1 entry */
 321         rlwinm. r10, r11,0,0,19 /* Extract page descriptor page address */
 322         beq     2f              /* If zero, don't try to find a pte */
 323
 324         /* We have a pte table, so load the MI_TWC with the attributes
 325          * for this "segment."
 326          */
 327         ori     r11,r11,1               /* Set valid bit */
 328         DO_8xx_CPU6(0x2b80, r3)
 329         mtspr   SPRN_MI_TWC, r11        /* Set segment attributes */
 330         DO_8xx_CPU6(0x3b80, r3)
 331         mtspr   SPRN_MD_TWC, r11        /* Load pte table base address */
 332         mfspr   r11, SPRN_MD_TWC        /* ....and get the pte address */
 333         lwz     r10, 0(r11)     /* Get the pte */
 334
 335         ori     r10, r10, _PAGE_ACCESSED
 336         stw     r10, 0(r11)
 337
 338         /* The Linux PTE won't go exactly into the MMU TLB.
 339          * Software indicator bits 21, 22 and 28 must be clear.
 340          * Software indicator bits 24, 25, 26, and 27 must be
 341          * set.  All other Linux PTE bits control the behavior
 342          * of the MMU.
 343          */
 344 2:      li      r11, 0x00f0
 345         rlwimi  r10, r11, 0, 24, 28     /* Set 24-27, clear 28 */
 346         DO_8xx_CPU6(0x2d80, r3)
 347         mtspr   SPRN_MI_RPN, r10        /* Update TLB entry */
 348
 349         mfspr   r10, SPRN_M_TW  /* Restore registers */
 350         lwz     r11, 0(r0)
 351         mtcr    r11
 352         lwz     r11, 4(r0)
 353 #ifdef CONFIG_8xx_CPU6
 354         lwz     r3, 8(r0)
 355 #endif
 356         rfi
 357
 358         . = 0x1200
 359 DataStoreTLBMiss:
 360 #ifdef CONFIG_8xx_CPU6
 361         stw     r3, 8(r0)
 362 #endif
 363         DO_8xx_CPU6(0x3f80, r3)
 364         mtspr   SPRN_M_TW, r10  /* Save a couple of working registers */
 365         mfcr    r10
 366         stw     r10, 0(r0)
 367         stw     r11, 4(r0)
 368         mfspr   r10, SPRN_M_TWB /* Get level 1 table entry address */
 369
 370         /* If we are faulting a kernel address, we have to use the
 371          * kernel page tables.
 372          */
 373         andi.   r11, r10, 0x0800
 374         beq     3f
 375         lis     r11, swapper_pg_dir@h
 376         ori     r11, r11, swapper_pg_dir@l
 377         rlwimi  r10, r11, 0, 2, 19
 378         stw     r12, 16(r0)
 379         b LoadLargeDTLB
 380 3:
 381         lwz     r11, 0(r10)     /* Get the level 1 entry */
 382         rlwinm. r10, r11,0,0,19 /* Extract page descriptor page address */
 383         beq     2f              /* If zero, don't try to find a pte */
 384
 385         /* We have a pte table, so load fetch the pte from the table.
 386          */
 387         ori     r11, r11, 1     /* Set valid bit in physical L2 page */
 388         DO_8xx_CPU6(0x3b80, r3)
 389         mtspr   SPRN_MD_TWC, r11        /* Load pte table base address */
 390         mfspr   r10, SPRN_MD_TWC        /* ....and get the pte address */
 391         lwz     r10, 0(r10)     /* Get the pte */
 392
 393         /* Insert the Guarded flag into the TWC from the Linux PTE.
 394          * It is bit 27 of both the Linux PTE and the TWC (at least
 395          * I got that right :-).  It will be better when we can put
 396          * this into the Linux pgd/pmd and load it in the operation
 397          * above.
 398          */
 399         rlwimi  r11, r10, 0, 27, 27
 400         DO_8xx_CPU6(0x3b80, r3)
 401         mtspr   SPRN_MD_TWC, r11
 402
 403         mfspr   r11, SPRN_MD_TWC        /* get the pte address again */
 404         ori     r10, r10, _PAGE_ACCESSED
 405         stw     r10, 0(r11)
 406
 407         /* The Linux PTE won't go exactly into the MMU TLB.
 408          * Software indicator bits 21, 22 and 28 must be clear.
 409          * Software indicator bits 24, 25, 26, and 27 must be
 410          * set.  All other Linux PTE bits control the behavior
 411          * of the MMU.
 412          */
 413 2:      li      r11, 0x00f0
 414         rlwimi  r10, r11, 0, 24, 28     /* Set 24-27, clear 28 */
 415         DO_8xx_CPU6(0x3d80, r3)
 416         mtspr   SPRN_MD_RPN, r10        /* Update TLB entry */
 417
 418         mfspr   r10, SPRN_M_TW  /* Restore registers */
 419         lwz     r11, 0(r0)
 420         mtcr    r11
 421         lwz     r11, 4(r0)
 422 #ifdef CONFIG_8xx_CPU6
 423         lwz     r3, 8(r0)
 424 #endif
 425         rfi
 426
 427 /* This is an instruction TLB error on the MPC8xx.  This could be due
 428  * to many reasons, such as executing guarded memory or illegal instruction
 429  * addresses.  There is nothing to do but handle a big time error fault.
 430  */
 431         . = 0x1300
 432 InstructionTLBError:
 433         b       InstructionAccess
 434
 435 LoadLargeDTLB:
 436         li      r12, 0
 437         lwz     r11, 0(r10)     /* Get the level 1 entry */
 438         rlwinm. r10, r11,0,0,19 /* Extract page descriptor page address */
 439         beq     3f              /* If zero, don't try to find a pte */
 440
 441         /* We have a pte table, so load fetch the pte from the table.
 442          */
 443         ori     r11, r11, 1     /* Set valid bit in physical L2 page */
 444         DO_8xx_CPU6(0x3b80, r3)
 445         mtspr   SPRN_MD_TWC, r11        /* Load pte table base address */
 446         mfspr   r10, SPRN_MD_TWC        /* ....and get the pte address */
 447         lwz     r10, 0(r10)     /* Get the pte */
 448
 449         /* Insert the Guarded flag into the TWC from the Linux PTE.
 450          * It is bit 27 of both the Linux PTE and the TWC (at least
 451          * I got that right :-).  It will be better when we can put
 452          * this into the Linux pgd/pmd and load it in the operation
 453          * above.
 454          */
 455         rlwimi  r11, r10, 0, 27, 27
 456
 457         rlwimi  r12, r10, 0, 0, 9       /* extract phys. addr */
 458         mfspr   r3, SPRN_MD_EPN
 459         rlwinm  r3, r3, 0, 0, 9         /* extract virtual address */
 460         tophys(r3, r3)
 461         cmpw    r3, r12                 /* only use 8M page if it is a direct
 462                                            kernel mapping */
 463         bne     1f
 464         ori     r11, r11, MD_PS8MEG
 465         li      r12, 1
 466         b       2f
 467 1:
 468         li      r12, 0          /* can't use 8MB TLB, so zero r12. */
 469 2:
 470         DO_8xx_CPU6(0x3b80, r3)
 471         mtspr   SPRN_MD_TWC, r11
 472
 473         /* The Linux PTE won't go exactly into the MMU TLB.
 474          * Software indicator bits 21, 22 and 28 must be clear.
 475          * Software indicator bits 24, 25, 26, and 27 must be
 476          * set.  All other Linux PTE bits control the behavior
 477          * of the MMU.
 478          */
 479 3:      li      r11, 0x00f0
 480         rlwimi  r10, r11, 0, 24, 28     /* Set 24-27, clear 28 */
 481         cmpwi   r12, 1
 482         bne 4f
 483         ori     r10, r10, 0x8
 484
 485         mfspr   r12, SPRN_MD_EPN
 486         lis     r3, 0xff80              /* 10-19 must be clear for 8MB TLB */
 487         ori     r3, r3, 0x0fff
 488         and     r12, r3, r12
 489         DO_8xx_CPU6(0x3780, r3)
 490         mtspr   SPRN_MD_EPN, r12
 491
 492         lis     r3, 0xff80              /* 10-19 must be clear for 8MB TLB */
 493         ori     r3, r3, 0x0fff
 494         and     r10, r3, r10
 495 4:
 496         DO_8xx_CPU6(0x3d80, r3)
 497         mtspr   SPRN_MD_RPN, r10        /* Update TLB entry */
 498
 499         mfspr   r10, SPRN_M_TW  /* Restore registers */
 500         lwz     r11, 0(r0)
 501         mtcr    r11
 502         lwz     r11, 4(r0)
 503
 504         lwz     r12, 16(r0)
 505 #ifdef CONFIG_8xx_CPU6
 506         lwz     r3, 8(r0)
 507 #endif
 508         rfi
 509
 510 /* This is the data TLB error on the MPC8xx.  This could be due to
 511  * many reasons, including a dirty update to a pte.  We can catch that
 512  * one here, but anything else is an error.  First, we track down the
 513  * Linux pte.  If it is valid, write access is allowed, but the
 514  * page dirty bit is not set, we will set it and reload the TLB.  For
 515  * any other case, we bail out to a higher level function that can
 516  * handle it.
 517  */
 518         . = 0x1400
 519 DataTLBError:
 520 #ifdef CONFIG_8xx_CPU6
 521         stw     r3, 8(r0)
 522 #endif
 523         DO_8xx_CPU6(0x3f80, r3)
 524         mtspr   SPRN_M_TW, r10  /* Save a couple of working registers */
 525         mfcr    r10
 526         stw     r10, 0(r0)
 527         stw     r11, 4(r0)
 528
 529         /* First, make sure this was a store operation.
 530         */
 531         mfspr   r10, SPRN_DSISR
 532         andis.  r11, r10, 0x0200        /* If set, indicates store op */
 533         beq     2f
 534
 535         /* The EA of a data TLB miss is automatically stored in the MD_EPN
 536          * register.  The EA of a data TLB error is automatically stored in
 537          * the DAR, but not the MD_EPN register.  We must copy the 20 most
 538          * significant bits of the EA from the DAR to MD_EPN before we
 539          * start walking the page tables.  We also need to copy the CASID
 540          * value from the M_CASID register.
 541          * Addendum:  The EA of a data TLB error is _supposed_ to be stored
 542          * in DAR, but it seems that this doesn't happen in some cases, such
 543          * as when the error is due to a dcbi instruction to a page with a
 544          * TLB that doesn't have the changed bit set.  In such cases, there
 545          * does not appear to be any way  to recover the EA of the error
 546          * since it is neither in DAR nor MD_EPN.  As a workaround, the
 547          * _PAGE_HWWRITE bit is set for all kernel data pages when the PTEs
 548          * are initialized in mapin_ram().  This will avoid the problem,
 549          * assuming we only use the dcbi instruction on kernel addresses.
 550          */
 551         mfspr   r10, SPRN_DAR
 552         rlwinm  r11, r10, 0, 0, 19
 553         ori     r11, r11, MD_EVALID
 554         mfspr   r10, SPRN_M_CASID
 555         rlwimi  r11, r10, 0, 28, 31
 556         DO_8xx_CPU6(0x3780, r3)
 557         mtspr   SPRN_MD_EPN, r11
 558
 559         mfspr   r10, SPRN_M_TWB /* Get level 1 table entry address */
 560
 561         /* If we are faulting a kernel address, we have to use the
 562          * kernel page tables.
 563          */
 564         andi.   r11, r10, 0x0800
 565         beq     3f
 566         lis     r11, swapper_pg_dir@h
 567         ori     r11, r11, swapper_pg_dir@l
 568         rlwimi  r10, r11, 0, 2, 19
 569 3:
 570         lwz     r11, 0(r10)     /* Get the level 1 entry */
 571         rlwinm. r10, r11,0,0,19 /* Extract page descriptor page address */
 572         beq     2f              /* If zero, bail */
 573
 574         /* We have a pte table, so fetch the pte from the table.
 575          */
 576         ori     r11, r11, 1             /* Set valid bit in physical L2 page */
 577         DO_8xx_CPU6(0x3b80, r3)
 578         mtspr   SPRN_MD_TWC, r11                /* Load pte table base address */
 579         mfspr   r11, SPRN_MD_TWC                /* ....and get the pte address */
 580         lwz     r10, 0(r11)             /* Get the pte */
 581
 582         andi.   r11, r10, _PAGE_RW      /* Is it writeable? */
 583         beq     2f                      /* Bail out if not */
 584
 585         /* Update 'changed', among others.
 586         */
 587         ori     r10, r10, _PAGE_DIRTY|_PAGE_ACCESSED|_PAGE_HWWRITE
 588         mfspr   r11, SPRN_MD_TWC                /* Get pte address again */
 589         stw     r10, 0(r11)             /* and update pte in table */
 590
 591         /* The Linux PTE won't go exactly into the MMU TLB.
 592          * Software indicator bits 21, 22 and 28 must be clear.
 593          * Software indicator bits 24, 25, 26, and 27 must be
 594          * set.  All other Linux PTE bits control the behavior
 595          * of the MMU.
 596          */
 597         li      r11, 0x00f0
 598         rlwimi  r10, r11, 0, 24, 28     /* Set 24-27, clear 28 */
 599         DO_8xx_CPU6(0x3d80, r3)
 600         mtspr   SPRN_MD_RPN, r10        /* Update TLB entry */
 601
 602         mfspr   r10, SPRN_M_TW  /* Restore registers */
 603         lwz     r11, 0(r0)
 604         mtcr    r11
 605         lwz     r11, 4(r0)
 606 #ifdef CONFIG_8xx_CPU6
 607         lwz     r3, 8(r0)
 608 #endif
 609         rfi
 610 2:
 611         mfspr   r10, SPRN_M_TW  /* Restore registers */
 612         lwz     r11, 0(r0)
 613         mtcr    r11
 614         lwz     r11, 4(r0)
 615 #ifdef CONFIG_8xx_CPU6
 616         lwz     r3, 8(r0)
 617 #endif
 618         b       DataAccess
 619
 620         EXCEPTION(0x1500, Trap_15, unknown_exception, EXC_XFER_EE)
 621         EXCEPTION(0x1600, Trap_16, unknown_exception, EXC_XFER_EE)
 622         EXCEPTION(0x1700, Trap_17, unknown_exception, EXC_XFER_EE)
 623         EXCEPTION(0x1800, Trap_18, unknown_exception, EXC_XFER_EE)
 624         EXCEPTION(0x1900, Trap_19, unknown_exception, EXC_XFER_EE)
 625         EXCEPTION(0x1a00, Trap_1a, unknown_exception, EXC_XFER_EE)
 626         EXCEPTION(0x1b00, Trap_1b, unknown_exception, EXC_XFER_EE)
 627
 628 /* On the MPC8xx, these next four traps are used for development
 629  * support of breakpoints and such.  Someday I will get around to
 630  * using them.
 631  */
 632         EXCEPTION(0x1c00, Trap_1c, unknown_exception, EXC_XFER_EE)
 633         EXCEPTION(0x1d00, Trap_1d, unknown_exception, EXC_XFER_EE)
 634         EXCEPTION(0x1e00, Trap_1e, unknown_exception, EXC_XFER_EE)
 635         EXCEPTION(0x1f00, Trap_1f, unknown_exception, EXC_XFER_EE)
 636
 637         . = 0x2000
 638
 639         .globl  giveup_fpu
 640 giveup_fpu:
 641         blr
 642
 643 /*
 644  * This is where the main kernel code starts.
 645  */
 646 start_here:
 647         /* ptr to current */
 648         lis     r2,init_task@h
 649         ori     r2,r2,init_task@l
 650
 651         /* ptr to phys current thread */
 652         tophys(r4,r2)
 653         addi    r4,r4,THREAD    /* init task's THREAD */
 654         mtspr   SPRN_SPRG3,r4
 655         li      r3,0
 656         mtspr   SPRN_SPRG2,r3   /* 0 => r1 has kernel sp */
 657
 658         /* stack */
 659         lis     r1,init_thread_union@ha
 660         addi    r1,r1,init_thread_union@l
 661         li      r0,0
 662         stwu    r0,THREAD_SIZE-STACK_FRAME_OVERHEAD(r1)
 663
 664         bl      early_init      /* We have to do this with MMU on */
 665
 666 /*
 667  * Decide what sort of machine this is and initialize the MMU.
 668  */
 669         mr      r3,r31
 670         mr      r4,r30
 671         mr      r5,r29
 672         mr      r6,r28
 673         mr      r7,r27
 674         bl      machine_init
 675         bl      MMU_init
 676
 677 /*
 678  * Go back to running unmapped so we can load up new values
 679  * and change to using our exception vectors.
 680  * On the 8xx, all we have to do is invalidate the TLB to clear
 681  * the old 8M byte TLB mappings and load the page table base register.
 682  */
 683         /* The right way to do this would be to track it down through
 684          * init's THREAD like the context switch code does, but this is
 685          * easier......until someone changes init's static structures.
 686          */
 687         lis     r6, swapper_pg_dir@h
 688         ori     r6, r6, swapper_pg_dir@l
 689         tophys(r6,r6)
 690 #ifdef CONFIG_8xx_CPU6
 691         lis     r4, cpu6_errata_word@h
 692         ori     r4, r4, cpu6_errata_word@l
 693         li      r3, 0x3980
 694         stw     r3, 12(r4)
 695         lwz     r3, 12(r4)
 696 #endif
 697         mtspr   SPRN_M_TWB, r6
 698         lis     r4,2f@h
 699         ori     r4,r4,2f@l
 700         tophys(r4,r4)
 701         li      r3,MSR_KERNEL & ~(MSR_IR|MSR_DR)
 702         mtspr   SPRN_SRR0,r4
 703         mtspr   SPRN_SRR1,r3
 704         rfi
 705 /* Load up the kernel context */
 706 2:
 707         SYNC                    /* Force all PTE updates to finish */
 708         tlbia                   /* Clear all TLB entries */
 709         sync                    /* wait for tlbia/tlbie to finish */
 710         TLBSYNC                 /* ... on all CPUs */
 711
 712         /* set up the PTE pointers for the Abatron bdiGDB.
 713         */
 714         tovirt(r6,r6)
 715         lis     r5, abatron_pteptrs@h
 716         ori     r5, r5, abatron_pteptrs@l
 717         stw     r5, 0xf0(r0)    /* Must match your Abatron config file */
 718         tophys(r5,r5)
 719         stw     r6, 0(r5)
 720
 721 /* Now turn on the MMU for real! */
 722         li      r4,MSR_KERNEL
 723         lis     r3,start_kernel@h
 724         ori     r3,r3,start_kernel@l
 725         mtspr   SPRN_SRR0,r3
 726         mtspr   SPRN_SRR1,r4
 727         rfi                     /* enable MMU and jump to start_kernel */
 728
 729 /* Set up the initial MMU state so we can do the first level of
 730  * kernel initialization.  This maps the first 8 MBytes of memory 1:1
 731  * virtual to physical.  Also, set the cache mode since that is defined
 732  * by TLB entries and perform any additional mapping (like of the IMMR).
 733  * If configured to pin some TLBs, we pin the first 8 Mbytes of kernel,
 734  * 24 Mbytes of data, and the 8M IMMR space.  Anything not covered by
 735  * these mappings is mapped by page tables.
 736  */
 737 initial_mmu:
 738         tlbia                   /* Invalidate all TLB entries */
 739 #ifdef CONFIG_PIN_TLB
 740         lis     r8, MI_RSV4I@h
 741         ori     r8, r8, 0x1c00
 742 #else
 743         li      r8, 0
 744 #endif
 745         mtspr   SPRN_MI_CTR, r8 /* Set instruction MMU control */
 746
 747 #ifdef CONFIG_PIN_TLB
 748         lis     r10, (MD_RSV4I | MD_RESETVAL)@h
 749         ori     r10, r10, 0x1c00
 750         mr      r8, r10
 751 #else
 752         lis     r10, MD_RESETVAL@h
 753 #endif
 754 #ifndef CONFIG_8xx_COPYBACK
 755         oris    r10, r10, MD_WTDEF@h
 756 #endif
 757         mtspr   SPRN_MD_CTR, r10        /* Set data TLB control */
 758
 759         /* Now map the lower 8 Meg into the TLBs.  For this quick hack,
 760          * we can load the instruction and data TLB registers with the
 761          * same values.
 762          */
 763         lis     r8, KERNELBASE@h        /* Create vaddr for TLB */
 764         ori     r8, r8, MI_EVALID       /* Mark it valid */
 765         mtspr   SPRN_MI_EPN, r8
 766         mtspr   SPRN_MD_EPN, r8
 767         li      r8, MI_PS8MEG           /* Set 8M byte page */
 768         ori     r8, r8, MI_SVALID       /* Make it valid */
 769         mtspr   SPRN_MI_TWC, r8
 770         mtspr   SPRN_MD_TWC, r8
 771         li      r8, MI_BOOTINIT         /* Create RPN for address 0 */
 772         mtspr   SPRN_MI_RPN, r8         /* Store TLB entry */
 773         mtspr   SPRN_MD_RPN, r8
 774         lis     r8, MI_Kp@h             /* Set the protection mode */
 775         mtspr   SPRN_MI_AP, r8
 776         mtspr   SPRN_MD_AP, r8
 777
 778         /* Map another 8 MByte at the IMMR to get the processor
 779          * internal registers (among other things).
 780          */
 781 #ifdef CONFIG_PIN_TLB
 782         addi    r10, r10, 0x0100
 783         mtspr   SPRN_MD_CTR, r10
 784 #endif
 785         mfspr   r9, 638                 /* Get current IMMR */
 786         andis.  r9, r9, 0xff80          /* Get 8Mbyte boundary */
 787
 788         mr      r8, r9                  /* Create vaddr for TLB */
 789         ori     r8, r8, MD_EVALID       /* Mark it valid */
 790         mtspr   SPRN_MD_EPN, r8
 791         li      r8, MD_PS8MEG           /* Set 8M byte page */
 792         ori     r8, r8, MD_SVALID       /* Make it valid */
 793         mtspr   SPRN_MD_TWC, r8
 794         mr      r8, r9                  /* Create paddr for TLB */
 795         ori     r8, r8, MI_BOOTINIT|0x2 /* Inhibit cache -- Cort */
 796         mtspr   SPRN_MD_RPN, r8
 797
 798 #ifdef CONFIG_PIN_TLB
 799         /* Map two more 8M kernel data pages.
 800         */
 801         addi    r10, r10, 0x0100
 802         mtspr   SPRN_MD_CTR, r10
 803
 804         lis     r8, KERNELBASE@h        /* Create vaddr for TLB */
 805         addis   r8, r8, 0x0080          /* Add 8M */
 806         ori     r8, r8, MI_EVALID       /* Mark it valid */
 807         mtspr   SPRN_MD_EPN, r8
 808         li      r9, MI_PS8MEG           /* Set 8M byte page */
 809         ori     r9, r9, MI_SVALID       /* Make it valid */
 810         mtspr   SPRN_MD_TWC, r9
 811         li      r11, MI_BOOTINIT        /* Create RPN for address 0 */
 812         addis   r11, r11, 0x0080        /* Add 8M */
 813         mtspr   SPRN_MD_RPN, r11
 814
 815         addi    r10, r10, 0x0100
 816         mtspr   SPRN_MD_CTR, r10
 817
 818         addis   r8, r8, 0x0080          /* Add 8M */
 819         mtspr   SPRN_MD_EPN, r8
 820         mtspr   SPRN_MD_TWC, r9
 821         addis   r11, r11, 0x0080        /* Add 8M */
 822         mtspr   SPRN_MD_RPN, r11
 823 #endif
 824
 825         /* Since the cache is enabled according to the information we
 826          * just loaded into the TLB, invalidate and enable the caches here.
 827          * We should probably check/set other modes....later.
 828          */
 829         lis     r8, IDC_INVALL@h
 830         mtspr   SPRN_IC_CST, r8
 831         mtspr   SPRN_DC_CST, r8
 832         lis     r8, IDC_ENABLE@h
 833         mtspr   SPRN_IC_CST, r8
 834 #ifdef CONFIG_8xx_COPYBACK
 835         mtspr   SPRN_DC_CST, r8
 836 #else
 837         /* For a debug option, I left this here to easily enable
 838          * the write through cache mode
 839          */
 840         lis     r8, DC_SFWT@h
 841         mtspr   SPRN_DC_CST, r8
 842         lis     r8, IDC_ENABLE@h
 843         mtspr   SPRN_DC_CST, r8
 844 #endif
 845         blr
 846
 847
 848 /*
 849  * Set up to use a given MMU context.
 850  * r3 is context number, r4 is PGD pointer.
 851  *
 852  * We place the physical address of the new task page directory loaded
 853  * into the MMU base register, and set the ASID compare register with
 854  * the new "context."
 855  */
 856 _GLOBAL(set_context)
 857
 858 #ifdef CONFIG_BDI_SWITCH
 859         /* Context switch the PTE pointer for the Abatron BDI2000.
 860          * The PGDIR is passed as second argument.
 861          */
 862         lis     r5, KERNELBASE@h
 863         lwz     r5, 0xf0(r5)
 864         stw     r4, 0x4(r5)
 865 #endif
 866
 867 #ifdef CONFIG_8xx_CPU6
 868         lis     r6, cpu6_errata_word@h
 869         ori     r6, r6, cpu6_errata_word@l
 870         tophys  (r4, r4)
 871         li      r7, 0x3980
 872         stw     r7, 12(r6)
 873         lwz     r7, 12(r6)
 874         mtspr   SPRN_M_TWB, r4               /* Update MMU base address */
 875         li      r7, 0x3380
 876         stw     r7, 12(r6)
 877         lwz     r7, 12(r6)
 878         mtspr   SPRN_M_CASID, r3             /* Update context */
 879 #else
 880         mtspr   SPRN_M_CASID,r3         /* Update context */
 881         tophys  (r4, r4)
 882         mtspr   SPRN_M_TWB, r4          /* and pgd */
 883 #endif
 884         SYNC
 885         blr
 886
 887 #ifdef CONFIG_8xx_CPU6
 888 /* It's here because it is unique to the 8xx.
 889  * It is important we get called with interrupts disabled.  I used to
 890  * do that, but it appears that all code that calls this already had
 891  * interrupt disabled.
 892  */
 893         .globl  set_dec_cpu6
 894 set_dec_cpu6:
 895         lis     r7, cpu6_errata_word@h
 896         ori     r7, r7, cpu6_errata_word@l
 897         li      r4, 0x2c00
 898         stw     r4, 8(r7)
 899         lwz     r4, 8(r7)
 900         mtspr   22, r3          /* Update Decrementer */
 901         SYNC
 902         blr
 903 #endif
 904
 905 /*
 906  * We put a few things here that have to be page-aligned.
 907  * This stuff goes at the beginning of the data segment,
 908  * which is page-aligned.
 909  */
 910         .data
 911         .globl  sdata
 912 sdata:
 913         .globl  empty_zero_page
 914 empty_zero_page:
 915         .space  4096
 916
 917         .globl  swapper_pg_dir
 918 swapper_pg_dir:
 919         .space  4096
 920
 921 /*
 922  * This space gets a copy of optional info passed to us by the bootstrap
 923  * Used to pass parameters into the kernel like root=/dev/sda1, etc.
 924  */
 925         .globl  cmd_line
 926 cmd_line:
 927         .space  512
 928
 929 /* Room for two PTE table poiners, usually the kernel and current user
 930  * pointer to their respective root page table (pgdir).
 931  */
 932 abatron_pteptrs:
 933         .space  8
 934
 935 #ifdef CONFIG_8xx_CPU6
 936         .globl  cpu6_errata_word
 937 cpu6_errata_word:
 938         .space  16
 939 #endif
 940