git.oblomov.eu Git - linux-2.6/blob - arch/arm/lib/putuser.S

   1 /*
   2  *  linux/arch/arm/lib/putuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make
  13  * them more efficient, especially as they return an error
  14  * value in addition to the "real" return value.
  15  *
  16  * __put_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  *              r2, r3 contains the value
  20  * Outputs:     r0 is the error code
  21  *              lr corrupted
  22  *
  23  * No other registers must be altered.  (see <asm/uaccess.h>
  24  * for specific ASM register usage).
  25  *
  26  * Note that ADDR_LIMIT is either 0 or 0xc0000000
  27  * Note also that it is intended that __put_user_bad is not global.
  28  */
  29 #include <linux/linkage.h>
  30 #include <asm/errno.h>
  31
  32 ENTRY(__put_user_1)
  33 1:      strbt   r2, [r0]
  34         mov     r0, #0
  35         mov     pc, lr
  36 ENDPROC(__put_user_1)
  37
  38 ENTRY(__put_user_2)
  39         mov     ip, r2, lsr #8
  40 #ifndef __ARMEB__
  41 2:      strbt   r2, [r0], #1
  42 3:      strbt   ip, [r0]
  43 #else
  44 2:      strbt   ip, [r0], #1
  45 3:      strbt   r2, [r0]
  46 #endif
  47         mov     r0, #0
  48         mov     pc, lr
  49 ENDPROC(__put_user_2)
  50
  51 ENTRY(__put_user_4)
  52 4:      strt    r2, [r0]
  53         mov     r0, #0
  54         mov     pc, lr
  55 ENDPROC(__put_user_4)
  56
  57 ENTRY(__put_user_8)
  58 5:      strt    r2, [r0], #4
  59 6:      strt    r3, [r0]
  60         mov     r0, #0
  61         mov     pc, lr
  62 ENDPROC(__put_user_8)
  63
  64 __put_user_bad:
  65         mov     r0, #-EFAULT
  66         mov     pc, lr
  67 ENDPROC(__put_user_bad)
  68
  69 .section __ex_table, "a"
  70         .long   1b, __put_user_bad
  71         .long   2b, __put_user_bad
  72         .long   3b, __put_user_bad
  73         .long   4b, __put_user_bad
  74         .long   5b, __put_user_bad
  75         .long   6b, __put_user_bad
  76 .previous