git.oblomov.eu Git - linux-2.6/blob - arch/sh/kernel/head.S

   1 /* $Id: head.S,v 1.7 2003/09/01 17:58:19 lethal Exp $
   2  *
   3  *  arch/sh/kernel/head.S
   4  *
   5  *  Copyright (C) 1999, 2000  Niibe Yutaka & Kaz Kojima
   6  *
   7  * This file is subject to the terms and conditions of the GNU General Public
   8  * License.  See the file "COPYING" in the main directory of this archive
   9  * for more details.
  10  *
  11  * Head.S contains the SH exception handlers and startup code.
  12  */
  13 #include <linux/linkage.h>
  14 #include <asm/thread_info.h>
  15
  16 #ifdef CONFIG_CPU_SH4A
  17 #define SYNCO()         synco
  18
  19 #define PREFI(label, reg)       \
  20         mov.l   label, reg;     \
  21         prefi   @reg
  22 #else
  23 #define SYNCO()
  24 #define PREFI(label, reg)
  25 #endif
  26
  27         .section        .empty_zero_page, "aw"
  28 ENTRY(empty_zero_page)
  29         .long   1               /* MOUNT_ROOT_RDONLY */
  30         .long   0               /* RAMDISK_FLAGS */
  31         .long   0x0200          /* ORIG_ROOT_DEV */
  32         .long   1               /* LOADER_TYPE */
  33         .long   0x00360000      /* INITRD_START */
  34         .long   0x000a0000      /* INITRD_SIZE */
  35         .long   0
  36 1:
  37         .skip   PAGE_SIZE - empty_zero_page - 1b
  38
  39         .section        .text.head, "ax"
  40
  41 /*
  42  * Condition at the entry of _stext:
  43  *
  44  *   BSC has already been initialized.
  45  *   INTC may or may not be initialized.
  46  *   VBR may or may not be initialized.
  47  *   MMU may or may not be initialized.
  48  *   Cache may or may not be initialized.
  49  *   Hardware (including on-chip modules) may or may not be initialized.
  50  *
  51  */
  52 ENTRY(_stext)
  53         !                       Initialize Status Register
  54         mov.l   1f, r0          ! MD=1, RB=0, BL=0, IMASK=0xF
  55         ldc     r0, sr
  56         !                       Initialize global interrupt mask
  57         mov     #0, r0
  58 #ifdef CONFIG_CPU_HAS_SR_RB
  59         ldc     r0, r6_bank
  60 #endif
  61
  62         /*
  63          * Prefetch if possible to reduce cache miss penalty.
  64          *
  65          * We do this early on for SH-4A as a micro-optimization,
  66          * as later on we will have speculative execution enabled
  67          * and this will become less of an issue.
  68          */
  69         PREFI(5f, r0)
  70         PREFI(6f, r0)
  71
  72         !
  73         mov.l   2f, r0
  74         mov     r0, r15         ! Set initial r15 (stack pointer)
  75         mov     #(THREAD_SIZE >> 10), r1
  76         shll8   r1              ! r1 = THREAD_SIZE
  77         shll2   r1
  78         sub     r1, r0          !
  79 #ifdef CONFIG_CPU_HAS_SR_RB
  80         ldc     r0, r7_bank     ! ... and initial thread_info
  81 #endif
  82
  83         !                       Clear BSS area
  84         mov.l   3f, r1
  85         add     #4, r1
  86         mov.l   4f, r2
  87         mov     #0, r0
  88 9:      cmp/hs  r2, r1
  89         bf/s    9b              ! while (r1 < r2)
  90          mov.l  r0,@-r2
  91
  92         !                       Additional CPU initialization
  93         mov.l   6f, r0
  94         jsr     @r0
  95          nop
  96
  97         SYNCO()                 ! Wait for pending instructions..
  98
  99         !                       Start kernel
 100         mov.l   5f, r0
 101         jmp     @r0
 102          nop
 103
 104         .balign 4
 105 #if defined(CONFIG_CPU_SH2)
 106 1:      .long   0x000000F0              ! IMASK=0xF
 107 #else
 108 1:      .long   0x400080F0              ! MD=1, RB=0, BL=0, FD=1, IMASK=0xF
 109 #endif
 110 2:      .long   init_thread_union+THREAD_SIZE
 111 3:      .long   __bss_start
 112 4:      .long   _end
 113 5:      .long   start_kernel
 114 6:      .long   sh_cpu_init