git.oblomov.eu Git - linux-2.6/blob - arch/ia64/kernel/entry.S

   1 /*
   2  * arch/ia64/kernel/entry.S
   3  *
   4  * Kernel entry points.
   5  *
   6  * Copyright (C) 1998-2003, 2005 Hewlett-Packard Co
   7  *      David Mosberger-Tang <davidm@hpl.hp.com>
   8  * Copyright (C) 1999, 2002-2003
   9  *      Asit Mallick <Asit.K.Mallick@intel.com>
  10  *      Don Dugger <Don.Dugger@intel.com>
  11  *      Suresh Siddha <suresh.b.siddha@intel.com>
  12  *      Fenghua Yu <fenghua.yu@intel.com>
  13  * Copyright (C) 1999 VA Linux Systems
  14  * Copyright (C) 1999 Walt Drummond <drummond@valinux.com>
  15  */
  16 /*
  17  * ia64_switch_to now places correct virtual mapping in in TR2 for
  18  * kernel stack. This allows us to handle interrupts without changing
  19  * to physical mode.
  20  *
  21  * Jonathan Nicklin     <nicklin@missioncriticallinux.com>
  22  * Patrick O'Rourke     <orourke@missioncriticallinux.com>
  23  * 11/07/2000
  24  */
  25 /*
  26  * Global (preserved) predicate usage on syscall entry/exit path:
  27  *
  28  *      pKStk:          See entry.h.
  29  *      pUStk:          See entry.h.
  30  *      pSys:           See entry.h.
  31  *      pNonSys:        !pSys
  32  */
  33
  34
  35 #include <asm/asmmacro.h>
  36 #include <asm/cache.h>
  37 #include <asm/errno.h>
  38 #include <asm/kregs.h>
  39 #include <asm/asm-offsets.h>
  40 #include <asm/pgtable.h>
  41 #include <asm/percpu.h>
  42 #include <asm/processor.h>
  43 #include <asm/thread_info.h>
  44 #include <asm/unistd.h>
  45
  46 #include "minstate.h"
  47
  48         /*
  49          * execve() is special because in case of success, we need to
  50          * setup a null register window frame.
  51          */
  52 ENTRY(ia64_execve)
  53         /*
  54          * Allocate 8 input registers since ptrace() may clobber them
  55          */
  56         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
  57         alloc loc1=ar.pfs,8,2,4,0
  58         mov loc0=rp
  59         .body
  60         mov out0=in0                    // filename
  61         ;;                              // stop bit between alloc and call
  62         mov out1=in1                    // argv
  63         mov out2=in2                    // envp
  64         add out3=16,sp                  // regs
  65         br.call.sptk.many rp=sys_execve
  66 .ret0:
  67 #ifdef CONFIG_IA32_SUPPORT
  68         /*
  69          * Check if we're returning to ia32 mode. If so, we need to restore ia32 registers
  70          * from pt_regs.
  71          */
  72         adds r16=PT(CR_IPSR)+16,sp
  73         ;;
  74         ld8 r16=[r16]
  75 #endif
  76         cmp4.ge p6,p7=r8,r0
  77         mov ar.pfs=loc1                 // restore ar.pfs
  78         sxt4 r8=r8                      // return 64-bit result
  79         ;;
  80         stf.spill [sp]=f0
  81 (p6)    cmp.ne pKStk,pUStk=r0,r0        // a successful execve() lands us in user-mode...
  82         mov rp=loc0
  83 (p6)    mov ar.pfs=r0                   // clear ar.pfs on success
  84 (p7)    br.ret.sptk.many rp
  85
  86         /*
  87          * In theory, we'd have to zap this state only to prevent leaking of
  88          * security sensitive state (e.g., if current->mm->dumpable is zero).  However,
  89          * this executes in less than 20 cycles even on Itanium, so it's not worth
  90          * optimizing for...).
  91          */
  92         mov ar.unat=0;          mov ar.lc=0
  93         mov r4=0;               mov f2=f0;              mov b1=r0
  94         mov r5=0;               mov f3=f0;              mov b2=r0
  95         mov r6=0;               mov f4=f0;              mov b3=r0
  96         mov r7=0;               mov f5=f0;              mov b4=r0
  97         ldf.fill f12=[sp];      mov f13=f0;             mov b5=r0
  98         ldf.fill f14=[sp];      ldf.fill f15=[sp];      mov f16=f0
  99         ldf.fill f17=[sp];      ldf.fill f18=[sp];      mov f19=f0
 100         ldf.fill f20=[sp];      ldf.fill f21=[sp];      mov f22=f0
 101         ldf.fill f23=[sp];      ldf.fill f24=[sp];      mov f25=f0
 102         ldf.fill f26=[sp];      ldf.fill f27=[sp];      mov f28=f0
 103         ldf.fill f29=[sp];      ldf.fill f30=[sp];      mov f31=f0
 104 #ifdef CONFIG_IA32_SUPPORT
 105         tbit.nz p6,p0=r16, IA64_PSR_IS_BIT
 106         movl loc0=ia64_ret_from_ia32_execve
 107         ;;
 108 (p6)    mov rp=loc0
 109 #endif
 110         br.ret.sptk.many rp
 111 END(ia64_execve)
 112
 113 /*
 114  * sys_clone2(u64 flags, u64 ustack_base, u64 ustack_size, u64 parent_tidptr, u64 child_tidptr,
 115  *            u64 tls)
 116  */
 117 GLOBAL_ENTRY(sys_clone2)
 118         /*
 119          * Allocate 8 input registers since ptrace() may clobber them
 120          */
 121         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
 122         alloc r16=ar.pfs,8,2,6,0
 123         DO_SAVE_SWITCH_STACK
 124         adds r2=PT(R16)+IA64_SWITCH_STACK_SIZE+16,sp
 125         mov loc0=rp
 126         mov loc1=r16                            // save ar.pfs across do_fork
 127         .body
 128         mov out1=in1
 129         mov out3=in2
 130         tbit.nz p6,p0=in0,CLONE_SETTLS_BIT
 131         mov out4=in3    // parent_tidptr: valid only w/CLONE_PARENT_SETTID
 132         ;;
 133 (p6)    st8 [r2]=in5                            // store TLS in r16 for copy_thread()
 134         mov out5=in4    // child_tidptr:  valid only w/CLONE_CHILD_SETTID or CLONE_CHILD_CLEARTID
 135         adds out2=IA64_SWITCH_STACK_SIZE+16,sp  // out2 = &regs
 136         mov out0=in0                            // out0 = clone_flags
 137         br.call.sptk.many rp=do_fork
 138 .ret1:  .restore sp
 139         adds sp=IA64_SWITCH_STACK_SIZE,sp       // pop the switch stack
 140         mov ar.pfs=loc1
 141         mov rp=loc0
 142         br.ret.sptk.many rp
 143 END(sys_clone2)
 144
 145 /*
 146  * sys_clone(u64 flags, u64 ustack_base, u64 parent_tidptr, u64 child_tidptr, u64 tls)
 147  *      Deprecated.  Use sys_clone2() instead.
 148  */
 149 GLOBAL_ENTRY(sys_clone)
 150         /*
 151          * Allocate 8 input registers since ptrace() may clobber them
 152          */
 153         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
 154         alloc r16=ar.pfs,8,2,6,0
 155         DO_SAVE_SWITCH_STACK
 156         adds r2=PT(R16)+IA64_SWITCH_STACK_SIZE+16,sp
 157         mov loc0=rp
 158         mov loc1=r16                            // save ar.pfs across do_fork
 159         .body
 160         mov out1=in1
 161         mov out3=16                             // stacksize (compensates for 16-byte scratch area)
 162         tbit.nz p6,p0=in0,CLONE_SETTLS_BIT
 163         mov out4=in2    // parent_tidptr: valid only w/CLONE_PARENT_SETTID
 164         ;;
 165 (p6)    st8 [r2]=in4                            // store TLS in r13 (tp)
 166         mov out5=in3    // child_tidptr:  valid only w/CLONE_CHILD_SETTID or CLONE_CHILD_CLEARTID
 167         adds out2=IA64_SWITCH_STACK_SIZE+16,sp  // out2 = &regs
 168         mov out0=in0                            // out0 = clone_flags
 169         br.call.sptk.many rp=do_fork
 170 .ret2:  .restore sp
 171         adds sp=IA64_SWITCH_STACK_SIZE,sp       // pop the switch stack
 172         mov ar.pfs=loc1
 173         mov rp=loc0
 174         br.ret.sptk.many rp
 175 END(sys_clone)
 176
 177 /*
 178  * prev_task <- ia64_switch_to(struct task_struct *next)
 179  *      With Ingo's new scheduler, interrupts are disabled when this routine gets
 180  *      called.  The code starting at .map relies on this.  The rest of the code
 181  *      doesn't care about the interrupt masking status.
 182  */
 183 GLOBAL_ENTRY(ia64_switch_to)
 184         .prologue
 185         alloc r16=ar.pfs,1,0,0,0
 186         DO_SAVE_SWITCH_STACK
 187         .body
 188
 189         adds r22=IA64_TASK_THREAD_KSP_OFFSET,r13
 190         movl r25=init_task
 191         mov r27=IA64_KR(CURRENT_STACK)
 192         adds r21=IA64_TASK_THREAD_KSP_OFFSET,in0
 193         dep r20=0,in0,61,3              // physical address of "next"
 194         ;;
 195         st8 [r22]=sp                    // save kernel stack pointer of old task
 196         shr.u r26=r20,IA64_GRANULE_SHIFT
 197         cmp.eq p7,p6=r25,in0
 198         ;;
 199         /*
 200          * If we've already mapped this task's page, we can skip doing it again.
 201          */
 202 (p6)    cmp.eq p7,p6=r26,r27
 203 (p6)    br.cond.dpnt .map
 204         ;;
 205 .done:
 206         ld8 sp=[r21]                    // load kernel stack pointer of new task
 207         mov IA64_KR(CURRENT)=in0        // update "current" application register
 208         mov r8=r13                      // return pointer to previously running task
 209         mov r13=in0                     // set "current" pointer
 210         ;;
 211         DO_LOAD_SWITCH_STACK
 212
 213 #ifdef CONFIG_SMP
 214         sync.i                          // ensure "fc"s done by this CPU are visible on other CPUs
 215 #endif
 216         br.ret.sptk.many rp             // boogie on out in new context
 217
 218 .map:
 219         rsm psr.ic                      // interrupts (psr.i) are already disabled here
 220         movl r25=PAGE_KERNEL
 221         ;;
 222         srlz.d
 223         or r23=r25,r20                  // construct PA | page properties
 224         mov r25=IA64_GRANULE_SHIFT<<2
 225         ;;
 226         mov cr.itir=r25
 227         mov cr.ifa=in0                  // VA of next task...
 228         ;;
 229         mov r25=IA64_TR_CURRENT_STACK
 230         mov IA64_KR(CURRENT_STACK)=r26  // remember last page we mapped...
 231         ;;
 232         itr.d dtr[r25]=r23              // wire in new mapping...
 233         ssm psr.ic                      // reenable the psr.ic bit
 234         ;;
 235         srlz.d
 236         br.cond.sptk .done
 237 END(ia64_switch_to)
 238
 239 /*
 240  * Note that interrupts are enabled during save_switch_stack and load_switch_stack.  This
 241  * means that we may get an interrupt with "sp" pointing to the new kernel stack while
 242  * ar.bspstore is still pointing to the old kernel backing store area.  Since ar.rsc,
 243  * ar.rnat, ar.bsp, and ar.bspstore are all preserved by interrupts, this is not a
 244  * problem.  Also, we don't need to specify unwind information for preserved registers
 245  * that are not modified in save_switch_stack as the right unwind information is already
 246  * specified at the call-site of save_switch_stack.
 247  */
 248
 249 /*
 250  * save_switch_stack:
 251  *      - r16 holds ar.pfs
 252  *      - b7 holds address to return to
 253  *      - rp (b0) holds return address to save
 254  */
 255 GLOBAL_ENTRY(save_switch_stack)
 256         .prologue
 257         .altrp b7
 258         flushrs                 // flush dirty regs to backing store (must be first in insn group)
 259         .save @priunat,r17
 260         mov r17=ar.unat         // preserve caller's
 261         .body
 262 #ifdef CONFIG_ITANIUM
 263         adds r2=16+128,sp
 264         adds r3=16+64,sp
 265         adds r14=SW(R4)+16,sp
 266         ;;
 267         st8.spill [r14]=r4,16           // spill r4
 268         lfetch.fault.excl.nt1 [r3],128
 269         ;;
 270         lfetch.fault.excl.nt1 [r2],128
 271         lfetch.fault.excl.nt1 [r3],128
 272         ;;
 273         lfetch.fault.excl [r2]
 274         lfetch.fault.excl [r3]
 275         adds r15=SW(R5)+16,sp
 276 #else
 277         add r2=16+3*128,sp
 278         add r3=16,sp
 279         add r14=SW(R4)+16,sp
 280         ;;
 281         st8.spill [r14]=r4,SW(R6)-SW(R4)        // spill r4 and prefetch offset 0x1c0
 282         lfetch.fault.excl.nt1 [r3],128  //              prefetch offset 0x010
 283         ;;
 284         lfetch.fault.excl.nt1 [r3],128  //              prefetch offset 0x090
 285         lfetch.fault.excl.nt1 [r2],128  //              prefetch offset 0x190
 286         ;;
 287         lfetch.fault.excl.nt1 [r3]      //              prefetch offset 0x110
 288         lfetch.fault.excl.nt1 [r2]      //              prefetch offset 0x210
 289         adds r15=SW(R5)+16,sp
 290 #endif
 291         ;;
 292         st8.spill [r15]=r5,SW(R7)-SW(R5)        // spill r5
 293         mov.m ar.rsc=0                  // put RSE in mode: enforced lazy, little endian, pl 0
 294         add r2=SW(F2)+16,sp             // r2 = &sw->f2
 295         ;;
 296         st8.spill [r14]=r6,SW(B0)-SW(R6)        // spill r6
 297         mov.m r18=ar.fpsr               // preserve fpsr
 298         add r3=SW(F3)+16,sp             // r3 = &sw->f3
 299         ;;
 300         stf.spill [r2]=f2,32
 301         mov.m r19=ar.rnat
 302         mov r21=b0
 303
 304         stf.spill [r3]=f3,32
 305         st8.spill [r15]=r7,SW(B2)-SW(R7)        // spill r7
 306         mov r22=b1
 307         ;;
 308         // since we're done with the spills, read and save ar.unat:
 309         mov.m r29=ar.unat
 310         mov.m r20=ar.bspstore
 311         mov r23=b2
 312         stf.spill [r2]=f4,32
 313         stf.spill [r3]=f5,32
 314         mov r24=b3
 315         ;;
 316         st8 [r14]=r21,SW(B1)-SW(B0)             // save b0
 317         st8 [r15]=r23,SW(B3)-SW(B2)             // save b2
 318         mov r25=b4
 319         mov r26=b5
 320         ;;
 321         st8 [r14]=r22,SW(B4)-SW(B1)             // save b1
 322         st8 [r15]=r24,SW(AR_PFS)-SW(B3)         // save b3
 323         mov r21=ar.lc           // I-unit
 324         stf.spill [r2]=f12,32
 325         stf.spill [r3]=f13,32
 326         ;;
 327         st8 [r14]=r25,SW(B5)-SW(B4)             // save b4
 328         st8 [r15]=r16,SW(AR_LC)-SW(AR_PFS)      // save ar.pfs
 329         stf.spill [r2]=f14,32
 330         stf.spill [r3]=f15,32
 331         ;;
 332         st8 [r14]=r26                           // save b5
 333         st8 [r15]=r21                           // save ar.lc
 334         stf.spill [r2]=f16,32
 335         stf.spill [r3]=f17,32
 336         ;;
 337         stf.spill [r2]=f18,32
 338         stf.spill [r3]=f19,32
 339         ;;
 340         stf.spill [r2]=f20,32
 341         stf.spill [r3]=f21,32
 342         ;;
 343         stf.spill [r2]=f22,32
 344         stf.spill [r3]=f23,32
 345         ;;
 346         stf.spill [r2]=f24,32
 347         stf.spill [r3]=f25,32
 348         ;;
 349         stf.spill [r2]=f26,32
 350         stf.spill [r3]=f27,32
 351         ;;
 352         stf.spill [r2]=f28,32
 353         stf.spill [r3]=f29,32
 354         ;;
 355         stf.spill [r2]=f30,SW(AR_UNAT)-SW(F30)
 356         stf.spill [r3]=f31,SW(PR)-SW(F31)
 357         add r14=SW(CALLER_UNAT)+16,sp
 358         ;;
 359         st8 [r2]=r29,SW(AR_RNAT)-SW(AR_UNAT)    // save ar.unat
 360         st8 [r14]=r17,SW(AR_FPSR)-SW(CALLER_UNAT) // save caller_unat
 361         mov r21=pr
 362         ;;
 363         st8 [r2]=r19,SW(AR_BSPSTORE)-SW(AR_RNAT) // save ar.rnat
 364         st8 [r3]=r21                            // save predicate registers
 365         ;;
 366         st8 [r2]=r20                            // save ar.bspstore
 367         st8 [r14]=r18                           // save fpsr
 368         mov ar.rsc=3            // put RSE back into eager mode, pl 0
 369         br.cond.sptk.many b7
 370 END(save_switch_stack)
 371
 372 /*
 373  * load_switch_stack:
 374  *      - "invala" MUST be done at call site (normally in DO_LOAD_SWITCH_STACK)
 375  *      - b7 holds address to return to
 376  *      - must not touch r8-r11
 377  */
 378 ENTRY(load_switch_stack)
 379         .prologue
 380         .altrp b7
 381
 382         .body
 383         lfetch.fault.nt1 [sp]
 384         adds r2=SW(AR_BSPSTORE)+16,sp
 385         adds r3=SW(AR_UNAT)+16,sp
 386         mov ar.rsc=0                                            // put RSE into enforced lazy mode
 387         adds r14=SW(CALLER_UNAT)+16,sp
 388         adds r15=SW(AR_FPSR)+16,sp
 389         ;;
 390         ld8 r27=[r2],(SW(B0)-SW(AR_BSPSTORE))   // bspstore
 391         ld8 r29=[r3],(SW(B1)-SW(AR_UNAT))       // unat
 392         ;;
 393         ld8 r21=[r2],16         // restore b0
 394         ld8 r22=[r3],16         // restore b1
 395         ;;
 396         ld8 r23=[r2],16         // restore b2
 397         ld8 r24=[r3],16         // restore b3
 398         ;;
 399         ld8 r25=[r2],16         // restore b4
 400         ld8 r26=[r3],16         // restore b5
 401         ;;
 402         ld8 r16=[r2],(SW(PR)-SW(AR_PFS))        // ar.pfs
 403         ld8 r17=[r3],(SW(AR_RNAT)-SW(AR_LC))    // ar.lc
 404         ;;
 405         ld8 r28=[r2]            // restore pr
 406         ld8 r30=[r3]            // restore rnat
 407         ;;
 408         ld8 r18=[r14],16        // restore caller's unat
 409         ld8 r19=[r15],24        // restore fpsr
 410         ;;
 411         ldf.fill f2=[r14],32
 412         ldf.fill f3=[r15],32
 413         ;;
 414         ldf.fill f4=[r14],32
 415         ldf.fill f5=[r15],32
 416         ;;
 417         ldf.fill f12=[r14],32
 418         ldf.fill f13=[r15],32
 419         ;;
 420         ldf.fill f14=[r14],32
 421         ldf.fill f15=[r15],32
 422         ;;
 423         ldf.fill f16=[r14],32
 424         ldf.fill f17=[r15],32
 425         ;;
 426         ldf.fill f18=[r14],32
 427         ldf.fill f19=[r15],32
 428         mov b0=r21
 429         ;;
 430         ldf.fill f20=[r14],32
 431         ldf.fill f21=[r15],32
 432         mov b1=r22
 433         ;;
 434         ldf.fill f22=[r14],32
 435         ldf.fill f23=[r15],32
 436         mov b2=r23
 437         ;;
 438         mov ar.bspstore=r27
 439         mov ar.unat=r29         // establish unat holding the NaT bits for r4-r7
 440         mov b3=r24
 441         ;;
 442         ldf.fill f24=[r14],32
 443         ldf.fill f25=[r15],32
 444         mov b4=r25
 445         ;;
 446         ldf.fill f26=[r14],32
 447         ldf.fill f27=[r15],32
 448         mov b5=r26
 449         ;;
 450         ldf.fill f28=[r14],32
 451         ldf.fill f29=[r15],32
 452         mov ar.pfs=r16
 453         ;;
 454         ldf.fill f30=[r14],32
 455         ldf.fill f31=[r15],24
 456         mov ar.lc=r17
 457         ;;
 458         ld8.fill r4=[r14],16
 459         ld8.fill r5=[r15],16
 460         mov pr=r28,-1
 461         ;;
 462         ld8.fill r6=[r14],16
 463         ld8.fill r7=[r15],16
 464
 465         mov ar.unat=r18                         // restore caller's unat
 466         mov ar.rnat=r30                         // must restore after bspstore but before rsc!
 467         mov ar.fpsr=r19                         // restore fpsr
 468         mov ar.rsc=3                            // put RSE back into eager mode, pl 0
 469         br.cond.sptk.many b7
 470 END(load_switch_stack)
 471
 472 GLOBAL_ENTRY(prefetch_stack)
 473         add r14 = -IA64_SWITCH_STACK_SIZE, sp
 474         add r15 = IA64_TASK_THREAD_KSP_OFFSET, in0
 475         ;;
 476         ld8 r16 = [r15]                         // load next's stack pointer
 477         lfetch.fault.excl [r14], 128
 478         ;;
 479         lfetch.fault.excl [r14], 128
 480         lfetch.fault [r16], 128
 481         ;;
 482         lfetch.fault.excl [r14], 128
 483         lfetch.fault [r16], 128
 484         ;;
 485         lfetch.fault.excl [r14], 128
 486         lfetch.fault [r16], 128
 487         ;;
 488         lfetch.fault.excl [r14], 128
 489         lfetch.fault [r16], 128
 490         ;;
 491         lfetch.fault [r16], 128
 492         br.ret.sptk.many rp
 493 END(prefetch_stack)
 494
 495 GLOBAL_ENTRY(kernel_execve)
 496         mov r15=__NR_execve                     // put syscall number in place
 497         break __BREAK_SYSCALL
 498         br.ret.sptk.many rp
 499 END(kernel_execve)
 500
 501 GLOBAL_ENTRY(clone)
 502         mov r15=__NR_clone                      // put syscall number in place
 503         break __BREAK_SYSCALL
 504         br.ret.sptk.many rp
 505 END(clone)
 506
 507         /*
 508          * Invoke a system call, but do some tracing before and after the call.
 509          * We MUST preserve the current register frame throughout this routine
 510          * because some system calls (such as ia64_execve) directly
 511          * manipulate ar.pfs.
 512          */
 513 GLOBAL_ENTRY(ia64_trace_syscall)
 514         PT_REGS_UNWIND_INFO(0)
 515         /*
 516          * We need to preserve the scratch registers f6-f11 in case the system
 517          * call is sigreturn.
 518          */
 519         adds r16=PT(F6)+16,sp
 520         adds r17=PT(F7)+16,sp
 521         ;;
 522         stf.spill [r16]=f6,32
 523         stf.spill [r17]=f7,32
 524         ;;
 525         stf.spill [r16]=f8,32
 526         stf.spill [r17]=f9,32
 527         ;;
 528         stf.spill [r16]=f10
 529         stf.spill [r17]=f11
 530         br.call.sptk.many rp=syscall_trace_enter // give parent a chance to catch syscall args
 531         adds r16=PT(F6)+16,sp
 532         adds r17=PT(F7)+16,sp
 533         ;;
 534         ldf.fill f6=[r16],32
 535         ldf.fill f7=[r17],32
 536         ;;
 537         ldf.fill f8=[r16],32
 538         ldf.fill f9=[r17],32
 539         ;;
 540         ldf.fill f10=[r16]
 541         ldf.fill f11=[r17]
 542         // the syscall number may have changed, so re-load it and re-calculate the
 543         // syscall entry-point:
 544         adds r15=PT(R15)+16,sp                  // r15 = &pt_regs.r15 (syscall #)
 545         ;;
 546         ld8 r15=[r15]
 547         mov r3=NR_syscalls - 1
 548         ;;
 549         adds r15=-1024,r15
 550         movl r16=sys_call_table
 551         ;;
 552         shladd r20=r15,3,r16                    // r20 = sys_call_table + 8*(syscall-1024)
 553         cmp.leu p6,p7=r15,r3
 554         ;;
 555 (p6)    ld8 r20=[r20]                           // load address of syscall entry point
 556 (p7)    movl r20=sys_ni_syscall
 557         ;;
 558         mov b6=r20
 559         br.call.sptk.many rp=b6                 // do the syscall
 560 .strace_check_retval:
 561         cmp.lt p6,p0=r8,r0                      // syscall failed?
 562         adds r2=PT(R8)+16,sp                    // r2 = &pt_regs.r8
 563         adds r3=PT(R10)+16,sp                   // r3 = &pt_regs.r10
 564         mov r10=0
 565 (p6)    br.cond.sptk strace_error               // syscall failed ->
 566         ;;                                      // avoid RAW on r10
 567 .strace_save_retval:
 568 .mem.offset 0,0; st8.spill [r2]=r8              // store return value in slot for r8
 569 .mem.offset 8,0; st8.spill [r3]=r10             // clear error indication in slot for r10
 570         br.call.sptk.many rp=syscall_trace_leave // give parent a chance to catch return value
 571 .ret3:
 572 (pUStk) cmp.eq.unc p6,p0=r0,r0                  // p6 <- pUStk
 573 (pUStk) rsm psr.i                               // disable interrupts
 574         br.cond.sptk .work_pending_syscall_end
 575
 576 strace_error:
 577         ld8 r3=[r2]                             // load pt_regs.r8
 578         sub r9=0,r8                             // negate return value to get errno value
 579         ;;
 580         cmp.ne p6,p0=r3,r0                      // is pt_regs.r8!=0?
 581         adds r3=16,r2                           // r3=&pt_regs.r10
 582         ;;
 583 (p6)    mov r10=-1
 584 (p6)    mov r8=r9
 585         br.cond.sptk .strace_save_retval
 586 END(ia64_trace_syscall)
 587
 588         /*
 589          * When traced and returning from sigreturn, we invoke syscall_trace but then
 590          * go straight to ia64_leave_kernel rather than ia64_leave_syscall.
 591          */
 592 GLOBAL_ENTRY(ia64_strace_leave_kernel)
 593         PT_REGS_UNWIND_INFO(0)
 594 {       /*
 595          * Some versions of gas generate bad unwind info if the first instruction of a
 596          * procedure doesn't go into the first slot of a bundle.  This is a workaround.
 597          */
 598         nop.m 0
 599         nop.i 0
 600         br.call.sptk.many rp=syscall_trace_leave // give parent a chance to catch return value
 601 }
 602 .ret4:  br.cond.sptk ia64_leave_kernel
 603 END(ia64_strace_leave_kernel)
 604
 605 GLOBAL_ENTRY(ia64_ret_from_clone)
 606         PT_REGS_UNWIND_INFO(0)
 607 {       /*
 608          * Some versions of gas generate bad unwind info if the first instruction of a
 609          * procedure doesn't go into the first slot of a bundle.  This is a workaround.
 610          */
 611         nop.m 0
 612         nop.i 0
 613         /*
 614          * We need to call schedule_tail() to complete the scheduling process.
 615          * Called by ia64_switch_to() after do_fork()->copy_thread().  r8 contains the
 616          * address of the previously executing task.
 617          */
 618         br.call.sptk.many rp=ia64_invoke_schedule_tail
 619 }
 620 .ret8:
 621         adds r2=TI_FLAGS+IA64_TASK_SIZE,r13
 622         ;;
 623         ld4 r2=[r2]
 624         ;;
 625         mov r8=0
 626         and r2=_TIF_SYSCALL_TRACEAUDIT,r2
 627         ;;
 628         cmp.ne p6,p0=r2,r0
 629 (p6)    br.cond.spnt .strace_check_retval
 630         ;;                                      // added stop bits to prevent r8 dependency
 631 END(ia64_ret_from_clone)
 632         // fall through
 633 GLOBAL_ENTRY(ia64_ret_from_syscall)
 634         PT_REGS_UNWIND_INFO(0)
 635         cmp.ge p6,p7=r8,r0                      // syscall executed successfully?
 636         adds r2=PT(R8)+16,sp                    // r2 = &pt_regs.r8
 637         mov r10=r0                              // clear error indication in r10
 638 (p7)    br.cond.spnt handle_syscall_error       // handle potential syscall failure
 639 END(ia64_ret_from_syscall)
 640         // fall through
 641 /*
 642  * ia64_leave_syscall(): Same as ia64_leave_kernel, except that it doesn't
 643  *      need to switch to bank 0 and doesn't restore the scratch registers.
 644  *      To avoid leaking kernel bits, the scratch registers are set to
 645  *      the following known-to-be-safe values:
 646  *
 647  *                r1: restored (global pointer)
 648  *                r2: cleared
 649  *                r3: 1 (when returning to user-level)
 650  *            r8-r11: restored (syscall return value(s))
 651  *               r12: restored (user-level stack pointer)
 652  *               r13: restored (user-level thread pointer)
 653  *               r14: set to __kernel_syscall_via_epc
 654  *               r15: restored (syscall #)
 655  *           r16-r17: cleared
 656  *               r18: user-level b6
 657  *               r19: cleared
 658  *               r20: user-level ar.fpsr
 659  *               r21: user-level b0
 660  *               r22: cleared
 661  *               r23: user-level ar.bspstore
 662  *               r24: user-level ar.rnat
 663  *               r25: user-level ar.unat
 664  *               r26: user-level ar.pfs
 665  *               r27: user-level ar.rsc
 666  *               r28: user-level ip
 667  *               r29: user-level psr
 668  *               r30: user-level cfm
 669  *               r31: user-level pr
 670  *            f6-f11: cleared
 671  *                pr: restored (user-level pr)
 672  *                b0: restored (user-level rp)
 673  *                b6: restored
 674  *                b7: set to __kernel_syscall_via_epc
 675  *           ar.unat: restored (user-level ar.unat)
 676  *            ar.pfs: restored (user-level ar.pfs)
 677  *            ar.rsc: restored (user-level ar.rsc)
 678  *           ar.rnat: restored (user-level ar.rnat)
 679  *       ar.bspstore: restored (user-level ar.bspstore)
 680  *           ar.fpsr: restored (user-level ar.fpsr)
 681  *            ar.ccv: cleared
 682  *            ar.csd: cleared
 683  *            ar.ssd: cleared
 684  */
 685 ENTRY(ia64_leave_syscall)
 686         PT_REGS_UNWIND_INFO(0)
 687         /*
 688          * work.need_resched etc. mustn't get changed by this CPU before it returns to
 689          * user- or fsys-mode, hence we disable interrupts early on.
 690          *
 691          * p6 controls whether current_thread_info()->flags needs to be check for
 692          * extra work.  We always check for extra work when returning to user-level.
 693          * With CONFIG_PREEMPT, we also check for extra work when the preempt_count
 694          * is 0.  After extra work processing has been completed, execution
 695          * resumes at .work_processed_syscall with p6 set to 1 if the extra-work-check
 696          * needs to be redone.
 697          */
 698 #ifdef CONFIG_PREEMPT
 699         rsm psr.i                               // disable interrupts
 700         cmp.eq pLvSys,p0=r0,r0                  // pLvSys=1: leave from syscall
 701 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
 702         ;;
 703         .pred.rel.mutex pUStk,pKStk
 704 (pKStk) ld4 r21=[r20]                   // r21 <- preempt_count
 705 (pUStk) mov r21=0                       // r21 <- 0
 706         ;;
 707         cmp.eq p6,p0=r21,r0             // p6 <- pUStk || (preempt_count == 0)
 708 #else /* !CONFIG_PREEMPT */
 709 (pUStk) rsm psr.i
 710         cmp.eq pLvSys,p0=r0,r0          // pLvSys=1: leave from syscall
 711 (pUStk) cmp.eq.unc p6,p0=r0,r0          // p6 <- pUStk
 712 #endif
 713 .work_processed_syscall:
 714 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 715         adds r2=PT(LOADRS)+16,r12
 716 (pUStk) mov.m r22=ar.itc                        // fetch time at leave
 717         adds r18=TI_FLAGS+IA64_TASK_SIZE,r13
 718         ;;
 719 (p6)    ld4 r31=[r18]                           // load current_thread_info()->flags
 720         ld8 r19=[r2],PT(B6)-PT(LOADRS)          // load ar.rsc value for "loadrs"
 721         adds r3=PT(AR_BSPSTORE)+16,r12          // deferred
 722         ;;
 723 #else
 724         adds r2=PT(LOADRS)+16,r12
 725         adds r3=PT(AR_BSPSTORE)+16,r12
 726         adds r18=TI_FLAGS+IA64_TASK_SIZE,r13
 727         ;;
 728 (p6)    ld4 r31=[r18]                           // load current_thread_info()->flags
 729         ld8 r19=[r2],PT(B6)-PT(LOADRS)          // load ar.rsc value for "loadrs"
 730         nop.i 0
 731         ;;
 732 #endif
 733         mov r16=ar.bsp                          // M2  get existing backing store pointer
 734         ld8 r18=[r2],PT(R9)-PT(B6)              // load b6
 735 (p6)    and r15=TIF_WORK_MASK,r31               // any work other than TIF_SYSCALL_TRACE?
 736         ;;
 737         ld8 r23=[r3],PT(R11)-PT(AR_BSPSTORE)    // load ar.bspstore (may be garbage)
 738 (p6)    cmp4.ne.unc p6,p0=r15, r0               // any special work pending?
 739 (p6)    br.cond.spnt .work_pending_syscall
 740         ;;
 741         // start restoring the state saved on the kernel stack (struct pt_regs):
 742         ld8 r9=[r2],PT(CR_IPSR)-PT(R9)
 743         ld8 r11=[r3],PT(CR_IIP)-PT(R11)
 744 (pNonSys) break 0               //      bug check: we shouldn't be here if pNonSys is TRUE!
 745         ;;
 746         invala                  // M0|1 invalidate ALAT
 747         rsm psr.i | psr.ic      // M2   turn off interrupts and interruption collection
 748         cmp.eq p9,p0=r0,r0      // A    set p9 to indicate that we should restore cr.ifs
 749
 750         ld8 r29=[r2],16         // M0|1 load cr.ipsr
 751         ld8 r28=[r3],16         // M0|1 load cr.iip
 752 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 753 (pUStk) add r14=TI_AC_LEAVE+IA64_TASK_SIZE,r13
 754         ;;
 755         ld8 r30=[r2],16         // M0|1 load cr.ifs
 756         ld8 r25=[r3],16         // M0|1 load ar.unat
 757 (pUStk) add r15=IA64_TASK_THREAD_ON_USTACK_OFFSET,r13
 758         ;;
 759 #else
 760         mov r22=r0              // A    clear r22
 761         ;;
 762         ld8 r30=[r2],16         // M0|1 load cr.ifs
 763         ld8 r25=[r3],16         // M0|1 load ar.unat
 764 (pUStk) add r14=IA64_TASK_THREAD_ON_USTACK_OFFSET,r13
 765         ;;
 766 #endif
 767         ld8 r26=[r2],PT(B0)-PT(AR_PFS)  // M0|1 load ar.pfs
 768 (pKStk) mov r22=psr                     // M2   read PSR now that interrupts are disabled
 769         nop 0
 770         ;;
 771         ld8 r21=[r2],PT(AR_RNAT)-PT(B0) // M0|1 load b0
 772         ld8 r27=[r3],PT(PR)-PT(AR_RSC)  // M0|1 load ar.rsc
 773         mov f6=f0                       // F    clear f6
 774         ;;
 775         ld8 r24=[r2],PT(AR_FPSR)-PT(AR_RNAT)    // M0|1 load ar.rnat (may be garbage)
 776         ld8 r31=[r3],PT(R1)-PT(PR)              // M0|1 load predicates
 777         mov f7=f0                               // F    clear f7
 778         ;;
 779         ld8 r20=[r2],PT(R12)-PT(AR_FPSR)        // M0|1 load ar.fpsr
 780         ld8.fill r1=[r3],16                     // M0|1 load r1
 781 (pUStk) mov r17=1                               // A
 782         ;;
 783 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 784 (pUStk) st1 [r15]=r17                           // M2|3
 785 #else
 786 (pUStk) st1 [r14]=r17                           // M2|3
 787 #endif
 788         ld8.fill r13=[r3],16                    // M0|1
 789         mov f8=f0                               // F    clear f8
 790         ;;
 791         ld8.fill r12=[r2]                       // M0|1 restore r12 (sp)
 792         ld8.fill r15=[r3]                       // M0|1 restore r15
 793         mov b6=r18                              // I0   restore b6
 794
 795         LOAD_PHYS_STACK_REG_SIZE(r17)
 796         mov f9=f0                                       // F    clear f9
 797 (pKStk) br.cond.dpnt.many skip_rbs_switch               // B
 798
 799         srlz.d                          // M0   ensure interruption collection is off (for cover)
 800         shr.u r18=r19,16                // I0|1 get byte size of existing "dirty" partition
 801         cover                           // B    add current frame into dirty partition & set cr.ifs
 802         ;;
 803 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 804         mov r19=ar.bsp                  // M2   get new backing store pointer
 805         st8 [r14]=r22                   // M    save time at leave
 806         mov f10=f0                      // F    clear f10
 807
 808         mov r22=r0                      // A    clear r22
 809         movl r14=__kernel_syscall_via_epc // X
 810         ;;
 811 #else
 812         mov r19=ar.bsp                  // M2   get new backing store pointer
 813         mov f10=f0                      // F    clear f10
 814
 815         nop.m 0
 816         movl r14=__kernel_syscall_via_epc // X
 817         ;;
 818 #endif
 819         mov.m ar.csd=r0                 // M2   clear ar.csd
 820         mov.m ar.ccv=r0                 // M2   clear ar.ccv
 821         mov b7=r14                      // I0   clear b7 (hint with __kernel_syscall_via_epc)
 822
 823         mov.m ar.ssd=r0                 // M2   clear ar.ssd
 824         mov f11=f0                      // F    clear f11
 825         br.cond.sptk.many rbs_switch    // B
 826 END(ia64_leave_syscall)
 827
 828 #ifdef CONFIG_IA32_SUPPORT
 829 GLOBAL_ENTRY(ia64_ret_from_ia32_execve)
 830         PT_REGS_UNWIND_INFO(0)
 831         adds r2=PT(R8)+16,sp                    // r2 = &pt_regs.r8
 832         adds r3=PT(R10)+16,sp                   // r3 = &pt_regs.r10
 833         ;;
 834         .mem.offset 0,0
 835         st8.spill [r2]=r8       // store return value in slot for r8 and set unat bit
 836         .mem.offset 8,0
 837         st8.spill [r3]=r0       // clear error indication in slot for r10 and set unat bit
 838 END(ia64_ret_from_ia32_execve)
 839         // fall through
 840 #endif /* CONFIG_IA32_SUPPORT */
 841 GLOBAL_ENTRY(ia64_leave_kernel)
 842         PT_REGS_UNWIND_INFO(0)
 843         /*
 844          * work.need_resched etc. mustn't get changed by this CPU before it returns to
 845          * user- or fsys-mode, hence we disable interrupts early on.
 846          *
 847          * p6 controls whether current_thread_info()->flags needs to be check for
 848          * extra work.  We always check for extra work when returning to user-level.
 849          * With CONFIG_PREEMPT, we also check for extra work when the preempt_count
 850          * is 0.  After extra work processing has been completed, execution
 851          * resumes at .work_processed_syscall with p6 set to 1 if the extra-work-check
 852          * needs to be redone.
 853          */
 854 #ifdef CONFIG_PREEMPT
 855         rsm psr.i                               // disable interrupts
 856         cmp.eq p0,pLvSys=r0,r0                  // pLvSys=0: leave from kernel
 857 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
 858         ;;
 859         .pred.rel.mutex pUStk,pKStk
 860 (pKStk) ld4 r21=[r20]                   // r21 <- preempt_count
 861 (pUStk) mov r21=0                       // r21 <- 0
 862         ;;
 863         cmp.eq p6,p0=r21,r0             // p6 <- pUStk || (preempt_count == 0)
 864 #else
 865 (pUStk) rsm psr.i
 866         cmp.eq p0,pLvSys=r0,r0          // pLvSys=0: leave from kernel
 867 (pUStk) cmp.eq.unc p6,p0=r0,r0          // p6 <- pUStk
 868 #endif
 869 .work_processed_kernel:
 870         adds r17=TI_FLAGS+IA64_TASK_SIZE,r13
 871         ;;
 872 (p6)    ld4 r31=[r17]                           // load current_thread_info()->flags
 873         adds r21=PT(PR)+16,r12
 874         ;;
 875
 876         lfetch [r21],PT(CR_IPSR)-PT(PR)
 877         adds r2=PT(B6)+16,r12
 878         adds r3=PT(R16)+16,r12
 879         ;;
 880         lfetch [r21]
 881         ld8 r28=[r2],8          // load b6
 882         adds r29=PT(R24)+16,r12
 883
 884         ld8.fill r16=[r3],PT(AR_CSD)-PT(R16)
 885         adds r30=PT(AR_CCV)+16,r12
 886 (p6)    and r19=TIF_WORK_MASK,r31               // any work other than TIF_SYSCALL_TRACE?
 887         ;;
 888         ld8.fill r24=[r29]
 889         ld8 r15=[r30]           // load ar.ccv
 890 (p6)    cmp4.ne.unc p6,p0=r19, r0               // any special work pending?
 891         ;;
 892         ld8 r29=[r2],16         // load b7
 893         ld8 r30=[r3],16         // load ar.csd
 894 (p6)    br.cond.spnt .work_pending
 895         ;;
 896         ld8 r31=[r2],16         // load ar.ssd
 897         ld8.fill r8=[r3],16
 898         ;;
 899         ld8.fill r9=[r2],16
 900         ld8.fill r10=[r3],PT(R17)-PT(R10)
 901         ;;
 902         ld8.fill r11=[r2],PT(R18)-PT(R11)
 903         ld8.fill r17=[r3],16
 904         ;;
 905         ld8.fill r18=[r2],16
 906         ld8.fill r19=[r3],16
 907         ;;
 908         ld8.fill r20=[r2],16
 909         ld8.fill r21=[r3],16
 910         mov ar.csd=r30
 911         mov ar.ssd=r31
 912         ;;
 913         rsm psr.i | psr.ic      // initiate turning off of interrupt and interruption collection
 914         invala                  // invalidate ALAT
 915         ;;
 916         ld8.fill r22=[r2],24
 917         ld8.fill r23=[r3],24
 918         mov b6=r28
 919         ;;
 920         ld8.fill r25=[r2],16
 921         ld8.fill r26=[r3],16
 922         mov b7=r29
 923         ;;
 924         ld8.fill r27=[r2],16
 925         ld8.fill r28=[r3],16
 926         ;;
 927         ld8.fill r29=[r2],16
 928         ld8.fill r30=[r3],24
 929         ;;
 930         ld8.fill r31=[r2],PT(F9)-PT(R31)
 931         adds r3=PT(F10)-PT(F6),r3
 932         ;;
 933         ldf.fill f9=[r2],PT(F6)-PT(F9)
 934         ldf.fill f10=[r3],PT(F8)-PT(F10)
 935         ;;
 936         ldf.fill f6=[r2],PT(F7)-PT(F6)
 937         ;;
 938         ldf.fill f7=[r2],PT(F11)-PT(F7)
 939         ldf.fill f8=[r3],32
 940         ;;
 941         srlz.d  // ensure that inter. collection is off (VHPT is don't care, since text is pinned)
 942         mov ar.ccv=r15
 943         ;;
 944         ldf.fill f11=[r2]
 945         bsw.0                   // switch back to bank 0 (no stop bit required beforehand...)
 946         ;;
 947 (pUStk) mov r18=IA64_KR(CURRENT)// M2 (12 cycle read latency)
 948         adds r16=PT(CR_IPSR)+16,r12
 949         adds r17=PT(CR_IIP)+16,r12
 950
 951 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 952         .pred.rel.mutex pUStk,pKStk
 953 (pKStk) mov r22=psr             // M2 read PSR now that interrupts are disabled
 954 (pUStk) mov.m r22=ar.itc        // M  fetch time at leave
 955         nop.i 0
 956         ;;
 957 #else
 958 (pKStk) mov r22=psr             // M2 read PSR now that interrupts are disabled
 959         nop.i 0
 960         nop.i 0
 961         ;;
 962 #endif
 963         ld8 r29=[r16],16        // load cr.ipsr
 964         ld8 r28=[r17],16        // load cr.iip
 965         ;;
 966         ld8 r30=[r16],16        // load cr.ifs
 967         ld8 r25=[r17],16        // load ar.unat
 968         ;;
 969         ld8 r26=[r16],16        // load ar.pfs
 970         ld8 r27=[r17],16        // load ar.rsc
 971         cmp.eq p9,p0=r0,r0      // set p9 to indicate that we should restore cr.ifs
 972         ;;
 973         ld8 r24=[r16],16        // load ar.rnat (may be garbage)
 974         ld8 r23=[r17],16        // load ar.bspstore (may be garbage)
 975         ;;
 976         ld8 r31=[r16],16        // load predicates
 977         ld8 r21=[r17],16        // load b0
 978         ;;
 979         ld8 r19=[r16],16        // load ar.rsc value for "loadrs"
 980         ld8.fill r1=[r17],16    // load r1
 981         ;;
 982         ld8.fill r12=[r16],16
 983         ld8.fill r13=[r17],16
 984 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 985 (pUStk) adds r3=TI_AC_LEAVE+IA64_TASK_SIZE,r18
 986 #else
 987 (pUStk) adds r18=IA64_TASK_THREAD_ON_USTACK_OFFSET,r18
 988 #endif
 989         ;;
 990         ld8 r20=[r16],16        // ar.fpsr
 991         ld8.fill r15=[r17],16
 992 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 993 (pUStk) adds r18=IA64_TASK_THREAD_ON_USTACK_OFFSET,r18  // deferred
 994 #endif
 995         ;;
 996         ld8.fill r14=[r16],16
 997         ld8.fill r2=[r17]
 998 (pUStk) mov r17=1
 999         ;;
1000 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
1001         //  mmi_ :  ld8 st1 shr;;         mmi_ : st8 st1 shr;;
1002         //  mib  :  mov add br        ->  mib  : ld8 add br
1003         //  bbb_ :  br  nop cover;;       mbb_ : mov br  cover;;
1004         //
1005         //  no one require bsp in r16 if (pKStk) branch is selected.
1006 (pUStk) st8 [r3]=r22            // save time at leave
1007 (pUStk) st1 [r18]=r17           // restore current->thread.on_ustack
1008         shr.u r18=r19,16        // get byte size of existing "dirty" partition
1009         ;;
1010         ld8.fill r3=[r16]       // deferred
1011         LOAD_PHYS_STACK_REG_SIZE(r17)
1012 (pKStk) br.cond.dpnt skip_rbs_switch
1013         mov r16=ar.bsp          // get existing backing store pointer
1014 #else
1015         ld8.fill r3=[r16]
1016 (pUStk) st1 [r18]=r17           // restore current->thread.on_ustack
1017         shr.u r18=r19,16        // get byte size of existing "dirty" partition
1018         ;;
1019         mov r16=ar.bsp          // get existing backing store pointer
1020         LOAD_PHYS_STACK_REG_SIZE(r17)
1021 (pKStk) br.cond.dpnt skip_rbs_switch
1022 #endif
1023
1024         /*
1025          * Restore user backing store.
1026          *
1027          * NOTE: alloc, loadrs, and cover can't be predicated.
1028          */
1029 (pNonSys) br.cond.dpnt dont_preserve_current_frame
1030         cover                           // add current frame into dirty partition and set cr.ifs
1031         ;;
1032         mov r19=ar.bsp                  // get new backing store pointer
1033 rbs_switch:
1034         sub r16=r16,r18                 // krbs = old bsp - size of dirty partition
1035         cmp.ne p9,p0=r0,r0              // clear p9 to skip restore of cr.ifs
1036         ;;
1037         sub r19=r19,r16                 // calculate total byte size of dirty partition
1038         add r18=64,r18                  // don't force in0-in7 into memory...
1039         ;;
1040         shl r19=r19,16                  // shift size of dirty partition into loadrs position
1041         ;;
1042 dont_preserve_current_frame:
1043         /*
1044          * To prevent leaking bits between the kernel and user-space,
1045          * we must clear the stacked registers in the "invalid" partition here.
1046          * Not pretty, but at least it's fast (3.34 registers/cycle on Itanium,
1047          * 5 registers/cycle on McKinley).
1048          */
1049 #       define pRecurse p6
1050 #       define pReturn  p7
1051 #ifdef CONFIG_ITANIUM
1052 #       define Nregs    10
1053 #else
1054 #       define Nregs    14
1055 #endif
1056         alloc loc0=ar.pfs,2,Nregs-2,2,0
1057         shr.u loc1=r18,9                // RNaTslots <= floor(dirtySize / (64*8))
1058         sub r17=r17,r18                 // r17 = (physStackedSize + 8) - dirtySize
1059         ;;
1060         mov ar.rsc=r19                  // load ar.rsc to be used for "loadrs"
1061         shladd in0=loc1,3,r17
1062         mov in1=0
1063         ;;
1064         TEXT_ALIGN(32)
1065 rse_clear_invalid:
1066 #ifdef CONFIG_ITANIUM
1067         // cycle 0
1068  { .mii
1069         alloc loc0=ar.pfs,2,Nregs-2,2,0
1070         cmp.lt pRecurse,p0=Nregs*8,in0  // if more than Nregs regs left to clear, (re)curse
1071         add out0=-Nregs*8,in0
1072 }{ .mfb
1073         add out1=1,in1                  // increment recursion count
1074         nop.f 0
1075         nop.b 0                         // can't do br.call here because of alloc (WAW on CFM)
1076         ;;
1077 }{ .mfi // cycle 1
1078         mov loc1=0
1079         nop.f 0
1080         mov loc2=0
1081 }{ .mib
1082         mov loc3=0
1083         mov loc4=0
1084 (pRecurse) br.call.sptk.many b0=rse_clear_invalid
1085
1086 }{ .mfi // cycle 2
1087         mov loc5=0
1088         nop.f 0
1089         cmp.ne pReturn,p0=r0,in1        // if recursion count != 0, we need to do a br.ret
1090 }{ .mib
1091         mov loc6=0
1092         mov loc7=0
1093 (pReturn) br.ret.sptk.many b0
1094 }
1095 #else /* !CONFIG_ITANIUM */
1096         alloc loc0=ar.pfs,2,Nregs-2,2,0
1097         cmp.lt pRecurse,p0=Nregs*8,in0  // if more than Nregs regs left to clear, (re)curse
1098         add out0=-Nregs*8,in0
1099         add out1=1,in1                  // increment recursion count
1100         mov loc1=0
1101         mov loc2=0
1102         ;;
1103         mov loc3=0
1104         mov loc4=0
1105         mov loc5=0
1106         mov loc6=0
1107         mov loc7=0
1108 (pRecurse) br.call.dptk.few b0=rse_clear_invalid
1109         ;;
1110         mov loc8=0
1111         mov loc9=0
1112         cmp.ne pReturn,p0=r0,in1        // if recursion count != 0, we need to do a br.ret
1113         mov loc10=0
1114         mov loc11=0
1115 (pReturn) br.ret.dptk.many b0
1116 #endif /* !CONFIG_ITANIUM */
1117 #       undef pRecurse
1118 #       undef pReturn
1119         ;;
1120         alloc r17=ar.pfs,0,0,0,0        // drop current register frame
1121         ;;
1122         loadrs
1123         ;;
1124 skip_rbs_switch:
1125         mov ar.unat=r25         // M2
1126 (pKStk) extr.u r22=r22,21,1     // I0 extract current value of psr.pp from r22
1127 (pLvSys)mov r19=r0              // A  clear r19 for leave_syscall, no-op otherwise
1128         ;;
1129 (pUStk) mov ar.bspstore=r23     // M2
1130 (pKStk) dep r29=r22,r29,21,1    // I0 update ipsr.pp with psr.pp
1131 (pLvSys)mov r16=r0              // A  clear r16 for leave_syscall, no-op otherwise
1132         ;;
1133         mov cr.ipsr=r29         // M2
1134         mov ar.pfs=r26          // I0
1135 (pLvSys)mov r17=r0              // A  clear r17 for leave_syscall, no-op otherwise
1136
1137 (p9)    mov cr.ifs=r30          // M2
1138         mov b0=r21              // I0
1139 (pLvSys)mov r18=r0              // A  clear r18 for leave_syscall, no-op otherwise
1140
1141         mov ar.fpsr=r20         // M2
1142         mov cr.iip=r28          // M2
1143         nop 0
1144         ;;
1145 (pUStk) mov ar.rnat=r24         // M2 must happen with RSE in lazy mode
1146         nop 0
1147 (pLvSys)mov r2=r0
1148
1149         mov ar.rsc=r27          // M2
1150         mov pr=r31,-1           // I0
1151         rfi                     // B
1152
1153         /*
1154          * On entry:
1155          *      r20 = &current->thread_info->pre_count (if CONFIG_PREEMPT)
1156          *      r31 = current->thread_info->flags
1157          * On exit:
1158          *      p6 = TRUE if work-pending-check needs to be redone
1159          *
1160          * Interrupts are disabled on entry, reenabled depend on work, and
1161          * disabled on exit.
1162          */
1163 .work_pending_syscall:
1164         add r2=-8,r2
1165         add r3=-8,r3
1166         ;;
1167         st8 [r2]=r8
1168         st8 [r3]=r10
1169 .work_pending:
1170         tbit.z p6,p0=r31,TIF_NEED_RESCHED       // is resched not needed?
1171 (p6)    br.cond.sptk.few .notify
1172 #ifdef CONFIG_PREEMPT
1173 (pKStk) dep r21=-1,r0,PREEMPT_ACTIVE_BIT,1
1174         ;;
1175 (pKStk) st4 [r20]=r21
1176 #endif
1177         ssm psr.i               // enable interrupts
1178         br.call.spnt.many rp=schedule
1179 .ret9:  cmp.eq p6,p0=r0,r0      // p6 <- 1 (re-check)
1180         rsm psr.i               // disable interrupts
1181         ;;
1182 #ifdef CONFIG_PREEMPT
1183 (pKStk) adds r20=TI_PRE_COUNT+IA64_TASK_SIZE,r13
1184         ;;
1185 (pKStk) st4 [r20]=r0            // preempt_count() <- 0
1186 #endif
1187 (pLvSys)br.cond.sptk.few  .work_pending_syscall_end
1188         br.cond.sptk.many .work_processed_kernel
1189
1190 .notify:
1191 (pUStk) br.call.spnt.many rp=notify_resume_user
1192 .ret10: cmp.ne p6,p0=r0,r0      // p6 <- 0 (don't re-check)
1193 (pLvSys)br.cond.sptk.few  .work_pending_syscall_end
1194         br.cond.sptk.many .work_processed_kernel
1195
1196 .work_pending_syscall_end:
1197         adds r2=PT(R8)+16,r12
1198         adds r3=PT(R10)+16,r12
1199         ;;
1200         ld8 r8=[r2]
1201         ld8 r10=[r3]
1202         br.cond.sptk.many .work_processed_syscall
1203
1204 END(ia64_leave_kernel)
1205
1206 ENTRY(handle_syscall_error)
1207         /*
1208          * Some system calls (e.g., ptrace, mmap) can return arbitrary values which could
1209          * lead us to mistake a negative return value as a failed syscall.  Those syscall
1210          * must deposit a non-zero value in pt_regs.r8 to indicate an error.  If
1211          * pt_regs.r8 is zero, we assume that the call completed successfully.
1212          */
1213         PT_REGS_UNWIND_INFO(0)
1214         ld8 r3=[r2]             // load pt_regs.r8
1215         ;;
1216         cmp.eq p6,p7=r3,r0      // is pt_regs.r8==0?
1217         ;;
1218 (p7)    mov r10=-1
1219 (p7)    sub r8=0,r8             // negate return value to get errno
1220         br.cond.sptk ia64_leave_syscall
1221 END(handle_syscall_error)
1222
1223         /*
1224          * Invoke schedule_tail(task) while preserving in0-in7, which may be needed
1225          * in case a system call gets restarted.
1226          */
1227 GLOBAL_ENTRY(ia64_invoke_schedule_tail)
1228         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
1229         alloc loc1=ar.pfs,8,2,1,0
1230         mov loc0=rp
1231         mov out0=r8                             // Address of previous task
1232         ;;
1233         br.call.sptk.many rp=schedule_tail
1234 .ret11: mov ar.pfs=loc1
1235         mov rp=loc0
1236         br.ret.sptk.many rp
1237 END(ia64_invoke_schedule_tail)
1238
1239         /*
1240          * Setup stack and call do_notify_resume_user(), keeping interrupts
1241          * disabled.
1242          *
1243          * Note that pSys and pNonSys need to be set up by the caller.
1244          * We declare 8 input registers so the system call args get preserved,
1245          * in case we need to restart a system call.
1246          */
1247 ENTRY(notify_resume_user)
1248         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(8)
1249         alloc loc1=ar.pfs,8,2,3,0 // preserve all eight input regs in case of syscall restart!
1250         mov r9=ar.unat
1251         mov loc0=rp                             // save return address
1252         mov out0=0                              // there is no "oldset"
1253         adds out1=8,sp                          // out1=&sigscratch->ar_pfs
1254 (pSys)  mov out2=1                              // out2==1 => we're in a syscall
1255         ;;
1256 (pNonSys) mov out2=0                            // out2==0 => not a syscall
1257         .fframe 16
1258         .spillsp ar.unat, 16
1259         st8 [sp]=r9,-16                         // allocate space for ar.unat and save it
1260         st8 [out1]=loc1,-8                      // save ar.pfs, out1=&sigscratch
1261         .body
1262         br.call.sptk.many rp=do_notify_resume_user
1263 .ret15: .restore sp
1264         adds sp=16,sp                           // pop scratch stack space
1265         ;;
1266         ld8 r9=[sp]                             // load new unat from sigscratch->scratch_unat
1267         mov rp=loc0
1268         ;;
1269         mov ar.unat=r9
1270         mov ar.pfs=loc1
1271         br.ret.sptk.many rp
1272 END(notify_resume_user)
1273
1274 ENTRY(sys_rt_sigreturn)
1275         PT_REGS_UNWIND_INFO(0)
1276         /*
1277          * Allocate 8 input registers since ptrace() may clobber them
1278          */
1279         alloc r2=ar.pfs,8,0,1,0
1280         .prologue
1281         PT_REGS_SAVES(16)
1282         adds sp=-16,sp
1283         .body
1284         cmp.eq pNonSys,pSys=r0,r0               // sigreturn isn't a normal syscall...
1285         ;;
1286         /*
1287          * leave_kernel() restores f6-f11 from pt_regs, but since the streamlined
1288          * syscall-entry path does not save them we save them here instead.  Note: we
1289          * don't need to save any other registers that are not saved by the stream-lined
1290          * syscall path, because restore_sigcontext() restores them.
1291          */
1292         adds r16=PT(F6)+32,sp
1293         adds r17=PT(F7)+32,sp
1294         ;;
1295         stf.spill [r16]=f6,32
1296         stf.spill [r17]=f7,32
1297         ;;
1298         stf.spill [r16]=f8,32
1299         stf.spill [r17]=f9,32
1300         ;;
1301         stf.spill [r16]=f10
1302         stf.spill [r17]=f11
1303         adds out0=16,sp                         // out0 = &sigscratch
1304         br.call.sptk.many rp=ia64_rt_sigreturn
1305 .ret19: .restore sp,0
1306         adds sp=16,sp
1307         ;;
1308         ld8 r9=[sp]                             // load new ar.unat
1309         mov.sptk b7=r8,ia64_leave_kernel
1310         ;;
1311         mov ar.unat=r9
1312         br.many b7
1313 END(sys_rt_sigreturn)
1314
1315 GLOBAL_ENTRY(ia64_prepare_handle_unaligned)
1316         .prologue
1317         /*
1318          * r16 = fake ar.pfs, we simply need to make sure privilege is still 0
1319          */
1320         mov r16=r0
1321         DO_SAVE_SWITCH_STACK
1322         br.call.sptk.many rp=ia64_handle_unaligned      // stack frame setup in ivt
1323 .ret21: .body
1324         DO_LOAD_SWITCH_STACK
1325         br.cond.sptk.many rp                            // goes to ia64_leave_kernel
1326 END(ia64_prepare_handle_unaligned)
1327
1328         //
1329         // unw_init_running(void (*callback)(info, arg), void *arg)
1330         //
1331 #       define EXTRA_FRAME_SIZE ((UNW_FRAME_INFO_SIZE+15)&~15)
1332
1333 GLOBAL_ENTRY(unw_init_running)
1334         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(2)
1335         alloc loc1=ar.pfs,2,3,3,0
1336         ;;
1337         ld8 loc2=[in0],8
1338         mov loc0=rp
1339         mov r16=loc1
1340         DO_SAVE_SWITCH_STACK
1341         .body
1342
1343         .prologue ASM_UNW_PRLG_RP|ASM_UNW_PRLG_PFS, ASM_UNW_PRLG_GRSAVE(2)
1344         .fframe IA64_SWITCH_STACK_SIZE+EXTRA_FRAME_SIZE
1345         SWITCH_STACK_SAVES(EXTRA_FRAME_SIZE)
1346         adds sp=-EXTRA_FRAME_SIZE,sp
1347         .body
1348         ;;
1349         adds out0=16,sp                         // &info
1350         mov out1=r13                            // current
1351         adds out2=16+EXTRA_FRAME_SIZE,sp        // &switch_stack
1352         br.call.sptk.many rp=unw_init_frame_info
1353 1:      adds out0=16,sp                         // &info
1354         mov b6=loc2
1355         mov loc2=gp                             // save gp across indirect function call
1356         ;;
1357         ld8 gp=[in0]
1358         mov out1=in1                            // arg
1359         br.call.sptk.many rp=b6                 // invoke the callback function
1360 1:      mov gp=loc2                             // restore gp
1361
1362         // For now, we don't allow changing registers from within
1363         // unw_init_running; if we ever want to allow that, we'd
1364         // have to do a load_switch_stack here:
1365         .restore sp
1366         adds sp=IA64_SWITCH_STACK_SIZE+EXTRA_FRAME_SIZE,sp
1367
1368         mov ar.pfs=loc1
1369         mov rp=loc0
1370         br.ret.sptk.many rp
1371 END(unw_init_running)
1372
1373         .rodata
1374         .align 8
1375         .globl sys_call_table
1376 sys_call_table:
1377         data8 sys_ni_syscall            //  This must be sys_ni_syscall!  See ivt.S.
1378         data8 sys_exit                          // 1025
1379         data8 sys_read
1380         data8 sys_write
1381         data8 sys_open
1382         data8 sys_close
1383         data8 sys_creat                         // 1030
1384         data8 sys_link
1385         data8 sys_unlink
1386         data8 ia64_execve
1387         data8 sys_chdir
1388         data8 sys_fchdir                        // 1035
1389         data8 sys_utimes
1390         data8 sys_mknod
1391         data8 sys_chmod
1392         data8 sys_chown
1393         data8 sys_lseek                         // 1040
1394         data8 sys_getpid
1395         data8 sys_getppid
1396         data8 sys_mount
1397         data8 sys_umount
1398         data8 sys_setuid                        // 1045
1399         data8 sys_getuid
1400         data8 sys_geteuid
1401         data8 sys_ptrace
1402         data8 sys_access
1403         data8 sys_sync                          // 1050
1404         data8 sys_fsync
1405         data8 sys_fdatasync
1406         data8 sys_kill
1407         data8 sys_rename
1408         data8 sys_mkdir                         // 1055
1409         data8 sys_rmdir
1410         data8 sys_dup
1411         data8 sys_pipe
1412         data8 sys_times
1413         data8 ia64_brk                          // 1060
1414         data8 sys_setgid
1415         data8 sys_getgid
1416         data8 sys_getegid
1417         data8 sys_acct
1418         data8 sys_ioctl                         // 1065
1419         data8 sys_fcntl
1420         data8 sys_umask
1421         data8 sys_chroot
1422         data8 sys_ustat
1423         data8 sys_dup2                          // 1070
1424         data8 sys_setreuid
1425         data8 sys_setregid
1426         data8 sys_getresuid
1427         data8 sys_setresuid
1428         data8 sys_getresgid                     // 1075
1429         data8 sys_setresgid
1430         data8 sys_getgroups
1431         data8 sys_setgroups
1432         data8 sys_getpgid
1433         data8 sys_setpgid                       // 1080
1434         data8 sys_setsid
1435         data8 sys_getsid
1436         data8 sys_sethostname
1437         data8 sys_setrlimit
1438         data8 sys_getrlimit                     // 1085
1439         data8 sys_getrusage
1440         data8 sys_gettimeofday
1441         data8 sys_settimeofday
1442         data8 sys_select
1443         data8 sys_poll                          // 1090
1444         data8 sys_symlink
1445         data8 sys_readlink
1446         data8 sys_uselib
1447         data8 sys_swapon
1448         data8 sys_swapoff                       // 1095
1449         data8 sys_reboot
1450         data8 sys_truncate
1451         data8 sys_ftruncate
1452         data8 sys_fchmod
1453         data8 sys_fchown                        // 1100
1454         data8 ia64_getpriority
1455         data8 sys_setpriority
1456         data8 sys_statfs
1457         data8 sys_fstatfs
1458         data8 sys_gettid                        // 1105
1459         data8 sys_semget
1460         data8 sys_semop
1461         data8 sys_semctl
1462         data8 sys_msgget
1463         data8 sys_msgsnd                        // 1110
1464         data8 sys_msgrcv
1465         data8 sys_msgctl
1466         data8 sys_shmget
1467         data8 sys_shmat
1468         data8 sys_shmdt                         // 1115
1469         data8 sys_shmctl
1470         data8 sys_syslog
1471         data8 sys_setitimer
1472         data8 sys_getitimer
1473         data8 sys_ni_syscall                    // 1120         /* was: ia64_oldstat */
1474         data8 sys_ni_syscall                                    /* was: ia64_oldlstat */
1475         data8 sys_ni_syscall                                    /* was: ia64_oldfstat */
1476         data8 sys_vhangup
1477         data8 sys_lchown
1478         data8 sys_remap_file_pages              // 1125
1479         data8 sys_wait4
1480         data8 sys_sysinfo
1481         data8 sys_clone
1482         data8 sys_setdomainname
1483         data8 sys_newuname                      // 1130
1484         data8 sys_adjtimex
1485         data8 sys_ni_syscall                                    /* was: ia64_create_module */
1486         data8 sys_init_module
1487         data8 sys_delete_module
1488         data8 sys_ni_syscall                    // 1135         /* was: sys_get_kernel_syms */
1489         data8 sys_ni_syscall                                    /* was: sys_query_module */
1490         data8 sys_quotactl
1491         data8 sys_bdflush
1492         data8 sys_sysfs
1493         data8 sys_personality                   // 1140
1494         data8 sys_ni_syscall            // sys_afs_syscall
1495         data8 sys_setfsuid
1496         data8 sys_setfsgid
1497         data8 sys_getdents
1498         data8 sys_flock                         // 1145
1499         data8 sys_readv
1500         data8 sys_writev
1501         data8 sys_pread64
1502         data8 sys_pwrite64
1503         data8 sys_sysctl                        // 1150
1504         data8 sys_mmap
1505         data8 sys_munmap
1506         data8 sys_mlock
1507         data8 sys_mlockall
1508         data8 sys_mprotect                      // 1155
1509         data8 ia64_mremap
1510         data8 sys_msync
1511         data8 sys_munlock
1512         data8 sys_munlockall
1513         data8 sys_sched_getparam                // 1160
1514         data8 sys_sched_setparam
1515         data8 sys_sched_getscheduler
1516         data8 sys_sched_setscheduler
1517         data8 sys_sched_yield
1518         data8 sys_sched_get_priority_max        // 1165
1519         data8 sys_sched_get_priority_min
1520         data8 sys_sched_rr_get_interval
1521         data8 sys_nanosleep
1522         data8 sys_nfsservctl
1523         data8 sys_prctl                         // 1170
1524         data8 sys_getpagesize
1525         data8 sys_mmap2
1526         data8 sys_pciconfig_read
1527         data8 sys_pciconfig_write
1528         data8 sys_perfmonctl                    // 1175
1529         data8 sys_sigaltstack
1530         data8 sys_rt_sigaction
1531         data8 sys_rt_sigpending
1532         data8 sys_rt_sigprocmask
1533         data8 sys_rt_sigqueueinfo               // 1180
1534         data8 sys_rt_sigreturn
1535         data8 sys_rt_sigsuspend
1536         data8 sys_rt_sigtimedwait
1537         data8 sys_getcwd
1538         data8 sys_capget                        // 1185
1539         data8 sys_capset
1540         data8 sys_sendfile64
1541         data8 sys_ni_syscall            // sys_getpmsg (STREAMS)
1542         data8 sys_ni_syscall            // sys_putpmsg (STREAMS)
1543         data8 sys_socket                        // 1190
1544         data8 sys_bind
1545         data8 sys_connect
1546         data8 sys_listen
1547         data8 sys_accept
1548         data8 sys_getsockname                   // 1195
1549         data8 sys_getpeername
1550         data8 sys_socketpair
1551         data8 sys_send
1552         data8 sys_sendto
1553         data8 sys_recv                          // 1200
1554         data8 sys_recvfrom
1555         data8 sys_shutdown
1556         data8 sys_setsockopt
1557         data8 sys_getsockopt
1558         data8 sys_sendmsg                       // 1205
1559         data8 sys_recvmsg
1560         data8 sys_pivot_root
1561         data8 sys_mincore
1562         data8 sys_madvise
1563         data8 sys_newstat                       // 1210
1564         data8 sys_newlstat
1565         data8 sys_newfstat
1566         data8 sys_clone2
1567         data8 sys_getdents64
1568         data8 sys_getunwind                     // 1215
1569         data8 sys_readahead
1570         data8 sys_setxattr
1571         data8 sys_lsetxattr
1572         data8 sys_fsetxattr
1573         data8 sys_getxattr                      // 1220
1574         data8 sys_lgetxattr
1575         data8 sys_fgetxattr
1576         data8 sys_listxattr
1577         data8 sys_llistxattr
1578         data8 sys_flistxattr                    // 1225
1579         data8 sys_removexattr
1580         data8 sys_lremovexattr
1581         data8 sys_fremovexattr
1582         data8 sys_tkill
1583         data8 sys_futex                         // 1230
1584         data8 sys_sched_setaffinity
1585         data8 sys_sched_getaffinity
1586         data8 sys_set_tid_address
1587         data8 sys_fadvise64_64
1588         data8 sys_tgkill                        // 1235
1589         data8 sys_exit_group
1590         data8 sys_lookup_dcookie
1591         data8 sys_io_setup
1592         data8 sys_io_destroy
1593         data8 sys_io_getevents                  // 1240
1594         data8 sys_io_submit
1595         data8 sys_io_cancel
1596         data8 sys_epoll_create
1597         data8 sys_epoll_ctl
1598         data8 sys_epoll_wait                    // 1245
1599         data8 sys_restart_syscall
1600         data8 sys_semtimedop
1601         data8 sys_timer_create
1602         data8 sys_timer_settime
1603         data8 sys_timer_gettime                 // 1250
1604         data8 sys_timer_getoverrun
1605         data8 sys_timer_delete
1606         data8 sys_clock_settime
1607         data8 sys_clock_gettime
1608         data8 sys_clock_getres                  // 1255
1609         data8 sys_clock_nanosleep
1610         data8 sys_fstatfs64
1611         data8 sys_statfs64
1612         data8 sys_mbind
1613         data8 sys_get_mempolicy                 // 1260
1614         data8 sys_set_mempolicy
1615         data8 sys_mq_open
1616         data8 sys_mq_unlink
1617         data8 sys_mq_timedsend
1618         data8 sys_mq_timedreceive               // 1265
1619         data8 sys_mq_notify
1620         data8 sys_mq_getsetattr
1621         data8 sys_kexec_load
1622         data8 sys_ni_syscall                    // reserved for vserver
1623         data8 sys_waitid                        // 1270
1624         data8 sys_add_key
1625         data8 sys_request_key
1626         data8 sys_keyctl
1627         data8 sys_ioprio_set
1628         data8 sys_ioprio_get                    // 1275
1629         data8 sys_move_pages
1630         data8 sys_inotify_init
1631         data8 sys_inotify_add_watch
1632         data8 sys_inotify_rm_watch
1633         data8 sys_migrate_pages                 // 1280
1634         data8 sys_openat
1635         data8 sys_mkdirat
1636         data8 sys_mknodat
1637         data8 sys_fchownat
1638         data8 sys_futimesat                     // 1285
1639         data8 sys_newfstatat
1640         data8 sys_unlinkat
1641         data8 sys_renameat
1642         data8 sys_linkat
1643         data8 sys_symlinkat                     // 1290
1644         data8 sys_readlinkat
1645         data8 sys_fchmodat
1646         data8 sys_faccessat
1647         data8 sys_pselect6
1648         data8 sys_ppoll                         // 1295
1649         data8 sys_unshare
1650         data8 sys_splice
1651         data8 sys_set_robust_list
1652         data8 sys_get_robust_list
1653         data8 sys_sync_file_range               // 1300
1654         data8 sys_tee
1655         data8 sys_vmsplice
1656         data8 sys_fallocate
1657         data8 sys_getcpu
1658         data8 sys_epoll_pwait                   // 1305
1659         data8 sys_utimensat
1660         data8 sys_signalfd
1661         data8 sys_ni_syscall
1662         data8 sys_eventfd
1663         data8 sys_timerfd_create                // 1310
1664         data8 sys_timerfd_settime
1665         data8 sys_timerfd_gettime
1666
1667         .org sys_call_table + 8*NR_syscalls     // guard against failures to increase NR_syscalls