git.oblomov.eu Git - linux-2.6/blob - arch/powerpc/kernel/cpu_setup_power4.S

   1 /*
   2  * This file contains low level CPU setup functions.
   3  *    Copyright (C) 2003 Benjamin Herrenschmidt (benh@kernel.crashing.org)
   4  *
   5  * This program is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU General Public License
   7  * as published by the Free Software Foundation; either version
   8  * 2 of the License, or (at your option) any later version.
   9  *
  10  */
  11
  12 #include <linux/config.h>
  13 #include <asm/processor.h>
  14 #include <asm/page.h>
  15 #include <asm/cputable.h>
  16 #include <asm/ppc_asm.h>
  17 #include <asm/asm-offsets.h>
  18 #include <asm/cache.h>
  19
  20 _GLOBAL(__970_cpu_preinit)
  21         /*
  22          * Do nothing if not running in HV mode
  23          */
  24         mfmsr   r0
  25         rldicl. r0,r0,4,63
  26         beqlr
  27
  28         /*
  29          * Deal only with PPC970 and PPC970FX.
  30          */
  31         mfspr   r0,SPRN_PVR
  32         srwi    r0,r0,16
  33         cmpwi   r0,0x39
  34         beq     1f
  35         cmpwi   r0,0x3c
  36         beq     1f
  37         cmpwi   r0,0x44
  38         bnelr
  39 1:
  40
  41         /* Make sure HID4:rm_ci is off before MMU is turned off, that large
  42          * pages are enabled with HID4:61 and clear HID5:DCBZ_size and
  43          * HID5:DCBZ32_ill
  44          */
  45         li      r0,0
  46         mfspr   r3,SPRN_HID4
  47         rldimi  r3,r0,40,23     /* clear bit 23 (rm_ci) */
  48         rldimi  r3,r0,2,61      /* clear bit 61 (lg_pg_en) */
  49         sync
  50         mtspr   SPRN_HID4,r3
  51         isync
  52         sync
  53         mfspr   r3,SPRN_HID5
  54         rldimi  r3,r0,6,56      /* clear bits 56 & 57 (DCBZ*) */
  55         sync
  56         mtspr   SPRN_HID5,r3
  57         isync
  58         sync
  59
  60         /* Setup some basic HID1 features */
  61         mfspr   r0,SPRN_HID1
  62         li      r3,0x1200               /* enable i-fetch cacheability */
  63         sldi    r3,r3,44                /* and prefetch */
  64         or      r0,r0,r3
  65         mtspr   SPRN_HID1,r0
  66         mtspr   SPRN_HID1,r0
  67         isync
  68
  69         /* Clear HIOR */
  70         li      r0,0
  71         sync
  72         mtspr   SPRN_HIOR,0             /* Clear interrupt prefix */
  73         isync
  74         blr
  75
  76 _GLOBAL(__setup_cpu_ppc970)
  77         mfspr   r0,SPRN_HID0
  78         li      r11,5                   /* clear DOZE and SLEEP */
  79         rldimi  r0,r11,52,8             /* set NAP and DPM */
  80         mtspr   SPRN_HID0,r0
  81         mfspr   r0,SPRN_HID0
  82         mfspr   r0,SPRN_HID0
  83         mfspr   r0,SPRN_HID0
  84         mfspr   r0,SPRN_HID0
  85         mfspr   r0,SPRN_HID0
  86         mfspr   r0,SPRN_HID0
  87         sync
  88         isync
  89         blr
  90
  91 /* Definitions for the table use to save CPU states */
  92 #define CS_HID0         0
  93 #define CS_HID1         8
  94 #define CS_HID4         16
  95 #define CS_HID5         24
  96 #define CS_SIZE         32
  97
  98         .data
  99         .balign L1_CACHE_BYTES,0
 100 cpu_state_storage:
 101         .space  CS_SIZE
 102         .balign L1_CACHE_BYTES,0
 103         .text
 104
 105 /* Called in normal context to backup CPU 0 state. This
 106  * does not include cache settings. This function is also
 107  * called for machine sleep. This does not include the MMU
 108  * setup, BATs, etc... but rather the "special" registers
 109  * like HID0, HID1, HID4, etc...
 110  */
 111 _GLOBAL(__save_cpu_setup)
 112         /* Some CR fields are volatile, we back it up all */
 113         mfcr    r7
 114
 115         /* Get storage ptr */
 116         LOAD_REG_IMMEDIATE(r5,cpu_state_storage)
 117
 118         /* We only deal with 970 for now */
 119         mfspr   r0,SPRN_PVR
 120         srwi    r0,r0,16
 121         cmpwi   r0,0x39
 122         beq     1f
 123         cmpwi   r0,0x3c
 124         beq     1f
 125         cmpwi   r0,0x44
 126         bne     2f
 127
 128 1:      /* Save HID0,1,4 and 5 */
 129         mfspr   r3,SPRN_HID0
 130         std     r3,CS_HID0(r5)
 131         mfspr   r3,SPRN_HID1
 132         std     r3,CS_HID1(r5)
 133         mfspr   r3,SPRN_HID4
 134         std     r3,CS_HID4(r5)
 135         mfspr   r3,SPRN_HID5
 136         std     r3,CS_HID5(r5)
 137
 138 2:
 139         mtcr    r7
 140         blr
 141
 142 /* Called with no MMU context (typically MSR:IR/DR off) to
 143  * restore CPU state as backed up by the previous
 144  * function. This does not include cache setting
 145  */
 146 _GLOBAL(__restore_cpu_setup)
 147         /* Get storage ptr (FIXME when using anton reloc as we
 148          * are running with translation disabled here
 149          */
 150         LOAD_REG_IMMEDIATE(r5,cpu_state_storage)
 151
 152         /* We only deal with 970 for now */
 153         mfspr   r0,SPRN_PVR
 154         srwi    r0,r0,16
 155         cmpwi   r0,0x39
 156         beq     1f
 157         cmpwi   r0,0x3c
 158         beq     1f
 159         cmpwi   r0,0x44
 160         bnelr
 161
 162 1:      /* Before accessing memory, we make sure rm_ci is clear */
 163         li      r0,0
 164         mfspr   r3,SPRN_HID4
 165         rldimi  r3,r0,40,23     /* clear bit 23 (rm_ci) */
 166         sync
 167         mtspr   SPRN_HID4,r3
 168         isync
 169         sync
 170
 171         /* Clear interrupt prefix */
 172         li      r0,0
 173         sync
 174         mtspr   SPRN_HIOR,0
 175         isync
 176
 177         /* Restore HID0 */
 178         ld      r3,CS_HID0(r5)
 179         sync
 180         isync
 181         mtspr   SPRN_HID0,r3
 182         mfspr   r3,SPRN_HID0
 183         mfspr   r3,SPRN_HID0
 184         mfspr   r3,SPRN_HID0
 185         mfspr   r3,SPRN_HID0
 186         mfspr   r3,SPRN_HID0
 187         mfspr   r3,SPRN_HID0
 188         sync
 189         isync
 190
 191         /* Restore HID1 */
 192         ld      r3,CS_HID1(r5)
 193         sync
 194         isync
 195         mtspr   SPRN_HID1,r3
 196         mtspr   SPRN_HID1,r3
 197         sync
 198         isync
 199
 200         /* Restore HID4 */
 201         ld      r3,CS_HID4(r5)
 202         sync
 203         isync
 204         mtspr   SPRN_HID4,r3
 205         sync
 206         isync
 207
 208         /* Restore HID5 */
 209         ld      r3,CS_HID5(r5)
 210         sync
 211         isync
 212         mtspr   SPRN_HID5,r3
 213         sync
 214         isync
 215         blr
 216