git.oblomov.eu Git - linux-2.6/blob - arch/arm26/kernel/vmlinux-arm26-xip.lds.in

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  * borrowed from Russels ARM port by Ian Molton
   5  */
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8
   9 OUTPUT_ARCH(arm)
  10 ENTRY(stext)
  11 jiffies = jiffies_64;
  12 SECTIONS
  13 {
  14         . = TEXTADDR;
  15         .init : {                       /* Init code and data           */
  16                 _stext = .;
  17                 __init_begin = .;
  18                         _sinittext = .;
  19                         *(.init.text)
  20                         _einittext = .;
  21                 __proc_info_begin = .;
  22                         *(.proc.info)
  23                 __proc_info_end = .;
  24                 __arch_info_begin = .;
  25                         *(.arch.info)
  26                 __arch_info_end = .;
  27                 __tagtable_begin = .;
  28                         *(.taglist)
  29                 __tagtable_end = .;
  30                 . = ALIGN(16);
  31                 __setup_start = .;
  32                         *(.init.setup)
  33                 __setup_end = .;
  34                 __early_begin = .;
  35                         *(__early_param)
  36                 __early_end = .;
  37                 __initcall_start = .;
  38                         *(.initcall1.init)
  39                         *(.initcall2.init)
  40                         *(.initcall3.init)
  41                         *(.initcall4.init)
  42                         *(.initcall5.init)
  43                         *(.initcall6.init)
  44                         *(.initcall7.init)
  45                 __initcall_end = .;
  46                 __con_initcall_start = .;
  47                         *(.con_initcall.init)
  48                 __con_initcall_end = .;
  49 #ifdef CONFIG_BLK_DEV_INITRD
  50                 . = ALIGN(32);
  51                 __initramfs_start = .;
  52                         usr/built-in.o(.init.ramfs)
  53                 __initramfs_end = .;
  54 #endif
  55                 . = ALIGN(32768);
  56                 __init_end = .;
  57         }
  58
  59         /DISCARD/ : {                   /* Exit code and data           */
  60                 *(.exit.text)
  61                 *(.exit.data)
  62                 *(.exitcall.exit)
  63         }
  64
  65         .text : {                       /* Real text segment            */
  66                 _text = .;              /* Text and read-only data      */
  67                         TEXT_TEXT
  68                         SCHED_TEXT
  69                         LOCK_TEXT       /* FIXME - borrowed from arm32 - check*/
  70                         *(.fixup)
  71                         *(.gnu.warning)
  72                         *(.rodata)
  73                         *(.rodata.*)
  74                         *(.glue_7)
  75                         *(.glue_7t)
  76                 *(.got)                 /* Global offset table          */
  77
  78                 _etext = .;             /* End of text section          */
  79         }
  80
  81         . = ALIGN(16);
  82         __ex_table : {                  /* Exception table              */
  83                 __start___ex_table = .;
  84                         *(__ex_table)
  85                 __stop___ex_table = .;
  86         }
  87
  88         RODATA
  89
  90         _endtext = .;
  91
  92         . = DATAADDR;
  93
  94         _sdata = .;
  95
  96         .data : {
  97                 . = ALIGN(8192);
  98                 /*
  99                  * first, the init thread union, aligned
 100                  * to an 8192 byte boundary. (see arm26/kernel/init_task.c)
 101                  * FIXME - sould this be 32K aligned on arm26?
 102                  */
 103                 *(.init.task)
 104
 105                 /*
 106                  * The cacheline aligned data
 107                  */
 108                 . = ALIGN(32);
 109                 *(.data.cacheline_aligned)
 110
 111                 /*
 112                  * and the usual data section
 113                  */
 114                 DATA_DATA
 115                 CONSTRUCTORS
 116
 117                 *(.init.data)
 118
 119                 _edata = .;
 120         }
 121
 122         .bss : {
 123                 __bss_start = .;        /* BSS                          */
 124                 *(.bss)
 125                 *(COMMON)
 126                 _end = . ;
 127         }
 128                                         /* Stabs debugging sections.    */
 129         .stab 0 : { *(.stab) }
 130         .stabstr 0 : { *(.stabstr) }
 131         .stab.excl 0 : { *(.stab.excl) }
 132         .stab.exclstr 0 : { *(.stab.exclstr) }
 133         .stab.index 0 : { *(.stab.index) }
 134         .stab.indexstr 0 : { *(.stab.indexstr) }
 135         .comment 0 : { *(.comment) }
 136 }