git.oblomov.eu Git - linux-2.6/blob - arch/powerpc/kernel/vdso64/vdso64.lds.S

   1 /*
   2  * This is the infamous ld script for the 64 bits vdso
   3  * library
   4  */
   5 #include <asm/vdso.h>
   6
   7 OUTPUT_FORMAT("elf64-powerpc", "elf64-powerpc", "elf64-powerpc")
   8 OUTPUT_ARCH(powerpc:common64)
   9 ENTRY(_start)
  10
  11 SECTIONS
  12 {
  13         . = VDSO64_LBASE + SIZEOF_HEADERS;
  14
  15         .hash           : { *(.hash) }                  :text
  16         .gnu.hash       : { *(.gnu.hash) }
  17         .dynsym         : { *(.dynsym) }
  18         .dynstr         : { *(.dynstr) }
  19         .gnu.version    : { *(.gnu.version) }
  20         .gnu.version_d  : { *(.gnu.version_d) }
  21         .gnu.version_r  : { *(.gnu.version_r) }
  22
  23         .note           : { *(.note.*) }                :text   :note
  24
  25         . = ALIGN(16);
  26         .text           : {
  27                 *(.text .stub .text.* .gnu.linkonce.t.*)
  28                 *(.sfpr .glink)
  29         }                                               :text
  30         PROVIDE(__etext = .);
  31         PROVIDE(_etext = .);
  32         PROVIDE(etext = .);
  33
  34         . = ALIGN(8);
  35         __ftr_fixup     : { *(__ftr_fixup) }
  36
  37         . = ALIGN(8);
  38         __fw_ftr_fixup  : { *(__fw_ftr_fixup) }
  39
  40         /*
  41          * Other stuff is appended to the text segment:
  42          */
  43         .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  44         .rodata1        : { *(.rodata1) }
  45
  46         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  47         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  48         .gcc_except_table : { *(.gcc_except_table) }
  49
  50         .opd ALIGN(8)   : { KEEP (*(.opd)) }
  51         .got ALIGN(8)   : { *(.got .toc) }
  52         .rela.dyn ALIGN(8) : { *(.rela.dyn) }
  53
  54         .dynamic        : { *(.dynamic) }               :text   :dynamic
  55
  56         _end = .;
  57         PROVIDE(end = .);
  58
  59         /*
  60          * Stabs debugging sections are here too.
  61          */
  62         .stab          0 : { *(.stab) }
  63         .stabstr       0 : { *(.stabstr) }
  64         .stab.excl     0 : { *(.stab.excl) }
  65         .stab.exclstr  0 : { *(.stab.exclstr) }
  66         .stab.index    0 : { *(.stab.index) }
  67         .stab.indexstr 0 : { *(.stab.indexstr) }
  68         .comment       0 : { *(.comment) }
  69
  70         /*
  71          * DWARF debug sections.
  72          * Symbols in the DWARF debugging sections are relative to the beginning
  73          * of the section so we begin them at 0.
  74          */
  75         /* DWARF 1 */
  76         .debug          0 : { *(.debug) }
  77         .line           0 : { *(.line) }
  78         /* GNU DWARF 1 extensions */
  79         .debug_srcinfo  0 : { *(.debug_srcinfo) }
  80         .debug_sfnames  0 : { *(.debug_sfnames) }
  81         /* DWARF 1.1 and DWARF 2 */
  82         .debug_aranges  0 : { *(.debug_aranges) }
  83         .debug_pubnames 0 : { *(.debug_pubnames) }
  84         /* DWARF 2 */
  85         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  86         .debug_abbrev   0 : { *(.debug_abbrev) }
  87         .debug_line     0 : { *(.debug_line) }
  88         .debug_frame    0 : { *(.debug_frame) }
  89         .debug_str      0 : { *(.debug_str) }
  90         .debug_loc      0 : { *(.debug_loc) }
  91         .debug_macinfo  0 : { *(.debug_macinfo) }
  92         /* SGI/MIPS DWARF 2 extensions */
  93         .debug_weaknames 0 : { *(.debug_weaknames) }
  94         .debug_funcnames 0 : { *(.debug_funcnames) }
  95         .debug_typenames 0 : { *(.debug_typenames) }
  96         .debug_varnames  0 : { *(.debug_varnames) }
  97
  98         /DISCARD/       : {
  99                 *(.note.GNU-stack)
 100                 *(.branch_lt)
 101                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
 102                 *(.bss .sbss .dynbss .dynsbss)
 103         }
 104 }
 105
 106 /*
 107  * Very old versions of ld do not recognize this name token; use the constant.
 108  */
 109 #define PT_GNU_EH_FRAME 0x6474e550
 110
 111 /*
 112  * We must supply the ELF program headers explicitly to get just one
 113  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 114  */
 115 PHDRS
 116 {
 117         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
 118         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
 119         note            PT_NOTE FLAGS(4);               /* PF_R */
 120         eh_frame_hdr    PT_GNU_EH_FRAME;
 121 }
 122
 123 /*
 124  * This controls what symbols we export from the DSO.
 125  */
 126 VERSION
 127 {
 128         VDSO_VERSION_STRING {
 129         global:
 130                 /*
 131                  * Has to be there for the kernel to find
 132                  */
 133                 __kernel_datapage_offset;
 134
 135                 __kernel_get_syscall_map;
 136                 __kernel_gettimeofday;
 137                 __kernel_clock_gettime;
 138                 __kernel_clock_getres;
 139                 __kernel_get_tbfreq;
 140                 __kernel_sync_dicache;
 141                 __kernel_sync_dicache_p5;
 142                 __kernel_sigtramp_rt64;
 143
 144         local: *;
 145         };
 146 }