git.oblomov.eu Git - linux-2.6/blob - arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 PHDRS {
  17         text PT_LOAD FLAGS(5);  /* R_E */
  18         data PT_LOAD FLAGS(7);  /* RWE */
  19         user PT_LOAD FLAGS(7);  /* RWE */
  20         data.init PT_LOAD FLAGS(7);     /* RWE */
  21         note PT_NOTE FLAGS(4);  /* R__ */
  22 }
  23 SECTIONS
  24 {
  25   . = __START_KERNEL;
  26   phys_startup_64 = startup_64 - LOAD_OFFSET;
  27   _text = .;                    /* Text and read-only data */
  28   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  29         /* First the code that has to be first for bootstrapping */
  30         *(.bootstrap.text)
  31         /* Then all the functions that are "hot" in profiles, to group them
  32            onto the same hugetlb entry */
  33         #include "functionlist"
  34         /* Then the rest */
  35         *(.text)
  36         SCHED_TEXT
  37         LOCK_TEXT
  38         KPROBES_TEXT
  39         *(.fixup)
  40         *(.gnu.warning)
  41         } :text = 0x9090
  42                                 /* out-of-line lock text */
  43   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  44
  45   _etext = .;                   /* End of text section */
  46
  47   . = ALIGN(16);                /* Exception table */
  48   __start___ex_table = .;
  49   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  50   __stop___ex_table = .;
  51
  52   RODATA
  53
  54 #ifdef CONFIG_STACK_UNWIND
  55   . = ALIGN(8);
  56   .eh_frame : AT(ADDR(.eh_frame) - LOAD_OFFSET) {
  57         __start_unwind = .;
  58         *(.eh_frame)
  59         __end_unwind = .;
  60   }
  61 #endif
  62
  63   . = ALIGN(PAGE_SIZE);        /* Align data segment to page size boundary */
  64                                 /* Data */
  65   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  66         *(.data)
  67         CONSTRUCTORS
  68         } :data
  69
  70   _edata = .;                   /* End of data section */
  71
  72   . = ALIGN(PAGE_SIZE);
  73   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  74   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  75         *(.data.cacheline_aligned)
  76   }
  77   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  78   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  79         *(.data.read_mostly)
  80   }
  81
  82 #define VSYSCALL_ADDR (-10*1024*1024)
  83 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  84 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  85
  86 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  87 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  88
  89 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  90 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  91
  92   . = VSYSCALL_ADDR;
  93   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  94   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  95
  96   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  97   .xtime_lock : AT(VLOAD(.xtime_lock)) { *(.xtime_lock) }
  98   xtime_lock = VVIRT(.xtime_lock);
  99
 100   .vxtime : AT(VLOAD(.vxtime)) { *(.vxtime) }
 101   vxtime = VVIRT(.vxtime);
 102
 103   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
 104   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 105
 106   .sys_tz : AT(VLOAD(.sys_tz)) { *(.sys_tz) }
 107   sys_tz = VVIRT(.sys_tz);
 108
 109   .sysctl_vsyscall : AT(VLOAD(.sysctl_vsyscall)) { *(.sysctl_vsyscall) }
 110   sysctl_vsyscall = VVIRT(.sysctl_vsyscall);
 111
 112   .xtime : AT(VLOAD(.xtime)) { *(.xtime) }
 113   xtime = VVIRT(.xtime);
 114
 115   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 116   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 117   jiffies = VVIRT(.jiffies);
 118
 119   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) { *(.vsyscall_1) }
 120   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) { *(.vsyscall_2) }
 121   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) { *(.vsyscall_3) }
 122
 123   . = VSYSCALL_VIRT_ADDR + 4096;
 124
 125 #undef VSYSCALL_ADDR
 126 #undef VSYSCALL_PHYS_ADDR
 127 #undef VSYSCALL_VIRT_ADDR
 128 #undef VLOAD_OFFSET
 129 #undef VLOAD
 130 #undef VVIRT_OFFSET
 131 #undef VVIRT
 132
 133   . = ALIGN(8192);              /* init_task */
 134   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 135         *(.data.init_task)
 136   }:data.init
 137
 138   . = ALIGN(4096);
 139   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 140         *(.data.page_aligned)
 141   }
 142
 143   /* might get freed after init */
 144   . = ALIGN(4096);
 145   __smp_alt_begin = .;
 146   __smp_alt_instructions = .;
 147   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 148         *(.smp_altinstructions)
 149   }
 150   __smp_alt_instructions_end = .;
 151   . = ALIGN(8);
 152   __smp_locks = .;
 153   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 154         *(.smp_locks)
 155   }
 156   __smp_locks_end = .;
 157   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 158         *(.smp_altinstr_replacement)
 159   }
 160   . = ALIGN(4096);
 161   __smp_alt_end = .;
 162
 163   . = ALIGN(4096);              /* Init code and data */
 164   __init_begin = .;
 165   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 166         _sinittext = .;
 167         *(.init.text)
 168         _einittext = .;
 169   }
 170   __initdata_begin = .;
 171   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 172   __initdata_end = .;
 173   . = ALIGN(16);
 174   __setup_start = .;
 175   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 176   __setup_end = .;
 177   __initcall_start = .;
 178   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 179         INITCALLS
 180   }
 181   __initcall_end = .;
 182   __con_initcall_start = .;
 183   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 184         *(.con_initcall.init)
 185   }
 186   __con_initcall_end = .;
 187   SECURITY_INIT
 188   . = ALIGN(8);
 189   __alt_instructions = .;
 190   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 191         *(.altinstructions)
 192   }
 193   __alt_instructions_end = .;
 194   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 195         *(.altinstr_replacement)
 196   }
 197   /* .exit.text is discard at runtime, not link time, to deal with references
 198      from .altinstructions and .eh_frame */
 199   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 200   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 201   . = ALIGN(4096);
 202   __initramfs_start = .;
 203   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 204   __initramfs_end = .;
 205     . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 206   __per_cpu_start = .;
 207   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 208   __per_cpu_end = .;
 209   . = ALIGN(4096);
 210   __init_end = .;
 211
 212   . = ALIGN(4096);
 213   __nosave_begin = .;
 214   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 215   . = ALIGN(4096);
 216   __nosave_end = .;
 217
 218   __bss_start = .;              /* BSS */
 219   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 220         *(.bss.page_aligned)
 221         *(.bss)
 222         }
 223   __bss_stop = .;
 224
 225   _end = . ;
 226
 227   /* Sections to be discarded */
 228   /DISCARD/ : {
 229         *(.exitcall.exit)
 230 #ifndef CONFIG_UNWIND_INFO
 231         *(.eh_frame)
 232 #endif
 233         }
 234
 235   STABS_DEBUG
 236
 237   DWARF_DEBUG
 238 }