git.oblomov.eu Git - linux-2.6/blob - arch/arm/lib/getuser.S

   1 /*
   2  *  linux/arch/arm/lib/getuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make them more
  13  * efficient, especially as they return an error value in addition to
  14  * the "real" return value.
  15  *
  16  * __get_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  * Outputs:     r0 is the error code
  20  *              r2, r3 contains the zero-extended value
  21  *              lr corrupted
  22  *
  23  * No other registers must be altered.  (see include/asm-arm/uaccess.h
  24  * for specific ASM register usage).
  25  *
  26  * Note that ADDR_LIMIT is either 0 or 0xc0000000.
  27  * Note also that it is intended that __get_user_bad is not global.
  28  */
  29 #include <asm/errno.h>
  30
  31         .global __get_user_1
  32 __get_user_1:
  33 1:      ldrbt   r2, [r0]
  34         mov     r0, #0
  35         mov     pc, lr
  36
  37         .global __get_user_2
  38 __get_user_2:
  39 2:      ldrbt   r2, [r0], #1
  40 3:      ldrbt   r3, [r0]
  41 #ifndef __ARMEB__
  42         orr     r2, r2, r3, lsl #8
  43 #else
  44         orr     r2, r3, r2, lsl #8
  45 #endif
  46         mov     r0, #0
  47         mov     pc, lr
  48
  49         .global __get_user_4
  50 __get_user_4:
  51 4:      ldrt    r2, [r0]
  52         mov     r0, #0
  53         mov     pc, lr
  54
  55 __get_user_bad:
  56         mov     r2, #0
  57         mov     r0, #-EFAULT
  58         mov     pc, lr
  59
  60 .section __ex_table, "a"
  61         .long   1b, __get_user_bad
  62         .long   2b, __get_user_bad
  63         .long   3b, __get_user_bad
  64         .long   4b, __get_user_bad
  65 .previous