git.oblomov.eu Git - linux-2.6/blob - scripts/checkstack.pl

   1 #!/usr/bin/perl
   2
   3 #       Check the stack usage of functions
   4 #
   5 #       Copyright Joern Engel <joern@wh.fh-wedel.de>
   6 #       Inspired by Linus Torvalds
   7 #       Original idea maybe from Keith Owens
   8 #       s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
   9 #       Mips port by Juan Quintela <quintela@mandrakesoft.com>
  10 #       IA64 port via Andreas Dilger
  11 #       Arm port by Holger Schurig
  12 #       sh64 port by Paul Mundt
  13 #       Random bits by Matt Mackall <mpm@selenic.com>
  14 #       M68k port by Geert Uytterhoeven and Andreas Schwab
  15 #       AVR32 port by Haavard Skinnemoen <hskinnemoen@atmel.com>
  16 #       PARISC port by Kyle McMartin <kyle@parisc-linux.org>
  17 #
  18 #       Usage:
  19 #       objdump -d vmlinux | scripts/checkstack.pl [arch]
  20 #
  21 #       TODO :  Port to all architectures (one regex per arch)
  22
  23 # check for arch
  24 #
  25 # $re is used for two matches:
  26 # $& (whole re) matches the complete objdump line with the stack growth
  27 # $1 (first bracket) matches the size of the stack growth
  28 #
  29 # use anything else and feel the pain ;)
  30 my (@stack, $re, $x, $xs);
  31 {
  32         my $arch = shift;
  33         if ($arch eq "") {
  34                 $arch = `uname -m`;
  35         }
  36
  37         $x      = "[0-9a-f]";   # hex character
  38         $xs     = "[0-9a-f ]";  # hex character or space
  39         if ($arch eq 'arm') {
  40                 #c0008ffc:      e24dd064        sub     sp, sp, #100    ; 0x64
  41                 $re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
  42         } elsif ($arch eq 'avr32') {
  43                 #8000008a:       20 1d           sub sp,4
  44                 #80000ca8:       fa cd 05 b0     sub sp,sp,1456
  45                 $re = qr/^.*sub.*sp.*,([0-9]{1,8})/o;
  46         } elsif ($arch =~ /^i[3456]86$/) {
  47                 #c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
  48                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%esp$/o;
  49         } elsif ($arch eq 'x86_64') {
  50                 #    2f60:      48 81 ec e8 05 00 00    sub    $0x5e8,%rsp
  51                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%rsp$/o;
  52         } elsif ($arch eq 'ia64') {
  53                 #e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
  54                 $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
  55         } elsif ($arch eq 'm68k') {
  56                 #    2b6c:       4e56 fb70       linkw %fp,#-1168
  57                 #  1df770:       defc ffe4       addaw #-28,%sp
  58                 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
  59         } elsif ($arch eq 'mips64') {
  60                 #8800402c:       67bdfff0        daddiu  sp,sp,-16
  61                 $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  62         } elsif ($arch eq 'mips') {
  63                 #88003254:       27bdffe0        addiu   sp,sp,-32
  64                 $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  65         } elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
  66                 $re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
  67         } elsif ($arch eq 'ppc') {
  68                 #c00029f4:       94 21 ff 30     stwu    r1,-208(r1)
  69                 $re = qr/.*stwu.*r1,-($x{1,8})\(r1\)/o;
  70         } elsif ($arch eq 'ppc64') {
  71                 #XXX
  72                 $re = qr/.*stdu.*r1,-($x{1,8})\(r1\)/o;
  73         } elsif ($arch eq 'powerpc') {
  74                 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
  75         } elsif ($arch =~ /^s390x?$/) {
  76                 #   11160:       a7 fb ff 60             aghi   %r15,-160
  77                 $re = qr/.*ag?hi.*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  78         } elsif ($arch =~ /^sh64$/) {
  79                 #XXX: we only check for the immediate case presently,
  80                 #     though we will want to check for the movi/sub
  81                 #     pair for larger users. -- PFM.
  82                 #a00048e0:       d4fc40f0        addi.l  r15,-240,r15
  83                 $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
  84         } elsif ($arch =~ /^blackfin$/) {
  85                 #   0:   00 e8 38 01     LINK 0x4e0;
  86                 $re = qr/.*[[:space:]]LINK[[:space:]]*(0x$x{1,8})/o;
  87         } else {
  88                 print("wrong or unknown architecture\n");
  89                 exit
  90         }
  91 }
  92
  93 sub bysize($) {
  94         my ($asize, $bsize);
  95         ($asize = $a) =~ s/.*:  *(.*)$/$1/;
  96         ($bsize = $b) =~ s/.*:  *(.*)$/$1/;
  97         $bsize <=> $asize
  98 }
  99
 100 #
 101 # main()
 102 #
 103 my $funcre = qr/^$x* <(.*)>:$/;
 104 my $func;
 105 my $file, $lastslash;
 106
 107 while (my $line = <STDIN>) {
 108         if ($line =~ m/$funcre/) {
 109                 $func = $1;
 110         }
 111         elsif ($line =~ m/(.*):\s*file format/) {
 112                 $file = $1;
 113                 $file =~ s/\.ko//;
 114                 $lastslash = rindex($file, "/");
 115                 if ($lastslash != -1) {
 116                         $file = substr($file, $lastslash + 1);
 117                 }
 118         }
 119         elsif ($line =~ m/$re/) {
 120                 my $size = $1;
 121                 $size = hex($size) if ($size =~ /^0x/);
 122
 123                 if ($size > 0xf0000000) {
 124                         $size = - $size;
 125                         $size += 0x80000000;
 126                         $size += 0x80000000;
 127                 }
 128                 next if ($size > 0x10000000);
 129
 130                 next if $line !~ m/^($xs*)/;
 131                 my $addr = $1;
 132                 $addr =~ s/ /0/g;
 133                 $addr = "0x$addr";
 134
 135                 my $intro = "$addr $func [$file]:";
 136                 my $padlen = 56 - length($intro);
 137                 while ($padlen > 0) {
 138                         $intro .= '     ';
 139                         $padlen -= 8;
 140                 }
 141                 next if ($size < 100);
 142                 push @stack, "$intro$size\n";
 143         }
 144 }
 145
 146 print sort bysize @stack;