git.oblomov.eu Git - linux-2.6/blob - arch/s390/kernel/vdso32/vdso32.lds.S

   1 /*
   2  * This is the infamous ld script for the 32 bits vdso
   3  * library
   4  */
   5 #include <asm/vdso.h>
   6
   7 OUTPUT_FORMAT("elf32-s390", "elf32-s390", "elf32-s390")
   8 OUTPUT_ARCH(s390:31-bit)
   9 ENTRY(_start)
  10
  11 SECTIONS
  12 {
  13         . = VDSO32_LBASE + SIZEOF_HEADERS;
  14
  15         .hash           : { *(.hash) }                  :text
  16         .gnu.hash       : { *(.gnu.hash) }
  17         .dynsym         : { *(.dynsym) }
  18         .dynstr         : { *(.dynstr) }
  19         .gnu.version    : { *(.gnu.version) }
  20         .gnu.version_d  : { *(.gnu.version_d) }
  21         .gnu.version_r  : { *(.gnu.version_r) }
  22
  23         .note           : { *(.note.*) }                :text   :note
  24
  25         . = ALIGN(16);
  26         .text           : {
  27                 *(.text .stub .text.* .gnu.linkonce.t.*)
  28         } :text
  29         PROVIDE(__etext = .);
  30         PROVIDE(_etext = .);
  31         PROVIDE(etext = .);
  32
  33         /*
  34          * Other stuff is appended to the text segment:
  35          */
  36         .rodata         : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  37         .rodata1        : { *(.rodata1) }
  38
  39         .dynamic        : { *(.dynamic) }               :text   :dynamic
  40
  41         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  42         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  43         .gcc_except_table : { *(.gcc_except_table .gcc_except_table.*) }
  44
  45         .rela.dyn ALIGN(8) : { *(.rela.dyn) }
  46         .got ALIGN(8)   : { *(.got .toc) }
  47
  48         _end = .;
  49         PROVIDE(end = .);
  50
  51         /*
  52          * Stabs debugging sections are here too.
  53          */
  54         .stab          0 : { *(.stab) }
  55         .stabstr       0 : { *(.stabstr) }
  56         .stab.excl     0 : { *(.stab.excl) }
  57         .stab.exclstr  0 : { *(.stab.exclstr) }
  58         .stab.index    0 : { *(.stab.index) }
  59         .stab.indexstr 0 : { *(.stab.indexstr) }
  60         .comment       0 : { *(.comment) }
  61
  62         /*
  63          * DWARF debug sections.
  64          * Symbols in the DWARF debugging sections are relative to the
  65          * beginning of the section so we begin them at 0.
  66          */
  67         /* DWARF 1 */
  68         .debug          0 : { *(.debug) }
  69         .line           0 : { *(.line) }
  70         /* GNU DWARF 1 extensions */
  71         .debug_srcinfo  0 : { *(.debug_srcinfo) }
  72         .debug_sfnames  0 : { *(.debug_sfnames) }
  73         /* DWARF 1.1 and DWARF 2 */
  74         .debug_aranges  0 : { *(.debug_aranges) }
  75         .debug_pubnames 0 : { *(.debug_pubnames) }
  76         /* DWARF 2 */
  77         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  78         .debug_abbrev   0 : { *(.debug_abbrev) }
  79         .debug_line     0 : { *(.debug_line) }
  80         .debug_frame    0 : { *(.debug_frame) }
  81         .debug_str      0 : { *(.debug_str) }
  82         .debug_loc      0 : { *(.debug_loc) }
  83         .debug_macinfo  0 : { *(.debug_macinfo) }
  84         /* SGI/MIPS DWARF 2 extensions */
  85         .debug_weaknames 0 : { *(.debug_weaknames) }
  86         .debug_funcnames 0 : { *(.debug_funcnames) }
  87         .debug_typenames 0 : { *(.debug_typenames) }
  88         .debug_varnames  0 : { *(.debug_varnames) }
  89         /* DWARF 3 */
  90         .debug_pubtypes 0 : { *(.debug_pubtypes) }
  91         .debug_ranges   0 : { *(.debug_ranges) }
  92         .gnu.attributes 0 : { KEEP (*(.gnu.attributes)) }
  93
  94         . = ALIGN(4096);
  95         PROVIDE(_vdso_data = .);
  96
  97         /DISCARD/       : {
  98                 *(.note.GNU-stack)
  99                 *(.branch_lt)
 100                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
 101                 *(.bss .sbss .dynbss .dynsbss)
 102         }
 103 }
 104
 105 /*
 106  * Very old versions of ld do not recognize this name token; use the constant.
 107  */
 108 #define PT_GNU_EH_FRAME 0x6474e550
 109
 110 /*
 111  * We must supply the ELF program headers explicitly to get just one
 112  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 113  */
 114 PHDRS
 115 {
 116         text            PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
 117         dynamic         PT_DYNAMIC FLAGS(4);            /* PF_R */
 118         note            PT_NOTE FLAGS(4);               /* PF_R */
 119         eh_frame_hdr    PT_GNU_EH_FRAME;
 120 }
 121
 122 /*
 123  * This controls what symbols we export from the DSO.
 124  */
 125 VERSION
 126 {
 127         VDSO_VERSION_STRING {
 128         global:
 129                 /*
 130                  * Has to be there for the kernel to find
 131                  */
 132                 __kernel_gettimeofday;
 133                 __kernel_clock_gettime;
 134                 __kernel_clock_getres;
 135
 136         local: *;
 137         };
 138 }