git.oblomov.eu Git - linux-2.6/blob - arch/mips/kernel/scall64-64.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * Copyright (C) 1995, 96, 97, 98, 99, 2000, 01, 02 by Ralf Baechle
   7  * Copyright (C) 1999, 2000 Silicon Graphics, Inc.
   8  * Copyright (C) 2001 MIPS Technologies, Inc.
   9  */
  10 #include <linux/errno.h>
  11 #include <asm/asm.h>
  12 #include <asm/asmmacro.h>
  13 #include <asm/mipsregs.h>
  14 #include <asm/regdef.h>
  15 #include <asm/stackframe.h>
  16 #include <asm/asm-offsets.h>
  17 #include <asm/sysmips.h>
  18 #include <asm/thread_info.h>
  19 #include <asm/unistd.h>
  20 #include <asm/war.h>
  21
  22 #ifndef CONFIG_BINFMT_ELF32
  23 /* Neither O32 nor N32, so define handle_sys here */
  24 #define handle_sys64 handle_sys
  25 #endif
  26
  27         .align  5
  28 NESTED(handle_sys64, PT_SIZE, sp)
  29 #if !defined(CONFIG_MIPS32_O32) && !defined(CONFIG_MIPS32_N32)
  30         /*
  31          * When 32-bit compatibility is configured scall_o32.S
  32          * already did this.
  33          */
  34         .set    noat
  35         SAVE_SOME
  36         STI
  37         .set    at
  38 #endif
  39
  40         dsubu   t0, v0, __NR_64_Linux   # check syscall number
  41         sltiu   t0, t0, __NR_64_Linux_syscalls + 1
  42 #if !defined(CONFIG_MIPS32_O32) && !defined(CONFIG_MIPS32_N32)
  43         ld      t1, PT_EPC(sp)          # skip syscall on return
  44         daddiu  t1, 4                   # skip to next instruction
  45         sd      t1, PT_EPC(sp)
  46 #endif
  47         beqz    t0, illegal_syscall
  48
  49         dsll    t0, v0, 3               # offset into table
  50         ld      t2, (sys_call_table - (__NR_64_Linux * 8))(t0)
  51                                         # syscall routine
  52
  53         sd      a3, PT_R26(sp)          # save a3 for syscall restarting
  54
  55         li      t1, _TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT
  56         LONG_L  t0, TI_FLAGS($28)       # syscall tracing enabled?
  57         and     t0, t1, t0
  58         bnez    t0, syscall_trace_entry
  59
  60         jalr    t2                      # Do The Real Thing (TM)
  61
  62         li      t0, -EMAXERRNO - 1      # error?
  63         sltu    t0, t0, v0
  64         sd      t0, PT_R7(sp)           # set error flag
  65         beqz    t0, 1f
  66
  67         dnegu   v0                      # error
  68         sd      v0, PT_R0(sp)           # set flag for syscall
  69                                         # restarting
  70 1:      sd      v0, PT_R2(sp)           # result
  71
  72 n64_syscall_exit:
  73         local_irq_disable               # make sure need_resched and
  74                                         # signals dont change between
  75                                         # sampling and return
  76         LONG_L  a2, TI_FLAGS($28)       # current->work
  77         li      t0, _TIF_ALLWORK_MASK
  78         and     t0, a2, t0
  79         bnez    t0, n64_syscall_exit_work
  80
  81         j       restore_partial
  82
  83 n64_syscall_exit_work:
  84         j       syscall_exit_work_partial
  85
  86 /* ------------------------------------------------------------------------ */
  87
  88 syscall_trace_entry:
  89         SAVE_STATIC
  90         move    s0, t2
  91         move    a0, sp
  92         li      a1, 0
  93         jal     do_syscall_trace
  94
  95         move    t0, s0
  96         RESTORE_STATIC
  97         ld      a0, PT_R4(sp)           # Restore argument registers
  98         ld      a1, PT_R5(sp)
  99         ld      a2, PT_R6(sp)
 100         ld      a3, PT_R7(sp)
 101         ld      a4, PT_R8(sp)
 102         ld      a5, PT_R9(sp)
 103         jalr    t0
 104
 105         li      t0, -EMAXERRNO - 1      # error?
 106         sltu    t0, t0, v0
 107         sd      t0, PT_R7(sp)           # set error flag
 108         beqz    t0, 1f
 109
 110         dnegu   v0                      # error
 111         sd      v0, PT_R0(sp)           # set flag for syscall restarting
 112 1:      sd      v0, PT_R2(sp)           # result
 113
 114         j       syscall_exit
 115
 116 illegal_syscall:
 117         /* This also isn't a 64-bit syscall, throw an error.  */
 118         li      v0, -ENOSYS                     # error
 119         sd      v0, PT_R2(sp)
 120         li      t0, 1                           # set error flag
 121         sd      t0, PT_R7(sp)
 122         j       n64_syscall_exit
 123         END(handle_sys64)
 124
 125         LEAF(mips_atomic_set)
 126         andi    v0, a1, 3                       # must be word aligned
 127         bnez    v0, bad_alignment
 128
 129         LONG_L  v1, TI_ADDR_LIMIT($28)          # in legal address range?
 130         LONG_ADDIU      a0, a1, 4
 131         or      a0, a0, a1
 132         and     a0, a0, v1
 133         bltz    a0, bad_address
 134
 135 #ifdef CONFIG_CPU_HAS_LLSC
 136         /* Ok, this is the ll/sc case.  World is sane :-)  */
 137 1:      ll      v0, (a1)
 138         move    a0, a2
 139 2:      sc      a0, (a1)
 140 #if R10000_LLSC_WAR
 141         beqzl   a0, 1b
 142 #else
 143         beqz    a0, 1b
 144 #endif
 145
 146         .section __ex_table,"a"
 147         PTR     1b, bad_stack
 148         PTR     2b, bad_stack
 149         .previous
 150 #else
 151         sw      a1, 16(sp)
 152         sw      a2, 20(sp)
 153
 154         move    a0, sp
 155         move    a2, a1
 156         li      a1, 1
 157         jal     do_page_fault
 158
 159         lw      a1, 16(sp)
 160         lw      a2, 20(sp)
 161
 162         /*
 163          * At this point the page should be readable and writable unless
 164          * there was no more memory available.
 165          */
 166 1:      lw      v0, (a1)
 167 2:      sw      a2, (a1)
 168
 169         .section __ex_table,"a"
 170         PTR     1b, no_mem
 171         PTR     2b, no_mem
 172         .previous
 173 #endif
 174
 175         sd      zero, PT_R7(sp)         # success
 176         sd      v0, PT_R2(sp)           # result
 177
 178         j       n64_syscall_exit        # continue like a normal syscall
 179
 180 no_mem: li      v0, -ENOMEM
 181         jr      ra
 182
 183 bad_address:
 184         li      v0, -EFAULT
 185         jr      ra
 186
 187 bad_alignment:
 188         li      v0, -EINVAL
 189         jr      ra
 190         END(mips_atomic_set)
 191
 192         LEAF(sys_sysmips)
 193         beq     a0, MIPS_ATOMIC_SET, mips_atomic_set
 194         j       _sys_sysmips
 195         END(sys_sysmips)
 196
 197         .align  3
 198 sys_call_table:
 199         PTR     sys_read                        /* 5000 */
 200         PTR     sys_write
 201         PTR     sys_open
 202         PTR     sys_close
 203         PTR     sys_newstat
 204         PTR     sys_newfstat                    /* 5005 */
 205         PTR     sys_newlstat
 206         PTR     sys_poll
 207         PTR     sys_lseek
 208         PTR     old_mmap
 209         PTR     sys_mprotect                    /* 5010 */
 210         PTR     sys_munmap
 211         PTR     sys_brk
 212         PTR     sys_rt_sigaction
 213         PTR     sys_rt_sigprocmask
 214         PTR     sys_ioctl                       /* 5015 */
 215         PTR     sys_pread64
 216         PTR     sys_pwrite64
 217         PTR     sys_readv
 218         PTR     sys_writev
 219         PTR     sys_access                      /* 5020 */
 220         PTR     sys_pipe
 221         PTR     sys_select
 222         PTR     sys_sched_yield
 223         PTR     sys_mremap
 224         PTR     sys_msync                       /* 5025 */
 225         PTR     sys_mincore
 226         PTR     sys_madvise
 227         PTR     sys_shmget
 228         PTR     sys_shmat
 229         PTR     sys_shmctl                      /* 5030 */
 230         PTR     sys_dup
 231         PTR     sys_dup2
 232         PTR     sys_pause
 233         PTR     sys_nanosleep
 234         PTR     sys_getitimer                   /* 5035 */
 235         PTR     sys_setitimer
 236         PTR     sys_alarm
 237         PTR     sys_getpid
 238         PTR     sys_sendfile64
 239         PTR     sys_socket                      /* 5040 */
 240         PTR     sys_connect
 241         PTR     sys_accept
 242         PTR     sys_sendto
 243         PTR     sys_recvfrom
 244         PTR     sys_sendmsg                     /* 5045 */
 245         PTR     sys_recvmsg
 246         PTR     sys_shutdown
 247         PTR     sys_bind
 248         PTR     sys_listen
 249         PTR     sys_getsockname                 /* 5050 */
 250         PTR     sys_getpeername
 251         PTR     sys_socketpair
 252         PTR     sys_setsockopt
 253         PTR     sys_getsockopt
 254         PTR     sys_clone                       /* 5055 */
 255         PTR     sys_fork
 256         PTR     sys_execve
 257         PTR     sys_exit
 258         PTR     sys_wait4
 259         PTR     sys_kill                        /* 5060 */
 260         PTR     sys_newuname
 261         PTR     sys_semget
 262         PTR     sys_semop
 263         PTR     sys_semctl
 264         PTR     sys_shmdt                       /* 5065 */
 265         PTR     sys_msgget
 266         PTR     sys_msgsnd
 267         PTR     sys_msgrcv
 268         PTR     sys_msgctl
 269         PTR     sys_fcntl                       /* 5070 */
 270         PTR     sys_flock
 271         PTR     sys_fsync
 272         PTR     sys_fdatasync
 273         PTR     sys_truncate
 274         PTR     sys_ftruncate                   /* 5075 */
 275         PTR     sys_getdents
 276         PTR     sys_getcwd
 277         PTR     sys_chdir
 278         PTR     sys_fchdir
 279         PTR     sys_rename                      /* 5080 */
 280         PTR     sys_mkdir
 281         PTR     sys_rmdir
 282         PTR     sys_creat
 283         PTR     sys_link
 284         PTR     sys_unlink                      /* 5085 */
 285         PTR     sys_symlink
 286         PTR     sys_readlink
 287         PTR     sys_chmod
 288         PTR     sys_fchmod
 289         PTR     sys_chown                       /* 5090 */
 290         PTR     sys_fchown
 291         PTR     sys_lchown
 292         PTR     sys_umask
 293         PTR     sys_gettimeofday
 294         PTR     sys_getrlimit                   /* 5095 */
 295         PTR     sys_getrusage
 296         PTR     sys_sysinfo
 297         PTR     sys_times
 298         PTR     sys_ptrace
 299         PTR     sys_getuid                      /* 5100 */
 300         PTR     sys_syslog
 301         PTR     sys_getgid
 302         PTR     sys_setuid
 303         PTR     sys_setgid
 304         PTR     sys_geteuid                     /* 5105 */
 305         PTR     sys_getegid
 306         PTR     sys_setpgid
 307         PTR     sys_getppid
 308         PTR     sys_getpgrp
 309         PTR     sys_setsid                      /* 5110 */
 310         PTR     sys_setreuid
 311         PTR     sys_setregid
 312         PTR     sys_getgroups
 313         PTR     sys_setgroups
 314         PTR     sys_setresuid                   /* 5115 */
 315         PTR     sys_getresuid
 316         PTR     sys_setresgid
 317         PTR     sys_getresgid
 318         PTR     sys_getpgid
 319         PTR     sys_setfsuid                    /* 5120 */
 320         PTR     sys_setfsgid
 321         PTR     sys_getsid
 322         PTR     sys_capget
 323         PTR     sys_capset
 324         PTR     sys_rt_sigpending               /* 5125 */
 325         PTR     sys_rt_sigtimedwait
 326         PTR     sys_rt_sigqueueinfo
 327         PTR     sys_rt_sigsuspend
 328         PTR     sys_sigaltstack
 329         PTR     sys_utime                       /* 5130 */
 330         PTR     sys_mknod
 331         PTR     sys_personality
 332         PTR     sys_ustat
 333         PTR     sys_statfs
 334         PTR     sys_fstatfs                     /* 5135 */
 335         PTR     sys_sysfs
 336         PTR     sys_getpriority
 337         PTR     sys_setpriority
 338         PTR     sys_sched_setparam
 339         PTR     sys_sched_getparam              /* 5140 */
 340         PTR     sys_sched_setscheduler
 341         PTR     sys_sched_getscheduler
 342         PTR     sys_sched_get_priority_max
 343         PTR     sys_sched_get_priority_min
 344         PTR     sys_sched_rr_get_interval       /* 5145 */
 345         PTR     sys_mlock
 346         PTR     sys_munlock
 347         PTR     sys_mlockall
 348         PTR     sys_munlockall
 349         PTR     sys_vhangup                     /* 5150 */
 350         PTR     sys_pivot_root
 351         PTR     sys_sysctl
 352         PTR     sys_prctl
 353         PTR     sys_adjtimex
 354         PTR     sys_setrlimit                   /* 5155 */
 355         PTR     sys_chroot
 356         PTR     sys_sync
 357         PTR     sys_acct
 358         PTR     sys_settimeofday
 359         PTR     sys_mount                       /* 5160 */
 360         PTR     sys_umount
 361         PTR     sys_swapon
 362         PTR     sys_swapoff
 363         PTR     sys_reboot
 364         PTR     sys_sethostname                 /* 5165 */
 365         PTR     sys_setdomainname
 366         PTR     sys_ni_syscall                  /* was create_module */
 367         PTR     sys_init_module
 368         PTR     sys_delete_module
 369         PTR     sys_ni_syscall                  /* 5170, was get_kernel_syms */
 370         PTR     sys_ni_syscall                  /* was query_module */
 371         PTR     sys_quotactl
 372         PTR     sys_nfsservctl
 373         PTR     sys_ni_syscall                  /* res. for getpmsg */
 374         PTR     sys_ni_syscall                  /* 5175  for putpmsg */
 375         PTR     sys_ni_syscall                  /* res. for afs_syscall */
 376         PTR     sys_ni_syscall                  /* res. for security */
 377         PTR     sys_gettid
 378         PTR     sys_readahead
 379         PTR     sys_setxattr                    /* 5180 */
 380         PTR     sys_lsetxattr
 381         PTR     sys_fsetxattr
 382         PTR     sys_getxattr
 383         PTR     sys_lgetxattr
 384         PTR     sys_fgetxattr                   /* 5185 */
 385         PTR     sys_listxattr
 386         PTR     sys_llistxattr
 387         PTR     sys_flistxattr
 388         PTR     sys_removexattr
 389         PTR     sys_lremovexattr                /* 5190 */
 390         PTR     sys_fremovexattr
 391         PTR     sys_tkill
 392         PTR     sys_ni_syscall
 393         PTR     sys_futex
 394         PTR     sys_sched_setaffinity           /* 5195 */
 395         PTR     sys_sched_getaffinity
 396         PTR     sys_cacheflush
 397         PTR     sys_cachectl
 398         PTR     sys_sysmips
 399         PTR     sys_io_setup                    /* 5200 */
 400         PTR     sys_io_destroy
 401         PTR     sys_io_getevents
 402         PTR     sys_io_submit
 403         PTR     sys_io_cancel
 404         PTR     sys_exit_group                  /* 5205 */
 405         PTR     sys_lookup_dcookie
 406         PTR     sys_epoll_create
 407         PTR     sys_epoll_ctl
 408         PTR     sys_epoll_wait
 409         PTR     sys_remap_file_pages            /* 5210 */
 410         PTR     sys_rt_sigreturn
 411         PTR     sys_set_tid_address
 412         PTR     sys_restart_syscall
 413         PTR     sys_semtimedop
 414         PTR     sys_fadvise64_64                /* 5215 */
 415         PTR     sys_timer_create
 416         PTR     sys_timer_settime
 417         PTR     sys_timer_gettime
 418         PTR     sys_timer_getoverrun
 419         PTR     sys_timer_delete                /* 5220 */
 420         PTR     sys_clock_settime
 421         PTR     sys_clock_gettime
 422         PTR     sys_clock_getres
 423         PTR     sys_clock_nanosleep
 424         PTR     sys_tgkill                      /* 5225 */
 425         PTR     sys_utimes
 426         PTR     sys_mbind
 427         PTR     sys_ni_syscall                  /* sys_get_mempolicy */
 428         PTR     sys_ni_syscall                  /* sys_set_mempolicy */
 429         PTR     sys_mq_open                     /* 5230 */
 430         PTR     sys_mq_unlink
 431         PTR     sys_mq_timedsend
 432         PTR     sys_mq_timedreceive
 433         PTR     sys_mq_notify
 434         PTR     sys_mq_getsetattr               /* 5235 */
 435         PTR     sys_ni_syscall                  /* sys_vserver */
 436         PTR     sys_waitid
 437         PTR     sys_ni_syscall                  /* available, was setaltroot */
 438         PTR     sys_add_key
 439         PTR     sys_request_key                 /* 5240 */
 440         PTR     sys_keyctl
 441         PTR     sys_set_thread_area
 442         PTR     sys_inotify_init
 443         PTR     sys_inotify_add_watch
 444         PTR     sys_inotify_rm_watch            /* 5245 */
 445         PTR     sys_migrate_pages
 446         PTR     sys_openat
 447         PTR     sys_mkdirat
 448         PTR     sys_mknodat
 449         PTR     sys_fchownat                    /* 5250 */
 450         PTR     sys_futimesat
 451         PTR     sys_newfstatat
 452         PTR     sys_unlinkat
 453         PTR     sys_renameat
 454         PTR     sys_linkat                      /* 5255 */
 455         PTR     sys_symlinkat
 456         PTR     sys_readlinkat
 457         PTR     sys_fchmodat
 458         PTR     sys_faccessat
 459         PTR     sys_pselect6                    /* 5260 */
 460         PTR     sys_ppoll
 461         PTR     sys_unshare
 462         PTR     sys_splice
 463         PTR     sys_sync_file_range
 464         PTR     sys_tee                         /* 5265 */