git.oblomov.eu Git - linux-2.6/blob - arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/thread_info.h>
   8 #include <asm/memory.h>
   9
  10 OUTPUT_ARCH(arm)
  11 ENTRY(stext)
  12
  13 #ifndef __ARMEB__
  14 jiffies = jiffies_64;
  15 #else
  16 jiffies = jiffies_64 + 4;
  17 #endif
  18
  19 SECTIONS
  20 {
  21 #ifdef CONFIG_XIP_KERNEL
  22         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  23 #else
  24         . = PAGE_OFFSET + TEXT_OFFSET;
  25 #endif
  26         .text.head : {
  27                 _stext = .;
  28                 _sinittext = .;
  29                 *(.text.head)
  30         }
  31
  32         .init : {                       /* Init code and data           */
  33                         *(.init.text)
  34                 _einittext = .;
  35                 __proc_info_begin = .;
  36                         *(.proc.info.init)
  37                 __proc_info_end = .;
  38                 __arch_info_begin = .;
  39                         *(.arch.info.init)
  40                 __arch_info_end = .;
  41                 __tagtable_begin = .;
  42                         *(.taglist.init)
  43                 __tagtable_end = .;
  44                 . = ALIGN(16);
  45                 __setup_start = .;
  46                         *(.init.setup)
  47                 __setup_end = .;
  48                 __early_begin = .;
  49                         *(.early_param.init)
  50                 __early_end = .;
  51                 __initcall_start = .;
  52                         INITCALLS
  53                 __initcall_end = .;
  54                 __con_initcall_start = .;
  55                         *(.con_initcall.init)
  56                 __con_initcall_end = .;
  57                 __security_initcall_start = .;
  58                         *(.security_initcall.init)
  59                 __security_initcall_end = .;
  60 #ifdef CONFIG_BLK_DEV_INITRD
  61                 . = ALIGN(32);
  62                 __initramfs_start = .;
  63                         usr/built-in.o(.init.ramfs)
  64                 __initramfs_end = .;
  65 #endif
  66                 . = ALIGN(4096);
  67                 __per_cpu_start = .;
  68                         *(.data.percpu)
  69                         *(.data.percpu.shared_aligned)
  70                 __per_cpu_end = .;
  71 #ifndef CONFIG_XIP_KERNEL
  72                 __init_begin = _stext;
  73                 *(.init.data)
  74                 . = ALIGN(4096);
  75                 __init_end = .;
  76 #endif
  77         }
  78
  79         /DISCARD/ : {                   /* Exit code and data           */
  80                 *(.exit.text)
  81                 *(.exit.data)
  82                 *(.exitcall.exit)
  83 #ifndef CONFIG_MMU
  84                 *(.fixup)
  85                 *(__ex_table)
  86 #endif
  87         }
  88
  89         .text : {                       /* Real text segment            */
  90                 _text = .;              /* Text and read-only data      */
  91                         __exception_text_start = .;
  92                         *(.exception.text)
  93                         __exception_text_end = .;
  94                         TEXT_TEXT
  95                         SCHED_TEXT
  96                         LOCK_TEXT
  97 #ifdef CONFIG_MMU
  98                         *(.fixup)
  99 #endif
 100                         *(.gnu.warning)
 101                         *(.rodata)
 102                         *(.rodata.*)
 103                         *(.glue_7)
 104                         *(.glue_7t)
 105                 *(.got)                 /* Global offset table          */
 106         }
 107
 108         RODATA
 109
 110         _etext = .;                     /* End of text and rodata section */
 111
 112 #ifdef CONFIG_XIP_KERNEL
 113         __data_loc = ALIGN(4);          /* location in binary */
 114         . = PAGE_OFFSET + TEXT_OFFSET;
 115 #else
 116         . = ALIGN(THREAD_SIZE);
 117         __data_loc = .;
 118 #endif
 119
 120         .data : AT(__data_loc) {
 121                 __data_start = .;       /* address in memory */
 122
 123                 /*
 124                  * first, the init task union, aligned
 125                  * to an 8192 byte boundary.
 126                  */
 127                 *(.data.init_task)
 128
 129 #ifdef CONFIG_XIP_KERNEL
 130                 . = ALIGN(4096);
 131                 __init_begin = .;
 132                 *(.init.data)
 133                 . = ALIGN(4096);
 134                 __init_end = .;
 135 #endif
 136
 137                 . = ALIGN(4096);
 138                 __nosave_begin = .;
 139                 *(.data.nosave)
 140                 . = ALIGN(4096);
 141                 __nosave_end = .;
 142
 143                 /*
 144                  * then the cacheline aligned data
 145                  */
 146                 . = ALIGN(32);
 147                 *(.data.cacheline_aligned)
 148
 149                 /*
 150                  * The exception fixup table (might need resorting at runtime)
 151                  */
 152                 . = ALIGN(32);
 153                 __start___ex_table = .;
 154 #ifdef CONFIG_MMU
 155                 *(__ex_table)
 156 #endif
 157                 __stop___ex_table = .;
 158
 159                 /*
 160                  * and the usual data section
 161                  */
 162                 DATA_DATA
 163                 CONSTRUCTORS
 164
 165                 _edata = .;
 166         }
 167         _edata_loc = __data_loc + SIZEOF(.data);
 168
 169         .bss : {
 170                 __bss_start = .;        /* BSS                          */
 171                 *(.bss)
 172                 *(COMMON)
 173                 _end = .;
 174         }
 175                                         /* Stabs debugging sections.    */
 176         .stab 0 : { *(.stab) }
 177         .stabstr 0 : { *(.stabstr) }
 178         .stab.excl 0 : { *(.stab.excl) }
 179         .stab.exclstr 0 : { *(.stab.exclstr) }
 180         .stab.index 0 : { *(.stab.index) }
 181         .stab.indexstr 0 : { *(.stab.indexstr) }
 182         .comment 0 : { *(.comment) }
 183 }
 184
 185 /*
 186  * These must never be empty
 187  * If you have to comment these two assert statements out, your
 188  * binutils is too old (for other reasons as well)
 189  */
 190 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 191 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")