git.oblomov.eu Git - linux-2.6/blob - arch/x86/vdso/vdso32/sysenter.S

   1 /*
   2  * Code for the vDSO.  This version uses the sysenter instruction.
   3  *
   4  * First get the common code for the sigreturn entry points.
   5  * This must come first.
   6  */
   7 #include "sigreturn.S"
   8
   9 /*
  10  * The caller puts arg2 in %ecx, which gets pushed. The kernel will use
  11  * %ecx itself for arg2. The pushing is because the sysexit instruction
  12  * (found in entry.S) requires that we clobber %ecx with the desired %esp.
  13  * User code might expect that %ecx is unclobbered though, as it would be
  14  * for returning via the iret instruction, so we must push and pop.
  15  *
  16  * The caller puts arg3 in %edx, which the sysexit instruction requires
  17  * for %eip. Thus, exactly as for arg2, we must push and pop.
  18  *
  19  * Arg6 is different. The caller puts arg6 in %ebp. Since the sysenter
  20  * instruction clobbers %esp, the user's %esp won't even survive entry
  21  * into the kernel. We store %esp in %ebp. Code in entry.S must fetch
  22  * arg6 from the stack.
  23  *
  24  * You can not use this vsyscall for the clone() syscall because the
  25  * three words on the parent stack do not get copied to the child.
  26  */
  27         .text
  28         .globl __kernel_vsyscall
  29         .type __kernel_vsyscall,@function
  30         ALIGN
  31 __kernel_vsyscall:
  32 .LSTART_vsyscall:
  33         push %ecx
  34 .Lpush_ecx:
  35         push %edx
  36 .Lpush_edx:
  37         push %ebp
  38 .Lenter_kernel:
  39         movl %esp,%ebp
  40         sysenter
  41
  42         /* 7: align return point with nop's to make disassembly easier */
  43         .space 7,0x90
  44
  45         /* 14: System call restart point is here! (SYSENTER_RETURN-2) */
  46         jmp .Lenter_kernel
  47         /* 16: System call normal return point is here! */
  48 VDSO32_SYSENTER_RETURN: /* Symbol used by sysenter.c via vdso32-syms.h */
  49         pop %ebp
  50 .Lpop_ebp:
  51         pop %edx
  52 .Lpop_edx:
  53         pop %ecx
  54 .Lpop_ecx:
  55         ret
  56 .LEND_vsyscall:
  57         .size __kernel_vsyscall,.-.LSTART_vsyscall
  58         .previous
  59
  60         .section .eh_frame,"a",@progbits
  61 .LSTARTFRAMEDLSI:
  62         .long .LENDCIEDLSI-.LSTARTCIEDLSI
  63 .LSTARTCIEDLSI:
  64         .long 0                 /* CIE ID */
  65         .byte 1                 /* Version number */
  66         .string "zR"            /* NUL-terminated augmentation string */
  67         .uleb128 1              /* Code alignment factor */
  68         .sleb128 -4             /* Data alignment factor */
  69         .byte 8                 /* Return address register column */
  70         .uleb128 1              /* Augmentation value length */
  71         .byte 0x1b              /* DW_EH_PE_pcrel|DW_EH_PE_sdata4. */
  72         .byte 0x0c              /* DW_CFA_def_cfa */
  73         .uleb128 4
  74         .uleb128 4
  75         .byte 0x88              /* DW_CFA_offset, column 0x8 */
  76         .uleb128 1
  77         .align 4
  78 .LENDCIEDLSI:
  79         .long .LENDFDEDLSI-.LSTARTFDEDLSI /* Length FDE */
  80 .LSTARTFDEDLSI:
  81         .long .LSTARTFDEDLSI-.LSTARTFRAMEDLSI /* CIE pointer */
  82         .long .LSTART_vsyscall-.        /* PC-relative start address */
  83         .long .LEND_vsyscall-.LSTART_vsyscall
  84         .uleb128 0
  85         /* What follows are the instructions for the table generation.
  86            We have to record all changes of the stack pointer.  */
  87         .byte 0x04              /* DW_CFA_advance_loc4 */
  88         .long .Lpush_ecx-.LSTART_vsyscall
  89         .byte 0x0e              /* DW_CFA_def_cfa_offset */
  90         .byte 0x08              /* RA at offset 8 now */
  91         .byte 0x04              /* DW_CFA_advance_loc4 */
  92         .long .Lpush_edx-.Lpush_ecx
  93         .byte 0x0e              /* DW_CFA_def_cfa_offset */
  94         .byte 0x0c              /* RA at offset 12 now */
  95         .byte 0x04              /* DW_CFA_advance_loc4 */
  96         .long .Lenter_kernel-.Lpush_edx
  97         .byte 0x0e              /* DW_CFA_def_cfa_offset */
  98         .byte 0x10              /* RA at offset 16 now */
  99         .byte 0x85, 0x04        /* DW_CFA_offset %ebp -16 */
 100         /* Finally the epilogue.  */
 101         .byte 0x04              /* DW_CFA_advance_loc4 */
 102         .long .Lpop_ebp-.Lenter_kernel
 103         .byte 0x0e              /* DW_CFA_def_cfa_offset */
 104         .byte 0x0c              /* RA at offset 12 now */
 105         .byte 0xc5              /* DW_CFA_restore %ebp */
 106         .byte 0x04              /* DW_CFA_advance_loc4 */
 107         .long .Lpop_edx-.Lpop_ebp
 108         .byte 0x0e              /* DW_CFA_def_cfa_offset */
 109         .byte 0x08              /* RA at offset 8 now */
 110         .byte 0x04              /* DW_CFA_advance_loc4 */
 111         .long .Lpop_ecx-.Lpop_edx
 112         .byte 0x0e              /* DW_CFA_def_cfa_offset */
 113         .byte 0x04              /* RA at offset 4 now */
 114         .align 4
 115 .LENDFDEDLSI:
 116         .previous
 117
 118         /*
 119          * Emit a symbol with the size of this .eh_frame data,
 120          * to verify it matches the other versions.
 121          */
 122 VDSO32_vsyscall_eh_frame_size = (.LENDFDEDLSI-.LSTARTFRAMEDLSI)