git.oblomov.eu Git - linux-2.6/blob - arch/um/kernel/dyn.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2
   3 OUTPUT_FORMAT(ELF_FORMAT)
   4 OUTPUT_ARCH(ELF_ARCH)
   5 ENTRY(_start)
   6 jiffies = jiffies_64;
   7
   8 SECTIONS
   9 {
  10   PROVIDE (__executable_start = START);
  11   . = START + SIZEOF_HEADERS;
  12   .interp         : { *(.interp) }
  13   __binary_start = .;
  14   . = ALIGN(4096);              /* Init code and data */
  15   _text = .;
  16   _stext = .;
  17   __init_begin = .;
  18   .init.text : {
  19         _sinittext = .;
  20         INIT_TEXT
  21         _einittext = .;
  22   }
  23
  24   . = ALIGN(4096);
  25
  26   /* Read-only sections, merged into text segment: */
  27   .hash           : { *(.hash) }
  28   .gnu.hash       : { *(.gnu.hash) }
  29   .dynsym         : { *(.dynsym) }
  30   .dynstr         : { *(.dynstr) }
  31   .gnu.version    : { *(.gnu.version) }
  32   .gnu.version_d  : { *(.gnu.version_d) }
  33   .gnu.version_r  : { *(.gnu.version_r) }
  34   .rel.init       : { *(.rel.init) }
  35   .rela.init      : { *(.rela.init) }
  36   .rel.text       : { *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*) }
  37   .rela.text      : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
  38   .rel.fini       : { *(.rel.fini) }
  39   .rela.fini      : { *(.rela.fini) }
  40   .rel.rodata     : { *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*) }
  41   .rela.rodata    : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
  42   .rel.data       : { *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*) }
  43   .rela.data      : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
  44   .rel.tdata      : { *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*) }
  45   .rela.tdata     : { *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*) }
  46   .rel.tbss       : { *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*) }
  47   .rela.tbss      : { *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*) }
  48   .rel.ctors      : { *(.rel.ctors) }
  49   .rela.ctors     : { *(.rela.ctors) }
  50   .rel.dtors      : { *(.rel.dtors) }
  51   .rela.dtors     : { *(.rela.dtors) }
  52   .rel.got        : { *(.rel.got) }
  53   .rela.got       : { *(.rela.got) }
  54   .rel.bss        : { *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*) }
  55   .rela.bss       : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
  56   .rel.plt        : { *(.rel.plt) }
  57   .rela.plt       : { *(.rela.plt) }
  58   .init           : {
  59     KEEP (*(.init))
  60   } =0x90909090
  61   .plt            : { *(.plt) }
  62   .text           : {
  63     TEXT_TEXT
  64     SCHED_TEXT
  65     LOCK_TEXT
  66     *(.fixup)
  67     *(.stub .text.* .gnu.linkonce.t.*)
  68     /* .gnu.warning sections are handled specially by elf32.em.  */
  69     *(.gnu.warning)
  70
  71     . = ALIGN(4096);
  72   } =0x90909090
  73   . = ALIGN(4096);
  74   .syscall_stub : {
  75         __syscall_stub_start = .;
  76         *(.__syscall_stub*)
  77         __syscall_stub_end = .;
  78   }
  79   .fini           : {
  80     KEEP (*(.fini))
  81   } =0x90909090
  82
  83   .kstrtab : { *(.kstrtab) }
  84
  85   #include "asm/common.lds.S"
  86
  87   init.data : { INIT_DATA }
  88
  89   /* Ensure the __preinit_array_start label is properly aligned.  We
  90      could instead move the label definition inside the section, but
  91      the linker would then create the section even if it turns out to
  92      be empty, which isn't pretty.  */
  93   . = ALIGN(32 / 8);
  94   .preinit_array     : { *(.preinit_array) }
  95   .init_array     : { *(.init_array) }
  96   .fini_array     : { *(.fini_array) }
  97   .data           : {
  98     . = ALIGN(KERNEL_STACK_SIZE);               /* init_task */
  99     *(.data.init_task)
 100     . = ALIGN(KERNEL_STACK_SIZE);
 101     *(.data.init_irqstack)
 102     DATA_DATA
 103     *(.data.* .gnu.linkonce.d.*)
 104     SORT(CONSTRUCTORS)
 105   }
 106   .data1          : { *(.data1) }
 107   .tdata          : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
 108   .tbss           : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
 109   .eh_frame       : { KEEP (*(.eh_frame)) }
 110   .gcc_except_table   : { *(.gcc_except_table) }
 111   .dynamic        : { *(.dynamic) }
 112   .ctors          : {
 113     /* gcc uses crtbegin.o to find the start of
 114        the constructors, so we make sure it is
 115        first.  Because this is a wildcard, it
 116        doesn't matter if the user does not
 117        actually link against crtbegin.o; the
 118        linker won't look for a file to match a
 119        wildcard.  The wildcard also means that it
 120        doesn't matter which directory crtbegin.o
 121        is in.  */
 122     KEEP (*crtbegin.o(.ctors))
 123     /* We don't want to include the .ctor section from
 124        from the crtend.o file until after the sorted ctors.
 125        The .ctor section from the crtend file contains the
 126        end of ctors marker and it must be last */
 127     KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
 128     KEEP (*(SORT(.ctors.*)))
 129     KEEP (*(.ctors))
 130   }
 131   .dtors          : {
 132     KEEP (*crtbegin.o(.dtors))
 133     KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
 134     KEEP (*(SORT(.dtors.*)))
 135     KEEP (*(.dtors))
 136   }
 137   .jcr            : { KEEP (*(.jcr)) }
 138   .got            : { *(.got.plt) *(.got) }
 139   _edata = .;
 140   PROVIDE (edata = .);
 141   .bss            : {
 142    __bss_start = .;
 143    *(.dynbss)
 144    *(.bss .bss.* .gnu.linkonce.b.*)
 145    *(COMMON)
 146    /* Align here to ensure that the .bss section occupies space up to
 147       _end.  Align after .bss to ensure correct alignment even if the
 148       .bss section disappears because there are no input sections.  */
 149    . = ALIGN(32 / 8);
 150   . = ALIGN(32 / 8);
 151   }
 152   _end = .;
 153   PROVIDE (end = .);
 154
 155   STABS_DEBUG
 156
 157   DWARF_DEBUG
 158 }